Udžbenik objašnjava što je složena godišnja stopa rasta i kako napraviti jasnu i lako razumljivu CAGR formulu u Excelu.

U jednom od naših prethodnih članaka, otkrili smo snagu složenih kamata i kako ih izračunati u Excelu. Danas ćemo napraviti korak dalje i istražiti različite načine za izračunavanje složene godišnje stope rasta (CAGR).

Jednostavno rečeno, CAGR mjeri povrat ulaganja u određenom vremenskom razdoblju. Strogo govoreći, to nije računovodstveni izraz, ali ga često koriste financijski analitičari, investicijski menadžeri i vlasnici tvrtki kako bi shvatili kako se njihovo poslovanje razvilo ili usporedili rast prihoda konkurentskih tvrtki.

U ovom vodiču, mi nećemo kopati duboko u aritmetiku i usredotočiti se na to kako napisati učinkovitu CAGR formulu u Excelu koja omogućuje izračun složene godišnje stope rasta na temelju 3 primarne ulazne vrijednosti: početne vrijednosti ulaganja, krajnje vrijednosti i vremenskog razdoblja.

Što je složena godišnja stopa rasta?

Složena godišnja stopa rasta (skraćeno CAGR) je financijski izraz koji mjeri srednju godišnju stopu rasta ulaganja tijekom određenog vremenskog razdoblja.

Da bismo bolje razumjeli CAGR logiku, pogledajmo sljedeći primjer. Pretpostavimo da u financijskom izvješću svoje tvrtke vidite sljedeće brojeve:

Nije velika stvar izračunati rast iz godine u godinustopu koristeći uobičajenu formulu povećanja postotka kao što je prikazano na slici ispod:

Ali kako dobiti jedan broj koji pokazuje stopu rasta tijekom 5 godina? Postoje dva načina da se to izračuna - prosječna i složena godišnja stopa rasta. Složena stopa rasta bolja je mjera zbog sljedećih razloga:

• Prosječna godišnja stopa rasta (AAGR) je aritmetička sredina niza stopa rasta, a to je lako izračunati pomoću normalne formule PROSJEČNOG. Međutim, potpuno zanemaruje učinke složenog rasta i stoga se rast ulaganja može precijeniti.
• Skupna godišnja stopa rasta (CAGR) je geometrijski prosjek koji predstavlja stopu povrata za investicije kao da se svake godine povećavaju ravnomjernom stopom. Drugim riječima, CAGR je "izglađena" stopa rasta koja bi, ako se sabere godišnje, bila ekvivalentna onome što je vaše ulaganje postiglo u određenom vremenskom razdoblju.

CAGR formula

Generička CAGR formula koja se koristi u analizi poslovanja, financija i ulaganja je sljedeća:

Gdje:

• BV - početna vrijednost ulaganja
• EV - Krajnja vrijednost ulaganja
• n - Broj razdoblja (kao što su godine, tromjesečja, mjeseci, dani itd.)

Kao što je prikazano u sljedećem snimka zaslona, ​​formule prosjeka i CAGR-a vraćaju različite rezultate:

Da bismo olakšali stvarida biste razumjeli, sljedeća slika pokazuje kako se CAGR izračunava za različita razdoblja u smislu BV, EV i n:

Kako izračunati CAGR u Excelu

Sada kada imate osnovnu ideju o tome što je složena godišnja stopa rasta, da vidimo kako je možete izračunati u svojim Excel radnim listovima. Sve u svemu, postoje 4 načina za stvaranje Excel formule za CAGR.

Formula 1: Izravan način za stvaranje CAGR kalkulatora u Excelu

Poznavanje generičke CAGR formule o kojoj se govori gore, stvaranje CAGR kalkulatora u Excelu je pitanje minuta, ako ne i sekundi. Samo navedite sljedeće vrijednosti u svom radnom listu:

• BV - Početna vrijednost ulaganja
• EV - Završna vrijednost ulaganja
• n - Broj razdoblja

A zatim unesite CAGR formulu u praznu ćeliju:

U ovom primjeru, BV nalazi se u ćeliji B1, EV u ćeliji B2, a n u ćeliji B3. Dakle, unosimo sljedeću formulu u B5:

=(B2/B1)^(1/B3)-1

Ako imate sve vrijednosti ulaganja navedene u nekom stupcu, tada možete dodati stupanj fleksibilnost vaše CAGR formule i neka automatski izračuna broj razdoblja.

Za izračun CAGR-a u našem oglednom radnom listu, formula je sljedeća:

=(B7/B2)^(1/(ROW(B7)-ROW(B2)))-1

Savjet. Ako se izlazna vrijednost prikazuje kao decimalni broj, primijeniteFormat postotka u ćeliju formule.

CAGR formula 2: RRI funkcija

Najlakši način za izračunavanje složene godišnje stope rasta u Excelu je pomoću funkcije RRI, koja je osmišljena za vraćanje ekvivalentne kamatne stope na zajam ili investiciju u odnosu na određenu razdoblje na temelju sadašnje vrijednosti, buduće vrijednosti i ukupnog broja razdoblja:

Gdje je:

• Nper ukupan broj razdoblja.
• Pv je sadašnja vrijednost ulaganja.
• Fv je buduća vrijednost ulaganja.

S nper u B4, pv u B2 i fv u B3, formula ima ovaj oblik:

=RRI(B4, B2, B3)

CAGR formula 3: funkcija POWER

Još jedan brz i jednostavan način za izračunavanje CAGR-a u Excelu je korištenje funkcije POWER koja vraća rezultat broja podignut na određenu potenciju.

Sintaksa funkcije POWER je sljedeća:

gdje je broj osnovni broj, a potencija je eksponent za podizanje osnovnog broja do.

Da biste napravili Excel CAGR kalkulator temeljen na funkciji POWER, definirajte argumente na ovaj način:

• Broj - završna vrijednost (EV) / početna vrijednost (BV)
• Snaga - 1/broj razdoblja (n)

I ovdje je naša SNAŽNA CAGR formula na djelu:

=POWER(B7/B2,1/5)-1

Kao u prvom primjeru, možeteimaju ROW funkciju za izračunavanje broja razdoblja za vas:

=POWER(B7/B2,1/(ROW(B7)-ROW(B2)))-1

CAGR formula 4: RATE funkcija

Još jedna metoda za izračunavanje CAGR u Excelu je korištenje RATE funkcija koja vraća kamatnu stopu po razdoblju anuiteta.

Na prvi pogled, sintaksa funkcije RATE izgleda malo komplicirano, ali kada shvatite argumente, možda će vam se svidjeti ovaj način izračunavanja CAGR-a u Excelu.

• Nper - ukupan broj uplata za anuitet, tj. broj razdoblja tijekom kojih treba platiti zajam ili investiciju. Obavezno.
• Pmt - iznos uplate za svako razdoblje. Ako je izostavljen, mora se navesti argument fv.
• Pv - sadašnja vrijednost ulaganja. Obavezno.
• Fv - buduća vrijednost ulaganja na kraju nper plaćanja. Ako je izostavljena, formula preuzima zadanu vrijednost 0.
• Vrsta - opcijska vrijednost koja označava dospijeće plaćanja:
  • 0 (zadano) - plaćanja su dospijevaju na kraju razdoblja.
  • 1 - plaćanja dospijevaju na početku razdoblja.
• Pogodite - vaša pretpostavka za što stopa bi mogla biti. Ako je izostavljeno, pretpostavlja se da je 10%.

Da biste funkciju RATE pretvorili u formulu za izračun CAGR-a, trebate unijeti 1. (nper), 3. (pv) i 4. (fv) argumente na ovaj način:

Podsjetit ću vas da je:

• BV početna vrijednost ulaganja
• EV je završna vrijednost ulaganja
• n je broj razdoblja

Napomena. Obavezno navedite početnu vrijednost (BV) kao negativan broj , inače bi vaša CAGR formula vratila #NUM! greška.

Za izračunavanje složene stope rasta u ovom primjeru, formula je sljedeća:

=RATE(5,,-B2,B7)

Kako biste se poštedjeli muke ručnog izračunavanja broja razdoblja, možete imati ROW izračunava za vas:

=RATE(ROW(B7)-ROW(B2),,-B2,B7)

CAGR formula 5: IRR funkcija

IRR funkcija u Excelu vraća internu stopu povrat za niz novčanih tokova koji se javljaju u redovitim vremenskim intervalima (tj. danima, mjesecima, kvartalima, godinama itd.). Ima sljedeću sintaksu:

Gdje:

• Vrijednosti - raspon brojeva koji predstavljaju novčane tokove. Raspon mora sadržavati barem jednu negativnu i barem jednu pozitivnu vrijednost.
• [Pogodi] - izborni argument koji predstavlja vašu pretpostavku o tome koja bi stopa povrata mogla biti. Ako je izostavljeno, uzima se zadana vrijednost od 10%.

Budući da Excel IRR funkcija nije baš dizajnirana za izračunavanje složene stope rasta, morali biste preoblikovati izvorne podatke na ovaj način:

• Početnu vrijednost investicije treba unijeti kao anegativan broj.
• Krajnja vrijednost ulaganja je pozitivan broj.
• Sve međuvrijednosti su nule.

Jednom vaši izvorni podaci su reorganizirani, možete izračunati CAGR ovom jednostavnom formulom:

=IRR(B2:B7)

Gdje je B2 početna vrijednost, a B7 krajnja vrijednost ulaganja:

Pa, ovako možete izračunati CAGR u Excelu. Ako ste pozorno pratili primjere, mogli ste primijetiti da sve 4 formule vraćaju identičan rezultat - 17,61%. Za bolje razumijevanje i vjerojatno obrnuti inženjering formula, dobrodošli ste preuzeti primjer radne tablice u nastavku. Zahvaljujem vam na čitanju i nadam se da se vidimo na našem blogu sljedeći tjedan!

Radna knjiga za vježbe za preuzimanje

Formule za izračun CAGR (.xlsx datoteka)