Udžbenik objašnjava sintaksu i osnovnu upotrebu funkcije CHOOSE i pruža nekoliko netrivijalnih primjera koji pokazuju kako koristiti formulu CHOOSE u programu Excel.

CHOOSE je jedan od onih Funkcije programa Excel koje same po sebi možda ne izgledaju korisne, ali u kombinaciji s drugim funkcijama daju niz nevjerojatnih prednosti. Na najosnovnijoj razini, koristite funkciju CHOOSE da dobijete vrijednost s popisa određivanjem položaja te vrijednosti. Dalje u ovom vodiču pronaći ćete nekoliko naprednih upotreba koje svakako vrijedi istražiti.

Funkcija CHOOSE programa Excel - sintaksa i osnovne upotrebe

Funkcija CHOOSE u programu Excel je dizajniran za vraćanje vrijednosti s popisa na temelju određene pozicije.

Funkcija je dostupna u programima Excel 365, Excel 2019, Excel 2016, Excel 2013, Excel 2010 i Excel 2007.

Sintaksa funkcije CHOOSE je sljedeća:

Gdje:

Index_num (obavezno) - položaj vrijednosti za vraćanje. To može biti bilo koji broj između 1 i 254, referenca na ćeliju ili neka druga formula.

Vrijednost1, vrijednost2, … - popis od najviše 254 vrijednosti za odabir. Vrijednost1 je obavezna, ostale vrijednosti nisu obavezne. To mogu biti brojevi, tekstualne vrijednosti, reference na ćelije, formule ili definirana imena.

Ovo je primjer formule CHOOSE u najjednostavnijem obliku:

=CHOOSE(3, "Mike", "Sally", "Amy", "Neal")

Formula vraća "Amy" jer index_num je 3, a "Amy" je treća vrijednost na popisu:

Excel funkcija CHOOSE - 3 stvari koje treba zapamtiti!

CHOOSE je vrlo jednostavna funkcija i teško da ćete naići na poteškoće pri implementaciji iste u svoje radne listove. Ako je rezultat koji vraća vaša formula CHOOSE neočekivan ili nije rezultat koji ste tražili, to može biti zbog sljedećih razloga:

1. Broj vrijednosti za odabir ograničen je na 254.
2. Ako je index_num manji od 1 ili veći od broja vrijednosti na popisu, #VALUE! vraća se pogreška.
3. Ako je argument index_num razlomak, on se skraćuje na najmanji cijeli broj.

Kako koristiti funkciju CHOOSE u Excelu - formula primjeri

Sljedeći primjeri pokazuju kako CHOOSE može proširiti mogućnosti drugih Excel funkcija i pružiti alternativna rješenja za neke uobičajene zadatke, čak i za one koje mnogi smatraju neizvedivim.

Excel CHOOSE umjesto ugniježđeni IF-ovi

Jedan od najčešćih zadataka u Excelu je vraćanje različitih vrijednosti na temelju određenog uvjeta. U većini slučajeva to se može učiniti korištenjem klasične ugniježđene IF naredbe. Ali funkcija CHOOSE može biti brza i lako razumljiva alternativa.

Primjer 1. Vraćanje različitih vrijednosti na temelju uvjeta

Pretpostavimo da imate stupac učeničkih rezultata i želite označiti ocjene temeljene nasljedeći uvjeti:

Jedan od načina da to učinite je ugniježditi nekoliko IF formula jednu u drugu:

=IF(B2>=151, "Excellent", IF(B2>=101, "Good", IF(B2>=51, "Satisfactory", "Poor")))

Drugi način je odabrati oznaku koja odgovara stanju:

=CHOOSE((B2>0) + (B2>=51) + (B2>=101) + (B2>=151), "Poor", "Satisfactory", "Good", "Excellent")

Kako ova formula radi:

U argumentu index_num procjenjujete svaki uvjet i vraćate TRUE ako je uvjet zadovoljen, FALSE u suprotnom. Na primjer, vrijednost u ćeliji B2 ispunjava prva tri uvjeta, tako da dobivamo ovaj međurezultat:

=CHOOSE(TRUE + TRUE + TRUE + FALSE, "Poor", "Satisfactory", "Good", "Excellent")

S obzirom da je u većini Excel formula TOČNO jednako 1, a NETOČNO 0, naš formula prolazi ovu transformaciju:

=CHOOSE(1 + 1 + 1 + 0, "Poor", "Satisfactory", "Good", "Excellent")

Nakon što je operacija zbrajanja izvršena, imamo:

=CHOOSE(3, "Poor", "Satisfactory", "Good", "Excellent")

Kao rezultat, 3. vrijednost u vraćena je lista, što je "Dobro".

Savjeti:

• Kako biste formulu učinili fleksibilnijom, možete koristiti reference ćelija umjesto tvrdo kodiranih oznaka, na primjer:

  =CHOOSE((B2>0) + (B2>=51) + (B2>=101) + (B2>=151), $E$1, $E$2, $E$3, $E$4)

• Ako niti jedan od vaših uvjeta nije TRUE, argument index_num bit će postavljen na 0 prisiljavajući vašu formulu da vrati #VALUE! greška. Da biste to izbjegli, jednostavno zamotajte CHOOSE u funkciju IFERROR ovako:

  =IFERROR(CHOOSE((B2>0) + (B2>=51) + (B2>=101) + (B2>=151), "Poor", "Satisfactory", "Good", "Excellent"), "")

Primjer 2. Izvedite različite izračune na temelju uvjeta

Na sličan način, vasmože koristiti Excelovu funkciju CHOOSE za izvođenje jednog izračuna u nizu mogućih izračuna/formula bez ugniježđivanja više IF naredbi jedne u drugu.

Kao primjer, izračunajmo proviziju svakog prodavača ovisno o njihovoj prodaji:

S iznosom prodaje u B2, formula ima sljedeći oblik:

=CHOOSE((B2>0) + (B2>=51) + (B2>=101), B2*5%, B2*7%, B2*10%)

Umjesto čvrstog kodiranja postotaka u formuli, možete se pozvati na odgovarajuću ćeliju u referentnoj tablici, ako postoji. Samo ne zaboravite popraviti reference pomoću znaka $.

=CHOOSE((B2>0) + (B2>=51) + (B2>=101), B2*$E$2, B2*$E$3, B2*$E$4)

Excel IZABERITE formulu za generiranje nasumičnih podataka

Kao što vjerojatno znate, Microsoft Excel ima posebnu funkciju za generiranje nasumični cijeli brojevi između donjeg i gornjeg broja koje navedete - funkcija RANDBETWEEN. Ugniježdite ga u index_num argument CHOOSE i vaša će formula generirati gotovo sve nasumične podatke koje želite.

Na primjer, ova formula može dati popis nasumičnih rezultata ispita:

=CHOOSE(RANDBETWEEN(1,4), "Poor", "Satisfactory", "Good", "Excellent")

Logika formule je očita: RANDBETWEEN generira nasumične brojeve od 1 do 4, a CHOOSE vraća odgovarajuću vrijednost s unaprijed definiranog popisa od četiri vrijednosti.

Napomena. RANDBETWEEN je nepostojana funkcija i ponovno izračunava sa svakimpromjene koje napravite na radnom listu. Kao rezultat toga, vaš popis nasumičnih vrijednosti također će se promijeniti. Kako biste spriječili da se to dogodi, možete zamijeniti formule njihovim vrijednostima pomoću značajke Posebno lijepljenje .

ODABERITE formulu da biste napravili lijevi Vlookup

Ako ste ikada izvodili okomito pretraživanje u Excelu, znate da funkcija VLOOKUP može pretraživati ​​samo u krajnjem lijevom stupcu. U situacijama kada trebate vratiti vrijednost lijevo od stupca pretraživanja, možete upotrijebiti kombinaciju INDEX / MATCH ili prevariti VLOOKUP ugniježđivanjem funkcije CHOOSE u njega. Evo kako:

Pretpostavimo da imate popis rezultata u stupcu A, imena učenika u stupcu B i želite dohvatiti rezultat određenog učenika. Budući da se povratni stupac nalazi lijevo od stupca pretraživanja, redovita Vlookup formula vraća pogrešku #N/A:

Da biste to popravili, zamijenite funkciju CHOOSE položaje stupaca, govoreći Excelu da je stupac 1 B, a stupac 2 A:

=CHOOSE({1,2}, B2:B5, A2:A5)

Zato što dostavljamo niz od {1,2} u index_num argument, funkcija CHOOSE prihvaća raspone u argumentima value (obično ne).

Sada, ugradite gornju formulu u argument table_array od VLOOKUP:

=VLOOKUP(E1,CHOOSE({1,2}, B2:B5, A2:A5),2,FALSE)

I voilà - pretraživanje ulijevo se izvodi bez problema!

ODABERITE formulu za vraćanje sljedeće radne dan

Ako niste sigurni da litrebali biste sutra ići na posao ili možete ostati kod kuće i uživati ​​u zasluženom vikendu, funkcija Excel CHOOSE može saznati kada je sljedeći radni dan.

Pod pretpostavkom da su vaši radni dani od ponedjeljka do petka, formula ide kako slijedi:

=TODAY()+CHOOSE(WEEKDAY(TODAY()),1,1,1,1,1,3,2)

Zamršeno na prvi pogled, nakon detaljnijeg pogleda logiku formule lako je pratiti:

DAN U TJEDNU (DANAS()) vraća serijski broj koji odgovara današnjem datumu, u rasponu od 1 (nedjelja) do 7 (subota). Ovaj broj ide u argument index_num naše formule CHOOSE.

Vrijednost1 - vrijednost7 (1,1,1,1,1, 3,2) odredite koliko dana dodati trenutnom datumu. Ako je danas nedjelja - četvrtak (index_num 1 - 5), dodajete 1 za povratak sljedeći dan. Ako je danas petak (index_num 6), dodajete 3 da biste vratili sljedeći ponedjeljak. Ako je danas subota (index_num 7), dodajete 2 da ponovno vratite sljedeći ponedjeljak. Da, tako je jednostavno :)

ODABIRITE formulu za vraćanje prilagođenog naziva dana/mjeseca od datuma

U situacijama kada želite dobiti naziv dana u standardnom formatu kao što je puno ime ( Ponedjeljak, utorak itd.) ili kratki naziv (pon, uto itd.), možete koristiti funkciju TEKST kao što je objašnjeno u ovom primjeru: Dobijte dan u tjednu iz datuma u Excelu.

Ako želite vrati dan u tjednu ili naziv mjeseca u prilagođenom formatu, upotrijebite funkciju CHOOSE na sljedeći način.

Da biste dobili dan u tjednu:

=CHOOSE(WEEKDAY(A2),"Su","Mo","Tu","We","Th","Fr","Sa")

Da biste dobili amjesec:

=CHOOSE(MONTH(A2), "Jan","Feb","Mar","Apr","May","Jun","Jul","Aug","Sep","Oct","Nov","Dec")

Gdje je A2 ćelija koja sadrži izvorni datum.

Nadam se da vam je ovaj vodič dao neke ideje o kako možete koristiti funkciju CHOOSE u Excelu za poboljšanje svojih podatkovnih modela. Zahvaljujem vam na čitanju i nadam se da se vidimo na našem blogu sljedeći tjedan!

Preuzmite radnu bilježnicu

Excel ODABERITE primjere funkcija