Осы оқулықта Excel бағдарламасында қолжетімді тренд сызығының барлық опцияларының толық сипаттамасын және оларды қашан пайдалану керектігін табасыз. Сондай-ақ диаграммада тренд сызығының теңдеуін көрсетуді және тренд сызығының еңісін табуды үйренесіз.

Excel бағдарламасында тренд сызығын қосу өте оңай. Жалғыз нақты мәселе - талдап жатқан деректер түріне ең жақсы сәйкес келетін тренд сызығының түрін таңдау. Бұл оқулықта сіз Excel бағдарламасында қолжетімді тренд сызығының барлық опцияларының толық сипаттамасын және оларды қашан пайдалану керектігін таба аласыз. Егер сіз Excel диаграммасына тренд сызығын кірістіру жолын іздесеңіз, жоғарыдағы байланысты оқулықты қараңыз.

Excel тренд сызығының түрлері

Excel бағдарламасында тренд сызығын қосқанда , сізде таңдауға болатын 6 түрлі опция бар. Сонымен қатар, Microsoft Excel бағдарламасы тренд сызығының теңдеуі мен R-квадрат мәнін диаграммада көрсетуге мүмкіндік береді:

• Тренд сызығының теңдеуі – деректер нүктелеріне ең жақсы сәйкес келетін сызықты табатын формула.
• R-шаршы мәні тренд сызығының сенімділігін өлшейді - R2 1-ге жақынырақ болса, тренд сызығы деректерге соғұрлым жақсы сәйкес келеді.

Төменде диаграмма мысалдарымен әрбір тренд сызығының түрінің қысқаша сипаттамасын табасыз.

Сызықтық тренд сызығы

Сызықтық тренд сызығы болған дұрыс диаграммадағы деректер нүктелері түзу сызыққа ұқсайтын кезде сызықтық деректер жиынымен пайдаланылады. Әдетте, сызықтық тренд сызығы үздіксіз көтерілуді немесе төмендеуін сипаттайдыуақыт өте келе.

Мысалы, келесі сызықтық тренд сызығы 6 ай ішінде сатылымның тұрақты өсуін көрсетеді. Ал 0,9855 R2 мәні болжанған тренд сызығының мәндерінің нақты деректерге өте жақсы сәйкестігін көрсетеді.

Экспоненциалды тренд сызығы

Экспоненциалды тренд сызығы өсу жылдамдығымен деректер мәндерінің өсуін немесе төмендеуін бейнелейтін қисық сызық болып табылады, сондықтан сызық әдетте бір жағында көбірек қисық болады. Бұл тренд сызығының түрі ғылымда жиі пайдаланылады, мысалы, адам популяциясының өсуін немесе жабайы табиғат популяциясының азаюын визуализациялау үшін.

Нөл немесе теріс мәндерден тұратын деректер үшін экспоненциалды тренд сызығын жасау мүмкін емес екенін ескеріңіз.

Экспоненциалды қисық сызығының жақсы мысалы - жердегі барлық жабайы жолбарыс популяциясының ыдырауы.

Логарифмдік тренд сызығы

Логарифмдік ең жақсы сәйкес сызық әдетте тез өсетін немесе азаятын, содан кейін деңгейлері өшірілетін деректерді сызу үшін пайдаланылады. Ол оң мәндерді де, теріс мәндерді де қамтуы мүмкін.

Логарифмдік тренд сызығының мысалы ретінде алдымен жоғарылайтын, бірақ біраз уақыттан кейін тұрақтанатын инфляция қарқыны болуы мүмкін.

Көпмүшелік тренд сызығы

Көпмүшенің қисық сызықты тренд сызығы тербелмелі мәндері бар үлкен деректер жиындары үшін жақсы жұмыс істейді, оларда бірден көп көтерілу және төмендеу бар.

Жалпы, көпмүше келесі бойынша жіктеледі. ең үлкен көрсеткіш дәрежесі. Көпмүшелік тренд сызығының дәрежесі мүмкінграфиктегі иілу санымен де анықталады. Әдетте квадраттық көпмүшелік тренд сызығының бір иілісі (төбе немесе аңғар), текше көпмүшенің 1 немесе 2 иілімі, ал төртмүшенің көпмүшесінің 3 иілуі болады.

Excel диаграммасында көпмүшелік тренд сызығын қосқанда, әдепкі бойынша 2 болатын Тренд сызығы пішімі тақтасындағы Тәртіп өрісіне сәйкес санды теру арқылы дәрежені көрсетесіз:

Мысалы, квадраттық көпмүшелік тренд пайда мен өнімнің нарықта болған жылдар саны арасындағы қатынасты көрсететін келесі графикте анық көрінеді: басында көтерілу, ортасында шыңы және аяғында құлдырау.

Қуат тренд сызығы

Қуат тренд сызығы экспоненциалды қисыққа өте ұқсас, тек оның симметриялы доғасы бар. Ол әдетте белгілі бір жылдамдықпен өсетін өлшемдерді сызу үшін қолданылады.

Нөл немесе теріс мәндерден тұратын Excel диаграммасына қуат тренд сызығын қосу мүмкін емес.

Мысал ретінде сурет салайық. химиялық реакция жылдамдығын визуализациялау үшін қуат тренд сызығы. 0,9918 R-квадрат мәніне назар аударыңыз, бұл біздің тренд сызығының деректерге дерлік сәйкес келетінін білдіреді.

Орташа жылжымалы тренд сызығы

Диаграммадағы деректер нүктелерінде көптеген көтерілулер мен төмендеулер болған кезде, жылжымалы орташа тренд сызығы үлгіні анық көрсету үшін деректер мәндеріндегі төтенше ауытқуларды тегістей алады. Ол үшін Excel есептейдісіз көрсеткен кезең санының жылжымалы орташа мәні (әдепкі бойынша 2) және сол орташа мәндерді жолға нүктелер ретінде қояды. Кезең мәні неғұрлым жоғары болса, сызық соғұрлым тегіс болады.

Жақсы практикалық мысал - акция бағасының ауытқуын анықтау үшін жылжымалы орташа тренд сызығын пайдалану, әйтпесе байқау қиын болады.

Қосымша ақпарат алу үшін мынаны қараңыз: Excel диаграммасына жылжымалы орташа тренд сызығын қосу жолы.

Excel тренд сызығының теңдеулері мен формулалары

Бұл бөлім Excel бағдарламасы пайдаланатын теңдеулерді сипаттайды. әртүрлі тренд сызығының түрлері үшін. Бұл формулаларды қолмен құрастырудың қажеті жоқ, жай ғана Excel бағдарламасына тренд сызығының теңдеуін диаграммада көрсетуін айтыңыз.

Сонымен қатар біз тренд сызығының көлбеуін және басқа коэффициенттерді табу формуласын талқылаймыз. Формулалар айнымалылардың 2 жиыны бар деп есептейді: тәуелсіз айнымалы x және тәуелді айнымалы y . Жұмыс парақтарыңызда осы формулаларды x кез келген берілген мәндері үшін болжанған y мәндерін алу үшін пайдалана аласыз.

Дәйектілік үшін біз бірдей деректерді пайдаланамыз. барлық мысалдар үшін шамалы өзгеретін мәндермен орнатыңыз. Дегенмен, бұл тек демонстрациялық мақсатта екенін есте сақтаңыз. Нақты жұмыс парақтарыңызда деректер түріне сәйкес тренд сызығының түрін таңдауыңыз керек.

Маңызды ескерту! Тренд сызығының формулаларын тек XY шашыраңқы диаграммаларымен пайдалану керек, себебі тек осыдиаграмма x және y осьтерінің екеуін де сандық мәндер ретінде көрсетеді. Қосымша ақпаратты Excel тренд сызығының теңдеуі неге дұрыс емес болуы мүмкін бөлімін қараңыз.

Сызықтық тренд сызығының теңдеуі және формулалары

Сызықтық тренд сызығының теңдеуі көлбеу іздеу үшін ең кіші квадраттар әдістерін пайдаланады. және кесінді коэффициенттері мынандай:

y = bx + a

Мұндағы:

• b - еңіс тренд сызығының.
• a - y-кесінді , ол барлық x<кезінде y күтілетін орташа мәні болып табылады. 2> айнымалылар 0-ге тең. Диаграммада бұл тренд сызығының y осін қиып өтетін нүктесі.

Сызықтық регрессия үшін Microsoft Excel бағдарламасы келесі мәндерді алу үшін арнайы функцияларды қамтамасыз етеді. көлбеу және кесінді коэффициенттері.

Тренд сызығының еңісі

b: =SLOPE(y,x)

Y-кесінді

a: =INTERCEPT(y,x)

x диапазоны B2:B13 және y ауқымы C2:C13 деп есептесек, нақты өмірлік формулалар келесідей болады:

=SLOPE(C2:C13, B2:B13)

=INTERCEPT(C2:C13,B2:B13)

Дәл осындай нәтижелерге LINEST функциясын массив формуласы ретінде пайдалану арқылы қол жеткізуге болады. Ол үшін бір қатардағы 2 көрші ұяшықты таңдап, формуланы енгізіп, оны аяқтау үшін Ctrl + Shift + Enter пернелерін басыңыз:

=LINEST(C2:C13,B2:B13)

Төмендегі скриншотта көрсетілгендей, көлбеу және кесінді формулалар арқылы қайтарылған коэффициенттер диаграммада көрсетілген сызықтық тренд сызығы теңдеуіндегі коэффициенттерге толық сәйкес келеді, тек соңғысы 4 ондық таңбаға дейін дөңгелектенеді:

Көрсеткіштік тренд сызығының теңдеуі және формулалары

Экспоненциалды тренд сызығы үшін Excel келесі теңдеуді пайдаланады:

y = aebx

Мұндағы a және b - есептелген коэффициенттер және e - математикалық тұрақты e (табиғи логарифмнің негізі).

Коэффициенттерді мына жалпы формулалар арқылы есептеуге болады:

a: =EXP(INDEX(LINEST(LN(y), x), 1, 2))

b: =INDEX(LINEST(LN(y), x), 1)

Біздің үлгі деректер жиыны үшін формулалар келесі пішінді алады:

a: =EXP(INDEX(LINEST(LN(C2:C13), B2:B13), 1, 2))

b: =INDEX(LINEST(LN(C2:C13), B2:B13), 1)

Логарифмдік тренд сызығының теңдеуі және формулалары

Міне, Excel бағдарламасындағы логарифмдік тренд сызығының теңдеуі:

y = a*ln(x)+b

Мұндағы a және b - тұрақтылар және ln - натурал логарифм функциясы.

Тұрақтыларды алу үшін соңғы аргументте ғана ерекшеленетін осы жалпы формулаларды пайдаланыңыз:

a: =INDEX(LINEST(y, LN(x)), 1)

b: =INDEX(LINEST(y, LN(x)), 1, 2)

Үлгі деректер жинағы үшін біз мыналарды қолданамыз:

a: =INDEX(LINEST(C2:C13, LN(B2:B13)), 1)

b: =INDEX(LINEST(C2:C13, LN(B2:B13)), 1, 2)

Көпмүшелік тренд сызығының теңдеуі және формулалары

Полиномдық тренд сызығын өңдеу үшін Excel мына теңдеуді пайдаланады:

y = b ₆ x6 + … + b ₂ x2 + b ₁ x + a

Мұндағы b ₁ … b ₆ және a тұрақты мәндер.

Полиномдық тренд сызығының дәрежесіне байланысты келесі формулалар жиынының бірін пайдаланыңыз. тұрақтыларды алу үшін.

Квадраттық (2-ші ретті) көпмүшелік тренд сызығы

Теңдеу: y = b ₂ x2+ b ₁ x + a

b ₂ : =INDEX(LINEST(y, x^{1,2}), 1)

b ₁ : =INDEX(LINEST(y, x^{1,2}), 1, 2)

a: =INDEX(LINEST(y, x^{1,2}), 1, 3)

Кубтық (3-ші ретті) көпмүшелік тренд сызығы

Теңдеу: y = b ₃ x3 + b ₂ x2+ b ₁ x + a

b ₃ : =INDEX(LINEST(y, x^{1,2,3}), 1)

b ₂ : =INDEX(LINEST(y, x^{1,2,3}), 1, 2)

b ₁ : =INDEX(LINEST(y, x^{1,2,3}), 1, 3)

a: =INDEX(LINEST(y, x^{1,2,3}), 1, 4)

Жоғары дәрежелі көпмүшелік тренд сызығына арналған формулаларды бірдей үлгіні пайдалану арқылы құруға болады.

Біздің деректер жиынымыз үшін 2-ші ретті көпмүшелік тренд сызығы жиынтығы жақсырақ, сондықтан біз мына формулаларды қолданамыз:

b ₂ : =INDEX(LINEST(C2:C13, B2:B13^{1,2}), 1)

b ₁ : =INDEX(LINEST(C2:C13, B2:B13^{1,2}), 1, 2)

a: =INDEX(LINEST(C2:C13, B2:B13^{1,2}), 1, 3)

Қуат тренд сызығының теңдеуі және формулалары

Excel бағдарламасындағы қуат тренд сызығы мына қарапайым теңдеуге негізделген:

y = axb

Мұндағы a және b - тұрақты мәндер, оларды мына формулалармен есептеуге болады:

a: =EXP(INDEX(LINEST(LN(y), LN(x),,), 1, 2))

b: =INDEX(LINEST(LN(y), LN(x),,), 1)

Біздің жағдайда келесі формулалар жұмыс істейді. :

a: =EXP(INDEX(LINEST(LN(C2:C13), LN(B2:B13),,), 1, 2))

b: =INDEX(LINEST(LN(C2:C13), LN(B2:B13),,), 1)

Excel тренд сызығының теңдеуі дұрыс емес - себептері мен түзетулері

Егер Excel тренд сызығын қате сызды деп ойласаңыз немесе диаграммаңызда көрсетілген тренд сызығының формуласы дұрыс емес болса, келесі екі нүкте аздап кетуі мүмкін жағдайға жарық.

Excel тренд сызығының теңдеуі шашыраңқы диаграммаларда ғана дұрыс

Excel тренд сызығының формулалары тек XY (шашырау) графиктерімен пайдаланылуы керек, себебі тек осы диаграммада у осінің екеуін де теріңіз. және х осі сандық мәндер ретінде сызылады.

Сызықтық диаграммаларда, бағандар мен бағаналық графиктерде сандық мәндер тек у осінде кескінделеді. x осі сызықтық қатармен берілген (1, 2,3,…) ось белгілерінің сандар немесе мәтін екендігіне қарамастан. Осы диаграммаларда тренд сызығын жасаған кезде, Excel бағдарламасы тренд сызығының формуласында сол болжанған x мәндерін пайдаланады.

Сандар Excel тренд сызығының теңдеуінде дөңгелектенеді

Диаграммада аз орын алу үшін Excel көрсетеді тренд сызығы теңдеуіндегі өте аз маңызды сандар. Дизайн жағынан жақсы, ол теңдеудегі x мәндерін қолмен бергенде формуланың дәлдігін айтарлықтай төмендетеді.

Оңай түзету - теңдеуде ондық бөлшектерді көбірек көрсету. Немесе, тренд сызығының түріне сәйкес формуланы пайдалану арқылы коэффициенттерді есептеп, формула ұяшықтарын ондық орындардың жеткілікті санын көрсететіндей пішімдеуге болады. Ол үшін жай ғана Сан тобындағы Үй қойындысындағы Ондықты көбейту түймесін басыңыз.

Осылайша тренд сызығының әртүрлі түрлерін жасауға болады. Excel бағдарламасында және олардың теңдеулерін алыңыз. Оқығаныңыз үшін алғыс айтамын және келесі аптада блогымызда көреміз деп үміттенемін!