В этом уроке вы найдете подробное описание всех вариантов линии тренда, доступных в Excel, и когда их следует использовать. Вы также узнаете, как отобразить уравнение линии тренда на графике и найти наклон линии тренда.

Добавить линию тренда в Excel очень просто. Единственная реальная проблема - выбрать тип линии тренда, который лучше всего соответствует типу данных, которые вы анализируете. В этом руководстве вы найдете подробное описание всех вариантов линии тренда, доступных в Excel, и когда их следует использовать. Если вы ищете, как вставить линию тренда в диаграмму Excel, ознакомьтесь с приведенным выше руководством по ссылке.

Типы линий тренда в Excel

При добавлении линии тренда в Excel у вас есть 6 различных вариантов на выбор. Кроме того, Microsoft Excel позволяет отображать уравнение линии тренда и значение R-квадрат на диаграмме:

• Уравнение линии тренда это формула, которая находит линию, наилучшим образом соответствующую точкам данных.
• Значение R-квадрата измеряет надежность линии тренда - чем ближе R2 к 1, тем лучше линия тренда соответствует данным.

Ниже приведено краткое описание каждого типа трендовой линии с примерами графиков.

Линейная линия тренда

Линию линейного тренда лучше всего использовать с линейными наборами данных, когда точки данных на графике похожи на прямую линию. Как правило, линия линейного тренда описывает непрерывный рост или падение с течением времени.

Например, следующая линейная линия тренда показывает устойчивый рост продаж в течение 6 месяцев. А значение R2, равное 0,9855, указывает на довольно хорошее соответствие расчетных значений линии тренда фактическим данным.

Экспоненциальная линия тренда

Экспоненциальная линия тренда - это изогнутая линия, которая иллюстрирует рост или падение значений данных с возрастающей скоростью, поэтому линия обычно более изогнута с одной стороны. Этот тип линии тренда часто используется в науке, например, для визуализации роста численности населения или сокращения популяций диких животных.

Обратите внимание, что экспоненциальная линия тренда не может быть создана для данных, содержащих нули или отрицательные значения.

Хорошим примером экспоненциальной кривой является сокращение всей популяции диких тигров на Земле.

Логарифмическая линия тренда

Логарифмическая линия наилучшего соответствия обычно используется для построения данных, которые быстро увеличиваются или уменьшаются, а затем выравниваются. Она может включать как положительные, так и отрицательные значения.

Примером логарифмической линии тренда может служить уровень инфляции, который сначала растет, но через некоторое время стабилизируется.

Полиномиальная линия тренда

Полиномиальная криволинейная линия тренда хорошо подходит для больших наборов данных с колеблющимися значениями, которые имеют более одного подъема и спада.

Обычно полином классифицируется по степени наибольшей экспоненты. Степень полиномиальной линии тренда можно также определить по количеству изгибов на графике. Обычно квадратичный полиномиальный тренд имеет один изгиб (холм или долину), кубический полином имеет 1 или 2 изгиба, а квартовый полином имеет до 3 изгибов.

При добавлении полиномиальной линии тренда на диаграмму Excel вы указываете степень, вводя соответствующее число в поле Заказ поле на Формат Линия тренда панели, которая по умолчанию равна 2:

Например, квадратичный полиномиальный тренд очевиден на следующем графике, который показывает зависимость между прибылью и количеством лет пребывания продукта на рынке: рост в начале, пик в середине и падение ближе к концу.

Линия тренда мощности

Линия тренда мощности очень похожа на экспоненциальную кривую, только имеет более симметричную дугу. Она обычно используется для построения графика измерений, которые увеличиваются с определенной скоростью.

Линию тренда нельзя добавить на график Excel, содержащий нулевые или отрицательные значения.

В качестве примера нарисуем линию тренда для визуализации скорости химической реакции. Обратите внимание на значение R-квадрат, равное 0,9918, что означает, что наша линия тренда практически идеально подходит к данным.

Скользящая средняя линия тренда

Когда точки данных на вашем графике имеют много взлетов и падений, линия тренда скользящей средней может сгладить экстремальные колебания значений данных, чтобы более четко показать закономерность. Для этого Excel рассчитывает скользящую среднюю за определенное количество периодов (по умолчанию 2) и помещает эти средние значения в качестве точек на линии. Чем выше значение скользящей средней, тем выше значение скользящей средней. Период значение, тем плавнее линия.

Хорошим практическим примером является использование линии тренда скользящей средней для выявления колебаний в цене акций, которые в противном случае было бы трудно заметить.

Дополнительную информацию см. в разделе: Как добавить линию тренда скользящей средней на график Excel.

Уравнения и формулы линии тренда в Excel

В этом разделе описаны уравнения, которые Excel использует для различных типов линий тренда. Вам не нужно строить эти формулы вручную, просто укажите Excel отобразить уравнение линии тренда на графике.

Также мы обсудим формулу для нахождения наклона линии тренда и другие коэффициенты. Формулы предполагают, что у вас есть 2 набора переменных: независимая переменная x и зависимая переменная y В своих рабочих листах вы можете использовать эти формулы для получения прогноза y значения для любых заданных значений x .

Для единообразия мы будем использовать один и тот же набор данных с немного отличающимися значениями для всех примеров. Однако, пожалуйста, помните, что это только для демонстрации. В ваших реальных рабочих листах вы должны выбрать тип линии тренда, соответствующий вашему типу данных.

Важное замечание! Формулы линии тренда следует использовать только в сочетании с Диаграммы разброса XY потому что только этот график отображает оба x и y Для получения дополнительной информации см. раздел "Почему уравнение линии тренда Excel может быть неверным".

Уравнение линии линейного тренда и формулы

Уравнение линейной линии тренда использует метод наименьших квадратов для поиска наклон и перехват коэффициенты такие, что:

Где:

• b это наклон линии тренда.
• a это y-интерцепт что является ожидаемым средним значением y когда все x переменные равны 0. На графике это точка, в которой линия тренда пересекает линию y ось.

Для линейной регрессии Microsoft Excel предоставляет специальные функции для получения коэффициентов наклона и перехвата.

Наклон линии тренда

b: =SLOPE(y,x)

Y-интерцепт

a: =INTERCEPT(y,x)

Если предположить, что x диапазон B2:B13 и y диапазон C2:C13, реальные формулы выглядят следующим образом:

=SLOPE(C2:C13, B2:B13)

=INTERCEPT(C2:C13,B2:B13)

Тех же результатов можно достичь, используя функцию LINEST в качестве формула массива Для этого выделите 2 соседние ячейки в одном ряду, введите формулу и нажмите Ctrl + Shift + Enter для ее завершения:

=LINEST(C2:C13,B2:B13)

Как показано на скриншоте ниже, коэффициенты наклона и перехвата, возвращаемые формулами, полностью совпадают с коэффициентами в уравнении линейного тренда, отображаемого на графике, только последние округлены до 4 знаков после запятой:

Уравнение и формулы экспоненциальной линии тренда

Для экспоненциальной линии тренда Excel использует следующее уравнение:

Где a и b расчетные коэффициенты, а e - математическая константа e (основание натурального логарифма).

Коэффициенты могут быть рассчитаны с помощью этих общих формул:

a: =EXP(INDEX(LINEST(LN(y), x), 1, 2))

b: =INDEX(LINEST(LN(y), x), 1)

Для нашего набора данных формулы имеют следующий вид:

a: =EXP(INDEX(LINEST(LN(C2:C13), B2:B13), 1, 2))

b: =INDEX(LINEST(LN(C2:C13), B2:B13), 1)

Уравнение и формулы логарифмической линии тренда

Вот уравнение логарифмической линии тренда в Excel:

Где a и b являются константами и ln является функцией натурального логарифма.

Чтобы получить константы, используйте эти общие формулы, которые отличаются только последним аргументом:

a: =INDEX(LINEST(y, LN(x)), 1)

b: =INDEX(LINEST(y, LN(x)), 1, 2)

Для нашего набора данных мы используем эти данные:

a: =INDEX(LINEST(C2:C13, LN(B2:B13)), 1)

b: =INDEX(LINEST(C2:C13, LN(B2:B13)), 1, 2)

Полиномиальное уравнение линии тренда и формулы

Для расчета полиномиальной линии тренда Excel использует это уравнение:

Где b ₁ ... b ₆ и a являются константами.

В зависимости от степени полиномиальной линии тренда, используйте один из следующих наборов формул для получения констант.

Квадратичная (2-го порядка) полиномиальная линия тренда

Уравнение: y = b ₂ x2+ b ₁ x + a

b ₂ : =INDEX(LINEST(y, x^{1,2}), 1)

b ₁ : =INDEX(LINEST(y, x^{1,2}), 1, 2)

a: =INDEX(LINEST(y, x^{1,2}), 1, 3)

Кубическая (3-го порядка) полиномиальная линия тренда

Уравнение: y = b ₃ x3 + b ₂ x2+ b ₁ x + a

b ₃ : =INDEX(LINEST(y, x^{1,2,3}), 1)

b ₂ : =INDEX(LINEST(y, x^{1,2,3}), 1, 2)

b ₁ : =INDEX(LINEST(y, x^{1,2,3}), 1, 3)

a: =INDEX(LINEST(y, x^{1,2,3}), 1, 4)

Формулы для полиномиальных линий тренда более высоких степеней могут быть построены по той же схеме.

Для нашего набора данных полиномиальная линия тренда 2-го порядка подходит лучше, поэтому мы используем эти формулы:

b ₂ : =INDEX(LINEST(C2:C13, B2:B13^{1,2}), 1)

b ₁ : =INDEX(LINEST(C2:C13, B2:B13^{1,2}), 1, 2)

a: =INDEX(LINEST(C2:C13, B2:B13^{1,2}), 1, 3)

Уравнение и формулы линии силового тренда

Линия тренда в Excel строится на основе этого простого уравнения:

Где a и b являются константами, которые можно вычислить по этим формулам:

a: =EXP(INDEX(LINEST(LN(y), LN(x),,), 1, 2))

b: =INDEX(LINEST(LN(y), LN(x),,), 1)

В нашем случае отлично работают следующие формулы:

a: =EXP(INDEX(LINEST(LN(C2:C13), LN(B2:B13),,), 1, 2))

b: =INDEX(LINEST(LN(C2:C13), LN(B2:B13),,), 1)

Уравнение линии тренда в Excel неверно - причины и исправления

Если вам кажется, что Excel неправильно нарисовал линию тренда или формула линии тренда, отображаемая на вашем графике, неверна, следующие два пункта могут пролить свет на ситуацию.

Уравнение линии тренда в Excel корректно только на диаграммах разброса

Формулы линии тренда Excel следует использовать только с графиками XY (разброса), поскольку только в этом типе графика ось y и ось x строятся как числовые значения.

В линейных, столбчатых и гистограммах числовые значения наносятся только на ось y. Ось x представлена линейным рядом (1, 2, 3,...) независимо от того, являются ли метки оси числами или текстом. Когда вы строите линию тренда в этих диаграммах, Excel использует эти предполагаемые значения x в формуле линии тренда.

Числа округляются в уравнении линии тренда в Excel

Чтобы занять меньше места на графике, Excel отображает очень мало значащих цифр в уравнении линии тренда. Приятное с точки зрения дизайна, оно значительно снижает точность формулы, когда вы вручную подставляете значения x в уравнение.

Простым решением является отображение большего количества десятичных знаков в уравнении. В качестве альтернативы вы можете рассчитать коэффициенты с помощью формулы, соответствующей типу вашей линии тренда, и отформатировать ячейки формулы так, чтобы в них отображалось достаточное количество десятичных знаков. Для этого просто нажмите кнопку Увеличить десятичную дробь кнопка на Главная вкладка в Номер группа.

Вот как можно сделать различные типы линий тренда в Excel и получить их уравнения. Я благодарю вас за чтение и надеюсь увидеть вас в нашем блоге на следующей неделе!