Yn dizze tutorial fine jo de detaillearre beskriuwing fan alle trendline-opsjes dy't beskikber binne yn Excel en wannear't jo se moatte brûke. Jo sille ek leare hoe't jo in trendline-fergeliking yn in diagram werjaan en de helling fan trendline fine.

It is heul maklik om in trendline ta te foegjen yn Excel. De ienige echte útdaging is om it trendline-type te kiezen dat it bêste oerienkomt mei it type gegevens dat jo analysearje. Yn dit tutorial fine jo de detaillearre beskriuwing fan alle trendline-opsjes dy't beskikber binne yn Excel en wannear't se se moatte brûke. As jo ​​op syk binne nei hoe't jo in trendline yn in Excel-diagram kinne ynfoegje, kontrolearje dan it boppesteande keppele tutorial.

Excel-trendlinetypen

As jo ​​in trendline tafoegje yn Excel , do hast 6 ferskillende opsjes a kieze út. Derneist lit Microsoft Excel in trendline-fergeliking en R-kwadraatwearde yn in diagram werjaan:

• Trendline-fergeliking is in formule dy't in line fynt dy't it bêste past by de gegevenspunten.
• R-kwadraatwearde mjit de betrouberens fan 'e trendline - hoe tichter R2 by 1 is, hoe better de trendline past by de gegevens.

Hjirûnder fine jo in koarte beskriuwing fan elk type trendline mei diagramfoarbylden.

Lineêre trendline

De lineêre trendline is it bêste om te wêzen brûkt mei lineêre gegevenssets as de gegevenspunten yn in diagram lykje op in rjochte line. Typysk beskriuwt in lineêre trendline in trochgeande opkomst of faloer de tiid.

Bygelyks, de folgjende lineêre trendline lit in fêste ferheging fan ferkeap oer 6 moannen sjen. En de R2 wearde fan 0.9855 jout in aardich goede fit fan 'e skatte trendline wearden oan' e eigentlike gegevens.

Eksponinsjele trendline

De eksponinsjele trendline is in bûgde line dy't in opkomst of fal yn gegevenswearden mei tanimmend taryf yllustrearret, dêrom is de line meastentiids mear kromme oan ien kant. Dit trendline-type wurdt faak brûkt yn wittenskippen, bygelyks om in minsklike populaasjegroei of ferfal yn wildlifepopulaasjes te visualisearjen.

Tink derom dat in eksponinsjele trendline net makke wurde kin foar gegevens dy't nullen of negative wearden befetsje.

In goed foarbyld fan in eksponinsjele kromme is it ferfal yn 'e hiele wylde tigerpopulaasje op 'e ierde.

Logarithmyske trendline

De logaritmyske best-fit-line wurdt oer it algemien brûkt om gegevens te plotjen dy't fluch tanimme of ôfnimme en dan ôffalje. It kin sawol positive as negative wearden befetsje.

In foarbyld fan in logaritmyske trendline kin in ynflaasjekoers wêze, dy't earst heger wurdt, mar nei in skoftke stabilisearret.

Polynomiale trendline

De polynomiale kromlineêre trendline wurket goed foar grutte datasets mei oscillerende wearden dy't mear as ien opkomst en falle hawwe.

Algemien wurdt in polynoom klassifisearre troch de graad fan de grutste eksponint. De graad fan de polynomiale trendline kinek wurde bepaald troch it oantal bochten op in grafyk. Typysk hat in kwadratyske polynoomtrendline ien bocht (heuvel of delling), in kubysk polynoom hat 1 of 2 bochten, en in kwadratyske polynoom hat maksimaal 3 bochten.

As jo ​​in polynomiale trendline tafoegje yn in Excel-diagram, jo spesifisearje de graad troch it oerienkommende nûmer yn te typen yn it fak Oarder yn it finster Format Trendline , dat standert 2 is:

Bygelyks de kwadratyske polynomiale trend is evident op 'e folgjende grafyk dy't de relaasje sjen lit tusken de winst en it oantal jierren dat it produkt op' e merk west hat: opkomst yn it begjin, peak yn 'e midden en falle tichtby de ein.

Power trendline

De macht trendline is heul ferlykber mei de eksponinsjele kromme, allinich hat it in mear symmetryske bôge. It wurdt ornaris brûkt om mjittingen te plotjen dy't tanimme mei in bepaald taryf.

In machtstrendline kin net tafoege wurde oan in Excel-diagram dat nul of negative wearden befettet.

Litte wy as foarbyld in tekenje in power trendline om de gemyske reaksjerate te visualisearjen. Notysje de R-kwadraatwearde fan 0.9918, wat betsjut dat ús trendline hast perfekt past by de gegevens.

Bewegende gemiddelde trendline

As de gegevenspunten yn jo diagram in protte ups en downs hawwe, kin in bewegende gemiddelde trendline de ekstreme fluktuaasjes yn gegevenswearden glêdje om in patroan dúdliker te sjen. Foar dit, Excel berekkent debewegend gemiddelde fan it oantal perioaden dat jo oantsjutte (standert 2) en set dy gemiddelde wearden as punten yn 'e rigel. Hoe heger de wearde fan Periode , hoe soepeler de line.

In goed praktysk foarbyld is it brûken fan de bewegende gemiddelde trendline om fluktuaasjes yn in oandielpriis te sjen dy't oars dreech te observearjen wêze soe.

Sjoch foar mear ynformaasje: Hoe kinne jo in bewegende gemiddelde trendline tafoegje oan in Excel-diagram.

Excel-trendline-fergelikingen en formules

Dizze seksje beskriuwt de fergelikingen dy't Excel brûkt foar ferskate trendline types. Jo hoege dizze formules net mei de hân te bouwen, fertel gewoan Excel om de trendline-fergeliking yn in diagram wer te jaan.

Ek sille wy de formule beprate om de helling fan in trendline en oare koeffizienten te finen. De formules geane derfan út dat jo 2 sets fan fariabelen hawwe: ûnôfhinklike fariabele x en ôfhinklike fariabele y . Yn jo wurkblêden kinne jo dizze formules brûke om de foarseine y -wearden te krijen foar elke opjûne wearden fan x .

Foar konsistinsje sille wy deselde gegevens brûke set mei in bytsje wikseljende wearden foar alle foarbylden. Hâld lykwols yn gedachten dat it allinich foar demonstraasjedoelen is. Yn jo echte wurkblêden moatte jo it trendline-type kieze dat oerienkomt mei jo gegevenstype.

Wichtige opmerking! De trendline-formules moatte allinich brûkt wurde mei XY-ferspriedingsdiagrammen om't allinich ditdiagram plott sawol x as y assen as numerike wearden. Sjoch foar mear ynformaasje Wêrom Excel-trendline-fergeliking miskien ferkeard is.

Lineêre trendline-fergeliking en formules

De lineêre trendline-fergeliking brûkt de minste kwadraten metoaden om de helling te sykjen en intercept koëffisjinten sadanich dat:

y = bx + a

Wêr:

• b de helling is fan in trendline.
• a is de y-ôfsnijding , dat is de ferwachte gemiddelde wearde fan y as alle x fariabelen binne lyk oan 0. Op in diagram is it it punt dêr't de trendline de y -as krúst.

Foar lineêre regression biedt Microsoft Excel spesjale funksjes om de helling en intercept koeffizienten.

Slope of trendline

b: =SLOPE(y,x)

Y-intercept

a: =INTERCEPT(y,x)

Oannommen dat it x -berik B2:B13 is en it y -berik C2:C13 is, geane de echte formules as folget:

=SLOPE(C2:C13, B2:B13)

=INTERCEPT(C2:C13,B2:B13)

Deselde resultaten kinne berikt wurde troch de LINEST-funksje te brûken as in arrayformule . Selektearje hjirfoar 2 neistlizzende sellen yn deselde rige, fier de formule yn en druk op Ctrl + Shift + Enter om it te foltôgjen:

=LINEST(C2:C13,B2:B13)

Lykas werjûn yn 'e skermôfbylding hjirûnder, de helling en ûnderskepping koeffizienten weromjûn troch de formules binne perfekt yn oerienstimming mei de koeffizienten yn 'e lineêre trendline-fergeliking werjûn yn' e diagram, allinich de lêste wurde rûn op 4 desimale plakken:

Eksponinsjele trendline-fergeliking en formules

Foar de eksponinsjele trendline brûkt Excel de folgjende fergeliking:

y = aebx

Wêr a en b binne berekkene koeffizienten en e is de wiskundige konstante e (de basis fan de natuerlike logaritme).

De koeffizienten kinne wurde berekkene mei dizze generyske formules:

a: =EXP(INDEX(LINEST(LN(y), x), 1, 2))

b: =INDEX(LINEST(LN(y), x), 1)

Foar ús foarbyldgegevensset hawwe de formules de folgjende foarm:

a: =EXP(INDEX(LINEST(LN(C2:C13), B2:B13), 1, 2))

b: =INDEX(LINEST(LN(C2:C13), B2:B13), 1)

Logaritmyske trendline-fergeliking en formules

Hjir is de logaritmyske trendline-fergeliking yn Excel:

y = a*ln(x)+b

Wêr a en b binne konstanten en ln is de natuerlike logaritmefunksje.

Om de konstanten te krijen, brûk dizze generyske formules, dy't allinich ferskille yn it lêste argumint:

a: =INDEX(LINEST(y, LN(x)), 1)

b: =INDEX(LINEST(y, LN(x)), 1, 2)

Foar ús foarbyldgegevensset brûke wy dizze:

a: =INDEX(LINEST(C2:C13, LN(B2:B13)), 1)

b: =INDEX(LINEST(C2:C13, LN(B2:B13)), 1, 2)

Polynomiale trendline-fergeliking en formules

Om de polynomiale trendline út te wurkjen, brûkt Excel dizze fergeliking:

y = b ₆ x6 + … + b ₂ x2 + b ₁ x + a

Wêr b ₁ ... b ₆ en a binne konstanten.

Ofhinklik fan de graad fan jo polynomiale trendline, brûk ien fan de folgjende sets formules om de konstanten te krijen.

Kwadratyske (2e oarder) polynomiale trendline

Fergeliking: y = b ₂ x2+ b ₁ x + a

b ₂ : =INDEX(LINEST(y, x^{1,2}), 1)

b ₁ : =INDEX(LINEST(y, x^{1,2}), 1, 2)

a: =INDEX(LINEST(y, x^{1,2}), 1, 3)

Kubyske (3e oarder) polynomiale trendline

Fergeliking: y = b ₃ x3 + b ₂ x2+ b ₁ x + a

b ₃ : =INDEX(LINEST(y, x^{1,2,3}), 1)

b ₂ : =INDEX(LINEST(y, x^{1,2,3}), 1, 2)

b ₁ : =INDEX(LINEST(y, x^{1,2,3}), 1, 3)

a: =INDEX(LINEST(y, x^{1,2,3}), 1, 4)

De formules foar hegere graad polynomiale trendlinen kinne wurde boud troch itselde patroan te brûken.

Foar ús gegevensset, de 2e oarder polynomiale trendline suites better, dus brûke wy dizze formules:

b ₂ : =INDEX(LINEST(C2:C13, B2:B13^{1,2}), 1)

b ₁ : =INDEX(LINEST(C2:C13, B2:B13^{1,2}), 1, 2)

a: =INDEX(LINEST(C2:C13, B2:B13^{1,2}), 1, 3)

Power trendline fergeliking en formules

In macht trendline yn Excel wurdt tekene basearre op dizze ienfâldige fergeliking:

y = axb

Wêr a en b binne konstanten, dy't mei dizze formules berekkene wurde kinne:

a: =EXP(INDEX(LINEST(LN(y), LN(x),,), 1, 2))

b: =INDEX(LINEST(LN(y), LN(x),,), 1)

Yn ús gefal wurkje de folgjende formules in traktaasje :

a: =EXP(INDEX(LINEST(LN(C2:C13), LN(B2:B13),,), 1, 2))

b: =INDEX(LINEST(LN(C2:C13), LN(B2:B13),,), 1)

Excel-trendline-fergeliking is ferkeard - redenen en reparaasjes

As jo ​​tinke dat Excel in trendline ferkeard tekene hat of de trendline-formule werjûn yn jo diagram is ferkeard, de folgjende twa punten kinne wat ferlieze ljocht op de situaasje.

Excel-trendline-fergeliking is allinich korrekt yn scatter-grafiken

Excel-trendline-formules moatte allinich brûkt wurde mei XY (scatter)-grafiken, om't allinich yn dit diagram de y-as typearje en x-as wurde as numerike wearden útset.

Yn linegrafiken, kolom- en staafgrafiken wurde numerike wearden allinnich op de y-as útset. De x-as wurdt fertsjintwurdige troch in lineêre rige (1, 2,3,...) nettsjinsteande oft de aslabels sifers of tekst binne. As jo ​​in trendline meitsje yn dizze diagrammen, brûkt Excel dy oannommen x-wearden yn 'e trendlineformule.

Sifers wurde rûn yn Excel-trendline-fergeliking

Om minder romte yn te nimmen yn 'e diagram, toant Excel hiel pear wichtige sifers yn in trendline fergeliking. Moai yn termen fan ûntwerp, it ferminderet de krektens fan 'e formule signifikant as jo x-wearden yn 'e fergeliking mei de hân leverje.

In maklike oplossing is om mear desimale plakken yn 'e fergeliking te sjen. As alternatyf kinne jo de koeffizienten berekkenje troch in formule te brûken dy't oerienkomt mei jo trendline-type, en de formulesellen opmeitsje sadat se in foldwaande oantal desimale plakken sjen litte. Klikje hjirfoar gewoan op de knop Desimaal fergrutsje op it ljepblêd Thús yn 'e groep Nûmer .

Sa kinne jo ferskate trendlinetypen meitsje yn Excel en krije harren fergelikingen. Ik tankje jo foar it lêzen en hoopje jo nije wike op ús blog te sjen!