Selles õpetuses leiate üksikasjaliku kirjelduse kõigi Excelis saadaval olevate trendijoone võimaluste kohta ja millal neid kasutada. Samuti saate teada, kuidas kuvada trendijoone võrrandit diagrammil ja leida trendijoone kaldenurk.

Trendijoone lisamine Excelis on väga lihtne. Ainus tõeline väljakutse on valida trendijoone tüüp, mis vastab kõige paremini analüüsitavatele andmetele. Selles õpetuses on üksikasjalikult kirjeldatud kõik Excelis saadaval olevad trendijoone võimalused ja millal neid kasutada. Kui otsite, kuidas lisada trendijoone Exceli diagrammi, vaadake ülalpool lingitud õpetust.

Exceli trendijoone tüübid

Trendijoone lisamisel Excelis on teil valida 6 erineva valiku vahel. Lisaks võimaldab Microsoft Excel trendijoone võrrandi ja R-ruutväärtuse kuvamist graafikus:

• Trendijoone võrrand on valem, mis leiab andmepunktidele kõige paremini sobiva joone.
• R-ruutarvu väärtus mõõdab trendijoone usaldusväärsust - mida lähemal R2 on 1-le, seda paremini sobib trendijoon andmetega.

Allpool leiad lühikirjeldus iga trendijoone tüüpi diagrammi näiteid.

Lineaarne trendijoon

Lineaarset trendijoont on kõige parem kasutada lineaarsete andmekogumite puhul, kui diagrammi andmepunktid sarnanevad sirgjoonega. Tavaliselt kirjeldab lineaarne trendijoon pidevat tõusu või langust aja jooksul.

Näiteks järgmine lineaarne trendijoon näitab müügi pidevat kasvu 6 kuu jooksul. Ja R2 väärtus 0,9855 näitab, et hinnangulised trendijoonte väärtused sobivad päris hästi tegelike andmetega.

Eksponentsiaalne trendijoon

Eksponentsiaalne trendijoon on kumer joon, mis illustreerib andmete väärtuste suurenevat tõusu või langust, seetõttu on joon tavaliselt ühel poolel rohkem kumer. Seda trendijoonetüüpi kasutatakse sageli teadustes, näiteks inimpopulatsiooni kasvu või eluslooduse populatsioonide vähenemise visualiseerimiseks.

Pange tähele, et eksponentsiaalset trendijoont ei saa luua andmete jaoks, mis sisaldavad nulle või negatiivseid väärtusi.

Hea näide eksponentsiaalsest kõverast on kogu loodusliku tiigripopulatsiooni kahanemine maa peal.

Logaritmiline trendijoon

Logaritmilist parima sobivuse joont kasutatakse tavaliselt selliste andmete joonistamiseks, mis kiiresti suurenevad või vähenevad ja seejärel tasanduvad. See võib sisaldada nii positiivseid kui ka negatiivseid väärtusi.

Logaritmilise trendijoone näiteks võib olla inflatsioonimäär, mis esialgu tõuseb, kuid mõne aja pärast stabiliseerub.

Polünoomi trendijoon

Polünoomi kõverjooneline trendijoon töötab hästi suurte andmekogumite puhul, millel on rohkem kui üks tõus ja langus.

Üldiselt liigitatakse polünoomi suurima eksponendi astme järgi. Polünoomi trendijoone astet saab määrata ka graafiku kurvide arvu järgi. Tavaliselt on kvadraatilisel polünoomi trendijoone üks kurv (mägi või org), kuubilisel polünoomil on 1 või 2 kurvi ja kvartaalsel polünoomil kuni 3 kurvi.

Polünoomi trendijoone lisamisel Exceli diagrammi määrate astme, sisestades vastava arvu lahtrisse Tellige kastis Formaat Trendjoon paneel, mis on vaikimisi 2:

Näiteks on kvadraatiline polünoomne trend ilmne järgmisel graafikul, mis näitab kasumi ja toote turul oldud aastate arvu vahelist seost: alguses tõus, keskel tipp ja lõpus langus.

Võimsuse trendijoonis

Võimsuse trendijoon on väga sarnane eksponentsiaalsele kõverale, ainult et sellel on sümmeetrilisem kaar. Seda kasutatakse tavaliselt teatud kiirusega suurenevate mõõtmiste joonistamiseks.

Power trendijoont ei saa lisada Exceli diagrammile, mis sisaldab null- või negatiivseid väärtusi.

Joonistame näiteks keemilise reaktsioonikiiruse visualiseerimiseks võimsuse trendijoone. Pange tähele R-ruutväärtust 0,9918, mis tähendab, et meie trendijoone sobib andmetega peaaegu ideaalselt.

Liikuva keskmine trendijoon

Kui teie diagrammi andmepunktidel on palju tõusu ja langust, võib libisev keskmine trendijoon siluda andmete väärtuste äärmuslikke kõikumisi, et näidata mustrit selgemalt. Selleks arvutab Excel teie poolt määratud perioodi arvu (vaikimisi 2) libiseva keskmise ja paigutab need keskmised väärtused punktidena joonele. Mida suurem on Ajavahemik väärtus, seda sujuvam on joon.

Hea praktiline näide on libiseva keskmise trendijoone kasutamine aktsia hinna kõikumiste avastamiseks, mida muidu oleks raske jälgida.

Lisateavet vt: Kuidas lisada libisev keskmine trendijoon Exceli diagrammi.

Exceli trendijoone võrrandid ja valemid

Selles jaotises kirjeldatakse võrrandeid, mida Excel kasutab erinevate trendijoontüüpide jaoks. Neid valemeid ei pea käsitsi koostama, lihtsalt käskige Excelil kuvada trendijoone võrrand diagrammil.

Samuti arutame valemit trendijoone kalde ja muude koefitsientide leidmiseks. Valemid eeldavad, et teil on 2 muutujate kogumit: sõltumatu muutuja x ja sõltuv muutuja y Oma töölehtedel võite kasutada neid valemeid, et saada prognoositud y väärtused mis tahes antud väärtuste puhul x .

Järjepidevuse huvides kasutame kõigis näidetes sama andmestikku veidi erinevate väärtustega. Pidage siiski meeles, et see on ainult demonstratsiooniks. Oma reaalsetes töölehtedes peaksite valima oma andmetüübile vastava trendijoone tüübi.

Tähtis märkus! Trendijoone valemeid tuleks kasutada ainult koos XY hajuvusdiagrammid sest ainult see graafik näitab nii x ja y telgedel numbriliste väärtustena. Lisateavet leiate jaotisest Miks Exceli trendijoone võrrand võib olla vale.

Lineaarse trendijoone võrrand ja valemid

Lineaarse trendijoone võrrand kasutab vähimate ruutude meetodit, et otsida kalle ja pealtkuulamine koefitsiendid selliselt, et:

Kus:

• b on kalle trendijoone.
• a on y-intertseptsioon , mis on eeldatav keskmine väärtus y kui kõik x muutujad on võrdsed 0. Diagrammil on see punkt, kus trendijoon ületab y telg.

Lineaarse regressiooni jaoks pakub Microsoft Excel spetsiaalseid funktsioone, et saada kalde- ja lõikekoefitsiendid.

Trendijoone kalle

b: =SLOPE(y,x)

Y-intertseptsioon

a: =INTERCEPT(y,x)

Eeldades, et x vahemik on B2:B13 ja y vahemik on C2:C13, tegelikus elus kasutatavad valemid on järgmised:

=SLOPE(C2:C13, B2:B13)

=INTERCEPT(C2:C13,B2:B13)

Samu tulemusi saab saavutada, kui kasutada funktsiooni LINEST kui massiivi valem Selleks valige 2 kõrvuti asetsevat lahtrit samas reas, sisestage valem ja vajutage Ctrl + Shift + Enter, et täita valem:

=LINEST(C2:C13,B2:B13)

Nagu on näidatud alloleval ekraanipildil, on valemite poolt tagastatud tõusu ja lõikekoefitsiendid täiesti kooskõlas graafikus kuvatava lineaarse trendijoone võrrandi koefitsientidega, ainult viimased on ümardatud 4 komakohani:

Eksponentsiaalse trendijoone võrrand ja valemid

Eksponentsiaalse trendijoone jaoks kasutab Excel järgmist võrrandit:

Kus a ja b on arvutatud koefitsiendid ja e on matemaatiline konstant e (loomuliku logaritmi alus).

Koefitsiente saab arvutada nende üldiste valemite abil:

a: =EXP(INDEX(LINEST(LN(y), x), 1, 2))

b: =INDEX(LINEST(LN(y), x), 1)

Meie näidisandmestiku puhul võtavad valemid järgmise kuju:

a: =EXP(INDEX(LINEST(LN(C2:C13), B2:B13), 1, 2))

b: =INDEX(LINEST(LN(C2:C13), B2:B13), 1)

Logaritmiline trendijoone võrrand ja valemid

Siin on logaritmiline trendijoone võrrand Excelis:

Kus a ja b on konstandid ja In on naturaalse logaritmi funktsioon.

Konstandite saamiseks kasutage neid üldisi valemeid, mis erinevad ainult viimase argumendi poolest:

a: =INDEX(LINEST(y, LN(x)), 1)

b: =INDEX(LINEST(y, LN(x)), 1, 2)

Meie näidisandmestiku puhul kasutame neid:

a: =INDEX(LINEST(C2:C13, LN(B2:B13)), 1)

b: =INDEX(LINEST(C2:C13, LN(B2:B13)), 1, 2)

Polünoomi trendijoone võrrand ja valemid

Polünoomi trendijoone arvutamiseks kasutab Excel seda võrrandit:

Kus b ₁ ... b ₆ ja a on konstandid.

Sõltuvalt teie polünoomi trendijoone astmest, kasutage konstandide saamiseks ühte järgmistest valemitest.

Kvadraatiline (2. järgu) polünoomi trendijoonis

Võrrand: y = b ₂ x2+ b ₁ x + a

b ₂ : =INDEX(LINEST(y, x^{1,2}), 1)

b ₁ : =INDEX(LINEST(y, x^{1,2}), 1, 2)

a: =INDEX(LINEST(y, x^{1,2}), 1, 3)

Kuubiline (3. järgu) polünoomi trendijoonis

Võrrand: y = b ₃ x3 + b ₂ x2+ b ₁ x + a

b ₃ : =INDEX(LINEST(y, x^{1,2,3}), 1)

b ₂ : =INDEX(LINEST(y, x^{1,2,3}), 1, 2)

b ₁ : =INDEX(LINEST(y, x^{1,2,3}), 1, 3)

a: =INDEX(LINEST(y, x^{1,2,3}), 1, 4)

Kõrgema astme polünoomi trendijoonte valemid saab ehitada sama mustri abil.

Meie andmekogumi puhul sobib paremini 2. järgu polünoomi trendijoon, seega kasutame neid valemeid:

b ₂ : =INDEX(LINEST(C2:C13, B2:B13^{1,2}), 1)

b ₁ : =INDEX(LINEST(C2:C13, B2:B13^{1,2}), 1, 2)

a: =INDEX(LINEST(C2:C13, B2:B13^{1,2}), 1, 3)

Võimsuse trendijoone võrrand ja valemid

Selle lihtsa võrrandi alusel joonistatakse Excelis võimsuse trendijoon:

Kus a ja b on konstandid, mida saab arvutada nende valemite abil:

a: =EXP(INDEX(LINEST(LN(y), LN(x),,,), 1, 2))

b: =INDEX(LINEST(LN(y), LN(x),,,), 1)

Meie puhul toimivad järgmised valemid suurepäraselt:

a: =EXP(INDEX(LINEST(LN(C2:C13), LN(B2:B13),,,), 1, 2))

b: =INDEX(LINEST(LN(C2:C13), LN(B2:B13),,), 1)

Exceli trendijoone võrrand on vale - põhjused ja parandused

Kui arvate, et Excel on joonistanud trendijoone valesti või teie graafikus kuvatav trendijoone valem on vale, võivad järgmised kaks punkti olukorda veidi valgustada.

Exceli trendijoone võrrand on õige ainult hajuvusdiagrammide puhul.

Exceli trendijoone valemeid tuleks kasutada ainult XY (hajutatud) graafikute puhul, sest ainult selles graafikutüübis on nii y-telg kui ka x-telg esitatud numbriliste väärtustena.

Joondiagrammides, tulpdiagrammides ja tulpdiagrammides joonistatakse numbrilised väärtused ainult y-teljel. x-teljel esitatakse lineaarne rida (1, 2, 3,...), olenemata sellest, kas telgede sildid on numbrid või tekst. Kui te koostate nendes diagrammides trendijoone, kasutab Excel trendijoone valemis neid eeldatavaid x-väärtusi.

Exceli trendijoone võrrandis on arvud ümardatud.

Et graafikus vähem ruumi hõivata, kuvab Excel trendijoone võrrandis väga vähe olulisi numbreid. Kujunduse seisukohalt on see tore, kuid vähendab oluliselt valemi täpsust, kui annate võrrandis käsitsi x-väärtusi.

Lihtne lahendus on näidata võrrandis rohkem kümnendkohti. Teise võimalusena saate koefitsiendid arvutada, kasutades oma trendijoone tüübile vastavat valemit, ja vormindada valemi lahtrid nii, et ne näitaksid piisavat arvu kümnendkohti. Selleks klõpsake lihtsalt nuppu Suurendada kümnendmäära nuppu Kodu vahekaart Number rühm.

Nii saab Excelis teha erinevaid trendijoonetüüpe ja saada nende võrrandid. Tänan teid lugemise eest ja loodan, et näeme teid järgmisel nädalal meie blogis!