У овом водичу ћете пронаћи детаљан опис свих опција линије тренда доступних у Екцел-у и када их користити. Такође ћете научити како да прикажете једначину линије тренда на графикону и пронађете нагиб линије тренда.

Веома је лако додати линију тренда у Екцел. Једини прави изазов је одабрати тип линије тренда који најбоље одговара типу података који анализирате. У овом водичу ћете пронаћи детаљан опис свих опција линије тренда доступних у Екцел-у и када их користити. Ако тражите како да уметнете линију тренда у Екцел графикон, погледајте горе повезани водич.

Екцел типови линија тренда

Када додајете линију тренда у Екцел , имате 6 различитих опција које можете изабрати. Поред тога, Мицрософт Екцел омогућава приказивање једначине линије тренда и вредности Р-квадрата на графикону:

• Једначина линије тренда је формула која проналази линију која најбоље одговара тачкама података.
• Вредност Р-квадрата мери поузданост линије тренда - што је Р2 ближе 1, то боље линија тренда одговара подацима.

У наставку ћете пронаћи кратак опис сваког типа линије тренда са примерима графикона.

Линеарна линија тренда

Линија линеарног тренда је најбоље да буде користи се са линеарним скуповима података када тачке података на графикону подсећају на праву линију. Типично, линеарна линија тренда описује континуирани раст или падтоком времена.

На пример, следећа линеарна линија тренда показује стабилан пораст продаје током 6 месеци. А вредност Р2 од 0,9855 указује на прилично добро уклапање процењених вредности линије тренда са стварним подацима.

Експоненцијална линија тренда

Експоненцијална линија тренда је крива линија која илуструје пораст или пад вредности података растућом стопом, стога је линија обично више закривљена на једној страни. Овај тип линије тренда се често користи у науци, на пример за визуелизацију раста људске популације или опадања популација дивљих животиња.

Имајте на уму да се експоненцијална линија тренда не може креирати за податке који садрже нуле или негативне вредности.

Добар пример експоненцијалне криве је пропадање целокупне популације дивљих тигрова на Земљи.

Логаритамска линија тренда

Логаритамска линија најбољег прилагођавања се генерално користи за цртање података који се брзо повећавају или смањују, а затим се нивелирају. Може да садржи и позитивне и негативне вредности.

Пример логаритамске линије тренда може бити стопа инфлације, која прво расте, али се после неког времена стабилизује.

Полиномска линија тренда

Полиномска криволинијска линија тренда добро функционише за велике скупове података са осцилирајућим вредностима које имају више од једног пораста и пада.

Генерално, полином се класификује према степен највећег експонента. Степен полиномске линије тренда можетакође бити одређен бројем савијања на графикону. Типично, квадратна полиномска линија тренда има једну кривину (брдо или долина), кубни полином има 1 или 2 кривине, а квартични полином има до 3 кривине.

Када додајете полиномску линију тренда у Екцел графикон, одређујете степен тако што ћете укуцати одговарајући број у поље Ордер у окну Формат Трендлине , што је подразумевано 2:

На пример, квадратни полиномски тренд је евидентно на следећем графикону који показује однос између профита и броја година колико је производ на тржишту: пораст на почетку, врхунац у средини и пад при крају.

Линија тренда снаге

Линија тренда снаге је веома слична експоненцијалној кривој, само што има симетричнији лук. Обично се користи за цртање мерења која се повећавају одређеном брзином.

Линија тренда снаге се не може додати у Екцел графикон који садржи нулте или негативне вредности.

Као пример, нацртајмо линија тренда снаге за визуелизацију брзине хемијске реакције. Обратите пажњу на вредност Р-квадрата од 0,9918, што значи да се наша линија тренда скоро савршено уклапа у податке.

Линија тренда покретног просека

Када тачке података на вашем графикону имају много успона и падова, линија тренда покретног просека може да изглади екстремне флуктуације у вредностима података да би јасније приказала образац. За ово, Екцел израчунавапокретни просек броја периода који наведете (подразумевано 2) и ставља те просечне вредности као тачке у линији. Што је виша вредност Период , то је линија глаткија.

Добар практични пример је коришћење линије тренда покретног просека за откривање флуктуација у цени акција које би иначе било тешко уочити.

За више информација погледајте: Како додати линију тренда покретног просека на Екцел графикон.

Екцел једначине и формуле линије тренда

Овај одељак описује једначине које Екцел користи за различите типове трендова. Не морате ручно да правите ове формуле, једноставно реците Екцел-у да прикаже једначину линије тренда на графикону.

Такође, разговараћемо о формули за проналажење нагиба линије тренда и других коефицијената. Формуле претпостављају да имате 2 скупа променљивих: независна променљива к и зависна променљива и . У својим радним листовима можете да користите ове формуле да бисте добили предвиђене вредности и за било које дате вредности к .

Ради доследности, користићемо исте податке сет са незнатно варирајућим вредностима за све примере. Међутим, имајте на уму да је то само у сврху демонстрације. У вашим стварним радним листовима, требало би да изаберете тип линије тренда који одговара вашем типу података.

Важна напомена! Формуле линије тренда треба да се користе само са КСИ графиконима расејања јер само овографикон приказује обе осе к и и као нумеричке вредности. За више информација погледајте Зашто Екцел једначина линије тренда може бити погрешна.

Једначина и формуле линеарне линије тренда

Једначина линеарне линије тренда користи методе најмањих квадрата за тражење нагиба и коефицијенти пресецања такви да је:

и = бк + а

Где је:

• б нагиб линије тренда.
• а је и-пресецање , што је очекивана средња вредност и када су сви к променљиве су једнаке 0. На графикону, то је тачка у којој линија тренда прелази осу и .

За линеарну регресију, Мицрософт Екцел обезбеђује посебне функције за добијање коефицијенти нагиба и пресека.

Нагиб линије тренда

б: =SLOPE(y,x)

И-пресецак

а: =INTERCEPT(y,x)

Под претпоставком да је опсег к Б2:Б13, а опсег и Ц2:Ц13, формуле из стварног живота иду на следећи начин:

=SLOPE(C2:C13, B2:B13)

=INTERCEPT(C2:C13,B2:B13)

Исти резултати се могу постићи коришћењем функције ЛИНЕСТ као формуле низа . За ово, изаберите 2 суседне ћелије у истом реду, унесите формулу и притисните Цтрл + Схифт + Ентер да бисте је довршили:

=LINEST(C2:C13,B2:B13)

Као што је приказано на снимку екрана испод, нагиб и пресек коефицијенти враћени формулама су савршено у складу са коефицијентима у једначини линеарне линије тренда приказаној на графикону, само су последњи заокружени на 4 децимале:

Експоненцијална једначина линије тренда и формуле

За експоненцијалну линију тренда, Екцел користи следећу једначину:

и = аебк

Где је а и б су израчунати коефицијенти, а е је математичка константа е (основа природног логаритма).

Коефицијенти се могу израчунати коришћењем ових генеричких формула:

а: =EXP(INDEX(LINEST(LN(y), x), 1, 2))

б: =INDEX(LINEST(LN(y), x), 1)

За наш скуп података узорка, формуле имају следећи облик:

а: =EXP(INDEX(LINEST(LN(C2:C13), B2:B13), 1, 2))

б: =INDEX(LINEST(LN(C2:C13), B2:B13), 1)

Логаритамска једначина и формуле линије тренда

Ево једначине логаритамске линије тренда у Екцел-у:

и = а*лн(к)+б

Где је а и б су константе и лн је функција природног логаритма.

Да бисте добили константе, користите ове генеричке формуле, које се разликују само у последњем аргументу:

а: =INDEX(LINEST(y, LN(x)), 1)

б: =INDEX(LINEST(y, LN(x)), 1, 2)

За наш скуп података узорка користимо ове:

а: =INDEX(LINEST(C2:C13, LN(B2:B13)), 1)

б: =INDEX(LINEST(C2:C13, LN(B2:B13)), 1, 2)

Једначина и формуле полиномске линије тренда

Да би разрадио полиномску линију тренда, Екцел користи ову једначину:

и = б ₆ к6 + … + б ₂ к2 + б ₁ к + а

Где је б ₁ … б ₆ и а су константе.

У зависности од степена ваше полиномске линије тренда, користите један од следећих скупова формула да добијете константе.

Квадратна (2. реда) полиномска линија тренда

Једначина: и = б ₂ к2+ б ₁ к + а

б ₂ : =INDEX(LINEST(y, x^{1,2}), 1)

б ₁ : =INDEX(LINEST(y, x^{1,2}), 1, 2)

а: =INDEX(LINEST(y, x^{1,2}), 1, 3)

Кубична (3. реда) полиномска линија тренда

Једначина: и = б ₃ к3 + б ₂ к2+ б ₁ к + а

б ₃ : =INDEX(LINEST(y, x^{1,2,3}), 1)

б ₂ : =INDEX(LINEST(y, x^{1,2,3}), 1, 2)

б ₁ : =INDEX(LINEST(y, x^{1,2,3}), 1, 3)

а: =INDEX(LINEST(y, x^{1,2,3}), 1, 4)

Формуле за полиномске линије тренда вишег степена могу се направити коришћењем истог обрасца.

За наш скуп података, пакети полиномских линија тренда 2. реда боље, па користимо ове формуле:

б ₂ : =INDEX(LINEST(C2:C13, B2:B13^{1,2}), 1)

б ₁ : =INDEX(LINEST(C2:C13, B2:B13^{1,2}), 1, 2)

а: =INDEX(LINEST(C2:C13, B2:B13^{1,2}), 1, 3)

Једначина и формуле линије тренда снаге

Линија тренда снаге у Екцел-у је нацртана на основу ове једноставне једначине:

и = акб

Где је а и б су константе, које се могу израчунати са овим формулама:

а: =EXP(INDEX(LINEST(LN(y), LN(x),,), 1, 2))

б: =INDEX(LINEST(LN(y), LN(x),,), 1)

У нашем случају, следеће формуле раде као посластица :

а: =EXP(INDEX(LINEST(LN(C2:C13), LN(B2:B13),,), 1, 2))

б: =INDEX(LINEST(LN(C2:C13), LN(B2:B13),,), 1)

Екцел једначина линије тренда је погрешна - разлози и исправке

Ако мислите да је Екцел погрешно нацртао линију тренда или је формула линије тренда приказана на вашем графикону погрешна, следеће две тачке могу нешто да одбаце осветлите ситуацију.

Екцел једначина линије тренда је тачна само у дијаграмима распршености

Екцел формуле линије тренда треба да се користе само са КСИ (распршеним) графиконима јер само у овом графикону откуцајте обе и-осе и к-оса су исцртане као нумеричке вредности.

У линијским графиконима, колонским и тракастим графиконима, нумеричке вредности су исцртане само на и-оси. к-оса је представљена линеарним низом (1, 2,3,…) без обзира да ли су ознаке осе бројеви или текст. Када направите линију тренда на овим графиконима, Екцел користи те претпостављене к-вредности у формули линије тренда.

Бројеви се заокружују у Екцел једначини линије тренда

Да би заузео мање простора на графикону, Екцел приказује врло мало значајних цифара у једначини линије тренда. Лепо у смислу дизајна, значајно смањује тачност формуле када ручно унесете к вредности у једначину.

Лако решење је да прикажете више децималних места у једначини. Алтернативно, можете израчунати коефицијенте користећи формулу која одговара вашем типу линије тренда и форматирати ћелије формуле тако да показују довољан број децималних места. За ово, једноставно кликните на дугме Повећај децимални број на картици Почетна у групи Број .

Тако можете направити различите типове линија тренда у Екцел-у и добију њихове једначине. Захваљујем вам се на читању и надам се да се видимо на нашем блогу следеће недеље!