Бұл оқулықта біз Excel бағанының нөмірлерін сәйкес алфавиттік таңбаларға қалай өзгерту керектігін қарастырамыз.

Excel бағдарламасында күрделі формулаларды құру кезінде кейде сізге қажет болуы мүмкін белгілі бір ұяшықтың немесе берілген санның баған әрпі. Мұны екі жолмен жасауға болады: кірістірілген функцияларды немесе теңшелетін функцияны пайдалану арқылы.

Баған нөмірін әліпбиге қалай түрлендіруге болады (бір әріпті бағандар)

Егер жағдайда баған атауы бір әріптен тұрады, А-дан Я-ға дейін, оны мына қарапайым формула арқылы алуға болады:

Мысалы, 10 санын келесіге түрлендіру үшін бағанның әрпі, формуласы:

=CHAR(64 + 10)

Сондай-ақ кейбір ұяшыққа санды енгізуге және формуладағы сол ұяшыққа сілтеме жасауға болады:

=CHAR(64 + A2)

Бұл формула қалай жұмыс істейді:

CHAR функциясы ASCII жиынындағы таңба кодына негізделген таңбаны қайтарады. Ағылшын алфавитінің бас әріптерінің ASCII мәндері 65 (A) - 90 (Z) аралығында. Сонымен, А бас әріптерінің таңба кодын алу үшін 64-ке 1-ді қосасыз; бас әріп B таңба кодын алу үшін 64-ке 2 қосасыз және т.б.

Excel бағанының нөмірін әріпке (кез келген бағанға) қалай түрлендіруге болады

Егер сіз жан-жақты нұсқаны іздесеңіз Excel бағдарламасындағы кез келген баған үшін жұмыс істейтін формула (1 әріп, 2 әріп және 3 әріп), одан кейін сәл күрделірек синтаксисті пайдалану қажет болады:

менA2 бағанының әрпі, формула келесі пішінді алады:

=SUBSTITUTE(ADDRESS(1, A2, 4), "1", "")

Бұл формула қалай жұмыс істейді:

Алдымен сіз қызықтыратын баған нөмірі бар ұяшық мекенжайын құрасыз. Ол үшін ADDRESS функциясына келесі аргументтерді беріңіз:

• 1 жол_саны үшін (жол нөмірі маңызды емес, сондықтан кез келгенін пайдалана аласыз).
• A2 (баған нөмірін қамтитын ұяшық) баған_саны үшін.
• 4, қатысты сілтемені қайтару үшін abs_num аргументі үшін.

Жоғарыда көрсетілген параметрлермен ADDRESS функциясы нәтиже ретінде «A1» мәтіндік жолын қайтарады.

Бізге тек баған әрпі қажет болғандықтан, жол нөмірін SUBSTITUTE функциясының көмегімен алып тастаймыз, ол іздейді. "A1" мәтініндегі "1" (немесе ADDRESS функциясының ішінде қатты кодталған кез келген жол нөмірі) және оны бос жолға ("") ауыстырады.

Теңшелетін функцияны пайдаланып баған нөмірінен баған әрпін алыңыз.

Егер баған нөмірлерін тұрақты негізде әліпбилік таңбаларға түрлендіру қажет болса, пайдаланушы анықтайтын пайдаланушы функциясы (UDF) уақытыңызды айтарлықтай үнемдей алады.

Функцияның коды әдемі. қарапайым және түсінікті:

Мұнда 1-жолдағы ұяшыққа сілтеме жасау үшін Ұяшықтар қасиетін қолданамыз. көрсетілген баған нөмірі және қайтарылатын Мекенжай сипаты aсол ұяшыққа абсолютті сілтемені қамтитын жол (мысалы, $A$1). Содан кейін Бөлу функциясы бөлгіш ретінде $ белгісін пайдаланып қайтарылған жолды жеке элементтерге бөледі және біз баған әрпі болып табылатын элементті (1) қайтарамыз.

Кодты VBA редакторына қойыңыз және жаңа ColumnLetter функциясы пайдалануға дайын. Егжей-тегжейлі нұсқаулықты қараңыз: Excel бағдарламасына VBA кодын енгізу жолы.

Түпкілікті пайдаланушы көзқарасы бойынша функцияның синтаксисі келесідей қарапайым:

Онда col_num - әріпке түрлендіргіңіз келетін баған нөмірі.

Сіздің нақты формулаңыз келесідей болуы мүмкін:

=ColumnLetter(A2)

Және ол қайтарылады алдыңғы мысалда қарастырылған түпнұсқа Excel функцияларымен дәл бірдей нәтижелер:

Белгілі бір ұяшықтың баған әрпін қалай алуға болады

Баған әрпін анықтау үшін белгілі бір ұяшықта баған нөмірін шығарып алу үшін БАҒАН функциясын пайдаланыңыз және сол нөмірге ADDRESS функциясына қызмет етіңіз. Толық формула келесі пішінді алады:

Мысал ретінде баған әрпін табайық C5 ұяшығының:

=SUBSTITUTE(ADDRESS(1, COLUMN(C5), 4), "1", "")

Нәтиже "С" екені анық :)

Ағымдағы бағанның әрпін қалай алуға болады ұяшық

Ағымдағы ұяшықтың әрпін өңдеу үшін формула жоғарыдағы мысалдағыдай дерлік. Жалғыз айырмашылық COLUMN() функциясы болып табыладыформуласы бар ұяшыққа сілтеме жасау үшін бос аргументпен пайдаланылады:

=SUBSTITUTE(ADDRESS(1, COLUMN(), 4), "1", "")

Баған нөмірінен динамикалық диапазон сілтемесін жасау жолы

Алдыңғы мысалдар сізге бірнеше жаңа тақырыптар берді деп үміттенеміз, бірақ сіз практикалық қолданбалар туралы қызықтыруыңыз мүмкін.

Бұл мысалда біз сізге "баған нөмірін әріпке дейін" қалай пайдалану керектігін көрсетеміз. « өмірлік тапсырмаларды шешу формуласы. Атап айтқанда, біз оның санына негізделген белгілі бір бағаннан мәндерді шығаратын динамикалық XLOOKUP формуласын жасаймыз.

Төмендегі үлгілік кестеден сіз берілген жоба үшін пайда көрсеткішін алғыңыз келеді делік (H2) ) және апта (H3).

Тапсырманы орындау үшін мәндерді қайтаратын ауқыммен XLOOKUP қамтамасыз ету керек. Бізде тек баған нөміріне сәйкес келетін апта нөмірі болғандықтан, біз алдымен бұл санды баған әрпіне түрлендіреміз, содан кейін диапазон анықтамасын құрастырамыз.

Ыңғайлы болу үшін бүкіл процесті талдап көрейік. орындауға оңай 3 қадамға айналдырыңыз.

1. Баған нөмірін әріпке түрлендіру

   H3 тіліндегі баған нөмірімен оны әліпбиге өзгерту үшін бұрыннан таныс формуланы пайдаланыңыз. сипаты:

   =SUBSTITUTE(ADDRESS(1, H3, 4), "1", "")

   

   Кеңес. Деректер жиынындағы сан баған нөміріне сәйкес келмесе, қажетті түзетуді жасауды ұмытпаңыз. Мысалы, егер бізде B бағанында 1 апта деректері болса, С бағанында 2 апта деректері жәнеосылайша, дұрыс баған нөмірін алу үшін H3+1 қолданамыз.

2. Ауқым сілтемесін білдіретін жолды құру

   Жол түрінде ауқым сілтемесін құру үшін жоғарыдағы формуламен қайтарылған баған әрпін бірінші әріппен байланыстырасыз. және соңғы жол нөмірлері. Біздің жағдайда деректер ұяшықтары 3-тен 8-ге дейінгі жолдарда орналасқан, сондықтан біз мына формуланы қолданамыз:

   =SUBSTITUTE(ADDRESS(1, H3, 4), "1", "") & "3:" & SUBSTITUTE(ADDRESS(1, H3, 4), "1", "") & "8"

   H3 құрамында "3" бар екенін ескере отырып, ол "C" түрлендіріледі. формуламыз келесі түрлендіруге ұшырайды:

   ="C"&"3:"&"C"&"8"

   Және C3:C8 жолын шығарады.

   

3. Жасау динамикалық диапазон сілтемесі

   Мәтін жолын Excel бағдарламасы түсінетін жарамды сілтемеге түрлендіру үшін жоғарыдағы формуланы ЖАМА функцияға кірістіріңіз де, оны XLOOKUP бағдарламасының 3-аргументіне өткізіңіз:

   =XLOOKUP(H2, E3:E8, INDIRECT(H4), "Not found")

   

   Қайтару ауқымы жолын қамтитын қосымша ұяшықтан құтылу үшін ЖАМА АДРЕСІ формуласын ЖАМА функциясының өзінде орналастыруға болады:

   =XLOOKUP(H2, E3:E8, INDIRECT(SUBSTITUTE(ADDRESS(1, H3, 4), "1", "") & "3:" & SUBSTITUTE(ADDRESS(1, H3, 4), "1", "") & "8"), "Not found")

   

Біздің теңшелетін ColumnLetter функциясы арқылы сіз ықшам әрі талғампаз шешім ала аласыз:

=XLOOKUP(H2, E3:E8, INDIRECT(ColumnLetter(H3) & "3:" & ColumnLetter(H3) & "8"), "Not found")

Бұл Excel бағдарламасында саннан баған әрпін қалай табуға болады. Оқығаныңыз үшін алғыс айтамын және сізді келесі аптада біздің блогта күтемін!

Жүктеп алуға арналған жұмыс кітабы

Excel бағанының нөмірін әріпке - мысалдар (.xlsm файлы)