W tym poradniku znajdziesz szczegółowy opis wszystkich opcji linii trendu dostępnych w Excelu i kiedy z nich korzystać. Dowiesz się również jak wyświetlić równanie linii trendu na wykresie i znaleźć nachylenie linii trendu.

Dodanie linii trendu w Excelu jest bardzo proste. Jedynym prawdziwym wyzwaniem jest wybór typu linii trendu, który najlepiej odpowiada rodzajowi danych, które analizujesz. W tym tutorialu znajdziesz szczegółowy opis wszystkich opcji linii trendu dostępnych w Excelu i kiedy należy z nich korzystać. Jeśli szukasz sposobu na wstawienie linii trendu na wykresie w Excelu, sprawdź wyżej podlinkowany tutorial.

Rodzaje linii trendu w programie Excel

Dodając linię trendu w Excelu, masz do wyboru 6 różnych opcji. Dodatkowo Microsoft Excel umożliwia wyświetlanie równania linii trendu oraz wartości R-squared na wykresie:

• Równanie linii trendu to wzór, który znajduje linię najlepiej pasującą do punktów danych.
• Wartość R-squared mierzy wiarygodność linii trendu - im R2 jest bliższe 1, tym lepiej linia trendu pasuje do danych.

Poniżej znajdziesz krótki opis każdego typu linii trendu wraz z przykładami wykresów.

Linia trendu liniowego

Linię trendu liniowego najlepiej stosować w przypadku liniowych zestawów danych, gdy punkty danych na wykresie przypominają linię prostą. Zazwyczaj linia trendu liniowego opisuje ciągły wzrost lub spadek w czasie.

Na przykład poniższa liniowa linia trendu pokazuje stały wzrost sprzedaży w ciągu 6 miesięcy. A wartość R2 wynosząca 0,9855 wskazuje na całkiem dobre dopasowanie oszacowanych wartości linii trendu do rzeczywistych danych.

Wykładnicza linia trendu

Wykładnicza linia trendu jest linią zakrzywioną, która ilustruje wzrost lub spadek wartości danych w rosnącym tempie, dlatego linia ta jest zwykle bardziej zakrzywiona po jednej stronie. Ten typ linii trendu jest często stosowany w nauce, na przykład do wizualizacji wzrostu populacji ludzkiej lub spadku populacji dzikich zwierząt.

Należy pamiętać, że wykładnicza linia trendu nie może być utworzona dla danych, które zawierają zera lub wartości ujemne.

Dobrym przykładem krzywej wykładniczej jest zanik całej populacji dzikich tygrysów na Ziemi.

Logarytmiczna linia trendu

Logarytmiczna linia najlepszego dopasowania jest zwykle używana do wykreślania danych, które szybko rosną lub maleją, a następnie wyrównują się. Może ona zawierać zarówno wartości dodatnie, jak i ujemne.

Przykładem logarytmicznej linii trendu może być wskaźnik inflacji, który najpierw jest coraz wyższy, ale po pewnym czasie stabilizuje się.

Wielomianowa linia trendu

Wielomianowa krzywoliniowa linia trendu dobrze sprawdza się w przypadku dużych zbiorów danych z oscylującymi wartościami, które mają więcej niż jeden wzrost i spadek.

Ogólnie wielomian klasyfikuje się według stopnia największego wykładnika. Stopień linii trendu wielomianu można również określić na podstawie liczby zagięć na wykresie. Zazwyczaj linia trendu wielomianu kwadratowego ma jedno zagięcie (górkę lub dolinę), wielomianu sześciennego - 1 lub 2 zagięcia, a wielomianu kwartalnego - do 3 zagięć.

Dodając wielomianową linię trendu do wykresu w Excelu, określasz stopień wpisując odpowiednią liczbę w polu Zamówienie pole na Format Linia trendu które domyślnie ma wartość 2:

Na przykład trend wielomianu kwadratowego jest widoczny na poniższym wykresie, który przedstawia zależność między zyskiem a liczbą lat obecności produktu na rynku: wzrost na początku, szczyt w środku i spadek w pobliżu końca.

Linia trendu mocy

Linia trendu mocy jest bardzo podobna do krzywej wykładniczej, tylko ma bardziej symetryczny łuk. Jest powszechnie stosowana do wykreślania pomiarów, które rosną w określonym tempie.

Do wykresu Excela, który zawiera wartości zerowe lub ujemne, nie można dodać linii trendu potęgowego.

Jako przykład narysujmy linię trendu potęgowego do wizualizacji szybkości reakcji chemicznej. Zwróćmy uwagę na wartość R-squared równą 0,9918, co oznacza, że nasza linia trendu pasuje do danych niemal idealnie.

Średnia krocząca linia trendu

Gdy punkty danych na wykresie mają wiele wzlotów i upadków, średnia krocząca linii trendu może wygładzić skrajne wahania wartości danych, aby wyraźniej pokazać wzór. W tym celu Excel oblicza średnią kroczącą z liczby okresów określonych przez użytkownika (domyślnie 2) i umieszcza te średnie wartości jako punkty na linii. Im wyższa jest średnia krocząca, tym bardziej jest ona widoczna. Okres wartość, tym gładsza linia.

Dobrym praktycznym przykładem jest wykorzystanie linii trendu średniej ruchomej do ujawnienia wahań ceny akcji, które w innym przypadku byłyby trudne do zaobserwowania.

Więcej informacji znajdziesz w: Jak dodać linię trendu średniej ruchomej do wykresu w Excelu.

Równania i formuły linii trendu w programie Excel

W tej części opisano równania, których Excel używa dla różnych typów linii trendu. Nie musisz budować tych formuł ręcznie, wystarczy, że powiesz Excelowi, aby wyświetlił równanie linii trendu na wykresie.

Omówimy również wzór na znalezienie nachylenia linii trendu i innych współczynników. Wzory zakładają, że masz 2 zestawy zmiennych: zmienna niezależna x oraz zmienna zależna y W swoich arkuszach możesz użyć tych wzorów, aby uzyskać przewidywane y dla dowolnych wartości x .

Dla zachowania spójności, we wszystkich przykładach będziemy używać tego samego zestawu danych z nieznacznie zmieniającymi się wartościami. Należy jednak pamiętać, że służy on tylko do celów demonstracyjnych. W swoich rzeczywistych arkuszach powinieneś wybrać typ linii trendu odpowiadający typowi danych.

Ważna uwaga! Formuły linii trendu powinny być używane tylko z Wykresy rozrzutu XY ponieważ tylko ten wykres przedstawia oba x oraz y osi jako wartości liczbowe. Więcej informacji można znaleźć na stronie Dlaczego równanie linii trendu w Excelu może być błędne.

Równanie linii trendu liniowego i wzory

W równaniu liniowej linii trendu wykorzystuje się metody najmniejszych kwadratów do poszukiwania nachylenie oraz przechwycenie współczynniki takie, że:

Gdzie:

• b to nachylenie linii trendu.
• a to punkt przecięcia y która jest oczekiwaną wartością średnią y gdy wszyscy x zmienne są równe 0. Na wykresie jest to punkt, w którym linia trendu przecina y oś.

W przypadku regresji liniowej Microsoft Excel udostępnia specjalne funkcje pozwalające uzyskać współczynniki nachylenia i przechwytu.

Nachylenie linii trendu

b: =SLOPE(y,x)

Punkt przecięcia Y

a: =INTERCEPT(y,x)

Zakładając, że x wynosi B2:B13, a zakres y zakres to C2:C13, rzeczywiste wzory są następujące:

=SLOPE(C2:C13, B2:B13)

=INTERCEPT(C2:C13,B2:B13)

Te same wyniki można uzyskać stosując funkcję LINEST jako formuła macierzowa . W tym celu wybierz 2 sąsiednie komórki w tym samym wierszu, wprowadź formułę i naciśnij Ctrl + Shift + Enter, aby ją zakończyć:

=LINEST(C2:C13,B2:B13)

Jak widać na poniższym zrzucie ekranu, współczynniki nachylenia i przechwycenia zwracane przez formuły są idealnie zgodne ze współczynnikami w równaniu liniowej linii trendu wyświetlanym na wykresie, tylko te ostatnie są zaokrąglone do 4 miejsc po przecinku:

Równanie i wzory wykładniczej linii trendu

W przypadku wykładniczej linii trendu Excel stosuje następujące równanie:

Gdzie a oraz b to obliczone współczynniki, a e to stała matematyczna e (podstawa logarytmu naturalnego).

Współczynniki można obliczyć za pomocą tych ogólnych wzorów:

a: =EXP(INDEX(LINEST(LN(y), x), 1, 2))

b: =INDEX(LINEST(LN(y), x), 1)

Dla naszego przykładowego zestawu danych formuły przyjmują następujący kształt:

a: =EXP(INDEX(LINEST(LN(C2:C13), B2:B13), 1, 2))

b: =INDEX(LINEST(LN(C2:C13), B2:B13), 1)

Równanie i wzory na logarytmiczną linię trendu

Oto równanie logarytmicznej linii trendu w Excelu:

Gdzie a oraz b są stałymi i ln jest funkcją logarytmu naturalnego.

Aby uzyskać stałe, użyj tych ogólnych wzorów, które różnią się tylko ostatnim argumentem:

a: =INDEX(LINEST(y, LN(x)), 1)

b: =INDEX(LINEST(y, LN(x)), 1, 2)

Dla naszego przykładowego zbioru danych wykorzystujemy te:

a: =INDEX(LINEST(C2:C13, LN(B2:B13)), 1)

b: =INDEX(LINEST(C2:C13, LN(B2:B13)), 1, 2)

Równanie i wzory wielomianowej linii trendu

Aby opracować wielomianową linię trendu, Excel używa tego równania:

Gdzie b ₁ ... b ₆ oraz a są stałymi.

W zależności od stopnia twojej wielomianowej linii trendu, użyj jednego z następujących zestawów wzorów, aby uzyskać stałe.

Kwadratowa (2. rzędu) wielomianowa linia trendu

Równanie: y = b ₂ x2+ b ₁ x + a

b ₂ : =INDEX(LINEST(y, x^{1,2}), 1)

b ₁ : =INDEX(LINEST(y, x^{1,2}), 1, 2)

a: =INDEX(LINEST(y, x^{1,2}), 1, 3)

Linia trendu z wielomianu sześciennego (trzeciego rzędu)

Równanie: y = b ₃ x3 + b ₂ x2+ b ₁ x + a

b ₃ : =INDEX(LINEST(y, x^{1,2,3}), 1)

b ₂ : =INDEX(LINEST(y, x^{1,2,3}), 1, 2)

b ₁ : =INDEX(LINEST(y, x^{1,2,3}), 1, 3)

a: =INDEX(LINEST(y, x^{1,2,3}), 1, 4)

Wzory na wielomianowe linie trendu wyższego stopnia można zbudować korzystając z tego samego schematu.

Dla naszego zestawu danych, wielomianowa linia trendu 2. rzędu pasuje lepiej, więc używamy tych wzorów:

b ₂ : =INDEX(LINEST(C2:C13, B2:B13^{1,2}), 1)

b ₁ : =INDEX(LINEST(C2:C13, B2:B13^{1,2}), 1, 2)

a: =INDEX(LINEST(C2:C13, B2:B13^{1,2}), 1, 3)

Równanie i wzory linii trendu mocy

Linia trendu siły w Excelu jest rysowana na podstawie tego prostego równania:

Gdzie a oraz b są stałymi, które można obliczyć za pomocą tych wzorów:

a: =EXP(INDEX(LINEST(LN(y), LN(x),), 1, 2))

b: =INDEX(LINEST(LN(y), LN(x),,), 1)

W naszym przypadku sprawdzają się następujące formuły:

a: =EXP(INDEX(LINEST(LN(C2:C13), LN(B2:B13),,), 1, 2))

b: =INDEX(LINEST(LN(C2:C13), LN(B2:B13),), 1)

Równanie linii trendu w Excelu jest błędne - przyczyny i poprawki

Jeśli uważasz, że Excel nieprawidłowo narysował linię trendu lub formuła linii trendu wyświetlana na Twoim wykresie jest błędna, to dwa poniższe punkty mogą rzucić nieco światła na sytuację.

Równanie linii trendu w programie Excel jest poprawne tylko w przypadku wykresów rozproszonych

Formuły linii trendu w Excelu powinny być stosowane tylko w przypadku wykresów XY (scatter), ponieważ tylko w tym typie wykresu zarówno oś y, jak i oś x są wykreślane jako wartości liczbowe.

Na wykresach liniowych, kolumnowych i słupkowych wartości liczbowe są wykreślane tylko na osi y. Oś x jest reprezentowana przez szereg liniowy (1, 2, 3,...) niezależnie od tego, czy etykiety osi są liczbami, czy tekstem. Kiedy tworzysz linię trendu na tych wykresach, Excel używa tych założonych wartości x w formule linii trendu.

Liczby są zaokrąglone w równaniu linii trendu w Excelu

Aby zajmować mniej miejsca na wykresie, Excel wyświetla bardzo mało cyfr znaczących w równaniu linii trendu. Ładne pod względem wyglądu, znacznie zmniejsza dokładność formuły, gdy ręcznie podajesz wartości x w równaniu.

Łatwym rozwiązaniem jest pokazanie większej liczby miejsc po przecinku w równaniu. Alternatywnie można obliczyć współczynniki za pomocą formuły odpowiadającej typowi linii trendu i sformatować komórki formuły tak, aby pokazały wystarczającą liczbę miejsc po przecinku. W tym celu wystarczy kliknąć przycisk Zwiększanie liczby dziesiętnej przycisk na Strona główna zakładka w Numer grupa.

W ten sposób można stworzyć w Excelu różne typy linii trendu i uzyskać ich równania. Dziękuję za przeczytanie i mam nadzieję, że zobaczymy się na naszym blogu za tydzień!