Bu dərslikdə siz Excel-də mövcud olan bütün trend xətti seçimlərinin ətraflı təsvirini və onlardan nə vaxt istifadə edəcəyinizi tapa bilərsiniz. Siz həmçinin qrafikdə trend xətti tənliyini necə göstərməyi və trend xəttinin yamacını tapmağı öyrənəcəksiniz.

Excel-də trend xətti əlavə etmək çox asandır. Yeganə real problem təhlil etdiyiniz məlumat növünə ən yaxşı uyğun gələn trend xəttinin növünü seçməkdir. Bu dərslikdə siz Excel-də mövcud olan bütün trend xətti seçimlərinin ətraflı təsvirini və onlardan nə vaxt istifadə edəcəyinizi tapa bilərsiniz. Excel diaqramına trend xəttini necə daxil edəcəyinizi axtarırsınızsa, lütfən, yuxarıdakı əlaqəli təlimata baxın.

Excel trend xətti növləri

Excel-də trend xətti əlavə edərkən , seçmək üçün 6 fərqli seçiminiz var. Əlavə olaraq, Microsoft Excel trend xətti tənliyini və R-kvadrat dəyərini qrafikdə göstərməyə imkan verir:

• Trend xətti tənliyi məlumat nöqtələrinə ən yaxşı uyğun gələn xətti tapan düsturdur.
• R-kvadrat dəyəri trend xəttinin etibarlılığını ölçür - R2 1-ə nə qədər yaxındırsa, trend xətti məlumatlara bir o qədər yaxşı uyğun gəlir.

Aşağıda siz qrafik nümunələri ilə hər bir trend xətti növünün qısa təsvirini tapa bilərsiniz.

Xətti trend xətti

Xətti trend xəttini seçmək daha yaxşıdır. diaqramdakı məlumat nöqtələri düz xəttə bənzədikdə xətti məlumat dəstləri ilə istifadə olunur. Tipik olaraq, xətti trend xətti davamlı yüksəliş və ya enişi təsvir edirzamanla.

Məsələn, aşağıdakı xətti trend xətti 6 ay ərzində satışların sabit artımını göstərir. Və 0,9855 R2 dəyəri təxmin edilən trend xətti dəyərlərinin faktiki məlumatlara olduqca yaxşı uyğunluğunu göstərir.

Eksponensial trend xətti

Eksponensial trend xətti artan sürətlə məlumat dəyərlərinin yüksəlməsini və ya azalmasını göstərən əyri xəttdir, ona görə də xətt adətən bir tərəfdən daha əyri olur. Bu tendensiya növü tez-tez elmlərdə istifadə olunur, məsələn, insan populyasiyasının artımını və ya vəhşi təbiət populyasiyalarının azalmasını vizuallaşdırmaq üçün.

Nəzərə alın ki, sıfır və ya mənfi dəyərlərdən ibarət məlumatlar üçün eksponensial trend xətti yaradıla bilməz.

Eksponensial əyrinin yaxşı nümunəsi yer üzündəki bütün vəhşi pələng populyasiyasının tənəzzülüdür.

Loqarifmik trend xətti

Loqarifmik ən uyğun xətt ümumiyyətlə sürətlə artan və ya azalan, sonra isə səviyyəni kəsən məlumatları çəkmək üçün istifadə olunur. O, həm müsbət, həm də mənfi dəyərləri əhatə edə bilər.

Loqarifmik trend xəttinə misal olaraq əvvəlcə yüksələn, lakin bir müddət sonra sabitləşən inflyasiya dərəcəsi ola bilər.

Çoxhədli trend xətti

Çoxhədli əyrixətti trend xətti birdən çox yüksəliş və enişi olan salınan dəyərləri olan böyük məlumat dəstləri üçün yaxşı işləyir.

Ümumiyyətlə, polinom aşağıdakılara görə təsnif edilir. ən böyük eksponentin dərəcəsi. Çoxhədli trend xəttinin dərəcəsi ola bilərhəm də qrafikdəki əyilmələrin sayı ilə müəyyən edilir. Tipik olaraq, kvadrat çoxhədli meyl xəttinin bir əyilmə (təpə və ya vadi), kub polinomunda 1 və ya 2 əyilmə, dörddəbir çoxhədlinin isə 3 əyilmə var.

Excel diaqramında polinom trend xətti əlavə edərkən, siz defolt olaraq 2 olan Trend xəttini formatla panelindəki Sifariş xanasına müvafiq rəqəmi yazaraq dərəcəni təyin edirsiniz:

Məsələn, kvadrat polinom tendensiyası mənfəətlə məhsulun bazarda olduğu illərin sayı arasındakı əlaqəni göstərən aşağıdakı qrafikdə aydın görünür: başlanğıcda yüksəliş, ortada pik və sona yaxın eniş.

Güc trend xətti

Güc meyl xətti eksponensial əyriyə çox bənzəyir, yalnız onun daha simmetrik qövsü var. O, adətən müəyyən sürətlə artan ölçmələrin qrafikini tərtib etmək üçün istifadə olunur.

Sıfır və ya mənfi dəyərlərdən ibarət Excel cədvəlinə güc trend xətti əlavə edilə bilməz.

Nümunə olaraq, bir rəqəm çəkək. kimyəvi reaksiya sürətini görüntüləmək üçün güc trend xətti. 0.9918 R-kvadrat dəyərinə diqqət yetirin, bu o deməkdir ki, trend xəttimiz məlumatlara demək olar ki, mükəmməl uyğun gəlir.

Hərəkətli orta trend xətti

Qrafikinizdəki data nöqtələrində çoxlu eniş və enişlər olduqda, hərəkət edən orta trend xətti nümunəni daha aydın göstərmək üçün data dəyərlərindəki həddindən artıq dalğalanmaları hamarlaya bilər. Bunun üçün Excel hesablayırtəyin etdiyiniz dövrlərin sayının hərəkətli ortalaması (standart olaraq 2) və həmin orta dəyərləri sətirdə xal kimi qoyur. Dövr dəyəri nə qədər yüksək olarsa, xətt bir o qədər hamar olar.

Yaxşı praktiki nümunə səhm qiymətindəki dəyişkənlikləri aşkar etmək üçün hərəkətli orta trend xəttindən istifadə etməkdir, əks halda müşahidə etmək çətin olacaq.

Ətraflı məlumat üçün baxın: Excel diaqramına hərəkətli orta trend xəttini necə əlavə etmək olar.

Excel trend xətti tənlikləri və düsturları

Bu bölmə Excel-in istifadə etdiyi tənlikləri təsvir edir. müxtəlif trend xətti növləri üçün. Siz bu düsturları əl ilə qurmaq məcburiyyətində deyilsiniz, sadəcə olaraq Excel-ə deyin ki, trend xətti tənliyini diaqramda göstərsin.

Həmçinin, trend xəttinin yamacını və digər əmsalları tapmaq üçün formulu müzakirə edəcəyik. Düsturlar sizin 2 dəyişən dəstinizin olduğunu güman edir: müstəqil dəyişən x və asılı dəyişən y . İş vərəqlərinizdə siz x -nin hər hansı verilmiş qiymətləri üçün proqnozlaşdırılan y dəyərlərini əldə etmək üçün bu düsturlardan istifadə edə bilərsiniz.

Uyumluluq üçün biz eyni datadan istifadə edəcəyik. bütün nümunələr üçün bir qədər dəyişən dəyərlərlə təyin edin. Bununla belə, bunun yalnız nümayiş məqsədləri üçün olduğunu unutmayın. Həqiqi iş vərəqlərində məlumat tipinizə uyğun trend xətti növünü seçməlisiniz.

Vacib qeyd! Trend xətti düsturları yalnız XY səpələnmə diaqramları ilə istifadə edilməlidir, çünki yalnız budiaqram həm x , həm də y oxlarını ədədi dəyərlər kimi göstərir. Ətraflı məlumat üçün Excel trend xətti tənliyinin niyə yanlış ola biləcəyinə baxın.

Xətti trend xətti tənliyi və düsturları

Xətti trend xətti tənliyi maili axtarmaq üçün ən kiçik kvadratlar metodlarından istifadə edir. və kəsişmə əmsalları belə ki:

y = bx + a

Burada:

• b mail trend xəttinin.
• a bütün x y -nin gözlənilən orta dəyəri olan y-kəsici -dur. 2> dəyişənləri 0-a bərabərdir. Qrafikdə bu, trend xəttinin y oxunu kəsdiyi nöqtədir.

Xətti reqressiya üçün Microsoft Excel xüsusi funksiyaları təmin edir. yamac və kəsişmə əmsalları.

Trend xəttinin mailliyi

b: =SLOPE(y,x)

Y-kəsici

a: =INTERCEPT(y,x)

x diapazonunun B2:B13 və y diapazonunun C2:C13 olduğunu fərz etsək, real həyat düsturları aşağıdakı kimi olur:

=SLOPE(C2:C13, B2:B13)

=INTERCEPT(C2:C13,B2:B13)

Eyni nəticələrə LINEST funksiyasından massiv düsturu kimi istifadə etməklə nail olmaq olar. Bunun üçün eyni cərgədə 2 bitişik xana seçin, düsturu daxil edin və tamamlamaq üçün Ctrl + Shift + Enter düymələrini basın:

=LINEST(C2:C13,B2:B13)

Aşağıdakı ekran görüntüsündə göstərildiyi kimi, yamac və kəsişmə düsturlarla qaytarılan əmsallar diaqramda göstərilən xətti trend xətti tənliyindəki əmsallara mükəmməl uyğun gəlir, yalnız sonuncular 4 onluq yerlərinə yuvarlaqlaşdırılır:

Eksponensial trend xətti tənliyi və düsturları

Eksponensial trend xətti üçün Excel aşağıdakı tənlikdən istifadə edir:

y = aebx

Burada a və b hesablanmış əmsallardır və e riyazi sabitdir e (təbii loqarifmin əsasıdır).

Əmsalları bu ümumi düsturlardan istifadə etməklə hesablamaq olar:

a: =EXP(INDEX(LINEST(LN(y), x), 1, 2))

b: =INDEX(LINEST(LN(y), x), 1)

Nümunə məlumat dəstimiz üçün düsturlar aşağıdakı formanı alır:

a: =EXP(INDEX(LINEST(LN(C2:C13), B2:B13), 1, 2))

b: =INDEX(LINEST(LN(C2:C13), B2:B13), 1)

Loqarifmik trend xətti tənliyi və düsturları

Budur Excel-də loqarifmik trend xətti tənliyi:

y = a*ln(x)+b

Burada a və b sabitlərdir və ln təbii loqarifm funksiyasıdır.

Sabitləri əldə etmək üçün yalnız sonuncu arqumentdə fərqlənən bu ümumi düsturlardan istifadə edin:

a: =INDEX(LINEST(y, LN(x)), 1)

b: =INDEX(LINEST(y, LN(x)), 1, 2)

Nümunə məlumat dəstimiz üçün bunlardan istifadə edirik:

a: =INDEX(LINEST(C2:C13, LN(B2:B13)), 1)

b: =INDEX(LINEST(C2:C13, LN(B2:B13)), 1, 2)

Polinom trend xətti tənliyi və düsturları

Çoxhədli trend xəttini işləmək üçün Excel bu tənlikdən istifadə edir:

y = b ₆ x6 + … + b ₂ x2 + b ₁ x + a

Burada b ₁ … b ₆ və a sabitdir.

Çoxhədli trend xəttinizin dərəcəsindən asılı olaraq, aşağıdakı düstur dəstlərindən birini istifadə edin sabitləri almaq üçün.

Kvadrat (2-ci tərtib) çoxhədli trend xətti

Tənlik: y = b ₂ x2+ b ₁ x + a

b ₂ : =INDEX(LINEST(y, x^{1,2}), 1)

b ₁ : =INDEX(LINEST(y, x^{1,2}), 1, 2)

a: =INDEX(LINEST(y, x^{1,2}), 1, 3)

Kubik (3-cü dərəcəli) polinom trend xətti

Tənlik: y = b ₃ x3 + b ₂ x2+ b ₁ x + a

b ₃ : =INDEX(LINEST(y, x^{1,2,3}), 1)

b ₂ : =INDEX(LINEST(y, x^{1,2,3}), 1, 2)

b ₁ : =INDEX(LINEST(y, x^{1,2,3}), 1, 3)

a: =INDEX(LINEST(y, x^{1,2,3}), 1, 4)

Daha yüksək dərəcəli çoxhədli trend xətləri üçün düsturlar eyni nümunədən istifadə etməklə qurula bilər.

Bizim məlumat dəstimiz üçün 2-ci dərəcəli çoxhədli trend xətti dəstləri daha yaxşı, buna görə də biz bu düsturlardan istifadə edirik:

b ₂ : =INDEX(LINEST(C2:C13, B2:B13^{1,2}), 1)

b ₁ : =INDEX(LINEST(C2:C13, B2:B13^{1,2}), 1, 2)

a: =INDEX(LINEST(C2:C13, B2:B13^{1,2}), 1, 3)

Güc trend xətti tənliyi və düsturları

Excel-də güc trend xətti bu sadə tənlik əsasında çəkilir:

y = axb

Burada a və b bu düsturlarla hesablana bilən sabitlərdir:

a: =EXP(INDEX(LINEST(LN(y), LN(x),,), 1, 2))

b: =INDEX(LINEST(LN(y), LN(x),,), 1)

Bizim vəziyyətimizdə aşağıdakı düsturlar bir iş görür. :

a: =EXP(INDEX(LINEST(LN(C2:C13), LN(B2:B13),,), 1, 2))

b: =INDEX(LINEST(LN(C2:C13), LN(B2:B13),,), 1)

Excel trend xətti tənliyi səhvdir - səbəblər və düzəlişlər

Excel-in trend xəttini səhv çəkdiyini düşünürsünüzsə və ya diaqramınızda göstərilən trend xətti düsturu səhvdirsə, aşağıdakı iki nöqtə bir qədər zərər verə bilər vəziyyətə işıq salır.

Excel trend xətti tənliyi yalnız səpələnmə diaqramlarında düzgündür

Excel trend xətti düsturları yalnız XY (səpələnmə) qrafikləri ilə istifadə edilməlidir, çünki yalnız bu diaqramda həm y oxunu yazın. və x oxu rəqəmli qiymətlər kimi çəkilir.

Xətt diaqramlarında, sütun və qrafa qrafiklərində ədədi qiymətlər yalnız y oxu üzərində qurulur. X oxu xətti sıra ilə təmsil olunur (1, 2,3,…) ox etiketlərinin rəqəm və ya mətn olmasından asılı olmayaraq. Bu diaqramlarda trend xətti yaratdığınız zaman Excel trend xətti düsturunda nəzərdə tutulan x-dəyərlərindən istifadə edir.

Nömrələr Excel trend xətti tənliyində yuvarlaqlaşdırılıb

Qrafikdə daha az yer tutmaq üçün Excel göstərir trend xətti tənliyində çox az əhəmiyyətli rəqəmlər. Dizayn baxımından gözəldir, tənlikdə x dəyərlərini əl ilə təmin etdiyiniz zaman düsturun dəqiqliyini əhəmiyyətli dərəcədə azaldır.

Asan bir həll tənlikdə daha çox onluq yer göstərməkdir. Alternativ olaraq, trend xətti tipinizə uyğun düsturdan istifadə edərək əmsalları hesablaya və düstur xanalarını kifayət qədər onluq yerləri göstərəcək şəkildə formatlaya bilərsiniz. Bunun üçün sadəcə olaraq Nömrə qrupunda Ev nişanında Ondalığı Artır düyməsini klikləyin.

Fərqli trend xətti növlərini belə yarada bilərsiniz. Excel-də və onların tənliklərini əldə edin. Oxuduğunuz üçün sizə təşəkkür edirəm və sizi gələn həftə bloqumuzda görməyə ümid edirəm!