ಪರಿವಿಡಿ
ಈ ಟ್ಯುಟೋರಿಯಲ್ ನಲ್ಲಿ, Excel ನಲ್ಲಿ ಲಭ್ಯವಿರುವ ಎಲ್ಲಾ ಟ್ರೆಂಡ್‌ಲೈನ್ ಆಯ್ಕೆಗಳ ವಿವರವಾದ ವಿವರಣೆಯನ್ನು ನೀವು ಕಾಣಬಹುದು ಮತ್ತು ಅವುಗಳನ್ನು ಯಾವಾಗ ಬಳಸಬೇಕು. ಚಾರ್ಟ್‌ನಲ್ಲಿ ಟ್ರೆಂಡ್‌ಲೈನ್ ಸಮೀಕರಣವನ್ನು ಹೇಗೆ ಪ್ರದರ್ಶಿಸಬೇಕು ಮತ್ತು ಟ್ರೆಂಡ್‌ಲೈನ್‌ನ ಇಳಿಜಾರನ್ನು ಕಂಡುಹಿಡಿಯುವುದು ಹೇಗೆ ಎಂಬುದನ್ನು ಸಹ ನೀವು ಕಲಿಯುವಿರಿ.
ಎಕ್ಸೆಲ್‌ನಲ್ಲಿ ಟ್ರೆಂಡ್‌ಲೈನ್ ಅನ್ನು ಸೇರಿಸುವುದು ತುಂಬಾ ಸುಲಭ. ನೀವು ವಿಶ್ಲೇಷಿಸುತ್ತಿರುವ ಡೇಟಾದ ಪ್ರಕಾರಕ್ಕೆ ಉತ್ತಮವಾಗಿ ಅನುರೂಪವಾಗಿರುವ ಟ್ರೆಂಡ್‌ಲೈನ್ ಪ್ರಕಾರವನ್ನು ಆಯ್ಕೆ ಮಾಡುವುದು ನಿಜವಾದ ಸವಾಲು. ಈ ಟ್ಯುಟೋರಿಯಲ್ ನಲ್ಲಿ, Excel ನಲ್ಲಿ ಲಭ್ಯವಿರುವ ಎಲ್ಲಾ ಟ್ರೆಂಡ್‌ಲೈನ್ ಆಯ್ಕೆಗಳ ವಿವರವಾದ ವಿವರಣೆಯನ್ನು ನೀವು ಕಾಣಬಹುದು ಮತ್ತು ಅವುಗಳನ್ನು ಯಾವಾಗ ಬಳಸಬೇಕು. ಎಕ್ಸೆಲ್ ಚಾರ್ಟ್‌ನಲ್ಲಿ ಟ್ರೆಂಡ್‌ಲೈನ್ ಅನ್ನು ಹೇಗೆ ಸೇರಿಸುವುದು ಎಂದು ನೀವು ಹುಡುಕುತ್ತಿದ್ದರೆ, ದಯವಿಟ್ಟು ಮೇಲಿನ ಲಿಂಕ್ ಮಾಡಲಾದ ಟ್ಯುಟೋರಿಯಲ್ ಅನ್ನು ಪರಿಶೀಲಿಸಿ.
ಎಕ್ಸೆಲ್ ಟ್ರೆಂಡ್‌ಲೈನ್ ಪ್ರಕಾರಗಳು
ಎಕ್ಸೆಲ್‌ನಲ್ಲಿ ಟ್ರೆಂಡ್‌ಲೈನ್ ಸೇರಿಸುವಾಗ , ನೀವು ಆಯ್ಕೆ ಮಾಡಲು 6 ವಿಭಿನ್ನ ಆಯ್ಕೆಗಳನ್ನು ಹೊಂದಿರುವಿರಿ. ಹೆಚ್ಚುವರಿಯಾಗಿ, ಮೈಕ್ರೋಸಾಫ್ಟ್ ಎಕ್ಸೆಲ್ ಚಾರ್ಟ್‌ನಲ್ಲಿ ಟ್ರೆಂಡ್‌ಲೈನ್ ಸಮೀಕರಣ ಮತ್ತು R-ವರ್ಗದ ಮೌಲ್ಯವನ್ನು ಪ್ರದರ್ಶಿಸಲು ಅನುಮತಿಸುತ್ತದೆ:
- ಟ್ರೆಂಡ್‌ಲೈನ್ ಸಮೀಕರಣ ಎಂಬುದು ಡೇಟಾ ಪಾಯಿಂಟ್‌ಗಳಿಗೆ ಉತ್ತಮವಾಗಿ ಹೊಂದಿಕೊಳ್ಳುವ ರೇಖೆಯನ್ನು ಕಂಡುಹಿಡಿಯುವ ಒಂದು ಸೂತ್ರವಾಗಿದೆ.
- R-ಸ್ಕ್ವೇರ್ ಮೌಲ್ಯ ಟ್ರೆಂಡ್‌ಲೈನ್ ವಿಶ್ವಾಸಾರ್ಹತೆಯನ್ನು ಅಳೆಯುತ್ತದೆ - R2 1 ಗೆ ಹತ್ತಿರದಲ್ಲಿದೆ, ಉತ್ತಮವಾದ ಪ್ರವೃತ್ತಿಯು ಡೇಟಾಗೆ ಸರಿಹೊಂದುತ್ತದೆ.
ಕೆಳಗೆ, ಚಾರ್ಟ್ ಉದಾಹರಣೆಗಳೊಂದಿಗೆ ಪ್ರತಿ ಟ್ರೆಂಡ್‌ಲೈನ್ ಪ್ರಕಾರದ ಸಂಕ್ಷಿಪ್ತ ವಿವರಣೆಯನ್ನು ನೀವು ಕಾಣಬಹುದು.
ಲೀನಿಯರ್ ಟ್ರೆಂಡ್‌ಲೈನ್
ಲೀನಿಯರ್ ಟ್ರೆಂಡ್ ಲೈನ್ ಉತ್ತಮವಾಗಿದೆ ಚಾರ್ಟ್‌ನಲ್ಲಿನ ಡೇಟಾ ಬಿಂದುಗಳು ನೇರ ರೇಖೆಯನ್ನು ಹೋಲುವ ಸಂದರ್ಭದಲ್ಲಿ ರೇಖೀಯ ಡೇಟಾ ಸೆಟ್‌ಗಳೊಂದಿಗೆ ಬಳಸಲಾಗುತ್ತದೆ. ವಿಶಿಷ್ಟವಾಗಿ, ರೇಖೀಯ ಪ್ರವೃತ್ತಿಯು ನಿರಂತರ ಏರಿಕೆ ಅಥವಾ ಕುಸಿತವನ್ನು ವಿವರಿಸುತ್ತದೆಕಾಲಾನಂತರದಲ್ಲಿ.
ಉದಾಹರಣೆಗೆ, ಕೆಳಗಿನ ರೇಖೀಯ ಟ್ರೆಂಡ್‌ಲೈನ್ 6 ತಿಂಗಳುಗಳಲ್ಲಿ ಮಾರಾಟದಲ್ಲಿ ಸ್ಥಿರವಾದ ಹೆಚ್ಚಳವನ್ನು ತೋರಿಸುತ್ತದೆ. ಮತ್ತು 0.9855 ರ R2 ಮೌಲ್ಯವು ನಿಜವಾದ ಡೇಟಾಗೆ ಅಂದಾಜು ಟ್ರೆಂಡ್‌ಲೈನ್ ಮೌಲ್ಯಗಳ ಉತ್ತಮ ಫಿಟ್ ಅನ್ನು ಸೂಚಿಸುತ್ತದೆ. 
ಘಾತೀಯ ಟ್ರೆಂಡ್‌ಲೈನ್
ಘಾತೀಯ ಟ್ರೆಂಡ್‌ಲೈನ್ ಒಂದು ಬಾಗಿದ ರೇಖೆಯಾಗಿದ್ದು ಅದು ಹೆಚ್ಚುತ್ತಿರುವ ದರದಲ್ಲಿ ಡೇಟಾ ಮೌಲ್ಯಗಳಲ್ಲಿನ ಏರಿಕೆ ಅಥವಾ ಕುಸಿತವನ್ನು ವಿವರಿಸುತ್ತದೆ, ಆದ್ದರಿಂದ ರೇಖೆಯು ಸಾಮಾನ್ಯವಾಗಿ ಒಂದು ಬದಿಯಲ್ಲಿ ಹೆಚ್ಚು ವಕ್ರವಾಗಿರುತ್ತದೆ. ಈ ಟ್ರೆಂಡ್‌ಲೈನ್ ಪ್ರಕಾರವನ್ನು ವಿಜ್ಞಾನದಲ್ಲಿ ಹೆಚ್ಚಾಗಿ ಬಳಸಲಾಗುತ್ತದೆ, ಉದಾಹರಣೆಗೆ ಮಾನವ ಜನಸಂಖ್ಯೆಯ ಬೆಳವಣಿಗೆ ಅಥವಾ ವನ್ಯಜೀವಿ ಜನಸಂಖ್ಯೆಯಲ್ಲಿನ ಕುಸಿತವನ್ನು ದೃಶ್ಯೀಕರಿಸಲು.
ದಯವಿಟ್ಟು ಗಮನಿಸಿ ಸೊನ್ನೆಗಳು ಅಥವಾ ಋಣಾತ್ಮಕ ಮೌಲ್ಯಗಳನ್ನು ಹೊಂದಿರುವ ಡೇಟಾಕ್ಕಾಗಿ ಘಾತೀಯ ಪ್ರವೃತ್ತಿಯನ್ನು ರಚಿಸಲಾಗುವುದಿಲ್ಲ.
ಘಾತೀಯ ವಕ್ರರೇಖೆಯ ಒಂದು ಉತ್ತಮ ಉದಾಹರಣೆಯೆಂದರೆ ಭೂಮಿಯ ಮೇಲಿನ ಸಂಪೂರ್ಣ ಕಾಡು ಹುಲಿ ಜನಸಂಖ್ಯೆಯಲ್ಲಿನ ಕೊಳೆತ. 
ಲಾಗರಿಥಮಿಕ್ ಟ್ರೆಂಡ್‌ಲೈನ್
ಲಾಗರಿಥಮಿಕ್ ಬೆಸ್ಟ್-ಫಿಟ್ ಲೈನ್ ಅನ್ನು ಸಾಮಾನ್ಯವಾಗಿ ಡೇಟಾವನ್ನು ಪ್ಲಾಟ್ ಮಾಡಲು ಬಳಸಲಾಗುತ್ತದೆ, ಅದು ತ್ವರಿತವಾಗಿ ಹೆಚ್ಚಾಗುತ್ತದೆ ಅಥವಾ ಕಡಿಮೆಯಾಗುತ್ತದೆ ಮತ್ತು ನಂತರ ಮಟ್ಟಗಳು ಆಫ್ ಆಗುತ್ತವೆ. ಇದು ಧನಾತ್ಮಕ ಮತ್ತು ಋಣಾತ್ಮಕ ಮೌಲ್ಯಗಳನ್ನು ಒಳಗೊಂಡಿರುತ್ತದೆ.
ಲಾಗರಿಥಮಿಕ್ ಟ್ರೆಂಡ್‌ಲೈನ್‌ನ ಉದಾಹರಣೆ ಹಣದುಬ್ಬರ ದರವಾಗಿರಬಹುದು, ಅದು ಮೊದಲು ಹೆಚ್ಚುತ್ತಿದೆ ಆದರೆ ಸ್ವಲ್ಪ ಸಮಯದ ನಂತರ ಸ್ಥಿರಗೊಳ್ಳುತ್ತದೆ. 
ಬಹುಪದೀಯ ಟ್ರೆಂಡ್‌ಲೈನ್
ಬಹುಪದೀಯ ಕರ್ವಿಲಿನಿಯರ್ ಟ್ರೆಂಡ್‌ಲೈನ್ ಒಂದಕ್ಕಿಂತ ಹೆಚ್ಚು ಏರಿಕೆ ಮತ್ತು ಕುಸಿತವನ್ನು ಹೊಂದಿರುವ ಆಂದೋಲನ ಮೌಲ್ಯಗಳೊಂದಿಗೆ ದೊಡ್ಡ ಡೇಟಾ ಸೆಟ್‌ಗಳಿಗೆ ಉತ್ತಮವಾಗಿ ಕಾರ್ಯನಿರ್ವಹಿಸುತ್ತದೆ.
ಸಾಮಾನ್ಯವಾಗಿ, ಬಹುಪದವನ್ನು ವರ್ಗೀಕರಿಸಲಾಗಿದೆ ದೊಡ್ಡ ಘಾತದ ಪದವಿ. ಬಹುಪದೀಯ ಟ್ರೆಂಡ್‌ಲೈನ್‌ನ ಪದವಿ ಮಾಡಬಹುದುಗ್ರಾಫ್‌ನಲ್ಲಿರುವ ಬೆಂಡ್‌ಗಳ ಸಂಖ್ಯೆಯಿಂದ ಸಹ ನಿರ್ಧರಿಸಲಾಗುತ್ತದೆ. ವಿಶಿಷ್ಟವಾಗಿ, ಕ್ವಾಡ್ರಾಟಿಕ್ ಬಹುಪದೀಯ ಟ್ರೆಂಡ್‌ಲೈನ್ ಒಂದು ಬೆಂಡ್ (ಬೆಟ್ಟ ಅಥವಾ ಕಣಿವೆ), ಘನ ಬಹುಪದೋಕ್ತಿ 1 ಅಥವಾ 2 ಬೆಂಡ್‌ಗಳನ್ನು ಹೊಂದಿರುತ್ತದೆ ಮತ್ತು ಕ್ವಾರ್ಟಿಕ್ ಬಹುಪದವು 3 ಬೆಂಡ್‌ಗಳನ್ನು ಹೊಂದಿರುತ್ತದೆ.
ಎಕ್ಸೆಲ್ ಚಾರ್ಟ್‌ನಲ್ಲಿ ಬಹುಪದೀಯ ಪ್ರವೃತ್ತಿಯನ್ನು ಸೇರಿಸಿದಾಗ, ಫಾರ್ಮ್ಯಾಟ್ ಟ್ರೆಂಡ್‌ಲೈನ್ ಪೇನ್‌ನಲ್ಲಿ ಆರ್ಡರ್ ಬಾಕ್ಸ್‌ನಲ್ಲಿ ಅನುಗುಣವಾದ ಸಂಖ್ಯೆಯನ್ನು ಟೈಪ್ ಮಾಡುವ ಮೂಲಕ ನೀವು ಪದವಿಯನ್ನು ನಿರ್ದಿಷ್ಟಪಡಿಸುತ್ತೀರಿ, ಇದು ಡಿಫಾಲ್ಟ್ ಆಗಿ 2 ಆಗಿದೆ: 
ಉದಾಹರಣೆಗೆ, ಕ್ವಾಡ್ರಾಟಿಕ್ ಬಹುಪದೀಯ ಪ್ರವೃತ್ತಿ ಉತ್ಪನ್ನವು ಮಾರುಕಟ್ಟೆಯಲ್ಲಿರುವ ಲಾಭ ಮತ್ತು ವರ್ಷಗಳ ಸಂಖ್ಯೆಯ ನಡುವಿನ ಸಂಬಂಧವನ್ನು ಈ ಕೆಳಗಿನ ಗ್ರಾಫ್‌ನಲ್ಲಿ ಸ್ಪಷ್ಟವಾಗಿ ತೋರಿಸುತ್ತದೆ: ಆರಂಭದಲ್ಲಿ ಏರಿಕೆ, ಮಧ್ಯದಲ್ಲಿ ಗರಿಷ್ಠ ಮತ್ತು ಕೊನೆಯಲ್ಲಿ ಬೀಳುವಿಕೆ. 
ಪವರ್ ಟ್ರೆಂಡ್‌ಲೈನ್
ಪವರ್ ಟ್ರೆಂಡ್ ಲೈನ್ ಘಾತೀಯ ಕರ್ವ್‌ಗೆ ಹೋಲುತ್ತದೆ, ಇದು ಹೆಚ್ಚು ಸಮ್ಮಿತೀಯ ಆರ್ಕ್ ಅನ್ನು ಮಾತ್ರ ಹೊಂದಿದೆ. ನಿರ್ದಿಷ್ಟ ದರದಲ್ಲಿ ಹೆಚ್ಚಾಗುವ ಮಾಪನಗಳನ್ನು ಯೋಜಿಸಲು ಇದನ್ನು ಸಾಮಾನ್ಯವಾಗಿ ಬಳಸಲಾಗುತ್ತದೆ.
ಶೂನ್ಯ ಅಥವಾ ಋಣಾತ್ಮಕ ಮೌಲ್ಯಗಳನ್ನು ಒಳಗೊಂಡಿರುವ ಎಕ್ಸೆಲ್ ಚಾರ್ಟ್‌ಗೆ ಪವರ್ ಟ್ರೆಂಡ್‌ಲೈನ್ ಅನ್ನು ಸೇರಿಸಲಾಗುವುದಿಲ್ಲ.
ಉದಾಹರಣೆಗೆ, ನಾವು ಎ ಸೆಳೆಯೋಣ ರಾಸಾಯನಿಕ ಕ್ರಿಯೆಯ ದರವನ್ನು ದೃಶ್ಯೀಕರಿಸಲು ಪವರ್ ಟ್ರೆಂಡ್‌ಲೈನ್. 0.9918 ರ R-ವರ್ಗದ ಮೌಲ್ಯವನ್ನು ಗಮನಿಸಿ, ಅಂದರೆ ನಮ್ಮ ಟ್ರೆಂಡ್‌ಲೈನ್ ಡೇಟಾಗೆ ಸಂಪೂರ್ಣವಾಗಿ ಹೊಂದಿಕೊಳ್ಳುತ್ತದೆ. 
ಚಲಿಸುವ ಸರಾಸರಿ ಟ್ರೆಂಡ್‌ಲೈನ್
ನಿಮ್ಮ ಚಾರ್ಟ್‌ನಲ್ಲಿರುವ ಡೇಟಾ ಪಾಯಿಂಟ್‌ಗಳು ಸಾಕಷ್ಟು ಏರಿಳಿತಗಳನ್ನು ಹೊಂದಿರುವಾಗ, ಚಲಿಸುವ ಸರಾಸರಿ ಟ್ರೆಂಡ್‌ಲೈನ್ ಮಾದರಿಯನ್ನು ಹೆಚ್ಚು ಸ್ಪಷ್ಟವಾಗಿ ತೋರಿಸಲು ಡೇಟಾ ಮೌಲ್ಯಗಳಲ್ಲಿನ ತೀವ್ರ ಏರಿಳಿತಗಳನ್ನು ಸುಗಮಗೊಳಿಸುತ್ತದೆ. ಇದಕ್ಕಾಗಿ, ಎಕ್ಸೆಲ್ ಲೆಕ್ಕಾಚಾರ ಮಾಡುತ್ತದೆನೀವು ನಿರ್ದಿಷ್ಟಪಡಿಸುವ ಅವಧಿಗಳ ಸಂಖ್ಯೆಯ ಚಲಿಸುವ ಸರಾಸರಿ (2 ಪೂರ್ವನಿಯೋಜಿತವಾಗಿ) ಮತ್ತು ಆ ಸರಾಸರಿ ಮೌಲ್ಯಗಳನ್ನು ಸಾಲಿನಲ್ಲಿ ಅಂಕಗಳಾಗಿ ಇರಿಸುತ್ತದೆ. ಹೆಚ್ಚಿನ ಅವಧಿ ಮೌಲ್ಯವು, ರೇಖೆಯು ಸುಗಮವಾಗಿರುತ್ತದೆ.
ಒಂದು ಉತ್ತಮ ಪ್ರಾಯೋಗಿಕ ಉದಾಹರಣೆಯೆಂದರೆ ಚಲಿಸುವ ಸರಾಸರಿ ಟ್ರೆಂಡ್‌ಲೈನ್ ಅನ್ನು ಸ್ಟಾಕ್ ಬೆಲೆಯಲ್ಲಿನ ಏರಿಳಿತಗಳನ್ನು ಬಹಿರಂಗಪಡಿಸುವುದು ಇಲ್ಲದಿದ್ದರೆ ಗಮನಿಸಲು ಕಷ್ಟವಾಗುತ್ತದೆ. 
ಹೆಚ್ಚಿನ ಮಾಹಿತಿಗಾಗಿ, ದಯವಿಟ್ಟು ನೋಡಿ: ಎಕ್ಸೆಲ್ ಚಾರ್ಟ್‌ಗೆ ಚಲಿಸುವ ಸರಾಸರಿ ಟ್ರೆಂಡ್‌ಲೈನ್ ಅನ್ನು ಹೇಗೆ ಸೇರಿಸುವುದು.
ಎಕ್ಸೆಲ್ ಟ್ರೆಂಡ್‌ಲೈನ್ ಸಮೀಕರಣಗಳು ಮತ್ತು ಸೂತ್ರಗಳು
ಈ ವಿಭಾಗವು ಎಕ್ಸೆಲ್ ಬಳಸುವ ಸಮೀಕರಣಗಳನ್ನು ವಿವರಿಸುತ್ತದೆ ವಿಭಿನ್ನ ಟ್ರೆಂಡ್‌ಲೈನ್ ಪ್ರಕಾರಗಳಿಗೆ. ನೀವು ಈ ಸೂತ್ರಗಳನ್ನು ಹಸ್ತಚಾಲಿತವಾಗಿ ನಿರ್ಮಿಸಬೇಕಾಗಿಲ್ಲ, ಚಾರ್ಟ್‌ನಲ್ಲಿ ಟ್ರೆಂಡ್‌ಲೈನ್ ಸಮೀಕರಣವನ್ನು ಪ್ರದರ್ಶಿಸಲು ಎಕ್ಸೆಲ್‌ಗೆ ಹೇಳಿ.
ಅಲ್ಲದೆ, ಟ್ರೆಂಡ್‌ಲೈನ್ ಮತ್ತು ಇತರ ಗುಣಾಂಕಗಳ ಇಳಿಜಾರನ್ನು ಕಂಡುಹಿಡಿಯಲು ನಾವು ಸೂತ್ರವನ್ನು ಚರ್ಚಿಸುತ್ತೇವೆ. ನೀವು 2 ಸೆಟ್ ವೇರಿಯೇಬಲ್‌ಗಳನ್ನು ಹೊಂದಿರುವಿರಿ ಎಂದು ಸೂತ್ರಗಳು ಊಹಿಸುತ್ತವೆ: ಸ್ವತಂತ್ರ ವೇರಿಯಬಲ್ x ಮತ್ತು ಅವಲಂಬಿತ ವೇರಿಯೇಬಲ್ y . ನಿಮ್ಮ ವರ್ಕ್‌ಶೀಟ್‌ಗಳಲ್ಲಿ, x ನ ಯಾವುದೇ ನಿರ್ದಿಷ್ಟ ಮೌಲ್ಯಗಳಿಗೆ ಊಹಿಸಲಾದ y ಮೌಲ್ಯಗಳನ್ನು ಪಡೆಯಲು ನೀವು ಈ ಸೂತ್ರಗಳನ್ನು ಬಳಸಬಹುದು.
ಸ್ಥಿರತೆಗಾಗಿ, ನಾವು ಅದೇ ಡೇಟಾವನ್ನು ಬಳಸುತ್ತೇವೆ ಎಲ್ಲಾ ಉದಾಹರಣೆಗಳಿಗಾಗಿ ಸ್ವಲ್ಪ ಬದಲಾಗುವ ಮೌಲ್ಯಗಳೊಂದಿಗೆ ಹೊಂದಿಸಲಾಗಿದೆ. ಆದಾಗ್ಯೂ, ಇದು ಪ್ರದರ್ಶನ ಉದ್ದೇಶಗಳಿಗಾಗಿ ಮಾತ್ರ ಎಂಬುದನ್ನು ದಯವಿಟ್ಟು ನೆನಪಿನಲ್ಲಿಡಿ. ನಿಮ್ಮ ನೈಜ ವರ್ಕ್‌ಶೀಟ್‌ಗಳಲ್ಲಿ, ನಿಮ್ಮ ಡೇಟಾ ಪ್ರಕಾರಕ್ಕೆ ಅನುಗುಣವಾಗಿ ಟ್ರೆಂಡ್‌ಲೈನ್ ಪ್ರಕಾರವನ್ನು ನೀವು ಆರಿಸಿಕೊಳ್ಳಬೇಕು.
ಪ್ರಮುಖ ಟಿಪ್ಪಣಿ! ಟ್ರೆಂಡ್‌ಲೈನ್ ಸೂತ್ರಗಳನ್ನು XY ಸ್ಕ್ಯಾಟರ್ ಚಾರ್ಟ್‌ಗಳೊಂದಿಗೆ ಮಾತ್ರ ಬಳಸಬೇಕು ಏಕೆಂದರೆ ಇದು ಮಾತ್ರಚಾರ್ಟ್ x ಮತ್ತು y ಅಕ್ಷಗಳನ್ನು ಸಂಖ್ಯಾತ್ಮಕ ಮೌಲ್ಯಗಳಾಗಿ ರೂಪಿಸುತ್ತದೆ. ಹೆಚ್ಚಿನ ಮಾಹಿತಿಗಾಗಿ, ದಯವಿಟ್ಟು ಎಕ್ಸೆಲ್ ಟ್ರೆಂಡ್‌ಲೈನ್ ಸಮೀಕರಣ ಏಕೆ ತಪ್ಪಾಗಿರಬಹುದು ಎಂಬುದನ್ನು ನೋಡಿ.
ಲೀನಿಯರ್ ಟ್ರೆಂಡ್‌ಲೈನ್ ಸಮೀಕರಣ ಮತ್ತು ಸೂತ್ರಗಳು
ರೇಖೀಯ ಟ್ರೆಂಡ್‌ಲೈನ್ ಸಮೀಕರಣವು ಇಳಿಜಾರು ಹುಡುಕಲು ಕನಿಷ್ಠ ಚೌಕಗಳ ವಿಧಾನಗಳನ್ನು ಬಳಸುತ್ತದೆ. ಮತ್ತು ಪ್ರತಿಬಂಧಕ ಗುಣಾಂಕಗಳು ಅಂದರೆ:
y = bx + aಎಲ್ಲಿ:
- b ಇಳಿಜಾರು ಟ್ರೆಂಡ್‌ಲೈನ್‌ನ.
- a y-ಇಂಟರ್‌ಸೆಪ್ಟ್ ಆಗಿದೆ, ಇದು ಎಲ್ಲಾ x<ಆಗಿರುವಾಗ y ನಿರೀಕ್ಷಿತ ಸರಾಸರಿ ಮೌಲ್ಯವಾಗಿದೆ 2> ವೇರಿಯೇಬಲ್‌ಗಳು 0 ಗೆ ಸಮಾನವಾಗಿರುತ್ತದೆ. ಚಾರ್ಟ್‌ನಲ್ಲಿ, ಇದು ಟ್ರೆಂಡ್‌ಲೈನ್ y ಅಕ್ಷವನ್ನು ದಾಟುವ ಬಿಂದುವಾಗಿದೆ.
ಲೀನಿಯರ್ ರಿಗ್ರೆಶನ್‌ಗಾಗಿ, ಮೈಕ್ರೋಸಾಫ್ಟ್ ಎಕ್ಸೆಲ್ ವಿಶೇಷ ಕಾರ್ಯಗಳನ್ನು ಒದಗಿಸುತ್ತದೆ ಇಳಿಜಾರು ಮತ್ತು ಪ್ರತಿಬಂಧ ಗುಣಾಂಕಗಳು.
ಟ್ರೆಂಡ್‌ಲೈನ್‌ನ ಇಳಿಜಾರು
b: =SLOPE(y,x)
Y-ಇಂಟರ್‌ಸೆಪ್ಟ್
a: =INTERCEPT(y,x)
x ಶ್ರೇಣಿಯು B2:B13 ಮತ್ತು y ಶ್ರೇಣಿಯು C2:C13 ಎಂದು ಊಹಿಸಿದರೆ, ನಿಜ ಜೀವನದ ಸೂತ್ರಗಳು ಈ ಕೆಳಗಿನಂತಿವೆ:
=SLOPE(C2:C13, B2:B13)
=INTERCEPT(C2:C13,B2:B13)
ಅದೇ ಫಲಿತಾಂಶಗಳನ್ನು LINEST ಫಂಕ್ಷನ್ ಅನ್ನು ಅರೇ ಫಾರ್ಮುಲಾ ಆಗಿ ಬಳಸುವ ಮೂಲಕ ಸಾಧಿಸಬಹುದು. ಇದಕ್ಕಾಗಿ, ಅದೇ ಸಾಲಿನಲ್ಲಿ 2 ಪಕ್ಕದ ಕೋಶಗಳನ್ನು ಆಯ್ಕೆಮಾಡಿ, ಸೂತ್ರವನ್ನು ನಮೂದಿಸಿ ಮತ್ತು ಅದನ್ನು ಪೂರ್ಣಗೊಳಿಸಲು Ctrl + Shift + Enter ಅನ್ನು ಒತ್ತಿರಿ:
=LINEST(C2:C13,B2:B13)
ಕೆಳಗಿನ ಸ್ಕ್ರೀನ್‌ಶಾಟ್‌ನಲ್ಲಿ ತೋರಿಸಿರುವಂತೆ, ಇಳಿಜಾರು ಮತ್ತು ಪ್ರತಿಬಂಧ ಸೂತ್ರಗಳಿಂದ ಹಿಂತಿರುಗಿಸಲಾದ ಗುಣಾಂಕಗಳು ಚಾರ್ಟ್‌ನಲ್ಲಿ ಪ್ರದರ್ಶಿಸಲಾದ ರೇಖೀಯ ಟ್ರೆಂಡ್‌ಲೈನ್ ಸಮೀಕರಣದಲ್ಲಿನ ಗುಣಾಂಕಗಳಿಗೆ ಸಂಪೂರ್ಣವಾಗಿ ಅನುಗುಣವಾಗಿರುತ್ತವೆ, ಎರಡನೆಯದು ಮಾತ್ರ 4 ದಶಮಾಂಶ ಸ್ಥಾನಗಳಿಗೆ ದುಂಡಾಗಿರುತ್ತದೆ: 
ಘಾತೀಯ ಟ್ರೆಂಡ್‌ಲೈನ್ ಸಮೀಕರಣ ಮತ್ತು ಸೂತ್ರಗಳು
ಘಾತೀಯ ಟ್ರೆಂಡ್‌ಲೈನ್‌ಗಾಗಿ, ಎಕ್ಸೆಲ್ ಈ ಕೆಳಗಿನ ಸಮೀಕರಣವನ್ನು ಬಳಸುತ್ತದೆ:
y = aebxಎಲ್ಲಿ a ಮತ್ತು b ಗಣಿಸಲಾದ ಗುಣಾಂಕಗಳು ಮತ್ತು e ಎಂಬುದು ಗಣಿತದ ಸ್ಥಿರಾಂಕ e (ನೈಸರ್ಗಿಕ ಲಾಗರಿಥಮ್‌ನ ಆಧಾರ) ಆಗಿದೆ.
ಈ ಸಾಮಾನ್ಯ ಸೂತ್ರಗಳನ್ನು ಬಳಸಿಕೊಂಡು ಗುಣಾಂಕಗಳನ್ನು ಲೆಕ್ಕಹಾಕಬಹುದು:
a: =EXP(INDEX(LINEST(LN(y), x), 1, 2))
b: =INDEX(LINEST(LN(y), x), 1)
ನಮ್ಮ ಮಾದರಿ ಡೇಟಾ ಸೆಟ್‌ಗಾಗಿ, ಸೂತ್ರಗಳು ಈ ಕೆಳಗಿನ ಆಕಾರವನ್ನು ತೆಗೆದುಕೊಳ್ಳುತ್ತವೆ:
a: =EXP(INDEX(LINEST(LN(C2:C13), B2:B13), 1, 2))
b: =INDEX(LINEST(LN(C2:C13), B2:B13), 1) 
ಲಾಗರಿಥಮಿಕ್ ಟ್ರೆಂಡ್‌ಲೈನ್ ಸಮೀಕರಣ ಮತ್ತು ಸೂತ್ರಗಳು
Excel ನಲ್ಲಿ ಲಾಗರಿಥಮಿಕ್ ಟ್ರೆಂಡ್‌ಲೈನ್ ಸಮೀಕರಣ ಇಲ್ಲಿದೆ:
y = a*ln(x)+bಎಲ್ಲಿ a ಮತ್ತು b ಸ್ಥಿರಾಂಕಗಳು ಮತ್ತು ln ನೈಸರ್ಗಿಕ ಲಾಗರಿಥಮ್ ಕಾರ್ಯವಾಗಿದೆ.
ಸ್ಥಿರಗಳನ್ನು ಪಡೆಯಲು, ಈ ಸಾಮಾನ್ಯ ಸೂತ್ರಗಳನ್ನು ಬಳಸಿ, ಇದು ಕೊನೆಯ ಆರ್ಗ್ಯುಮೆಂಟ್‌ನಲ್ಲಿ ಮಾತ್ರ ಭಿನ್ನವಾಗಿರುತ್ತದೆ:
a: =INDEX(LINEST(y, LN(x)), 1)
b: =INDEX(LINEST(y, LN(x)), 1, 2)
ನಮ್ಮ ಮಾದರಿ ಡೇಟಾ ಸೆಟ್‌ಗಾಗಿ, ನಾವು ಇವುಗಳನ್ನು ಬಳಸುತ್ತೇವೆ:
a: =INDEX(LINEST(C2:C13, LN(B2:B13)), 1)
b: =INDEX(LINEST(C2:C13, LN(B2:B13)), 1, 2) 
ಬಹುಪದೀಯ ಟ್ರೆಂಡ್‌ಲೈನ್ ಸಮೀಕರಣ ಮತ್ತು ಸೂತ್ರಗಳು
ಬಹುಪದಿಯ ಟ್ರೆಂಡ್‌ಲೈನ್ ಅನ್ನು ಕೆಲಸ ಮಾಡಲು, ಎಕ್ಸೆಲ್ ಈ ಸಮೀಕರಣವನ್ನು ಬಳಸುತ್ತದೆ:
y = b 6 x6 + … + b 2 x2 + b 1 x + aಎಲ್ಲಿ b 1 … b 6 ಮತ್ತು a ಸ್ಥಿರಾಂಕಗಳಾಗಿವೆ.
ನಿಮ್ಮ ಬಹುಪದೀಯ ಟ್ರೆಂಡ್‌ಲೈನ್‌ನ ಮಟ್ಟವನ್ನು ಅವಲಂಬಿಸಿ, ಸೂತ್ರಗಳ ಕೆಳಗಿನ ಸೆಟ್‌ಗಳಲ್ಲಿ ಒಂದನ್ನು ಬಳಸಿ ಸ್ಥಿರಾಂಕಗಳನ್ನು ಪಡೆಯುವುದು>
b 2 : =INDEX(LINEST(y, x^{1,2}), 1)
b 1 : =INDEX(LINEST(y, x^{1,2}), 1, 2)
a: =INDEX(LINEST(y, x^{1,2}), 1, 3)
ಘನ (3ನೇ ಕ್ರಮ) ಬಹುಪದೀಯ ಟ್ರೆಂಡ್‌ಲೈನ್
ಸಮೀಕರಣ: y = b 3 x3 + b 2 x2+ b 1 x + a
b 3 : =INDEX(LINEST(y, x^{1,2,3}), 1)
b 2 : =INDEX(LINEST(y, x^{1,2,3}), 1, 2)
b 1 : =INDEX(LINEST(y, x^{1,2,3}), 1, 3)
a: =INDEX(LINEST(y, x^{1,2,3}), 1, 4)
ಉನ್ನತ ಪದವಿಯ ಬಹುಪದೀಯ ಟ್ರೆಂಡ್‌ಲೈನ್‌ಗಳ ಸೂತ್ರಗಳನ್ನು ಅದೇ ಮಾದರಿಯನ್ನು ಬಳಸಿಕೊಂಡು ನಿರ್ಮಿಸಬಹುದಾಗಿದೆ.
ನಮ್ಮ ಡೇಟಾ ಸೆಟ್‌ಗಾಗಿ, 2ನೇ ಕ್ರಮಾಂಕದ ಬಹುಪದೀಯ ಟ್ರೆಂಡ್‌ಲೈನ್ ಸೂಟ್‌ಗಳು ಉತ್ತಮವಾಗಿದೆ, ಆದ್ದರಿಂದ ನಾವು ಈ ಸೂತ್ರಗಳನ್ನು ಬಳಸುತ್ತಿದ್ದೇವೆ:
b 2 : =INDEX(LINEST(C2:C13, B2:B13^{1,2}), 1)
b 1 : =INDEX(LINEST(C2:C13, B2:B13^{1,2}), 1, 2)
a: =INDEX(LINEST(C2:C13, B2:B13^{1,2}), 1, 3) 
ಪವರ್ ಟ್ರೆಂಡ್‌ಲೈನ್ ಸಮೀಕರಣ ಮತ್ತು ಸೂತ್ರಗಳು
ಈ ಸರಳ ಸಮೀಕರಣದ ಆಧಾರದ ಮೇಲೆ Excel ನಲ್ಲಿ ಪವರ್ ಟ್ರೆಂಡ್‌ಲೈನ್ ಅನ್ನು ಎಳೆಯಲಾಗುತ್ತದೆ:
y = axbಎಲ್ಲಿ a ಮತ್ತು b ಸ್ಥಿರಾಂಕಗಳಾಗಿವೆ, ಇವುಗಳನ್ನು ಈ ಸೂತ್ರಗಳೊಂದಿಗೆ ಲೆಕ್ಕಹಾಕಬಹುದು:
a: =EXP(INDEX(LINEST(LN(y), LN(x),,), 1, 2))
b: =INDEX(LINEST(LN(y), LN(x),,), 1)
ನಮ್ಮ ಸಂದರ್ಭದಲ್ಲಿ, ಈ ಕೆಳಗಿನ ಸೂತ್ರಗಳು ಸತ್ಕಾರವಾಗಿ ಕಾರ್ಯನಿರ್ವಹಿಸುತ್ತವೆ :
a: =EXP(INDEX(LINEST(LN(C2:C13), LN(B2:B13),,), 1, 2))
b: =INDEX(LINEST(LN(C2:C13), LN(B2:B13),,), 1) 
Excel ಟ್ರೆಂಡ್‌ಲೈನ್ ಸಮೀಕರಣವು ತಪ್ಪಾಗಿದೆ - ಕಾರಣಗಳು ಮತ್ತು ಪರಿಹಾರಗಳು
ಎಕ್ಸೆಲ್ ತಪ್ಪಾಗಿ ಟ್ರೆಂಡ್‌ಲೈನ್ ಅನ್ನು ಚಿತ್ರಿಸಿದೆ ಎಂದು ನೀವು ಭಾವಿಸಿದರೆ ಅಥವಾ ನಿಮ್ಮ ಚಾರ್ಟ್‌ನಲ್ಲಿ ಪ್ರದರ್ಶಿಸಲಾದ ಟ್ರೆಂಡ್‌ಲೈನ್ ಸೂತ್ರವು ತಪ್ಪಾಗಿದೆ, ಈ ಕೆಳಗಿನ ಎರಡು ಅಂಶಗಳು ಕೆಲವನ್ನು ಚೆಲ್ಲಬಹುದು ಪರಿಸ್ಥಿತಿಯ ಮೇಲೆ ಬೆಳಕು.
ಎಕ್ಸೆಲ್ ಟ್ರೆಂಡ್‌ಲೈನ್ ಸಮೀಕರಣವು ಸ್ಕ್ಯಾಟರ್ ಚಾರ್ಟ್‌ಗಳಲ್ಲಿ ಮಾತ್ರ ಸರಿಯಾಗಿದೆ
ಎಕ್ಸೆಲ್ ಟ್ರೆಂಡ್‌ಲೈನ್ ಸೂತ್ರಗಳನ್ನು XY (ಸ್ಕ್ಯಾಟರ್) ಗ್ರಾಫ್‌ಗಳೊಂದಿಗೆ ಮಾತ್ರ ಬಳಸಬೇಕು ಏಕೆಂದರೆ ಈ ಚಾರ್ಟ್‌ನಲ್ಲಿ ಮಾತ್ರ y-ಆಕ್ಸಿಸ್ ಎರಡನ್ನೂ ಟೈಪ್ ಮಾಡಿ ಮತ್ತು x-ಆಕ್ಸಿಸ್ ಅನ್ನು ಸಂಖ್ಯಾತ್ಮಕ ಮೌಲ್ಯಗಳಾಗಿ ರೂಪಿಸಲಾಗಿದೆ.
ಲೈನ್ ಚಾರ್ಟ್‌ಗಳು, ಕಾಲಮ್ ಮತ್ತು ಬಾರ್ ಗ್ರಾಫ್‌ಗಳಲ್ಲಿ, ಸಂಖ್ಯಾ ಮೌಲ್ಯಗಳನ್ನು y-ಅಕ್ಷದಲ್ಲಿ ಮಾತ್ರ ರೂಪಿಸಲಾಗಿದೆ. x-ಅಕ್ಷವನ್ನು ರೇಖೀಯ ಸರಣಿಯಿಂದ ಪ್ರತಿನಿಧಿಸಲಾಗುತ್ತದೆ (1, 2,3,...) ಅಕ್ಷದ ಲೇಬಲ್‌ಗಳು ಸಂಖ್ಯೆಗಳು ಅಥವಾ ಪಠ್ಯವೇ ಎಂಬುದನ್ನು ಲೆಕ್ಕಿಸದೆ. ಈ ಚಾರ್ಟ್‌ಗಳಲ್ಲಿ ನೀವು ಟ್ರೆಂಡ್‌ಲೈನ್ ಮಾಡಿದಾಗ, ಎಕ್ಸೆಲ್ ಟ್ರೆಂಡ್‌ಲೈನ್ ಸೂತ್ರದಲ್ಲಿ ಆ ಭಾವಿಸಲಾದ x-ಮೌಲ್ಯಗಳನ್ನು ಬಳಸುತ್ತದೆ.
ಸಂಖ್ಯೆಗಳನ್ನು ಎಕ್ಸೆಲ್ ಟ್ರೆಂಡ್‌ಲೈನ್ ಸಮೀಕರಣದಲ್ಲಿ ದುಂಡಾಗಿರುತ್ತದೆ
ಚಾರ್ಟ್‌ನಲ್ಲಿ ಕಡಿಮೆ ಜಾಗವನ್ನು ಆಕ್ರಮಿಸಲು, ಎಕ್ಸೆಲ್ ಡಿಸ್‌ಪ್ಲೇ ಮಾಡುತ್ತದೆ ಟ್ರೆಂಡ್‌ಲೈನ್ ಸಮೀಕರಣದಲ್ಲಿ ಕೆಲವೇ ಕೆಲವು ಗಮನಾರ್ಹ ಅಂಕೆಗಳು. ವಿನ್ಯಾಸದ ವಿಷಯದಲ್ಲಿ ಉತ್ತಮವಾಗಿದೆ, ನೀವು ಸಮೀಕರಣದಲ್ಲಿ x ಮೌಲ್ಯಗಳನ್ನು ಹಸ್ತಚಾಲಿತವಾಗಿ ಪೂರೈಸಿದಾಗ ಇದು ಸೂತ್ರದ ನಿಖರತೆಯನ್ನು ಗಮನಾರ್ಹವಾಗಿ ಕಡಿಮೆ ಮಾಡುತ್ತದೆ.
ಸಮೀಕರಣದಲ್ಲಿ ಹೆಚ್ಚು ದಶಮಾಂಶ ಸ್ಥಾನಗಳನ್ನು ತೋರಿಸುವುದು ಸುಲಭವಾದ ಪರಿಹಾರವಾಗಿದೆ. ಪರ್ಯಾಯವಾಗಿ, ನಿಮ್ಮ ಟ್ರೆಂಡ್‌ಲೈನ್ ಪ್ರಕಾರಕ್ಕೆ ಅನುಗುಣವಾದ ಸೂತ್ರವನ್ನು ಬಳಸಿಕೊಂಡು ನೀವು ಗುಣಾಂಕಗಳನ್ನು ಲೆಕ್ಕ ಹಾಕಬಹುದು ಮತ್ತು ಫಾರ್ಮುಲಾ ಕೋಶಗಳನ್ನು ಫಾರ್ಮ್ಯಾಟ್ ಮಾಡಬಹುದು ಇದರಿಂದ ಅವು ಸಾಕಷ್ಟು ಸಂಖ್ಯೆಯ ದಶಮಾಂಶ ಸ್ಥಾನಗಳನ್ನು ತೋರಿಸುತ್ತವೆ. ಇದಕ್ಕಾಗಿ, ಸಂಖ್ಯೆ ಗುಂಪಿನಲ್ಲಿರುವ ಹೋಮ್ ಟ್ಯಾಬ್‌ನಲ್ಲಿ ದಶಮಾಂಶ ಹೆಚ್ಚಿಸಿ ಬಟನ್ ಅನ್ನು ಕ್ಲಿಕ್ ಮಾಡಿ.
ನೀವು ವಿವಿಧ ಟ್ರೆಂಡ್‌ಲೈನ್ ಪ್ರಕಾರಗಳನ್ನು ಹೇಗೆ ಮಾಡಬಹುದು ಎಕ್ಸೆಲ್ ನಲ್ಲಿ ಮತ್ತು ಅವುಗಳ ಸಮೀಕರಣಗಳನ್ನು ಪಡೆಯಿರಿ. ಓದಿದ್ದಕ್ಕಾಗಿ ನಾನು ನಿಮಗೆ ಧನ್ಯವಾದಗಳು ಮತ್ತು ಮುಂದಿನ ವಾರ ನಮ್ಮ ಬ್ಲಾಗ್‌ನಲ್ಲಿ ನಿಮ್ಮನ್ನು ನೋಡುತ್ತೇನೆ ಎಂದು ಭಾವಿಸುತ್ತೇನೆ! 3>
