මෙම නිබන්ධනයේදී, Excel හි ඇති සියලුම ප්‍රවණතා විකල්ප සහ ඒවා භාවිතා කළ යුත්තේ කවදාද යන්න පිළිබඳ සවිස්තරාත්මක විස්තරයක් ඔබට සොයාගත හැකිය. ප්‍රස්ථාරයක ප්‍රවනතා සමීකරණයක් ප්‍රදර්ශනය කරන්නේ කෙසේද සහ ප්‍රවනතා රේඛාවේ බෑවුම සොයා ගන්නේ කෙසේදැයි ඔබ ඉගෙන ගනු ඇත.

Excel හි ප්‍රවණතා රේඛාවක් එක් කිරීම ඉතා පහසුය. එකම සැබෑ අභියෝගය වන්නේ ඔබ විශ්ලේෂණය කරන දත්ත වර්ගයට වඩාත් ගැලපෙන ප්‍රවණතා වර්ගය තෝරා ගැනීමයි. මෙම නිබන්ධනයේදී, Excel හි ඇති සියලුම ප්‍රවණතා විකල්ප සහ ඒවා භාවිතා කළ යුත්තේ කවදාද යන්න පිළිබඳ සවිස්තරාත්මක විස්තරයක් ඔබට සොයාගත හැකිය. ඔබ Excel ප්‍රස්ථාරයකට ප්‍රවනතා රේඛාවක් ඇතුළත් කරන්නේ කෙසේදැයි සොයන්නේ නම්, කරුණාකර ඉහත සම්බන්ධිත නිබන්ධනය පරීක්ෂා කරන්න.

Excel trendline වර්ග

Excel හි ප්‍රවණතා රේඛාවක් එක් කරන විට , ඔබට තෝරා ගැනීමට විවිධ විකල්ප 6ක් ඇත. මීට අමතරව, Microsoft Excel ප්‍රස්ථාරයක ප්‍රවණතා සමීකරණයක් සහ R-වර්ග අගයක් පෙන්වීමට ඉඩ දෙයි:

• Trendline සමීකරණය යනු දත්ත ලක්ෂ්‍යවලට වඩාත් ගැලපෙන රේඛාවක් සොයා ගන්නා සූත්‍රයකි.
• R-වර්ග අගය ප්‍රවනතා රේඛා විශ්වසනීයත්වය මනිනු ලබයි - R2 1 ට ආසන්න වන තරමට ප්‍රවණතා රේඛාව දත්ත වලට ගැලපේ.

පහත, ඔබට ප්‍රස්ථාර උදාහරණ සමඟ එක් එක් ප්‍රවණතා වර්ගය පිළිබඳ කෙටි විස්තරයක් සොයාගත හැකිය.

රේඛීය ප්‍රවණතා රේඛාව

රේඛීය ප්‍රවණතා රේඛාව වීමට හොඳම වේ. ප්‍රස්ථාරයක දත්ත ලක්ෂ්‍ය සරල රේඛාවකට සමාන වන විට රේඛීය දත්ත කට්ටල සමඟ භාවිතා වේ. සාමාන්‍යයෙන්, රේඛීය ප්‍රවණතා රේඛාවක් අඛණ්ඩ නැගීමක් හෝ වැටීමක් විස්තර කරයිකාලයත් සමඟ.

උදාහරණයක් ලෙස, පහත රේඛීය ප්‍රවණතා මාස 6ක් පුරා විකුණුම්වල ස්ථාවර වැඩිවීමක් පෙන්නුම් කරයි. තවද 0.9855 හි R2 අගය පෙන්නුම් කරන්නේ ඇස්තමේන්තුගත ප්‍රවණතා අගයන් සත්‍ය දත්තවලට ඉතා හොඳින් ගැලපෙන බවයි.

ඝාතීය ප්‍රවණතා රේඛාව

ඝාතීය ප්‍රවණතා රේඛාව යනු වැඩිවන වේගයකින් දත්ත අගයන්හි ඉහළ යාමක් හෝ පහත වැටීමක් නිරූපණය කරන වක්‍ර රේඛාවකි, එබැවින් රේඛාව සාමාන්‍යයෙන් එක් පැත්තක වක්‍ර වේ. මෙම ප්‍රවනතා රේඛා වර්ගය බොහෝ විට විද්‍යාවන්හි භාවිතා වේ, උදාහරණයක් ලෙස මිනිස් ජනගහන වර්ධනයක් හෝ වනජීවී ගහනය අඩුවීමක් දෘශ්‍යමාන කිරීමට.

ශූන්‍ය හෝ සෘණ අගයන් අඩංගු දත්ත සඳහා ඝාතීය ප්‍රවණතා රේඛාවක් නිර්මාණය කළ නොහැකි බව කරුණාවෙන් සලකන්න.

ඝාතීය වක්‍රය සඳහා හොඳ උදාහරණයක් වන්නේ පෘථිවියේ මුළු වල් කොටි ගහනයම ක්ෂය වීමයි.

ලඝුගණක ප්‍රවණතා

සාමාන්‍යයෙන් ලඝුගණක හොඳම යෝග්‍යතා රේඛාව ඉක්මනින් වැඩිවන හෝ අඩුවන සහ පසුව මට්ටම් ක්‍රියාවිරහිත වන දත්ත සැලසුම් කිරීමට භාවිතා කරයි. එයට ධන සහ සෘණ අගයන් දෙකම ඇතුළත් විය හැක.

ලඝුගණක ප්‍රවණතාවයක උදාහරණයක් ලෙස උද්ධමන අනුපාතයක් විය හැක, එය පළමුව ඉහළ යන නමුත් ටික වේලාවකට පසු ස්ථාවර වේ.

බහුපද ප්‍රවණතා

බහුපද වක්‍ර ප්‍රවනතා එකකට වඩා වැඩි දෝලනය වන අගයන් සහිත විශාල දත්ත කට්ටල සඳහා හොඳින් ක්‍රියා කරයි.

සාමාන්‍යයෙන්, බහුපදයක් වර්ගීකරණය කරනු ලබන්නේ විශාලතම ඝාතක උපාධිය. බහුපද ප්‍රවණතා රේඛාවේ උපාධිය හැකප්‍රස්ථාරයක නැමීම් ගණන අනුවද තීරණය කළ හැක. සාමාන්‍යයෙන්, චතුරස්‍ර බහුපද ප්‍රවණතා රේඛාවකට එක් වංගුවක් (කඳු හෝ මිටියාවත) ඇත, ඝන බහුපදයකට වංගු 1ක් හෝ 2ක් ඇත, ක්වාටික බහුපදයකට වංගු 3ක් දක්වා ඇත.

Excel ප්‍රස්ථාරයක බහුපද ප්‍රවණතා එකතු කරන විට, පෙරනිමියෙන් 2 වන Format Trendline කවුළුවෙහි Order කොටුවේ අනුරූප අංකය ටයිප් කිරීමෙන් ඔබ උපාධිය සඳහන් කරයි:

උදාහරණයක් ලෙස, quadratic polynomial trend ලාභය සහ නිෂ්පාදිතය වෙළඳපොලේ පවතින වසර ගණන අතර සම්බන්ධතාවය පෙන්නුම් කරන පහත ප්‍රස්ථාරයෙන් පැහැදිලි වේ: ආරම්භයේ නැගීම, මැද උච්චතම සහ අවසානයේ වැටීම.

බල ප්‍රවණතා රේඛාව

බල ප්‍රවණතා රේඛාව ඝාතීය වක්‍රයට බෙහෙවින් සමාන ය, එයට ඇත්තේ වඩාත් සමමිතික චාපයක් පමණි. එය සාමාන්‍යයෙන් භාවිතා වන්නේ යම් වේගයකින් වැඩි වන මිනුම් සැලසුම් කිරීමට ය.

ශුන්‍ය හෝ සෘණ අගයන් අඩංගු Excel ප්‍රස්ථාරයකට බල ප්‍රවණතා රේඛාවක් එක් කළ නොහැක.

උදාහරණයක් ලෙස, අපි අඳිමු රසායනික ප්‍රතික්‍රියා අනුපාතය දෘශ්‍යමාන කිරීමට බල ප්‍රවණතා රේඛාව. 0.9918 හි R-වර්ග අගය සටහන් කරන්න, එයින් අදහස් වන්නේ අපගේ ප්‍රවණතා රේඛාව දත්තවලට සම්පූර්ණයෙන්ම පාහේ ගැලපෙන බවයි.

චලනය වන සාමාන්‍ය ප්‍රවණතා

ඔබේ ප්‍රස්ථාරයේ දත්ත ලක්ෂ්‍යවල බොහෝ උස් පහත්වීම් ඇති විට, චලනය වන සාමාන්‍ය ප්‍රවණතා රටාවකට රටාවක් වඩාත් පැහැදිලිව පෙන්වීමට දත්ත අගයන්හි අධික උච්චාවචනයන් සුමට කළ හැක. මේ සඳහා, Excel ගණනය කරයිඔබ සඳහන් කරන කාල පරිච්ඡේද ගණනෙහි චලනය වන සාමාන්‍යය (පෙරනිමියෙන් 2) සහ එම සාමාන්‍ය අගයන් රේඛාවේ ලක්ෂ්‍ය ලෙස තබයි. කාලසීමාව අගය වැඩි වන තරමට රේඛාව සුමට වේ.

හොඳ ප්‍රායෝගික උදාහරණයක් වන්නේ චලනය වන සාමාන්‍ය ප්‍රවණතාවය භාවිතා කරමින් කොටස් මිලෙහි උච්චාවචනයන් හෙළිදරව් කිරීම සහ එසේ නොමැතිනම් නිරීක්ෂණය කිරීමට අපහසු වීමයි.

වැඩිදුර තොරතුරු සඳහා කරුණාකර බලන්න: Excel ප්‍රස්ථාරයකට චලනය වන සාමාන්‍ය ප්‍රවණතා එකතු කරන්නේ කෙසේද යන්න.

Excel trendline සමීකරණ සහ සූත්‍ර

මෙම කොටස Excel භාවිතා කරන සමීකරණ විස්තර කරයි. විවිධ ප්රවණතා වර්ග සඳහා. ඔබට මෙම සූත්‍ර අතින් තැනීමට අවශ්‍ය නැත, සරලව Excel හට ප්‍රවනතා රේඛා සමීකරණය ප්‍රස්ථාරයක පෙන්වීමට පවසන්න.

එමෙන්ම, අපි ප්‍රවණතා රේඛාවක බෑවුම සහ අනෙකුත් සංගුණක සොයා ගැනීමට සූත්‍රය සාකච්ඡා කරමු. සූත්‍ර ඔබට විචල්‍ය කට්ටල 2ක් ඇතැයි උපකල්පනය කරයි: ස්වාධීන විචල්‍යය x සහ ඩිපෙන්ඩන විචල්‍ය y . ඔබේ වැඩ පත්‍රිකා තුළ, x හි ඕනෑම අගයක් සඳහා පුරෝකථනය කළ y අගයන් ලබා ගැනීමට ඔබට මෙම සූත්‍ර භාවිත කළ හැක.

අනුකූලතාව සඳහා, අපි එම දත්තම භාවිත කරන්නෙමු. සියලුම උදාහරණ සඳහා තරමක් වෙනස් අගයන් සමඟ සකසන්න. කෙසේ වෙතත්, එය නිදර්ශන අරමුණු සඳහා පමණක් බව කරුණාවෙන් සලකන්න. ඔබේ සැබෑ වැඩ පත්‍රිකා තුළ, ඔබ ඔබේ දත්ත වර්ගයට අනුරූප ප්‍රවණතා වර්ගය තෝරාගත යුතුය.

වැදගත් සටහන! ප්‍රවණතා රේඛා සූත්‍ර XY විසිරුම් ප්‍රස්ථාර සමඟ පමණක් භාවිතා කළ යුතු වන්නේ මෙය පමණිප්‍රස්ථාර x සහ y යන අක්ෂ දෙකම සංඛ්‍යාත්මක අගයන් ලෙස සටහන් කරයි. වැඩි විස්තර සඳහා, කරුණාකර Excel ප්‍රවණතා සමීකරණය වැරදි විය හැක්කේ මන්දැයි බලන්න.

රේඛීය ප්‍රවණතා සමීකරණය සහ සූත්‍ර

රේඛීය ප්‍රවණතා සමීකරණය බෑවුම සෙවීමට අවම වර්ග ක්‍රම භාවිතා කරයි. සහ intercept සංගුණක එවැනි:

y = bx + a

කොහේද:

• b බෑවුම ප්‍රවනතා රේඛාවක.
• a යනු y-අන්තර්ඡේදනය වේ, එය සියලු x<විට y හි අපේක්ෂිත මධ්‍ය අගය වේ 2> විචල්‍යයන් 0 ට සමාන වේ. ප්‍රස්ථාරයක, එය ප්‍රවනතා රේඛාව y අක්ෂය හරහා යන ලක්ෂ්‍යය වේ.

රේඛීය ප්‍රතිගාමීත්වය සඳහා, මයික්‍රොසොෆ්ට් එක්සෙල් විශේෂ කාර්යයන් සපයයි බෑවුම සහ අතුරු සංගුණක.

ප්‍රවණතා රේඛාවේ බෑවුම

b: =SLOPE(y,x)

Y-ඉන්ටර්සෙප්ට්

a: =INTERCEPT(y,x)

x පරාසය B2:B13 සහ y පරාසය C2:C13 ලෙස උපකල්පනය කළහොත්, සැබෑ ජීවිත සූත්‍ර පහත පරිදි වේ:

=SLOPE(C2:C13, B2:B13)

=INTERCEPT(C2:C13,B2:B13)

අරා සූත්‍රයක් ලෙස LINEST ශ්‍රිතය භාවිතා කිරීමෙන් එම ප්‍රතිඵලම ලබා ගත හැක. මේ සඳහා, එම පේළියේම යාබද කොටු 2ක් තෝරා, සූත්‍රය ඇතුළත් කර එය සම්පූර්ණ කිරීමට Ctrl + Shift + Enter ඔබන්න:

=LINEST(C2:C13,B2:B13)

පහත තිර පිටපතේ පෙන්වා ඇති පරිදි, බෑවුම සහ බාධාව සූත්‍ර මගින් ආපසු ලබා දෙන සංගුණක ප්‍රස්ථාරයේ ප්‍රදර්ශනය කර ඇති රේඛීය ප්‍රවණතා සමීකරණයේ සංගුණක සමඟ පරිපූර්ණව අනුකූල වේ, දෙවැන්න පමණක් දශම ස්ථාන 4 ට වට කර ඇත:

ඝාතීය ප්‍රවණතා සමීකරණය සහ සූත්‍ර

ඝාතීය ප්‍රවණතා රේඛාව සඳහා, Excel පහත සමීකරණය භාවිතා කරයි:

y = aebx

a සහ b ගණනය කළ සංගුණක වන අතර e යනු ගණිතමය නියතය e (ස්වාභාවික ලඝුගණකයේ පාදය) වේ.

මෙම සාමාන්‍ය සූත්‍ර භාවිතයෙන් සංගුණක ගණනය කළ හැක:

a: =EXP(INDEX(LINEST(LN(y), x), 1, 2))

b: =INDEX(LINEST(LN(y), x), 1)

අපගේ නියැදි දත්ත කට්ටලය සඳහා, සූත්‍ර පහත හැඩය ගනී:

a: =EXP(INDEX(LINEST(LN(C2:C13), B2:B13), 1, 2))

b: =INDEX(LINEST(LN(C2:C13), B2:B13), 1)

ලඝුගණක ප්‍රවණතා සමීකරණය සහ සූත්‍ර

මෙන්න Excel හි ලඝුගණක ප්‍රවණතා සමීකරණය:

y = a*ln(x)+b

a සහ b නියතයන් වන අතර ln යනු ස්වභාවික ලඝුගණක ශ්‍රිතයයි.

නිරන්තර ලබා ගැනීමට, මෙම සාමාන්‍ය සූත්‍ර භාවිතා කරන්න, එය අවසාන තර්කයට පමණක් වෙනස් වේ:

a: =INDEX(LINEST(y, LN(x)), 1)

b: =INDEX(LINEST(y, LN(x)), 1, 2)

අපගේ නියැදි දත්ත කට්ටලය සඳහා, අපි මේවා භාවිතා කරමු:

a: =INDEX(LINEST(C2:C13, LN(B2:B13)), 1)

b: =INDEX(LINEST(C2:C13, LN(B2:B13)), 1, 2)

බහුපද ප්‍රවණතා සමීකරණය සහ සූත්‍ර

බහුපද ප්‍රවනතා සකස් කිරීමට, Excel මෙම සමීකරණය භාවිතා කරයි:

y = b ₆ x6 + … + b ₂ x2 + b ₁ x + a

තැන b ₁ … b ₆ සහ a නියත වේ.

ඔබේ බහුපද ප්‍රවණතා මට්ටම අනුව, පහත සූත්‍ර කට්ටලවලින් එකක් භාවිතා කරන්න නියතයන් ලබා ගැනීමට.

චතුරස්‍ර (2වන අනුපිළිවෙල) බහුපද ප්‍රවණතා

සමීකරණය: y = b ₂ x2+ b ₁ x + a

b ₂ : =INDEX(LINEST(y, x^{1,2}), 1)

b ₁ : =INDEX(LINEST(y, x^{1,2}), 1, 2)

a: =INDEX(LINEST(y, x^{1,2}), 1, 3)

ඝනක (3වන අනුපිළිවෙල) බහුපද ප්‍රවණතා

සමීකරණය: y = b ₃ x3 + b ₂ x2+ b ₁ x + a

b ₃ : =INDEX(LINEST(y, x^{1,2,3}), 1)

b ₂ : =INDEX(LINEST(y, x^{1,2,3}), 1, 2)

b ₁ : =INDEX(LINEST(y, x^{1,2,3}), 1, 3)

a: =INDEX(LINEST(y, x^{1,2,3}), 1, 4)

ඉහළ උපාධි බහුපද ප්‍රවණතා සඳහා සූත්‍ර එකම රටාව භාවිතයෙන් ගොඩනැගිය හැක.

අපගේ දත්ත කට්ටලය සඳහා, 2වන අනුපිළිවෙල බහුපද ප්‍රවණතා කට්ටල වඩා හොඳයි, එබැවින් අපි මෙම සූත්‍ර භාවිතා කරමු:

b ₂ : =INDEX(LINEST(C2:C13, B2:B13^{1,2}), 1)

b ₁ : =INDEX(LINEST(C2:C13, B2:B13^{1,2}), 1, 2)

a: =INDEX(LINEST(C2:C13, B2:B13^{1,2}), 1, 3)

බල ප්‍රවණතා සමීකරණය සහ සූත්‍ර

මෙම සරල සමීකරණය මත පදනම්ව Excel හි බල ප්‍රවණතා රේඛාවක් ඇඳ ඇත:

y = axb

a සහ b යනු නියතයන් වන අතර, ඒවා මෙම සූත්‍ර සමඟින් ගණනය කළ හැක:

a: =EXP(INDEX(LINEST(LN(y), LN(x),,), 1, 2))

b: =INDEX(LINEST(LN(y), LN(x),,), 1)

අපගේ නඩුවේදී, පහත සූත්‍ර සංග්‍රහයක් ලෙස ක්‍රියා කරයි. :

a: =EXP(INDEX(LINEST(LN(C2:C13), LN(B2:B13),,), 1, 2))

b: =INDEX(LINEST(LN(C2:C13), LN(B2:B13),,), 1)

Excel trendline සමීකරණය වැරදියි - හේතු සහ නිවැරදි කිරීම්

Excel වැරදි ලෙස ප්‍රවණතා රේඛාවක් ඇඳ ඇතැයි ඔබ සිතන්නේ නම් හෝ ඔබේ ප්‍රස්ථාරයේ ප්‍රදර්ශනය කර ඇති ප්‍රවණතා රේඛා සූත්‍රය වැරදියි, පහත කරුණු දෙක සමහරක් වැගිරවිය හැක තත්වය මත ආලෝකය.

Excel trendline සමීකරණය නිවැරදි වන්නේ විසිරුම් ප්‍රස්ථාරවල පමණි

Excel trendline සූත්‍ර XY (විසිරුම්) ප්‍රස්ථාර සමඟ පමණක් භාවිතා කළ යුතුය මන්ද මෙම ප්‍රස්ථාරයේ පමණක් y-axis දෙකම ටයිප් කරන්න. සහ x-අක්ෂය සංඛ්‍යාත්මක අගයන් ලෙස සටහන් කර ඇත.

රේඛා ප්‍රස්ථාර, තීරු සහ තීරු ප්‍රස්ථාරවල, සංඛ්‍යාත්මක අගයන් සටහන් කර ඇත්තේ y-අක්ෂයේ පමණි. x අක්ෂය රේඛීය ශ්‍රේණියක් මගින් නිරූපණය කෙරේ (1, 2,3,...) අක්ෂ ලේබල අංක හෝ පෙළ ද යන්න නොසලකා. ඔබ මෙම ප්‍රස්ථාරවල ප්‍රවනතා රේඛාවක් සාදන විට, Excel විසින් එම උපකල්පනය කරන ලද x අගයන් ප්‍රවනතා රේඛා සූත්‍රයේ භාවිතා කරයි.

එක්සෙල් ප්‍රවනතා සමීකරණයෙන් සංඛ්‍යා වට කර ඇත

ප්‍රස්ථාරයේ අඩු ඉඩක් ලබා ගැනීමට, Excel සංදර්ශක කරයි. ප්‍රවණතා සමීකරණයක සැලකිය යුතු ඉලක්කම් ඉතා ස්වල්පයකි. සැලසුම අනුව හොඳයි, ඔබ සමීකරණයේ x අගයන් අතින් සපයන විට එය සූත්‍රයේ නිරවද්‍යතාවය සැලකිය යුතු ලෙස අඩු කරයි.

පහසු විසඳුමක් වන්නේ සමීකරණයේ වැඩි දශම ස්ථාන පෙන්වීමයි. විකල්පයක් ලෙස, ඔබට ඔබේ ප්‍රවණතා වර්ගයට අනුරූප වන සූත්‍රයක් භාවිතා කිරීමෙන් සංගුණක ගණනය කළ හැකිය, සහ ප්‍රමාණවත් දශම ස්ථාන සංඛ්‍යාවක් පෙන්වන පරිදි සූත්‍ර කොටු සංයුති කරන්න. මේ සඳහා, Number group හි Home ටැබය මත ඇති දශම වැඩි කරන්න බොත්තම ක්ලික් කරන්න.

ඔබට විවිධ ප්‍රවණතා වර්ග සෑදිය හැක්කේ එලෙසිනි. එක්සෙල් හි සහ ඒවායේ සමීකරණ ලබා ගන්න. කියවීම ගැන මම ඔබට ස්තූතිවන්ත වන අතර ලබන සතියේ ඔබව අපගේ බ්ලොග් අඩවියෙන් දැකීමට බලාපොරොත්තු වෙමි!

3>