સામગ્રીઓનું કોષ્ટક
આ ટ્યુટોરીયલમાં, તમને એક્સેલમાં ઉપલબ્ધ તમામ ટ્રેન્ડલાઇન વિકલ્પો અને તેનો ઉપયોગ ક્યારે કરવો તેનું વિગતવાર વર્ણન મળશે. તમે ચાર્ટમાં ટ્રેન્ડલાઇન સમીકરણ કેવી રીતે પ્રદર્શિત કરવું અને ટ્રેન્ડલાઇનનો ઢોળાવ કેવી રીતે શોધવો તે પણ શીખી શકશો.
એક્સેલમાં ટ્રેન્ડલાઇન ઉમેરવી ખૂબ જ સરળ છે. એકમાત્ર વાસ્તવિક પડકાર એ ટ્રેન્ડલાઇન પ્રકાર પસંદ કરવાનો છે જે તમે વિશ્લેષણ કરી રહ્યાં છો તે ડેટાના પ્રકારને શ્રેષ્ઠ રીતે અનુરૂપ છે. આ ટ્યુટોરીયલમાં, તમને એક્સેલમાં ઉપલબ્ધ તમામ ટ્રેન્ડલાઇન વિકલ્પો અને તેનો ઉપયોગ ક્યારે કરવો તેનું વિગતવાર વર્ણન મળશે. જો તમે એક્સેલ ચાર્ટમાં ટ્રેન્ડલાઈન કેવી રીતે દાખલ કરવી તે શોધી રહ્યા છો, તો કૃપા કરીને ઉપરોક્ત લિંક કરેલ ટ્યુટોરીયલ તપાસો.
Excel ટ્રેન્ડલાઈન પ્રકારો
જ્યારે Excel માં ટ્રેન્ડલાઈન ઉમેરવી. , તમારી પાસે પસંદ કરવા માટે 6 વિવિધ વિકલ્પો છે. વધુમાં, માઈક્રોસોફ્ટ એક્સેલ ચાર્ટમાં ટ્રેન્ડલાઈન સમીકરણ અને આર-સ્ક્વેર વેલ્યુ પ્રદર્શિત કરવાની મંજૂરી આપે છે:
- ટ્રેન્ડલાઈન સમીકરણ એ એક ફોર્મ્યુલા છે જે ડેટા પોઈન્ટને શ્રેષ્ઠ રીતે બંધબેસતી લીટી શોધે છે.
- R-ચોરસ મૂલ્ય ટ્રેન્ડલાઇનની વિશ્વસનીયતાને માપે છે - R2 1 ની નજીક છે, ટ્રેન્ડલાઇન ડેટા સાથે વધુ સારી રીતે બંધબેસે છે.
નીચે, તમને ચાર્ટ ઉદાહરણો સાથે દરેક ટ્રેન્ડલાઇન પ્રકારનું સંક્ષિપ્ત વર્ણન મળશે.
રેખીય વલણ રેખા
રેખીય વલણ રેખા શ્રેષ્ઠ છે. જ્યારે ચાર્ટમાંના ડેટા પોઈન્ટ સીધી રેખા જેવા હોય ત્યારે રેખીય ડેટા સેટ સાથે વપરાય છે. સામાન્ય રીતે, એક રેખીય ટ્રેન્ડલાઇન સતત વધારો અથવા ઘટાડાને વર્ણવે છેસમય જતાં.
ઉદાહરણ તરીકે, નીચેની લીનિયર ટ્રેન્ડલાઇન 6 મહિનામાં વેચાણમાં સતત વધારો દર્શાવે છે. અને 0.9855 નું R2 મૂલ્ય વાસ્તવિક ડેટા માટે અંદાજિત ટ્રેન્ડલાઇન મૂલ્યોની ખૂબ સારી ફિટ સૂચવે છે. 
ઘાતાંકીય વલણ
ઘાતાંકીય વલણ એ વક્ર રેખા છે જે વધતા દરે ડેટા મૂલ્યોમાં વધારો અથવા ઘટાડો દર્શાવે છે, તેથી રેખા સામાન્ય રીતે એક બાજુએ વધુ વક્ર હોય છે. આ ટ્રેન્ડલાઇન પ્રકારનો ઉપયોગ ઘણીવાર વિજ્ઞાનમાં કરવામાં આવે છે, ઉદાહરણ તરીકે માનવ વસ્તી વૃદ્ધિ અથવા વન્યજીવનની વસ્તીમાં ઘટાડો જોવા માટે.
કૃપા કરીને નોંધ કરો કે શૂન્ય અથવા નકારાત્મક મૂલ્યો ધરાવતા ડેટા માટે ઘાતાંકીય ટ્રેન્ડલાઇન બનાવી શકાતી નથી.
ઘાતાંકીય વળાંકનું સારું ઉદાહરણ પૃથ્વી પરની સમગ્ર જંગલી વાઘની વસ્તીનો સડો છે. 
લોગરીધમિક ટ્રેન્ડલાઇન
લોગરીધમિક બેસ્ટ-ફીટ લાઇનનો ઉપયોગ સામાન્ય રીતે ડેટાને પ્લોટ કરવા માટે થાય છે જે ઝડપથી વધે છે અથવા ઘટે છે અને પછી સ્તર બંધ થાય છે. તેમાં સકારાત્મક અને નકારાત્મક બંને મૂલ્યો શામેલ હોઈ શકે છે.
લોગરીધમિક ટ્રેન્ડલાઈનનું ઉદાહરણ ફુગાવાનો દર હોઈ શકે છે, જે પહેલા ઊંચો થઈ રહ્યો છે પરંતુ થોડા સમય પછી સ્થિર થઈ જાય છે. 
બહુપદી ટ્રેન્ડલાઈન
બહુપદી વક્રીય ટ્રેન્ડલાઈન એક કરતા વધુ ઉદય અને પતન ધરાવતા ઓસીલેટીંગ મૂલ્યો સાથે મોટા ડેટા સેટ માટે સારી રીતે કામ કરે છે.
સામાન્ય રીતે, બહુપદીનું વર્ગીકરણ દ્વારા વર્ગીકૃત કરવામાં આવે છે. સૌથી મોટા ઘાતાંકની ડિગ્રી. બહુપદી ટ્રેન્ડલાઇનની ડિગ્રી કરી શકે છેગ્રાફ પરના વળાંકોની સંખ્યા દ્વારા પણ નક્કી કરવામાં આવે છે. સામાન્ય રીતે, ચતુર્ભુજ બહુપદી વલણમાં એક વળાંક (પહાડી અથવા ખીણ) હોય છે, ઘન બહુપદીમાં 1 અથવા 2 વળાંક હોય છે, અને ચતુર્થાંશ બહુપદીમાં 3 વળાંક હોય છે.
એક્સેલ ચાર્ટમાં બહુપદી ટ્રેન્ડલાઇન ઉમેરતી વખતે, તમે ફોર્મેટ ટ્રેન્ડલાઇન ફલક પર ઓર્ડર બોક્સમાં અનુરૂપ નંબર લખીને ડિગ્રીનો ઉલ્લેખ કરો છો, જે મૂળભૂત રીતે 2 છે: 
ઉદાહરણ તરીકે, ચતુર્ભુજ બહુપદી વલણ નીચેના ગ્રાફ પર સ્પષ્ટ છે જે નફો અને ઉત્પાદન કેટલાં વર્ષોથી બજારમાં છે તે વચ્ચેનો સંબંધ દર્શાવે છે: શરૂઆતમાં વધારો, મધ્યમાં ટોચ અને અંતની નજીક પતન. 
પાવર ટ્રેન્ડલાઇન
પાવર ટ્રેન્ડ લાઇન ઘાતાંકીય વળાંક જેવી જ છે, માત્ર તેની પાસે વધુ સપ્રમાણ ચાપ છે. તેનો ઉપયોગ સામાન્ય રીતે ચોક્કસ દરે વધતા માપને પ્લોટ કરવા માટે થાય છે.
એક પાવર ટ્રેન્ડલાઇન એક્સેલ ચાર્ટમાં ઉમેરી શકાતી નથી જેમાં શૂન્ય અથવા નકારાત્મક મૂલ્યો હોય છે.
ઉદાહરણ તરીકે, ચાલો એક દોરીએ રાસાયણિક પ્રતિક્રિયા દરની કલ્પના કરવા માટે પાવર ટ્રેન્ડલાઇન. 0.9918 ના R-ચોરસ મૂલ્યની નોંધ લો, જેનો અર્થ છે કે અમારી ટ્રેન્ડલાઇન ડેટાને લગભગ સંપૂર્ણ રીતે બંધબેસે છે. 
મૂવિંગ એવરેજ ટ્રેન્ડલાઈન
જ્યારે તમારા ચાર્ટમાંના ડેટા પોઈન્ટ્સમાં ઘણા બધા ઉતાર-ચઢાવ હોય છે, ત્યારે મૂવિંગ એવરેજ ટ્રેન્ડલાઈન કોઈ પેટર્નને વધુ સ્પષ્ટ રીતે બતાવવા માટે ડેટા મૂલ્યોમાં ભારે વધઘટને સરળ બનાવી શકે છે. આ માટે, એક્સેલ ગણતરી કરે છેતમે ઉલ્લેખિત કરો છો તે સમયગાળાની સંખ્યાની મૂવિંગ એવરેજ (ડિફોલ્ટ રૂપે 2) અને તે સરેરાશ મૂલ્યોને લાઇનમાં પોઈન્ટ તરીકે મૂકે છે. પીરિયડ મૂલ્ય જેટલું ઊંચું છે, તેટલી લીટી સરળ.
એક સારું વ્યવહારુ ઉદાહરણ મૂવિંગ એવરેજ ટ્રેન્ડલાઇનનો ઉપયોગ કરીને શેરના ભાવમાં થતી વધઘટને જાહેર કરે છે જે અન્યથા અવલોકન કરવું મુશ્કેલ હશે. 
વધુ માહિતી માટે, કૃપા કરીને જુઓ: એક્સેલ ચાર્ટમાં મૂવિંગ એવરેજ ટ્રેન્ડલાઈન કેવી રીતે ઉમેરવી.
એક્સેલ ટ્રેન્ડલાઈન સમીકરણો અને સૂત્રો
આ વિભાગ એ સમીકરણોનું વર્ણન કરે છે જેનો એક્સેલ ઉપયોગ કરે છે. વિવિધ ટ્રેન્ડલાઇન પ્રકારો માટે. તમારે આ સૂત્રો જાતે બનાવવાની જરૂર નથી, ફક્ત એક્સેલને ચાર્ટમાં ટ્રેન્ડલાઈન સમીકરણ દર્શાવવા માટે કહો.
ઉપરાંત, અમે ટ્રેન્ડલાઈન અને અન્ય ગુણાંકનો ઢોળાવ શોધવા માટે સૂત્રની ચર્ચા કરીશું. સૂત્રો ધારે છે કે તમારી પાસે ચલોના 2 સેટ છે: સ્વતંત્ર ચલ x અને આશ્રિત ચલ y . તમારી કાર્યપત્રકોમાં, તમે x ના કોઈપણ આપેલ મૂલ્યો માટે અનુમાનિત y મૂલ્યો મેળવવા માટે આ સૂત્રોનો ઉપયોગ કરી શકો છો.
સતતતા માટે, અમે સમાન ડેટાનો ઉપયોગ કરીશું. બધા ઉદાહરણો માટે સહેજ અલગ મૂલ્યો સાથે સેટ કરો. જો કે, કૃપા કરીને ધ્યાનમાં રાખો કે તે માત્ર પ્રદર્શન હેતુઓ માટે છે. તમારી વાસ્તવિક કાર્યપત્રકોમાં, તમારે તમારા ડેટા પ્રકારને અનુરૂપ ટ્રેન્ડલાઇન પ્રકાર પસંદ કરવો જોઈએ.
મહત્વપૂર્ણ નોંધ! ટ્રેન્ડલાઇન ફોર્મ્યુલાનો ઉપયોગ ફક્ત XY સ્કેટર ચાર્ટ્સ સાથે થવો જોઈએ કારણ કે માત્ર આઆંકડાકીય મૂલ્યો તરીકે x અને y અક્ષ બંને ચાર્ટ પ્લોટ. વધુ માહિતી માટે, કૃપા કરીને જુઓ કે એક્સેલ ટ્રેન્ડલાઈન સમીકરણ કેમ ખોટું હોઈ શકે છે.
રેખીય ટ્રેન્ડલાઈન સમીકરણ અને સૂત્રો
રેખીય ટ્રેન્ડલાઈન સમીકરણ સ્લોપ શોધવા માટે ઓછામાં ઓછા ચોરસ પદ્ધતિઓનો ઉપયોગ કરે છે. અને ઇન્ટરસેપ્ટ ગુણાંક જેમ કે:
y = bx + aક્યાં:
- b એ સ્લોપ છે ટ્રેન્ડલાઇનનું.
- a એ y-ઇન્ટરસેપ્ટ છે, જે y નું અપેક્ષિત સરેરાશ મૂલ્ય છે જ્યારે બધા x ચલો 0 ની બરાબર છે. ચાર્ટ પર, તે તે બિંદુ છે જ્યાં ટ્રેન્ડલાઇન y અક્ષને પાર કરે છે.
રેખીય રીગ્રેસન માટે, માઇક્રોસોફ્ટ એક્સેલ વિશેષ કાર્યો પ્રદાન કરે છે. સ્લોપ અને ઈન્ટરસેપ્ટ ગુણાંક.
ટ્રેન્ડલાઈનનો ઢોળાવ
b: =SLOPE(y,x)
Y- ઈન્ટરસેપ્ટ
a: =INTERCEPT(y,x)
માની લઈએ કે x શ્રેણી B2:B13 છે અને y શ્રેણી C2:C13 છે, વાસ્તવિક જીવનના સૂત્રો નીચે મુજબ છે:
=SLOPE(C2:C13, B2:B13)
=INTERCEPT(C2:C13,B2:B13)
એરે ફોર્મ્યુલા તરીકે LINEST ફંક્શનનો ઉપયોગ કરીને સમાન પરિણામો પ્રાપ્ત કરી શકાય છે. આ માટે, સમાન પંક્તિમાં 2 સંલગ્ન કોષો પસંદ કરો, ફોર્મ્યુલા દાખલ કરો અને તેને પૂર્ણ કરવા માટે Ctrl + Shift + Enter દબાવો:
=LINEST(C2:C13,B2:B13)
નીચેના સ્ક્રીનશૉટમાં બતાવ્યા પ્રમાણે, સ્લોપ અને ઇન્ટરસેપ્ટ સૂત્રો દ્વારા પરત કરવામાં આવેલા ગુણાંકો ચાર્ટમાં પ્રદર્શિત રેખીય ટ્રેન્ડલાઇન સમીકરણમાંના ગુણાંક સાથે સંપૂર્ણ રીતે સુસંગત છે, માત્ર બાદમાં 4 દશાંશ સ્થાનો પર ગોળાકાર છે: 
ઘાતાંકીય ટ્રેન્ડલાઇન સમીકરણ અને સૂત્રો
ઘાતાંકીય ટ્રેન્ડલાઇન માટે, એક્સેલ નીચેના સમીકરણનો ઉપયોગ કરે છે:
y = aebxજ્યાં a અને b એ ગણિત ગુણાંક છે અને e એ ગાણિતિક સ્થિરાંક છે (કુદરતી લઘુગણકનો આધાર).
આ સામાન્ય સૂત્રોનો ઉપયોગ કરીને ગુણાંકની ગણતરી કરી શકાય છે:
a: =EXP(INDEX(LINEST(LN(y), x), 1, 2))
b: =INDEX(LINEST(LN(y), x), 1)
અમારા નમૂના ડેટા સેટ માટે, સૂત્રો નીચેનો આકાર લે છે:
a: =EXP(INDEX(LINEST(LN(C2:C13), B2:B13), 1, 2))
b: =INDEX(LINEST(LN(C2:C13), B2:B13), 1) 
લોગરીધમિક ટ્રેન્ડલાઈન સમીકરણ અને ફોર્મ્યુલા
અહીં Excel માં લોગરીધમિક ટ્રેન્ડલાઈન સમીકરણ છે:
y = a*ln(x)+bજ્યાં a અને b સ્થિરાંકો છે અને ln એ કુદરતી લઘુગણક કાર્ય છે.
અચલ મેળવવા માટે, આ સામાન્ય સૂત્રોનો ઉપયોગ કરો, જે ફક્ત છેલ્લા દલીલમાં અલગ પડે છે:
a: =INDEX(LINEST(y, LN(x)), 1)
b: =INDEX(LINEST(y, LN(x)), 1, 2)
અમારા નમૂના ડેટા સેટ માટે, અમે આનો ઉપયોગ કરીએ છીએ:
a: =INDEX(LINEST(C2:C13, LN(B2:B13)), 1)
b: =INDEX(LINEST(C2:C13, LN(B2:B13)), 1, 2) 
બહુપદી ટ્રેન્ડલાઈન સમીકરણ અને સૂત્રો
બહુપદી ટ્રેન્ડલાઈન પર કામ કરવા માટે, એક્સેલ આ સમીકરણનો ઉપયોગ કરે છે:
y = b 6 x6 + … + b 2 x2 + b 1 x + aજ્યાં b 1 … b 6 અને a એ સ્થિરાંકો છે.
તમારી બહુપદી ટ્રેન્ડલાઇનની ડિગ્રીના આધારે, નીચેના ફોર્મ્યુલાના સેટમાંથી એકનો ઉપયોગ કરો સ્થિરાંકો મેળવવા માટે.
ચતુર્ભુજ (બીજો ક્રમ) બહુપદી વલણ
સમીકરણ: y = b 2 x2+ b 1 x + a
b 2 : =INDEX(LINEST(y, x^{1,2}), 1)
b 1 : =INDEX(LINEST(y, x^{1,2}), 1, 2)
a: =INDEX(LINEST(y, x^{1,2}), 1, 3)
ઘન (ત્રીજો ક્રમ) બહુપદી વલણ
સમીકરણ: y = b 3 x3 + b 2 x2+ b 1 x + a
b 3 : =INDEX(LINEST(y, x^{1,2,3}), 1)
b 2 : =INDEX(LINEST(y, x^{1,2,3}), 1, 2)
b 1 : =INDEX(LINEST(y, x^{1,2,3}), 1, 3)
a: =INDEX(LINEST(y, x^{1,2,3}), 1, 4)
b 2 : =INDEX(LINEST(C2:C13, B2:B13^{1,2}), 1)
b 1 : =INDEX(LINEST(C2:C13, B2:B13^{1,2}), 1, 2)
a: =INDEX(LINEST(C2:C13, B2:B13^{1,2}), 1, 3) 
પાવર ટ્રેન્ડલાઇન સમીકરણ અને સૂત્રો
એક્સેલમાં પાવર ટ્રેન્ડલાઇન આ સરળ સમીકરણના આધારે દોરવામાં આવે છે:
y = axbજ્યાં a અને b સ્થિરાંકો છે, જેની ગણતરી આ સૂત્રો દ્વારા કરી શકાય છે:
a: =EXP(INDEX(LINEST(LN(y), LN(x),,), 1, 2))
b: =INDEX(LINEST(LN(y), LN(x),,), 1)
અમારા કિસ્સામાં, નીચેના સૂત્રો એક સારવારનું કામ કરે છે :
a: =EXP(INDEX(LINEST(LN(C2:C13), LN(B2:B13),,), 1, 2))
b: =INDEX(LINEST(LN(C2:C13), LN(B2:B13),,), 1) 
Excel ટ્રેન્ડલાઈન સમીકરણ ખોટું છે - કારણો અને સુધારા
જો તમને લાગે કે એક્સેલ એ ખોટી રીતે ટ્રેન્ડલાઈન દોરી છે અથવા તમારા ચાર્ટમાં પ્રદર્શિત ટ્રેન્ડલાઇન ફોર્મ્યુલા ખોટો છે, નીચેના બે મુદ્દાઓ કેટલાક શેડ કરી શકે છે પરિસ્થિતિ પર પ્રકાશ.
એક્સેલ ટ્રેન્ડલાઈન સમીકરણ માત્ર સ્કેટર ચાર્ટમાં જ સાચું છે
એક્સેલ ટ્રેન્ડલાઈન ફોર્મ્યુલાનો ઉપયોગ ફક્ત XY (સ્કેટર) ગ્રાફ સાથે થવો જોઈએ કારણ કે માત્ર આ ચાર્ટમાં બંને y-અક્ષ લખે છે અને x-અક્ષને આંકડાકીય મૂલ્યો તરીકે પ્લોટ કરવામાં આવે છે.
લાઇન ચાર્ટ, કૉલમ અને બાર ગ્રાફમાં, આંકડાકીય મૂલ્યો માત્ર y-અક્ષ પર રચાય છે. x-અક્ષ રેખીય શ્રેણી (1, 2,3,…) અક્ષ લેબલ્સ સંખ્યાઓ અથવા ટેક્સ્ટ છે કે કેમ તે ધ્યાનમાં લીધા વિના. જ્યારે તમે આ ચાર્ટમાં ટ્રેન્ડલાઈન બનાવો છો, ત્યારે એક્સેલ ટ્રેન્ડલાઈન ફોર્મ્યુલામાં ધારેલા x-મૂલ્યોનો ઉપયોગ કરે છે.
એક્સેલ ટ્રેન્ડલાઈન સમીકરણમાં નંબરો ગોળાકાર હોય છે
ચાર્ટમાં ઓછી જગ્યા ફાળવવા માટે, એક્સેલ પ્રદર્શિત કરે છે. ટ્રેન્ડલાઇન સમીકરણમાં બહુ ઓછા નોંધપાત્ર અંકો. ડિઝાઇનની દ્રષ્ટિએ સરસ, જ્યારે તમે સમીકરણમાં x મૂલ્યોને મેન્યુઅલી સપ્લાય કરો છો ત્યારે તે ફોર્મ્યુલાની ચોકસાઈને નોંધપાત્ર રીતે ઘટાડે છે.
સમીકરણમાં વધુ દશાંશ સ્થાનો બતાવવાનું સરળ ફિક્સ છે. વૈકલ્પિક રીતે, તમે તમારા ટ્રેન્ડલાઈન પ્રકારને અનુરૂપ ફોર્મ્યુલાનો ઉપયોગ કરીને ગુણાંકની ગણતરી કરી શકો છો અને ફોર્મ્યુલા કોષોને ફોર્મેટ કરી શકો છો જેથી તેઓ દશાંશ સ્થાનોની પૂરતી સંખ્યા બતાવે. આ માટે, નંબર જૂથમાં હોમ ટેબ પર ફક્ત દશાંશ વધારો બટનને ક્લિક કરો.
આ રીતે તમે વિવિધ ટ્રેન્ડલાઇન પ્રકારો બનાવી શકો છો. Excel માં અને તેમના સમીકરણો મેળવો. હું વાંચવા બદલ તમારો આભાર માનું છું અને આશા રાખું છું કે તમને આવતા અઠવાડિયે અમારા બ્લોગ પર મળીશ!
