Dina tutorial ieu, anjeun bakal mendakan katerangan lengkep ngeunaan sadaya pilihan trendline anu aya dina Excel sareng nalika dianggo. Anjeun oge bakal diajar kumaha cara mintonkeun persamaan trendline dina bagan sarta manggihan kemiringan trendline.

Gampang pisan pikeun nambahkeun trendline dina Excel. Hiji-hijina tantangan nyata nyaéta milih jinis trendline anu paling cocog sareng jinis data anu anjeun analisa. Dina tutorial ieu, anjeun bakal mendakan katerangan lengkep ngeunaan sadaya pilihan trendline anu aya dina Excel sareng iraha nganggona. Upami anjeun milarian cara nyelapkeun garis tren dina bagan Excel, mangga tingali tutorial anu dihubungkeun di luhur.

Jenis garis trend Excel

Nalika nambahkeun garis trend dina Excel , anjeun gaduh 6 pilihan anu béda pikeun dipilih. Salaku tambahan, Microsoft Excel ngamungkinkeun mintonkeun persamaan trendline sareng nilai R-kuadrat dina bagan:

• Persamaan Trendline mangrupikeun rumus anu mendakan garis anu paling pas sareng titik data.
• Nilai R-kuadrat ngukur reliabilitas trendline - beuki deukeut R2 ka 1, leuwih hade trendline cocog data.

Di handap, anjeun bakal manggihan pedaran ringkes unggal tipe trendline kalawan conto grafik.

Tren linear

Garis trend linier pangalusna pikeun jadi dipaké kalawan susunan data linier lamun titik data dina bagan nyarupaan garis lempeng. Ilaharna, garis trend linier ngajelaskeun naék atanapi turun kontinyukana waktosna.

Contona, garis trend linier di handap ieu nunjukkeun paningkatan anu tetep dina penjualan salami 6 bulan. Sareng nilai R2 tina 0.9855 nunjukkeun pas anu saé tina estimasi nilai trendline kana data anu saleresna.

Garis tren éksponénsial

Garis tren éksponénsial nyaéta garis melengkung anu ngagambarkeun naék atawa turunna niléy data dina laju ngaronjat, ku kituna garisna biasana leuwih melengkung dina hiji sisi. Jinis trendline ieu sering dianggo dina élmu, contona pikeun ngabayangkeun pertumbuhan populasi manusa atanapi turunna populasi satwa.

Perhatikeun yén garis trend eksponénsial teu tiasa diciptakeun pikeun data anu ngandung nol atanapi nilai négatip.

Conto alus tina kurva eksponensial nyaéta burukna sakabéh populasi macan liar di bumi.

Garis logaritmik

Garis logaritmik paling pas umumna dipaké pikeun plot data nu gancang nambahan atawa ngurangan lajeng level off. Bisa ngawengku duanana nilai positif jeung negatif.

Conto garis trend logaritmik bisa jadi laju inflasi, nu mimitina beuki luhur tapi sanggeus sababaraha waktu stabilizes.

Garis tren polinomial

Garis trendlinear polinomial dianggo saé pikeun set data ageung kalayan nilai osilasi anu gaduh langkung ti hiji naék sareng turun.

Sacara umum, polinomial digolongkeun ku darajat éksponén panggedéna. Darajat garis trend polynomial tiasaogé ditangtukeun ku jumlah bends dina grafik. Ilaharna, garis tren polinomial kuadrat gaduh hiji tikungan (pagunungan atanapi lebak), polinomial kubik gaduh 1 atanapi 2 tikungan, sareng polinomial kuartik dugi ka 3 tikungan.

Nalika nambihan garis tren polinomial dina bagan Excel, Anjeun nangtukeun gelar ku ngetik nomer nu cocog dina kotak Pesenan dina panel Format Trendline , nyaéta 2 sacara standar:

Contona, tren polinomial kuadrat. dibuktikeun dina grafik di handap ieu nu nembongkeun hubungan antara kauntungan jeung jumlah taun produk geus di pasar: naek di awal, puncak di tengah jeung ragrag deukeut tungtung.

Power trendline

Power trend line mirip pisan jeung eksponensial kurva, ngan eta boga busur leuwih simetris. Biasana dianggo pikeun ngarencanakeun pangukuran anu ningkat dina laju anu tangtu.

Garis tren kakuatan teu tiasa diasupkeun kana bagan Excel anu ngandung nilai nol atanapi négatip.

Salaku conto, hayu urang ngagambar kakuatan trendline pikeun visualize laju réaksi kimiawi. Catetan nilai R-kuadrat 0.9918, nu hartina trendline kami fits data ampir sampurna.

Garis tren rata-rata pindah

Lamun titik data dina bagan anjeun loba naek jeung turun, garis trend rata-rata gerak bisa ngalancarkeun turun naek ekstrim dina nilai data pikeun nembongkeun pola anu leuwih jelas. Pikeun ieu, Excel ngitungrata-rata pindah tina jumlah période anu anjeun tangtukeun (2 sacara standar) sareng nempatkeun nilai rata-rata éta salaku titik dina garis. Nu leuwih luhur nilai Periode , garis smoother.

Conto praktis anu alus nyaéta ngagunakeun garis trend rata-rata pikeun nembongkeun fluctuations dina harga saham nu disebutkeun bakal hese dititénan.

Pikeun inpo nu leuwih lengkep, mangga tingali: Cara nambihkeun garis tren rata-rata pindah ka bagan Excel.

Persamaan sareng rumus garis trend Excel

Bagian ieu ngajelaskeun persamaan anu dianggo ku Excel. pikeun jenis trendline béda. Anjeun teu kudu nyieun rumus ieu sacara manual, cukup ngabejaan Excel pikeun mintonkeun persamaan trendline dina bagan.

Oge, urang bakal ngabahas rumus pikeun manggihan kemiringan trendline jeung koefisien séjén. Rumusna nganggap yén anjeun gaduh 2 sét variabel: variabel bébas x sareng variabel terikat y . Dina lembar kerja anjeun, anjeun tiasa nganggo rumus ieu pikeun kéngingkeun nilai y anu diprediksi pikeun nilai anu dipasihkeun tina x .

Pikeun konsistensi, urang bakal ngagunakeun data anu sami set kalawan nilai rada varying pikeun sakabéh conto. Nanging, punten émut yén éta ngan ukur pikeun tujuan démo. Dina lembar kerja nyata anjeun, anjeun kedah milih jinis garis tren anu cocog sareng jinis data anjeun.

Catetan penting! Rumus trendline ngan kudu dipaké kalawan XY scatter chart sabab ngan ieugrafik plot duanana x jeung y sumbu salaku nilai numerik. Kanggo inpo nu leuwih lengkep, mangga tingali Naha persamaan garis trend Excel bisa jadi salah.

Persamaan garis trend linier jeung rumus

Persamaan garis trend linier ngagunakeun métode kuadrat pangleutikna pikeun néangan kemiringan jeung intercept koefisien saperti kieu:

y = bx + a

Dimana:

• b nyaeta lamping tina garis trend.
• a nyaeta y-intercept , nu ngarupakeun nilai rata-rata ekspektasi y lamun kabeh x variabel sarua jeung 0. Dina bagan, éta titik dimana garis trend ngaliwatan sumbu y .

Pikeun régrési linier, Microsoft Excel nyadiakeun pungsi husus pikeun meunangkeun koéfisién slope sareng intercept.

Slope of trendline

b: =SLOPE(y,x)

Y-intercept

a: =INTERCEPT(y,x)

Anggap rentang x nyaeta B2:B13 jeung rentang y nyaeta C2:C13, rumus kahirupan nyata saperti kieu:

=SLOPE(C2:C13, B2:B13)

=INTERCEPT(C2:C13,B2:B13)

Hasil anu sarua bisa dihontal ku ngagunakeun pungsi LINEST salaku rumus array . Jang ngalampahkeun ieu, pilih 2 sél anu padeukeut dina baris anu sami, lebetkeun rumus sareng pencét Ctrl + Shift + Enter pikeun ngarengsekeunana:

=LINEST(C2:C13,B2:B13)

Sapertos anu dipidangkeun dina screenshot di handap, lamping sareng intercept. koefisien anu dipulangkeun ku rumus sampurna saluyu sareng koefisien dina persamaan garis trend linier anu dipidangkeun dina bagan, ngan anu terakhir dibuleurkeun ka 4 tempat perpuluhan:

Persamaan jeung rumus garis trend eksponensial

Pikeun garis trend eksponensial, Excel ngagunakeun persamaan ieu:

y = aebx

Dimana a jeung b diitung koefisien jeung e ngarupakeun konstanta matematik e (dasar logaritma alam).

Koefisien bisa diitung ku rumus generik ieu:

a: =EXP(INDEX(LINEST(LN(y), x), 1, 2))

b: =INDEX(LINEST(LN(y), x), 1)

Pikeun kumpulan data sampel urang, rumusna saperti kieu:

a: =EXP(INDEX(LINEST(LN(C2:C13), B2:B13), 1, 2))

b: =INDEX(LINEST(LN(C2:C13), B2:B13), 1)

Persamaan garis tren logaritmik sareng rumus

Ieu persamaan garis tren logaritmik dina Excel:

y = a*ln(x)+b

Dimana a sareng b mangrupakeun konstanta sarta ln mangrupa fungsi logaritma natural.

Pikeun meunangkeun konstanta, make rumus generik ieu, nu ngan béda dina argumen panungtungan:

a: =INDEX(LINEST(y, LN(x)), 1)

b: =INDEX(LINEST(y, LN(x)), 1, 2)

Pikeun kumpulan data sampel, kami nganggo ieu:

a: =INDEX(LINEST(C2:C13, LN(B2:B13)), 1)

b: =INDEX(LINEST(C2:C13, LN(B2:B13)), 1, 2)

Persamaan garis tren polinomial sareng rumus

Pikeun ngadamel garis tren polinomial, Excel nganggo persamaan ieu:

y = b ₆ x6 + … + b ₂ x2 + b ₁ x + a

Dimana b ₁ … b ₆ jeung a mangrupakeun konstanta.

Gumantung kana darajat garis trend polynomial anjeun, make salah sahiji susunan rumus di handap ieu. pikeun meunangkeun konstanta.

Quadratic (2nd orde) polynomial trendline

Persamaan: y = b ₂ x2+ b ₁ x + a

b ₂ : =INDEX(LINEST(y, x^{1,2}), 1)

b ₁ : =INDEX(LINEST(y, x^{1,2}), 1, 2)

a: =INDEX(LINEST(y, x^{1,2}), 1, 3)

Kubik (urutan ka-3) polynomial trendline

Persamaan: y = b ₃ x3 + b ₂ x2+ b ₁ x + a

b ₃ : =INDEX(LINEST(y, x^{1,2,3}), 1)

b ₂ : =INDEX(LINEST(y, x^{1,2,3}), 1, 2)

b ₁ : =INDEX(LINEST(y, x^{1,2,3}), 1, 3)

a: =INDEX(LINEST(y, x^{1,2,3}), 1, 4)

Rumus pikeun garis tren polinomial tingkat luhur bisa diwangun ku cara make pola anu sarua.

Pikeun set data urang, susunan garis trend polinomial ka-2 langkung saé, janten urang nganggo rumus ieu:

b ₂ : =INDEX(LINEST(C2:C13, B2:B13^{1,2}), 1)

b ₁ : =INDEX(LINEST(C2:C13, B2:B13^{1,2}), 1, 2)

a: =INDEX(LINEST(C2:C13, B2:B13^{1,2}), 1, 3)

Persamaan sareng rumus garis tren kakuatan

Garis tren kakuatan dina Excel digambar dumasar kana persamaan basajan ieu:

y = axb

Dimana a sareng b nyaéta konstanta, nu bisa diitung ku rumus ieu:

a: =EXP(INDEX(LINEST(LN(y), LN(x),,), 1, 2))

b: =INDEX(LINEST(LN(y), LN(x),,), 1)

Dina kasus urang, rumus di handap ieu dianggo saréat. :

a: =EXP(INDEX(LINEST(LN(C2:C13), LN(B2:B13),,), 1, 2))

b: =INDEX(LINEST(LN(C2:C13), LN(B2:B13),,), 1)

Persamaan garis trend Excel lepat - alesan sareng perbaikan

Upami anjeun nyangka yén Excel salah ngagambar garis tren atanapi rumus trendline ditampilkeun dina bagan anjeun salah, dua titik di handap ieu bisa héd sababaraha terang kana kaayaan.

Persamaan garis trend Excel leres ngan dina bagan paburencay

Rumus garis trend Excel ngan kedah dianggo sareng grafik XY (paburencay) sabab ngan dina bagan ieu ngetik duanana sumbu-y. jeung sumbu-x diplot jadi nilai numerik.

Dina diagram garis, kolom jeung grafik batang, nilai numerik diplot ukur dina sumbu-y. Sumbu-x digambarkeun ku runtuyan linier (1, 2,3,…) henteu paduli naha labél sumbuna nyaéta nomer atanapi téks. Lamun anjeun nyieun garis trend dina bagan ieu, Excel ngagunakeun asumsina nilai-x dina rumus trendline.

Jumlah dibuleudkeun dina persamaan garis trend Excel

Pikeun ngeusian kirang spasi dina bagan, Excel mintonkeun saeutik pisan digit signifikan dina persamaan trendline. Dina hal desain, éta sacara signifikan ngirangan akurasi rumus nalika anjeun nyayogikeun nilai x sacara manual dina persamaan.

Perbaikan anu gampang nyaéta nunjukkeun langkung seueur tempat desimal dina persamaan. Alternatipna, anjeun tiasa ngitung koefisien nganggo rumus anu cocog sareng jinis garis trend anjeun, sareng pormat sél rumus supados nunjukkeun jumlah tempat perpuluhan anu cekap. Jang ngalampahkeun ieu, cukup klik tombol Tambahkeun Decimal dina tab Imah dina grup Jumlah .

Ku kituna anjeun tiasa ngadamel jinis garis trend anu béda. dina Excel sareng kéngingkeun persamaanna. Kuring hatur nuhun pikeun maca sareng ngarepkeun anjeun tiasa ningali dina blog urang minggu payun!