En aquest tutorial, trobareu la descripció detallada de totes les opcions de línia de tendència disponibles a Excel i quan utilitzar-les. També aprendràs a mostrar una equació de línia de tendència en un gràfic i a trobar el pendent de la línia de tendència.

És molt fàcil afegir una línia de tendència a Excel. L'únic repte real és triar el tipus de línia de tendència que millor es correspongui amb el tipus de dades que esteu analitzant. En aquest tutorial, trobareu la descripció detallada de totes les opcions de tendències disponibles a Excel i quan utilitzar-les. Si esteu buscant com inserir una línia de tendència en un gràfic d'Excel, consulteu el tutorial enllaçat anteriorment.

Tipus de línies de tendència d'Excel

Quan afegiu una línia de tendència a Excel , tens 6 opcions diferents per triar. A més, Microsoft Excel permet mostrar una equació de línia de tendència i un valor R-quadrat en un gràfic:

• L'equació de la línia de tendència és una fórmula que troba una línia que s'ajusti millor als punts de dades.
• El valor R-quadrat mesura la fiabilitat de la línia de tendència: com més a prop estigui R2 a 1, millor s'ajusta la línia de tendència a les dades.

A continuació, trobareu una breu descripció de cada tipus de línia de tendència amb exemples de gràfics.

Línia de tendència lineal

La línia de tendència lineal és millor que sigui s'utilitza amb conjunts de dades lineals quan els punts de dades d'un gràfic s'assemblen a una línia recta. Normalment, una línia de tendència lineal descriu un augment o una caiguda contínuaal llarg del temps.

Per exemple, la línia de tendència lineal següent mostra un augment constant de les vendes durant 6 mesos. I el valor R2 de 0,9855 indica un ajust força bo dels valors estimats de la línia de tendència a les dades reals.

Línia de tendència exponencial

La línia de tendència exponencial és una línia corba que il·lustra un augment o una caiguda dels valors de les dades a un ritme creixent, per tant, la línia sol ser més corba per un costat. Aquest tipus de línia de tendència s'utilitza sovint en ciències, per exemple, per visualitzar el creixement de la població humana o la disminució de les poblacions de fauna salvatge.

Tingueu en compte que no es pot crear una línia de tendència exponencial per a dades que continguin zeros o valors negatius.

Un bon exemple de corba exponencial és la decadència de tota la població de tigres salvatges a la terra.

Línia de tendència logarítmica

La línia de millor ajust logarítmica s'utilitza generalment per representar dades que augmenten o disminueixen ràpidament i després s'anivella. Pot incloure valors tant positius com negatius.

Un exemple de línia de tendència logarítmica pot ser una taxa d'inflació, que primer augmenta, però després d'un temps s'estabilitza.

Línia de tendència polinòmica

La línia de tendència polinomi curvilínia funciona bé per a grans conjunts de dades amb valors oscil·lants que tenen més d'una pujada i una baixada.

En general, un polinomi es classifica per la grau del màxim exponent. El grau de la línia de tendència del polinomi pottambé es determina pel nombre de corbes d'un gràfic. Normalment, una línia de tendència polinomi quadràtica té un revolt (turó o vall), un polinomi cúbic té 1 o 2 corbes i un polinomi quàrtic té fins a 3 corbes.

Quan s'afegeix una línia de tendència polinomi en un gràfic d'Excel, especifiqueu el grau escrivint el número corresponent al quadre Ordre del panell Format de línia de tendència , que és 2 per defecte:

Per exemple, la tendència polinomi quadràtica. s'evidencia en el gràfic següent que mostra la relació entre el benefici i el nombre d'anys que porta el producte al mercat: pujada al principi, pic al mig i baixada al final.

Línia de tendència de potència

La línia de tendència de potència és molt semblant a la corba exponencial, només que té un arc més simètric. S'utilitza habitualment per representar mesures que augmenten a un ritme determinat.

No es pot afegir una línia de tendència de potència a un gràfic d'Excel que contingui valors zero o negatius.

Com a exemple, dibuixem un línia de tendència de potència per visualitzar la velocitat de la reacció química. Tingueu en compte el valor R-quadrat de 0,9918, el que significa que la nostra línia de tendència s'ajusta a les dades gairebé perfectament.

Línia de tendència mitjana mòbil

Quan els punts de dades del vostre gràfic tenen molts alts i baixos, una línia de tendència mitjana mòbil pot suavitzar les fluctuacions extremes dels valors de les dades per mostrar un patró més clarament. Per a això, Excel calcula elmitjana mòbil del nombre de períodes que especifiqueu (2 per defecte) i posa aquests valors mitjans com a punts a la línia. Com més alt sigui el valor Període , més suau serà la línia.

Un bon exemple pràctic és utilitzar la línia de tendència mitjana mòbil per revelar les fluctuacions del preu de les accions que, d'altra manera, serien difícils d'observar.

Per obtenir més informació, vegeu: Com afegir una línia de tendència mitjana mòbil a un gràfic d'Excel.

Equacions i fórmules de línia de tendència d'Excel

Aquesta secció descriu les equacions que utilitza Excel per a diferents tipus de línies de tendència. No cal que creeu aquestes fórmules manualment, simplement digueu a Excel que mostri l'equació de la línia de tendència en un gràfic.

A més, parlarem de la fórmula per trobar el pendent d'una línia de tendència i altres coeficients. Les fórmules suposen que teniu 2 conjunts de variables: variable independent x i variable dependent y . Als vostres fulls de treball, podeu utilitzar aquestes fórmules per obtenir els valors y previstos per a qualsevol valor donat de x .

Per a la coherència, utilitzarem les mateixes dades. establert amb valors lleugerament variables per a tots els exemples. Tanmateix, tingueu en compte que només és amb finalitats de demostració. Als vostres fulls de treball reals, hauríeu de triar el tipus de línia de tendència corresponent al vostre tipus de dades.

Nota important! Les fórmules de línia de tendència només s'han d'utilitzar amb gràfics de dispersió XY perquè només aixòel gràfic representa els dos eixos x i y com a valors numèrics. Per obtenir més informació, consulteu Per què l'equació de línia de tendència d'Excel pot ser incorrecta.

Equació de línia de tendència lineal i fórmules

L'equació de línia de tendència lineal utilitza els mètodes de mínims quadrats per cercar el pendent i coeficients d'intercepció tals que:

y = bx + a

On:

• b és el pendent d'una línia de tendència.
• a és la intercepció y , que és el valor mitjà esperat de y quan tots x són iguals a 0. En un gràfic, és el punt on la línia de tendència creua l'eix y .

Per a la regressió lineal, Microsoft Excel proporciona funcions especials per obtenir la coeficients de pendent i intercepció.

Pendent de la línia de tendència

b: =SLOPE(y,x)

Intercepció en Y

a: =INTERCEPT(y,x)

Suposant que l'interval x és B2:B13 i l'interval y és C2:C13, les fórmules de la vida real són les següents:

=SLOPE(C2:C13, B2:B13)

=INTERCEPT(C2:C13,B2:B13)

Es poden aconseguir els mateixos resultats utilitzant la funció LINEST com a fórmula de matriu . Per a això, seleccioneu 2 cel·les adjacents a la mateixa fila, introduïu la fórmula i premeu Ctrl + Maj + Intro per completar-la:

=LINEST(C2:C13,B2:B13)

Com es mostra a la captura de pantalla següent, el pendent i la intercepció els coeficients retornats per les fórmules estan perfectament en línia amb els coeficients de l'equació de línia de tendència lineal que es mostra al gràfic, només aquests últims s'arrodoneixen a 4 decimals:

Equació i fórmules de la línia de tendència exponencial

Per a la línia de tendència exponencial, Excel utilitza l'equació següent:

y = aebx

On a i b són coeficients calculats i e és la constant matemàtica e (la base del logaritme natural).

Els coeficients es poden calcular utilitzant aquestes fórmules genèriques:

a: =EXP(INDEX(LINEST(LN(y), x), 1, 2))

b: =INDEX(LINEST(LN(y), x), 1)

Per al nostre conjunt de dades de mostra, les fórmules prenen la forma següent:

a: =EXP(INDEX(LINEST(LN(C2:C13), B2:B13), 1, 2))

b: =INDEX(LINEST(LN(C2:C13), B2:B13), 1)

Equació i fórmules de línia de tendència logarítmica

Aquí teniu l'equació de línia de tendència logarítmica a Excel:

y = a*ln(x)+b

On a i b són constants i ln és la funció de logaritme natural.

Per obtenir les constants, utilitzeu aquestes fórmules genèriques, que només difereixen en l'últim argument:

a: =INDEX(LINEST(y, LN(x)), 1)

b: =INDEX(LINEST(y, LN(x)), 1, 2)

Per al nostre conjunt de dades de mostra, fem servir aquestes:

a: =INDEX(LINEST(C2:C13, LN(B2:B13)), 1)

b: =INDEX(LINEST(C2:C13, LN(B2:B13)), 1, 2)

Equació i fórmules de la línia de tendència polinòmica

Per calcular la línia de tendència polinòmica, Excel utilitza aquesta equació:

y = b ₆ x6 + … + b ₂ x2 + b ₁ x + a

On b ₁ … b ₆ i a són constants.

Depenent del grau de la línia de tendència del polinomi, utilitzeu un dels següents conjunts de fórmules per obtenir les constants.

Línia de tendència polinòmica quadrada (2n ordre)

Equació: y = b ₂ x2+ b ₁ x + a

b ₂ : =INDEX(LINEST(y, x^{1,2}), 1)

b ₁ : =INDEX(LINEST(y, x^{1,2}), 1, 2)

a: =INDEX(LINEST(y, x^{1,2}), 1, 3)

Línia de tendència polinòmica cúbica (tercer ordre)

Equació: y = b ₃ x3 + b ₂ x2+ b ₁ x + a

b ₃ : =INDEX(LINEST(y, x^{1,2,3}), 1)

b ₂ : =INDEX(LINEST(y, x^{1,2,3}), 1, 2)

b ₁ : =INDEX(LINEST(y, x^{1,2,3}), 1, 3)

a: =INDEX(LINEST(y, x^{1,2,3}), 1, 4)

Les fórmules per a línies de tendència polinòmiques de grau superior es poden crear utilitzant el mateix patró.

Per al nostre conjunt de dades, les suites de línies de tendència polinòmiques de segon ordre millor, per tant estem utilitzant aquestes fórmules:

b ₂ : =INDEX(LINEST(C2:C13, B2:B13^{1,2}), 1)

b ₁ : =INDEX(LINEST(C2:C13, B2:B13^{1,2}), 1, 2)

a: =INDEX(LINEST(C2:C13, B2:B13^{1,2}), 1, 3)

Equació i fórmules de la línia de tendència de potència

A Excel es dibuixa una línia de tendència de potència a partir d'aquesta equació senzilla:

y = axb

On a i b són constants, que es poden calcular amb aquestes fórmules:

a: =EXP(INDEX(LINEST(LN(y), LN(x),,), 1, 2))

b: =INDEX(LINEST(LN(y), LN(x),,), 1)

En el nostre cas, les fórmules següents funcionen com una delícia :

a: =EXP(INDEX(LINEST(LN(C2:C13), LN(B2:B13),,), 1, 2))

b: =INDEX(LINEST(LN(C2:C13), LN(B2:B13),,), 1)

L'equació de la línia de tendència d'Excel és incorrecta: raons i solucions

Si creieu que Excel ha dibuixat una línia de tendència incorrectament o la fórmula de la línia de tendència que es mostra al vostre gràfic és incorrecta, els dos punts següents poden perdre'n llum sobre la situació.

L'equació de línia de tendència d'Excel només és correcta als gràfics de dispersió

Les fórmules de línia de tendència d'Excel només s'han d'utilitzar amb gràfics XY (dispersió), perquè només en aquest gràfic escriuen tant l'eix y i l'eix x es representen com a valors numèrics.

En els gràfics de línies, columnes i gràfics de barres, els valors numèrics només es representen a l'eix y. L'eix x està representat per una sèrie lineal (1, 2,3,...) independentment de si les etiquetes dels eixos són números o text. Quan feu una línia de tendència en aquests gràfics, Excel utilitza els valors x suposats a la fórmula de la línia de tendència.

Els nombres s'arrodonen a l'equació de la línia de tendència d'Excel

Per ocupar menys espai al gràfic, Excel mostra molt pocs dígits significatius en una equació de línia de tendència. Agradable pel que fa al disseny, redueix significativament la precisió de la fórmula quan proporcioneu manualment valors x a l'equació.

Una solució fàcil és mostrar més decimals a l'equació. Alternativament, podeu calcular els coeficients mitjançant una fórmula corresponent al vostre tipus de línia de tendència i donar format a les cel·les de la fórmula perquè mostrin un nombre suficient de decimals. Per fer-ho, només cal que feu clic al botó Incrementa decimal a la pestanya Inici del grup Nombre .

Així podeu crear diferents tipus de línies de tendència. en Excel i obteniu les seves equacions. Us agraeixo la lectura i espero veure-us al nostre blog la setmana vinent!