ટ્યુટોરીયલ બતાવે છે કે કેવી રીતે Excel માં AND તેમજ OR તર્ક સાથે બહુવિધ IF સ્ટેટમેન્ટ બનાવવું. ઉપરાંત, તમે અન્ય એક્સેલ ફંક્શન્સ સાથે IF નો ઉપયોગ કેવી રીતે કરવો તે શીખી શકશો.

અમારા એક્સેલ IF ટ્યુટોરીયલના પહેલા ભાગમાં, અમે ટેક્સ્ટ માટે એક શરત સાથે સરળ IF સ્ટેટમેન્ટ કેવી રીતે બનાવવું તે જોયું, સંખ્યાઓ, તારીખો, ખાલી જગ્યાઓ અને બિન-ખાલીઓ. શક્તિશાળી ડેટા પૃથ્થકરણ માટે, જો કે, તમારે ઘણીવાર એક સમયે બહુવિધ શરતોનું મૂલ્યાંકન કરવાની જરૂર પડી શકે છે. નીચેના સૂત્રના ઉદાહરણો તમને આ કરવાની સૌથી અસરકારક રીતો બતાવશે.

બહુવિધ શરતો સાથે IF ફંક્શનનો ઉપયોગ કેવી રીતે કરવો

સારમાં, બે પ્રકારના છે AND/OR તર્ક પર આધારિત બહુવિધ માપદંડો સાથે IF ફોર્મ્યુલા . પરિણામે, તમારા IF ફોર્મ્યુલાની તાર્કિક કસોટીમાં, તમારે આમાંથી એક ફંક્શનનો ઉપયોગ કરવો જોઈએ:

• AND ફંક્શન - જો બધી શરતો પૂરી થાય તો TRUE પરત કરે છે; અન્યથા FALSE.
• અથવા ફંક્શન - જો કોઈપણ એક શરત પૂરી થાય તો TRUE પરત કરે છે; અન્યથા ખોટું.

બિંદુને વધુ સારી રીતે સમજાવવા માટે, ચાલો કેટલાક વાસ્તવિક જીવનના સૂત્રોના ઉદાહરણોની તપાસ કરીએ.

એક્સેલ IF સ્ટેટમેન્ટ બહુવિધ શરતો (અને તર્ક) સાથે

આ બે અથવા વધુ શરતો સાથે એક્સેલ IF નું સામાન્ય સૂત્ર આ છે:

IF(AND( condition1, condition2, …), value_if_true, value_if_false)

માનવમાં અનુવાદિત ભાષામાં, સૂત્ર કહે છે: જો શરત 1 સાચી હોય અને શરત 2 સાચી હોય, તો પાછા આવો value_if_true ; અન્યથા value_if_false પરત કરો.

ધારો કે તમારી પાસે કૉલમ B અને Cમાં બે ટેસ્ટના સ્કોર્સની યાદી આપતું ટેબલ છે. અંતિમ પરીક્ષા પાસ કરવા માટે, વિદ્યાર્થી પાસે બંને સ્કોર 50 કરતા વધુ હોવા જોઈએ.

લોજિકલ ટેસ્ટ માટે, તમે નીચેના AND સ્ટેટમેન્ટનો ઉપયોગ કરો છો: AND(B2>50, C2>50)

જો બંને શરતો સાચી હોય, તો ફોર્મ્યુલા "પાસ" આપશે; જો કોઈ શરત ખોટી હોય તો - "નિષ્ફળ."

=IF(AND(B2>50, B2>50), "Pass", "Fail")

સરળ છે, તે નથી? નીચેનો સ્ક્રીનશોટ સાબિત કરે છે કે અમારું એક્સેલ IF /AND ફોર્મ્યુલા બરાબર કામ કરે છે:

એવી જ રીતે, તમે બહુવિધ ટેક્સ્ટ શરતો સાથે એક્સેલ IF ફંક્શનનો ઉપયોગ કરી શકો છો.

માટે ઉદાહરણ તરીકે, જો B2 અને C2 બંને 50 કરતા વધારે હોય તો "સારા" ને આઉટપુટ કરવા માટે, "ખરાબ" નહિંતર, સૂત્ર છે:

=IF(AND(B2="pass", C2="pass"), "Good!", "Bad")

મહત્વપૂર્ણ નોંધ! AND ફંક્શન તમામ શરતો ને તપાસે છે, પછી ભલેને પહેલાથી જ પરીક્ષણ કરેલ (ઓ)નું મૂલ્યાંકન FALSE કરવામાં આવ્યું હોય. આવી વર્તણૂક થોડી અસામાન્ય છે કારણ કે મોટાભાગની પ્રોગ્રામિંગ ભાષાઓમાં, જો અગાઉના પરીક્ષણોમાંથી કોઈપણ FALSE પાછું આવ્યું હોય તો અનુગામી શરતોનું પરીક્ષણ કરવામાં આવતું નથી.

વ્યવહારમાં, સાચા લાગતા IF સ્ટેટમેન્ટ આના કારણે ભૂલમાં પરિણમી શકે છે. વિશિષ્ટતા ઉદાહરણ તરીકે, નીચેનું સૂત્ર #DIV/0 આપશે! ("શૂન્ય દ્વારા ભાગાકાર કરો" ભૂલ) જો સેલ A2 0 ની બરાબર છે:

=IF(AND(A20, (1/A2)>0.5),"Good", "Bad")

આને ટાળો, તમારે નેસ્ટેડ IF ફંક્શનનો ઉપયોગ કરવો જોઈએ:

=IF(A20, IF((1/A2)>0.5, "Good", "Bad"), "Bad") <3

વધુ માહિતી માટે, કૃપા કરીને Excel માં IF AND ફોર્મ્યુલા જુઓ.

એક્સેલ IF ફંક્શન બહુવિધ સાથેશરતો (અથવા તર્ક)

જો કોઈપણ શરત પૂરી થાય તો એક વસ્તુ કરવા માટે, અન્યથા બીજું કંઈક કરવા માટે, IF અને OR કાર્યોના આ સંયોજનનો ઉપયોગ કરો:

IF(OR( શરત1 , શરત2 , …), value_if_true, value_if_false)

ઉપર ચર્ચા કરેલ IF / AND ફોર્મ્યુલાથી તફાવત એ છે કે જો ઉલ્લેખિત શરતોમાંથી કોઈપણ સાચી હોય તો Excel TRUE આપે છે.

તેથી, જો અગાઉના ફોર્મ્યુલામાં, આપણે AND ને બદલે OR નો ઉપયોગ કરીએ છીએ:

=IF(OR(B2>50, B2>50), "Pass", "Fail")

તો કોઈપણ પરીક્ષામાં 50 થી વધુ પોઈન્ટ્સ મેળવનારને "પાસ" થશે. કૉલમ ડી. આવી પરિસ્થિતિઓ સાથે, અમારા વિદ્યાર્થીઓ પાસે અંતિમ પરીક્ષા પાસ કરવાની વધુ સારી તક છે (યવેટ ખાસ કરીને કમનસીબ છે અને માત્ર 1 પોઈન્ટથી નિષ્ફળ રહી છે :)

ટીપ. જો તમે ટેક્સ્ટ સાથે બહુવિધ IF સ્ટેટમેન્ટ બનાવી રહ્યા હોવ અને OR તર્ક સાથે એક કોષમાં મૂલ્યનું પરીક્ષણ કરી રહ્યાં હોવ (એટલે ​​કે સેલ "આ" અથવા "તે" હોઈ શકે), તો તમે વધુ કોમ્પેક્ટ બનાવી શકો છો. એરે કોન્સ્ટન્ટનો ઉપયોગ કરીને ફોર્મ્યુલા.

ઉદાહરણ તરીકે, જો સેલ B2 ક્યાં તો "વિતરિત" અથવા "ચુકવેલ" હોય, તો વેચાણને "બંધ" તરીકે ચિહ્નિત કરવા માટે, સૂત્ર છે:

=IF(OR(B2={"delivered", "paid"}), "Closed", "")

વધુ ફોર્મ્યુલા ઉદાહરણો Excel IF OR ફંક્શનમાં મળી શકે છે.

IF સાથે બહુવિધ AND & અથવા નિવેદનો

જો તમારા કાર્યને બહુવિધ શરતોના કેટલાક સેટનું મૂલ્યાંકન કરવાની જરૂર હોય, તો તમારે AND & અથવા એક સમયે કાર્ય કરે છે.

અમારા નમૂના કોષ્ટકમાં, ધારો કે પરીક્ષાના પરિણામો તપાસવા માટે તમારી પાસે નીચેના માપદંડો છે:

• શરત 1:પરીક્ષા1>50 અને પરીક્ષા2>50
• શરત 2: પરીક્ષા1>40 અને પરીક્ષા2>60

જો બેમાંથી કોઈ એક શરત પૂરી થાય, તો અંતિમ પરીક્ષા પાસ થઈ હોવાનું માનવામાં આવે છે.

પ્રથમ દૃષ્ટિએ, સૂત્ર થોડું મુશ્કેલ લાગે છે, પરંતુ હકીકતમાં એવું નથી! તમે ફક્ત ઉપરોક્ત દરેક શરતોને AND સ્ટેટમેન્ટ તરીકે વ્યક્ત કરો અને તેમને OR ફંક્શનમાં માળો (કારણ કે તે બંને શરતોને પૂરી કરવી જરૂરી નથી, ક્યાં તો પૂરતું હશે):

OR(AND(B2>50, C2>50), AND(B2>40, C2>60)

પછી, ઉપયોગ કરો IF ના તાર્કિક પરીક્ષણ માટે OR ફંક્શન અને ઇચ્છિત value_if_true અને value_if_false મૂલ્યો પૂરા પાડે છે. પરિણામે, તમને બહુવિધ AND / OR શરતો સાથે નીચેના IF ફોર્મ્યુલા મળે છે:

=IF(OR(AND(B2>50, C2>50), AND(B2>40, C2>60), "Pass", "Fail")

નીચેનો સ્ક્રીનશોટ સૂચવે છે કે અમે ફોર્મ્યુલા બરાબર કર્યું છે:

સ્વાભાવિક રીતે , તમે તમારા IF ફોર્મ્યુલામાં માત્ર બે AND/OR ફંક્શનનો ઉપયોગ કરવા માટે મર્યાદિત નથી. તમારા વ્યવસાયના તર્ક માટે જરૂરી હોય તેટલા તમે તેમાંના ઘણાનો ઉપયોગ કરી શકો છો, જો કે:

• એક્સેલ 2007 અને ઉચ્ચમાં, તમારી પાસે 255 થી વધુ દલીલો નથી અને IF ફોર્મ્યુલાની કુલ લંબાઈ ઓળંગતી નથી. 8,192 અક્ષરો.
• એક્સેલ 2003 અને નીચલામાં, ત્યાં 30 થી વધુ દલીલો નથી, અને તમારા IF ફોર્મ્યુલાની કુલ લંબાઈ 1,024 અક્ષરો કરતાં વધી નથી.

નેસ્ટેડ IF સ્ટેટમેન્ટ બહુવિધ તાર્કિક પરીક્ષણો તપાસો

જો તમે એક સૂત્રમાં બહુવિધ તાર્કિક પરીક્ષણોનું મૂલ્યાંકન કરવા માંગતા હો, તો પછી તમે ઘણા ફંક્શનને એક બીજામાં નેસ્ટ કરી શકો છો. આવા કાર્યોને નેસ્ટેડ કહેવામાં આવે છેIF કાર્યો . તેઓ ખાસ કરીને ઉપયોગી સાબિત થાય છે જ્યારે તમે તાર્કિક પરીક્ષણોના પરિણામોના આધારે વિવિધ મૂલ્યો પરત કરવા માંગો છો.

અહીં એક લાક્ષણિક ઉદાહરણ છે: ધારો કે તમે વિદ્યાર્થીઓની સિદ્ધિઓને " સારી " તરીકે લાયક બનાવવા માંગો છો. નીચેના સ્કોર પર આધારિત " સંતોષકારક " અને " નબળું ":

• સારું: 60 અથવા વધુ (>=60)
• સંતોષકારક: 40 અને 60 વચ્ચે (>40 અને <60)
• નબળું: 40 અથવા તેથી ઓછું (<=40)

સૂત્ર લખતા પહેલા, ઓર્ડરને ધ્યાનમાં લો તમે માળખામાં જઈ રહ્યા છો. એક્સેલ તાર્કિક પરીક્ષણોનું મૂલ્યાંકન ફોર્મ્યુલામાં જે ક્રમમાં દેખાશે તે રીતે કરશે. એકવાર શરતનું TRUE મૂલ્યાંકન થઈ જાય, પછીની શરતોનું પરીક્ષણ કરવામાં આવતું નથી, એટલે કે પ્રથમ TRUE પરિણામ પછી ફોર્મ્યુલા અટકી જાય છે.

અમારા કિસ્સામાં, ફંક્શન સૌથી મોટાથી નાનામાં ગોઠવાય છે:

=IF(B2>=60, "Good", IF(B2>40, "Satisfactory", "Poor"))

સ્વાભાવિક રીતે, જો જરૂરી હોય તો તમે વધુ કાર્યોને નેસ્ટ કરી શકો છો (આધુનિક સંસ્કરણોમાં 64 સુધી).

વધુ માહિતી માટે, કૃપા કરીને જુઓ એક્સેલમાં બહુવિધ નેસ્ટેડ IF સ્ટેટમેન્ટનો ઉપયોગ કેવી રીતે કરવો.

એક્સેલ IF એરે ફોર્મ્યુલા બહુવિધ શરતો સાથે

ચકાસવા માટે એક્સેલ IF મેળવવાની બીજી રીત બહુવિધ શરતો એરે ફોર્મ્યુલાનો ઉપયોગ કરીને છે.

અને તર્ક સાથે શરતોનું મૂલ્યાંકન કરવા માટે, ફૂદડીનો ઉપયોગ કરો:

IF( condition1 ) * ( condition2 ) * …, value_if_true, value_if_false)

OR તર્ક સાથે શરતોનું પરીક્ષણ કરવા માટે, વત્તા ચિહ્નનો ઉપયોગ કરો:

IF( condition1 ) + ( condition2 ) + …,value_if_true, value_if_false)

એરે ફોર્મ્યુલાને યોગ્ય રીતે પૂર્ણ કરવા માટે, Ctrl + Shift + Enter કીને એકસાથે દબાવો. એક્સેલ 365 અને એક્સેલ 2021 માં, ડાયનેમિક એરેના સમર્થનને કારણે આ નિયમિત ફોર્મ્યુલા તરીકે પણ કામ કરે છે.

ઉદાહરણ તરીકે, જો B2 અને C2 બંને 50 કરતા વધારે હોય તો "પાસ" મેળવવા માટે, સૂત્ર છે:

=IF((B2>50) * (C2>50), "Pass", "Fail")

મારા એક્સેલ 365માં, સામાન્ય ફોર્મ્યુલા બરાબર કામ કરે છે (જેમ તમે ઉપરના સ્ક્રીનશોટમાં જોઈ શકો છો). એક્સેલ 2019 અને તેનાથી નીચેના ભાગમાં, Ctrl + Shift + Enter શૉર્ટકટનો ઉપયોગ કરીને તેને અરે ફોર્મ્યુલા બનાવવાનું યાદ રાખો.

OR તર્ક સાથે બહુવિધ પરિસ્થિતિઓનું મૂલ્યાંકન કરવા માટે, સૂત્ર છે:

=IF((B2>50) + (C2>50), "Pass", "Fail")

અન્ય ફંક્શન્સ સાથે IF નો એકસાથે ઉપયોગ કરવો

આ વિભાગ સમજાવે છે કે IF નો ઉપયોગ અન્ય એક્સેલ ફંક્શન્સ સાથે કેવી રીતે કરવો અને તેનાથી તમને શું ફાયદો થાય છે.

ઉદાહરણ 1. જો #N VLOOKUPમાં /એક ભૂલ

જ્યારે VLOOKUP અથવા અન્ય લુકઅપ ફંક્શન કંઈક શોધી શકતું નથી, ત્યારે તે #N/A ભૂલ પરત કરે છે. તમારા કોષ્ટકોને વધુ સુંદર બનાવવા માટે, તમે શૂન્ય, ખાલી અથવા ચોક્કસ ટેક્સ્ટ પરત કરી શકો છો જો #N/A. આ માટે, આ સામાન્ય સૂત્રનો ઉપયોગ કરો:

IF(ISNA(VLOOKUP(…)), value_if_na , VLOOKUP(…))

ઉદાહરણ તરીકે:

જો #N/ વળતર 0:

જો E1 માં લુકઅપ મૂલ્ય ન મળે, તો સૂત્ર શૂન્ય આપે છે.

=IF(ISNA(VLOOKUP(E1, A2:B10, 2,FALSE )), 0, VLOOKUP(E1, A2:B10, 2, FALSE))

જો #N/A ખાલી પરત કરે છે:

જો લુકઅપ વેલ્યુ ન મળે, તો ફોર્મ્યુલા કંઈ પાછું આપતું નથી (ખાલી સ્ટ્રિંગ).

=IF(ISNA(VLOOKUP(E1, A2:B10, 2,FALSE )), "", VLOOKUP(E1, A2:B10, 2, FALSE))

જો #N/A ચોક્કસ ટેક્સ્ટ આપે છે:

જો લુકઅપ મૂલ્ય મળ્યું નથી, આફોર્મ્યુલા ચોક્કસ ટેક્સ્ટ આપે છે.

=IF(ISNA(VLOOKUP(E1, A2:B10, 2,FALSE )), "Not found", VLOOKUP(E1, A2:B10, 2, FALSE))

વધુ ફોર્મ્યુલા ઉદાહરણો માટે, કૃપા કરીને એક્સેલમાં IF સ્ટેટમેન્ટ સાથે VLOOKUP જુઓ.

ઉદાહરણ 2. IF SUM, AVERAGE, MIN અને MAX સાથે કાર્યો

ચોક્કસ માપદંડો પર આધારિત સેલ મૂલ્યોનો સરવાળો કરવા માટે, એક્સેલ SUMIF અને SUMIFS કાર્યો પૂરા પાડે છે.

કેટલીક પરિસ્થિતિઓમાં, તમારા વ્યવસાયના તર્કને IF ના તાર્કિક પરીક્ષણમાં SUM કાર્યનો સમાવેશ કરવાની જરૂર પડી શકે છે. ઉદાહરણ તરીકે, B2 અને C2 માં મૂલ્યોના સરવાળાના આધારે વિવિધ ટેક્સ્ટ લેબલ પરત કરવા માટે, સૂત્ર છે:

=IF(SUM(B2:C2)>130, "Good", IF(SUM(B2:C2)>110, "Satisfactory", "Poor"))

જો સરવાળો 130 કરતાં વધુ હોય, તો પરિણામ "સારું "; જો 110 થી વધુ હોય તો - "સંતોષકારક', જો 110 અથવા નીચું - "નબળું."

એવી જ રીતે, તમે IF ની લોજિકલ કસોટીમાં AVERAGE ફંક્શનને એમ્બેડ કરી શકો છો અને સરેરાશ સ્કોર પર આધારિત વિવિધ લેબલ્સ પરત કરી શકો છો. :

=IF(AVERAGE(B2:C2)>65, "Good", IF(AVERAGE(B2:C2)>55, "Satisfactory", "Poor"))

કુલ સ્કોર કોલમ Dમાં છે એમ ધારી રહ્યા છીએ, તમે MAX અને MIN કાર્યોની મદદથી સૌથી વધુ અને સૌથી નીચા મૂલ્યોને ઓળખી શકો છો:

=IF(D2=MAX($D$2:$D$10), "Best result", "")

=IF(D2=MAX($D$2:$D$10), "Best result", "")

એક કૉલમમાં બંને લેબલ રાખવા માટે, ઉપરોક્ત ફંક્શનને એક બીજામાં નેસ્ટ કરો:

=IF(D2=MAX($D$2:$D$10), "Best result", IF(D2=MIN($D$2:$D$10), "Worst result", ""))

તેમજ, તમે તમારા કસ્ટમ સાથે IF નો ઉપયોગ કરી શકો છો ફંક્શન્સ. ઉદાહરણ તરીકે, તમે સેલ કલર પર આધારિત વિવિધ પરિણામો પરત કરવા માટે તેને GetCellColor અથવા GetCellFontColor સાથે જોડી શકો છો.

વધુમાં, એક્સેલ શરતોના આધારે ડેટાની ગણતરી કરવા માટે સંખ્યાબંધ ફંક્શન પ્રદાન કરે છે. વિગતવાર ફોર્મ્યુલા ઉદાહરણો માટે, કૃપા કરીને નીચેના તપાસોટ્યુટોરિયલ્સ:

• COUNTIF - શરત પૂરી કરતા કોષોની ગણતરી કરો
• COUNTIFS - બહુવિધ માપદંડો સાથે કોષોની ગણતરી કરો
• SUMIF - શરતી રીતે કોષોનો સરવાળો કરો
• SUMIFS - બહુવિધ માપદંડો સાથેના કોષોનો સરવાળો

ઉદાહરણ 3. ISNUMBER, ISTEXT અને ISBLANK સાથે IF

ટેક્સ્ટ, નંબરો અને ખાલી કોષોને ઓળખવા માટે, Microsoft Excel વિશિષ્ટ કાર્યો પ્રદાન કરે છે જેમ કે ISTEXT, ISNUMBER અને ISBLANK. તેમને ત્રણ નેસ્ટેડ IF સ્ટેટમેન્ટના લોજિકલ ટેસ્ટમાં મૂકીને, તમે એક જ વારમાં તમામ વિવિધ ડેટા પ્રકારોને ઓળખી શકો છો:

=IF(ISTEXT(A2), "Text", IF(ISNUMBER(A2), "Number", IF(ISBLANK(A2), "Blank", "")))

ઉદાહરણ 4. IF અને CONCATENATE

પ્રતિ IF ના પરિણામ અને કેટલાક ટેક્સ્ટને એક કોષમાં આઉટપુટ કરો, CONCATENATE અથવા CONCAT (Excel 2016 - 365 માં) અને IF ફંક્શનનો એકસાથે ઉપયોગ કરો. ઉદાહરણ તરીકે:

=CONCATENATE("You performed ", IF(B1>100,"fantastic!", IF(B1>50, "well", "poor")))

=CONCAT("You performed ", IF(B1>100,"fantastic!", IF(B1>50, "well", "poor")))

નીચેનો સ્ક્રીનશોટ જોતાં, તમારે ફોર્મ્યુલા શું કરે છે તેના વિશે ભાગ્યે જ કોઈ સમજૂતીની જરૂર પડશે:

જો ISERROR એક્સેલમાં / ISNA ફોર્મ્યુલા

એક્સેલના આધુનિક સંસ્કરણોમાં ભૂલોને પકડવા અને તેને અન્ય ગણતરી અથવા પૂર્વવ્યાખ્યાયિત મૂલ્ય - IFERROR (એક્સેલ 2007 અને પછીનામાં) અને IFNA (એક્સેલ 2013 અને પછીનામાં) સાથે બદલવા માટે વિશેષ કાર્યો છે. અગાઉના એક્સેલ વર્ઝનમાં, તમે તેના બદલે IF ISERROR અને IF ISNA સંયોજનોનો ઉપયોગ કરી શકો છો.

ફરક એ છે કે IFERROR અને ISERROR તમામ સંભવિત એક્સેલ ભૂલોને હેન્ડલ કરે છે, જેમાં #VALUE!, #N/A, #NAME?, #REF!, #NUM!, #DIV/0!, અને #NULL!. જ્યારે IFNA અને ISNA માત્ર #N/A ભૂલોમાં નિષ્ણાત છે.

ઉદાહરણ તરીકે,"શૂન્ય દ્વારા વિભાજીત કરો" ભૂલ (#DIV/0!) ને તમારા કસ્ટમ ટેક્સ્ટ સાથે બદલો, તમે નીચે આપેલા સૂત્રનો ઉપયોગ કરી શકો છો:

=IF(ISERROR(A2/B2), "N/A", A2/B2)

અને આનો ઉપયોગ કરવા વિશે મારે એટલું જ કહેવું છે Excel માં IF કાર્ય. હું વાંચવા બદલ તમારો આભાર માનું છું અને આગામી અઠવાડિયે તમને અમારા બ્લોગ પર મળવાની આશા રાખું છું!

ડાઉનલોડ માટે પ્રેક્ટિસ વર્કબુક

Excel IF બહુવિધ માપદંડ - ઉદાહરણો (.xlsx ફાઇલ)