Výukový program ukazuje, jak vypočítat vnitřní výnosové procento projektu v aplikaci Excel pomocí vzorců a funkce Goal Seek. Dozvíte se také, jak vytvořit šablonu vnitřního výnosového procenta, která bude všechny výpočty IRR provádět automaticky.

Když znáte vnitřní výnosové procento navrhované investice, můžete si myslet, že máte vše, co potřebujete k jejímu vyhodnocení - čím větší IRR, tím lépe. V praxi to není tak jednoduché. Microsoft Excel poskytuje tři různé funkce pro zjištění vnitřního výnosového procenta a skutečně pochopit, co vlastně s IRR počítáte, bude velmi užitečné.

Co je to IRR?

Na stránkách vnitřní výnosové procento (IRR) je běžně používaná metrika pro odhad ziskovosti potenciální investice. Někdy se také označuje jako tzv. diskontovaná míra peněžních toků návratnosti nebo ekonomická míra návratnosti .

Technicky vzato je IRR diskontní sazba, díky níž je čistá současná hodnota všech peněžních toků (přílivů i odlivů) z určité investice rovna nule.

Výraz "interní" znamená, že IRR bere v úvahu pouze interní faktory; externí faktory, jako je inflace, náklady na kapitál a různá finanční rizika, jsou z výpočtu vyloučeny.

Co prozrazuje vnitřní výnosová míra?

V kapitálovém rozpočtování se vnitřní výnosové procento hojně využívá k hodnocení výnosnosti potenciální investice a k hodnocení pořadí více projektů. Obecný princip je jednoduchý: čím vyšší je vnitřní výnosové procento, tím je projekt atraktivnější.

Při odhadu jednotlivého projektu finanční analytici obvykle porovnávají vnitřní návratnost s výnosy společnosti. vážené průměrné náklady kapitálu nebo překážková sazba , což je minimální míra návratnosti investice, kterou může společnost akceptovat. V hypotetické situaci, kdy je IRR jediným kritériem pro rozhodování, je projekt považován za dobrou investici, pokud je jeho IRR vyšší než překážková míra. Pokud je IRR nižší než náklady na kapitál, měl by být projekt zamítnut. V praxi existuje mnoho dalších faktorů, které ovlivňují výši IRR.rozhodnutí, jako je čistá současná hodnota (NPV), doba návratnosti, absolutní hodnota výnosu atd.

Omezení IRR

Přestože je IRR velmi oblíbenou metodou hodnocení kapitálových projektů, má řadu vnitřních nedostatků, které mohou vést k neoptimálním rozhodnutím. Hlavní problémy IRR jsou následující:

• Relativní míra . IRR bere v úvahu procenta, ale ne absolutní hodnotu, v důsledku čehož může upřednostňovat projekt s vysokou mírou návratnosti, ale velmi malou hodnotou v dolarech. V praxi mohou společnosti upřednostnit velký projekt s nižší IRR před malým projektem s vyšší IRR. V tomto ohledu je NPV lepší metrikou, protože bere v úvahu skutečnou částku získanou nebo ztracenou realizací projektu.
• Stejná míra reinvestic . IRR předpokládá, že všechny peněžní toky generované projektem jsou reinvestovány sazbou rovnající se samotné IRR, což je velmi nerealistický scénář. Tento problém řeší MIRR, který umožňuje zadat různé finanční a reinvestiční sazby.
• Více výsledků . u projektů se střídavě kladnými a zápornými peněžními toky lze nalézt více než jednu IRR. Tento problém je řešen i u metody MIRR, která je navržena tak, aby poskytovala pouze jednu sazbu.

Navzdory těmto nedostatkům je IRR i nadále důležitým měřítkem kapitálového rozpočtování a před investičním rozhodnutím byste se na ni měli přinejmenším podívat skepticky.

Výpočet IRR v aplikaci Excel

Protože vnitřní výnosové procento je diskontní sazba, při níž je čistá současná hodnota dané řady peněžních toků rovna nule, vychází výpočet IRR z tradičního vzorce NPV:

Pokud nejste příliš obeznámeni se součtovým zápisem, může být rozšířená forma vzorce IRR srozumitelnější:

Kde:

• CF ₀ - počáteční investice (vyjádřená záporným číslem).
• CF ₁ , CF ₂ ... CF _n - peněžní toky
• i - číslo období
• n - období celkem
• IRR - vnitřní výnosové procento

Povaha tohoto vzorce je taková, že neexistuje žádný analytický způsob výpočtu IRR. Pro jeho zjištění musíme použít přístup "odhadni a zkontroluj". Abychom lépe pochopili koncept vnitřního výnosového procenta, proveďme výpočet IRR na velmi jednoduchém příkladu.

Příklad : Nyní investujete 1000 USD a v následujících dvou letech získáte zpět 500 USD a 660 USD. Jaká diskontní sazba způsobí, že čistá současná hodnota bude nulová?

Jako první tip zkusíme 8% sazbu:

• Nyní: PV = -$1,000
• Rok 1: PV = 500 USD / (1+0,08)1 = 462,96 USD
• Rok 2: PV = $660 / (1+0,08)2 = $565,84

Když je sečteme, dostaneme NPV ve výši 28,81 USD:

Možná by to mohl změnit lepší odhad, řekněme 10 %.

• Nyní: PV = -$1,000
• Rok 1: PV = 500 USD / (1+0,1)1 = 454,55 USD
• Rok 2: PV = $660 / (1+0,1)2 = $545,45
• NPV: -1000 + $454,55 + $545,45 = $0,00

To je vše! Při 10% diskontní sazbě je čistá současná hodnota přesně 0. Takže vnitřní výnosnost této investice je 10 %:

Takto se vnitřní výnosové procento počítá ručně. Microsoft Excel, další softwarové programy a různé online kalkulačky IRR se také spoléhají na tuto metodu pokusu a omylu. Na rozdíl od člověka však počítače mohou velmi rychle provést několik iterací.

Jak vypočítat IRR v aplikaci Excel pomocí vzorců

Microsoft Excel nabízí 3 funkce pro zjištění vnitřního výnosového procenta:

• IRR - nejčastěji používanou funkcí pro výpočet vnitřního výnosového procenta pro řadu peněžních toků, které se vyskytují při pravidelné intervaly .
• XIRR - zjistí IRR pro sérii peněžních toků, které se vyskytují při nepravidelné intervaly Protože tato funkce bere v úvahu přesná data plateb, zajišťuje lepší přesnost výpočtu.
• MIRR - vrací modifikované vnitřní výnosové procento , což je varianta IRR, která zohledňuje jak náklady na výpůjčky, tak složené úroky získané z reinvestice kladných peněžních toků.

Níže naleznete příklady všech těchto funkcí. Z důvodu konzistence budeme ve všech vzorcích používat stejnou sadu dat.

Vzorec IRR pro výpočet vnitřního výnosového procenta

Předpokládejme, že uvažujete o pětileté investici s peněžními toky v B2:B7. Pro výpočet IRR použijte tento jednoduchý vzorec:

=IRR(B2:B7)

Poznámka: Aby vzorec IRR fungoval správně, ujistěte se, že vaše peněžní toky mají alespoň jednu hodnotu. negativní (odtok) a jeden pozitivní (přítok) a všechny hodnoty jsou uvedeny na seznamu chronologické řazení .

Další informace naleznete ve funkci IRR aplikace Excel.

Vzorec XIRR pro zjištění IRR pro nepravidelné peněžní toky

V případě peněžních toků s nerovnoměrným načasováním může být použití funkce IRR riskantní, protože předpokládá, že všechny platby nastanou na konci období a všechna časová období jsou stejná. V takovém případě by bylo rozumnější zvolit funkci XIRR.

S peněžními toky v B2:B7 a jejich daty v C2:C7 by vzorec vypadal takto:

=XIRR(B2:B7,C2:C7)

Poznámky:

• Ačkoli funkce XIRR nevyžaduje nutně data v chronologickém pořadí, datum prvního peněžního toku (počáteční investice) by mělo být v poli na prvním místě.
• Data musí být uvedena jako platná data aplikace Excel ; zadávání dat v textovém formátu vystavuje aplikaci Excel riziku jejich nesprávné interpretace.
• Funkce XIRR aplikace Excel používá k získání výsledku jiný vzorec. Vzorec XIRR diskontuje následné platby na základě 365denního roku, ve výsledku XIRR vždy vrací hodnotu anualizované vnitřní výnosové procento.

Podrobnější informace naleznete ve funkci XIRR aplikace Excel.

Vzorec MIRR pro výpočet modifikované IRR

Pro realističtější situaci, kdy jsou prostředky projektu reinvestovány s úrokovou sazbou blížící se nákladům na kapitál společnosti, lze vypočítat modifikované vnitřní výnosové procento pomocí vzorce MIRR:

=MIRR(B2:B7,E1,E2)

Kde B2:B7 jsou peněžní toky, E1 je finanční sazba (náklady na vypůjčení peněz) a E2 je reinvestiční sazba (úrok získaný z reinvestice zisku).

Poznámka: Protože funkce MIRR aplikace Excel počítá složené úročení zisků, může se její výsledek podstatně lišit od výsledků funkcí IRR a XIRR.

IRR, XIRR a MIRR - co je lepší?

Domnívám se, že na tuto otázku nemůže nikdo dát obecnou odpověď, protože teoretický základ, výhody a nevýhody všech tří metod jsou mezi finančními akademiky stále předmětem sporů. Možná by bylo nejlepší provést všechny tři výpočty a porovnat výsledky:

Obecně se má za to, že:

• XIRR poskytuje lepší přesnost výpočtu než IRR, protože bere v úvahu přesná data peněžních toků.
• IRR často poskytuje nepřiměřeně optimistický odhad ziskovosti projektu, zatímco MIRR poskytuje realističtější obraz.

Kalkulačka IRR - šablona Excel

Pokud potřebujete pravidelně provádět výpočet IRR v aplikaci Excel, může vám nastavení šablony vnitřní míry návratnosti značně usnadnit život.

Naše kalkulačka obsahuje všechny tři vzorce (IRR, XIRR a MIRR), takže se nemusíte starat o to, který výsledek je platnější, ale můžete vzít v úvahu všechny.

1. Zadejte peněžní toky a data do dvou sloupců (v našem případě A a B).
2. Zadejte finanční sazbu a reinvestiční sazbu do 2 samostatných buněk. Volitelně tyto prodeje pojmenujte. Finance_rate a Reinvest_rate , resp.
3. Vytvořte dva dynamicky definované rozsahy s názvy Cash_flows a Data .

   Za předpokladu, že se váš pracovní list jmenuje List1 , první peněžní tok (počáteční investice) je v buňce A2 a datum prvního peněžního toku je v buňce B2, vytvořte pojmenované rozsahy na základě těchto vzorců:

   Cash_flows:

   =OFFSET(List1!$A$2,0,0,COUNT(List1!$A:$A),1)

   Termíny:

   =OFFSET(List1!$B$2,0,0,COUNT(List1!$B:$B),1)

   Podrobný postup najdete v článku Jak vytvořit dynamický pojmenovaný rozsah v aplikaci Excel.

4. Právě vytvořené názvy použijte jako argumenty následujících vzorců. Upozorňujeme, že vzorce lze zadat do libovolného sloupce kromě sloupců A a B, které jsou vyhrazeny výhradně pro peněžní toky, resp. data.

   =IRR(Cash_flows)

   =XIRR(Cash_flows, Dates)

   =MIRR(Cash_flows, Finance_rate, Reinvest_rate)

Hotovo! Nyní můžete do sloupce A zadat libovolný počet peněžních toků a vzorce dynamického vnitřního výnosového procenta se podle toho přepočítají:

Jako prevenci proti neopatrným uživatelům, kteří mohou zapomenout vyplnit všechny požadované vstupní buňky, můžete své vzorce obalit funkcí IFERROR, abyste předešli chybám:

=IFERROR(IRR(Cash_flows), "")

=IFERROR(XIRR(Cash_flows, Dates), "")

=IFERROR(MIRR(Cash_flows, Finance_rate, Reinvest_rate), "")

Mějte na paměti, že pokud jsou buňky Finance_rate a/nebo Reinvest_rate prázdné, funkce MIRR aplikace Excel předpokládá, že jsou rovny nule.

Jak provést IRR v aplikaci Excel pomocí nástroje Goal Seek

Funkce IRR aplikace Excel provede pouze 20 iterací, aby dospěla k hodnotě, a funkce XIRR provede 100 iterací. Pokud po tomto počtu iterací není nalezen výsledek s přesností na 0,00001 %, je vrácena chyba #NUM!.

Pokud chcete výpočet IRR provést s větší přesností, můžete aplikaci Excel donutit k provedení více než 32 000 iterací pomocí funkce Goal Seek, která je součástí What-If Analysis.

Jde o to, aby program Goal Seek našel takovou procentní sazbu, aby se čistá současná hodnota rovnala nule:

1. Tímto způsobem nastavte zdrojová data:
   • Zadejte peněžní toky do sloupce (v tomto příkladu B2:B7).
   • Do některé buňky (B9) vložte očekávanou vnitřní návratnost. Na zadané hodnotě vlastně nezáleží, potřebujete pouze "nakrmit" vzorec NPV, takže stačí vložit libovolné procento, které vás napadne, například 10 %.
   • Do jiné buňky (B10) zadejte následující vzorec NPV:

=NPV(B9,B3:B7)+B2

• Nastavit buňku - odkaz na buňku NPV (B10).
• Hodnotit - zadejte hodnotu 0, což je požadovaná hodnota pro buňku Set.
• Změnou buňky - odkaz na buňku IRR (B9).

Po dokončení klikněte na tlačítko OK .

Podobným způsobem můžete použít funkci Goal Seek ke zjištění XIRR. Jediný rozdíl je v tom, že místo NPV budete muset použít vzorec XNPV.

Poznámka: Hodnota IRR zjištěná pomocí nástroje Goal Seek je statické , nepřepočítává se dynamicky jako vzorce. Po každé změně původních údajů budete muset zopakovat výše uvedené kroky, abyste získali novou hodnotu IRR.

To je postup výpočtu IRR v aplikaci Excel. Chcete-li se blíže seznámit se vzorci popsanými v tomto návodu, můžete si stáhnout náš ukázkový sešit níže. Děkuji vám za přečtení a doufám, že se uvidíme na našem blogu příští týden!

Cvičebnice ke stažení

Kalkulačka IRR v aplikaci Excel - příklady (.xlsx soubor)