Tutorialul explică formula dobânzii compuse pentru Excel și oferă exemple de calculare a valorii viitoare a investiției la o rată anuală, lunară sau zilnică a dobânzii compuse. Veți găsi, de asemenea, pașii detaliați pentru a vă crea propriul E xcel calculator de calcul al dobânzii compuse.

Dobânda compusă este unul dintre elementele de bază ale sistemului bancar și una dintre cele mai puternice forțe financiare care determină rezultatul investițiilor dumneavoastră.

Dacă nu sunteți absolvent de contabilitate, analist financiar sau investitor experimentat, ar putea fi puțin dificil să înțelegeți conceptul din cărțile și manualele financiare specializate. Scopul acestui articol este de a ușura acest lucru : ) De asemenea, veți învăța cum să utilizați o formulă de dobândă compusă în Excel și să creați un calculator universal de dobândă compusă pentru propriile foi de calcul.

Ce este dobânda compusă?

În termeni foarte simpli, dobânda compusă este dobânda obținută din dobândă. Mai exact, dobânda compusă este obținută atât din depozitul inițial (principalul), cât și din dobânda acumulată în perioadele anterioare.

Poate că ar fi mai ușor să începem cu dobânda simplă, care se calculează doar la suma principală. De exemplu, puneți 10 $ într-un cont bancar. Cât va valora depozitul dvs. după un an, la o rată anuală a dobânzii de 7%? Răspunsul este 10,70 $ (10 + 10*0,07 = 10,70), iar dvs. dobânda câștigată este de 0,70 dolari.

În caz de dobândă compusă În cazul în care, în fiecare perioadă de timp, principalul este diferit. Banca nu vă va da înapoi dobânda câștigată, ci o adaugă la investiția dvs. principală. Această sumă mărită devine principalul pentru următoarea perioadă de timp (perioada de capitalizare) și, de asemenea, câștigă dobândă. Cu alte cuvinte, câștigați dobândă nu numai pentru suma principală, ci și pentru dobânda câștigată în fiecare perioadă de capitalizare.

În exemplul nostru, în plus față de suma principală de 10 $, dobânda acumulată de 0,70 $ va genera, de asemenea, dobândă anul viitor. Așadar, cât va valora depozitul dvs. de 10 $ după 2 ani, la o rată anuală a dobânzii de 7 % compusă anual? Răspunsul este 11,45 $ (10,7 + 10,7*0,07 = 11,45 $) și dvs. dobânda câștigată este de 1,45 USD. După cum vedeți, la sfârșitul celui de-al doilea an, nu numai că ați câștigat 0,70 USD din depozitul inițial de 10 USD, dar ați câștigat și 0,05 USD din dobânda de 0,70 USD acumulată în primul an.

Există mai multe moduri de a calcula dobânda compusă în Excel și vom discuta fiecare dintre ele în detaliu.

Cum se calculează dobânda compusă în Excel

Investițiile pe termen lung pot fi o strategie eficientă pentru a-ți crește averea și chiar și depozitele mici pot face o mare diferență în timp. Formulele Excel de dobândă compusă explicate în continuare te vor ajuta să faci să funcționeze strategia de economisire. În cele din urmă, vom realiza o formulă universală care să calculeze valoarea viitoare cu diferite perioade de compunere - zilnică, săptămânală, lunară, trimestrială sauanual.

Calcularea dobânzii compuse anuale în Excel

Pentru a înțelege mai bine ideea de dobândă compusă, să începem cu un exemplu foarte simplu discutat la începutul acestui tutorial și să scriem o formulă pentru a calcula dobânda compusă anuală în Excel. După cum vă amintiți, investiți 10 $ la o rată anuală a dobânzii de 7% și doriți să știți cum compunerea anuală vă crește economiile.

Dobânda compusă anuală - formula 1

Un mod simplu și direct de a calcula suma câștigată cu o dobândă compusă anuală este folosirea formulei de creștere a unui număr cu un procent:

= Suma * (1 + %) .

În exemplul nostru, formula este:

=A2*(1+$B2)

Unde A2 este depozitul dvs. inițial și B2 este rata anuală a dobânzii. Vă rugăm să acordați atenție faptului că fixăm referința la coloana B prin utilizarea semnului $.

După cum vă amintiți, 1% este o parte dintr-o sută, adică 0,01, deci 7% este 0,07, și acesta este modul în care sunt stocate procentele în Excel. Ținând cont de acest lucru, puteți verifica rezultatul returnat de formulă prin efectuarea unui calcul simplu de 10*(1+0,07) sau 10*1,07 și asigurați-vă că soldul dvs. după 1 an va fi într-adevăr de 10,70 USD.

Și acum, să calculăm soldul după 2 ani. Deci, cât va valora depozitul dvs. de 10 $ peste doi ani la o rată anuală a dobânzii de 7%? Răspunsul este 11,45 $ și îl puteți obține copiind aceeași formulă în coloana D.

Pentru a calcula câți bani veți găsi în contul dvs. bancar la sfârșitul a 3 ani, copiați pur și simplu aceeași formulă în coloana E și veți obține 12,25 dolari.

Cei dintre voi care au ceva experiență cu formulele Excel și-au dat probabil seama că formula de mai sus înmulțește de fapt depozitul inițial de 10 $ cu 1,07 de trei ori:

=10*1.07*1.07*1.07=12.25043

Rotunjiți-l la două zecimale și veți obține același număr ca în celula E2 din imaginea de mai sus - 12,25 USD. Desigur, puteți calcula direct soldul după 3 ani folosind această formulă:

=A2*1.07*1.07*1.07

Dobânda compusă anuală - formula 2

Un alt mod de a realiza o formulă de dobândă compusă anuală este de a calcula dobânda câștigată pentru fiecare an și apoi de a o adăuga la depozitul inițial.

Presupunând că Depozit inițial se află în celula B1 și Rata anuală a dobânzii în celula B2, următoarea formulă funcționează de minune:

=B1 + B1 * $B$2

Pentru ca formula să funcționeze corect, vă rugăm să țineți cont de următoarele detalii:

• Corectează referința la Rata anuală a dobânzii (B2 în cazul nostru) prin adăugarea semnului $, ar trebui să fie o coloană absolută și un rând absolut, ca $B$2.
• Pentru anul 2 (B6) și pentru toți anii următori, modificați formula în:

  Soldul anului 1 + Soldul anului 1 * Rata dobânzii

În acest exemplu, introduceți următoarea formulă în celula B6 și apoi copiați-o în alte rânduri, așa cum se arată în captura de ecran de mai jos:

=B5 + B5 * $B$2

Pentru a afla câtă dobândă ați câștigat efectiv cu capitalizarea anuală, scădeți din Depozit inițial (B1) de la Sold după 1 an (B5). Această formulă ajunge la C5:

=B5-B1

În C6, se scade Sold după 1 an de la Sold după 2 ani , și trageți formula în jos în alte celule:

=B6-B5

Ar trebui să vedeți dobânda câștigată creștere ca în imaginea de mai jos.

Exemplele de mai sus ilustrează bine ideea de dobândă compusă, nu-i așa? Dar niciuna dintre formule nu este suficient de bună pentru a fi numită o formulă universală de dobândă compusă pentru Excel. În primul rând, pentru că nu vă permit să specificați o frecvență de compunere și, în al doilea rând, pentru că trebuie să construiți un întreg tabel, în loc să introduceți pur și simplu o anumită durată și o anumită rată a dobânzii.

Ei bine, haideți să facem un pas înainte și să creăm o formulă universală de dobândă compusă pentru Excel, care poate calcula câți bani veți câștiga prin compunere anuală, trimestrială, lunară, săptămânală sau zilnică.

Formula generală a dobânzii compuse

Atunci când consilierii financiari analizează impactul dobânzii compuse asupra unei investiții, aceștia iau în considerare, de obicei, trei factori care determină valoarea viitoare a investiției (FV):

• PV - valoarea actualizată a investiției
• i - rata dobânzii obținute în fiecare perioadă
• n - numărul de perioade

Cunoscând aceste componente, puteți folosi următoarea formulă pentru a obține valoarea valoarea viitoare a investiției cu o anumită rată compusă a dobânzii:

Pentru a ilustra mai bine acest lucru, iată câteva exemple rapide.

Exemplul 1: Formula dobânzii compuse lunare

Să presupunem că investiți 2.000 de dolari la o rată a dobânzii de 8% compusă lunar și doriți să aflați valoarea investiției dumneavoastră după 5 ani.

În primul rând, să scriem o listă de componente pentru formula dobânzii compuse:

• PV = 2.000 DE DOLARI
• i = 8% pe an, compus lunar (0,08/12= 00666666667)
• n = 5 ani x 12 luni (5*12=60)

Introduceți numerele de mai sus în formulă și veți obține:

= $2,000 * (1 + 0.8/12)5x12

sau

= $2,000 * 1.00666666760

sau

= $2,000 * 1.489845708 = $2,979.69

Exemplul 2: Formula dobânzii compuse zilnice

Sper că exemplul cu dobânda compusă lunară a fost bine înțeles, iar acum puteți utiliza aceeași abordare pentru dobânda compusă zilnică. Investiția inițială, rata dobânzii, durata și formula sunt exact aceleași ca în exemplul de mai sus, doar perioada de capitalizare este diferită:

• PV = 2.000 DE DOLARI
• i = 8% pe an, compus zilnic (0,08/365 = 0,000219178)
• n = 5 ani x 365 de zile (5*365 =1825)

Introduceți numerele de mai sus în formula dobânzii compuse și veți obține următorul rezultat:

=$2,000 * (1 + 0.000219178)1825 = $2,983.52

După cum vedeți, cu o dobândă compusă zilnic, valoarea viitoare a aceleiași investiții este puțin mai mare decât cu o dobândă compusă lunar. Acest lucru se datorează faptului că rata dobânzii de 8% adaugă dobânda la suma principală în fiecare zi și nu în fiecare lună. După cum puteți ghici, rezultatul compusului lunar va fi mai mare decât cel al compusului anual.

Toate acestea sunt bune, dar ceea ce doriți cu adevărat este o formulă Excel pentru dobânda compusă, nu-i așa? Aveți puțină răbdare cu mine pentru încă puțin timp, vă rog. Acum ajungem la partea cea mai interesantă - construirea propriului calculator puternic și versatil pentru dobânda compusă în Excel.

Formula dobânzii compuse în Excel (compunere zilnică, săptămânală, lunară, anuală)

De obicei, există mai multe moduri de a face ceva în Excel, iar o formulă de calcul a dobânzii compuse nu face excepție :) Deși Microsoft Excel nu oferă nicio funcție specială pentru calcularea dobânzii compuse, puteți utiliza alte funcții pentru a vă crea propriul calculator de calcul al dobânzii compuse.

Să începem să creăm calculatorul nostru Excel de calcul al dobânzii compuse prin introducerea factorilor de bază care determină valoarea viitoare a unei investiții într-o foaie de calcul Excel:

• investiția inițială (B3)
• rata anuală a dobânzii (B4)
• numărul de perioade de capitalizare pe an (B5)
• numărul de ani (B6)

După ce ați terminat, foaia Excel ar putea arăta asemănător cu aceasta:

Tot ceea ce vă trebuie acum este formula dobânzii compuse pentru a calcula suma câștigată (Soldul) pe baza valorilor de intrare. Cea mai bună veste este că nu trebuie să reinventați roata. Vom lua pur și simplu formula dobânzii compuse testate în timp și utilizate de instituțiile bancare și alte instituții financiare și o vom traduce în limbajul Excel.

Formula dobânzii compuse pentru Excel:

Pentru datele sursă de mai sus, formula are următoarea formă:

=B3 * (1 + B4 /B5) ^ (B6 * B5)

Numerele vă par destul de familiare? Da, sunt aceleași valori și calcule pe care le-am efectuat cu o formulă de dobândă compusă lunară, iar rezultatul dovedește că am făcut totul corect!

Dacă vrei să știi cât va valora investiția ta la o rată anuală a dobânzii de 8% compusă trimestrial , introduceți pur și simplu 4 în celula B5:

Pentru a calcula valoarea viitoare a investiției dvs. cu semestrial compunere, introduceți 2 ca valoare Perioade de capitalizare pe an valoare. Pentru săptămânal ratele dobânzii, introduceți 52, acesta este numărul de săptămâni pe care le conține fiecare an. Dacă vă interesează zilnic compunere, introduceți 365 și așa mai departe.

Pentru a afla cantitatea de dobânda câștigată , calculați pur și simplu diferența dintre valoarea viitoare (soldul) și valoarea prezentă (investiția inițială). În cazul nostru, formula din B9 este la fel de simplă ca:

=B8-B3

După cum vedeți, am creat un calculator cu adevărat universal de calcul al dobânzii compuse pentru Excel. Sperăm că acum nu mai aveți niciun regret că ați investit câteva minute prețioase pentru a afla dificila formulă a dobânzii compuse folosită de planificatorii financiari : )

Calculator avansat al dobânzii compuse pentru Excel

Dacă, din anumite motive, nu sunteți mulțumit de abordarea de mai sus, puteți crea calculatorul Excel de calcul al dobânzii compuse utilizând funcția FV, disponibilă în toate versiunile Excel 2000-2019.

Funcția FV calculează valoarea viitoare a unei investiții pe baza unor date de intrare similare cu cele discutate anterior, deși sintaxa sa este puțin diferită:

Explicația detaliată a argumentelor poate fi găsită în tutorialul funcției Excel FV.

Între timp, haideți să construim o formulă FV folosind aceleași date sursă ca în exemplul cu dobândă compusă lunară și să vedem dacă obținem același rezultat.

După cum probabil vă amintiți, am depus 2.000 de dolari timp de 5 ani într-un cont de economii cu o rată anuală a dobânzii de 8% compusă lunar, fără plăți suplimentare. Deci, formula noastră de dobândă compusă este următoarea:

=FV(0.08/12, 5*12, ,-2000)

Dacă aveți nevoie de o explicație a parametrilor, poftiți aici:

• este 0,008/12, deoarece aveți o rată anuală a dobânzii de 8% compusă lunar.
• nper este 5*12, adică 5 ani * 12 luni
• pmt este lăsat în alb, deoarece nu avem plăți suplimentare.
• pv este -2000, deoarece este o ieșire și ar trebui să fie reprezentată de un număr negativ.

Introduceți formula de mai sus într-o celulă goală, iar rezultatul va fi de 2.979,69 USD (ceea ce este perfect în concordanță cu rezultatul calculului matematic efectuat în exemplul cu dobânda compusă lunară).

Firește, nimic nu vă împiedică să înlocuiți valorile cu referințe de celule:

=FV(B4/B5, B6*B5, , -B3)

Imaginea de mai jos arată valoarea viitoare a investiției de 4.000 de dolari după 15 ani la o rată anuală a dobânzii de 7% compusă săptămânal:

Pentru a face calculatorul Excel de calcul al dobânzii compuse și mai puternic, îl puteți extinde cu ajutorul funcției Contribuții suplimentare opțiune (plăți suplimentare) și modificați în consecință formula dobânzii compuse.

=FV(B4/B5, B6*B5, -B8, -B3, B9)

Unde:

• B3 - investiție principală
• B4 - rata anuală a dobânzii
• B5 - numărul de perioade de capitalizare pe an
• B6 - numărul de ani de economisire
• B8 - contribuții suplimentare (opțional)
• B9 - tip de contribuții suplimentare. Rețineți că introduceți 1 dacă depuneți o sumă suplimentară la începutul perioadei de capitalizare, 0 sau omis dacă plățile suplimentare sunt efectuate la sfârșitul perioadei.

Dacă sunteți curioși să încercați acest calculator avansat de calcul al dobânzii compuse pentru Excel pentru a vă calcula economiile, îl puteți descărca la sfârșitul acestui articol.

Sfat. O altă modalitate rapidă de a calcula dobânda compusă este de a face o analiză de tip "dacă" cu ajutorul tabelului de date Excel.

Calculatoare de dobândă compusă online

Dacă preferați să investiți mai degrabă bani decât timp în a vă da seama cum să calculați dobânda compusă în Excel, calculatoarele online de dobândă compusă vă pot fi de folos. Puteți găsi o mulțime de ele introducând ceva de genul "calculator de dobândă compusă" în motorul de căutare preferat. Între timp, permiteți-mi să vă prezint rapid câteva dintre cele preferate de mine.

Calculator de dobândă compusă de Bankrate

Beneficiile cheie ale calculatorului de dobândă compusă Bankrate sunt ușurința de utilizare și prezentarea vizuală a rezultatelor. Acest calculator vă permite să introduceți datele de economisire manual în căsuțe sau prin deplasarea unui cursor. Pe măsură ce faceți acest lucru, totalul estimat este afișat în partea de sus și se reflectă imediat în graficul de mai jos:

Dacă faceți clic pe butonul Vezi raportul generează un "Raport de sinteză", precum și "Soldul economiilor", care oferă informații detaliate privind valoarea contribuțiilor suplimentare, dobânda acumulată și soldul pentru fiecare an.

Calculator de dobândă compusă de Money-Zine

Calculatorul online de la Money-Zine este mult mai simplu în comparație cu cel de la Bankrate. Acesta vă cere să specificați doar 3 valori: investiția principală, rata dobânzii și durata. Imediat ce furnizați aceste numere și faceți clic pe butonul Calculați vă va afișa toate tipurile de rată compusă a dobânzii (zilnică, săptămânală, lunară, anuală etc.), precum și valorile viitoare cu o compunere corespunzătoare.

Calculator de dobândă compusă de MoneySmart

Acesta este un foarte bun calculator online al dobânzii compuse, gestionat de Comisia australiană pentru valori mobiliare și investiții. Vă permite să introduceți toți factorii relevanți care determină valoarea viitoare a investiției dvs. și afișează rezultatul sub formă de grafic. Dacă treceți deasupra unei anumite bare din grafic, puteți vedea informațiile sumare pentru anul respectiv.

Iată cum se calculează dobânda compusă în Excel și în afara lui :) Sper că cel puțin o formulă de calcul a dobânzii compuse discutată în acest articol ți s-a dovedit utilă. Oricum, îți mulțumesc pentru lectură și sper să ne revedem pe blog săptămâna viitoare!

Caietul de practică pentru descărcare

Calculator de dobândă compusă pentru Excel (.xlsx file)