Tabla de contenido
El tutorial muestra las formas más eficaces de buscar, filtrar y resaltar valores únicos y distintos en Excel.
En el tutorial de la semana pasada, exploramos diferentes formas de contar valores únicos en Excel. Pero ocasionalmente puede que desee ver sólo los valores únicos o distintos en una columna - no cuántos, sino los valores reales. Antes de seguir adelante, vamos a asegurarnos de que estamos en la misma página con los términos. Entonces, ¿qué son valores distintos y qué son valores únicos en Excel?
- Único son los elementos que sólo aparecen una vez en un conjunto de datos.
- Distinto son todos los elementos diferentes de una lista, es decir, valores únicos y 1ª aparición de valores duplicados.
Y ahora, vamos a investigar las técnicas más eficaces para tratar valores únicos y distintos en tus hojas de Excel.
Cómo encontrar valores únicos/distintos en Excel
La forma más sencilla de identificar valores únicos y distintos en Excel es utilizando la función IF junto con COUNTIF. Puede haber algunas variaciones de la fórmula dependiendo del tipo de valores que desee encontrar, como se demuestra en los siguientes ejemplos.
Buscar valores únicos en una columna
Para encontrar valores distintos o únicos en una lista, utilice una de las siguientes fórmulas, donde A2 es la primera y A10 es la última celda con datos.
Cómo encontrar valores únicos en Excel:
=IF(COUNTIF($A$2:$A$10, $A2)=1, "Único", "")
Cómo conseguir valores distintos en Excel:
=IF(COUNTIF($A$2:$A2, $A2)=1, "Distinto", "")
En la fórmula distinta, sólo hay una pequeña desviación en la segunda referencia de celda, que sin embargo marca una gran diferencia:
Consejo: si desea buscar valores únicos entre 2 columnas es decir, busque los valores que están presentes en una columna pero ausentes en otra, y utilice la fórmula explicada en Cómo comparar 2 columnas en busca de diferencias.
Buscar filas únicas / distintas en Excel
De forma similar, puede encontrar filas únicas en su tabla Excel basándose en valores de 2 o más columnas. En este caso, debe utilizar la función COUNTIFS en lugar de COUNTIF para evaluar los valores de varias columnas (se pueden evaluar hasta 127 pares rango/criterio en una sola fórmula).
Por ejemplo, para encontrar nombres únicos o distintos en la lista, utilice las siguientes fórmulas:
Fórmula para obtener filas únicas :
=IF(COUNTIFS($A$2:$A$10, $A2, $B$2:$B$10, $B2)=1, "Fila única", "")
Fórmula para encontrar filas distintas :
=IF(COUNTIFS($A$2:$A2, $A2, $B$2:$B2, $B2)=1, "Fila distinta", "")
Buscar valores únicos / distintos sensibles a mayúsculas/minúsculas en Excel
Si está trabajando con un conjunto de datos en el que importa el caso, necesitaría una fórmula de matriz un poco más complicada.
Búsqueda de mayúsculas y minúsculas valores únicos :
=IF(SUM((--EXACT($A$2:$A$10,A2)))=1, "Único","")
Búsqueda de mayúsculas y minúsculas valores distintos :
=IF(SUM((--EXACT($A$2:$A2,$A2)))=1, "Distinto","")
Dado que ambas son fórmulas de matriz, asegúrese de pulsar Ctrl + Mayús + Intro para completarlas correctamente.
Una vez encontrados los valores únicos o distintos, puede filtrarlos, seleccionarlos y copiarlos fácilmente como se muestra a continuación.
Cómo filtrar valores únicos y distintos en Excel
Para ver sólo valores únicos o distintos en la lista, fíltrelos realizando los siguientes pasos.
- Aplique una de las fórmulas anteriores para identificar valores o filas únicos / distintos.
- Seleccione sus datos y haga clic en el botón Filtro en el botón Datos O haga clic en Ordenar y filtrar > Filtro en el Inicio en la pestaña Edición de grupo.
- Haga clic en la flecha de filtrado
en la cabecera de la columna que contiene su fórmula y seleccione los valores que desea ver:
Cómo seleccionar valores distintos / únicos
Si tiene una lista relativamente pequeña de valores únicos / distintos, puede seleccionarla simplemente de la forma habitual utilizando el ratón. Si la lista filtrada contiene cientos o miles de filas, puede utilizar uno de los siguientes atajos que le ahorrarán tiempo.
Para seleccionar rápidamente la lista única o distinta incluidos los encabezados de columna Para filtrar valores únicos, haga clic en cualquier celda de la lista de valores únicos y pulse Ctrl + A .
Para seleccionar valores distintos o únicos sin cabeceras de columna Para filtrar valores únicos, seleccione la primera celda con datos y pulse Ctrl + Mayús + Fin para ampliar la selección hasta la última celda.
Consejo: En algunos casos, sobre todo en libros muy grandes, los métodos abreviados anteriores pueden seleccionar celdas visibles e invisibles. Para solucionarlo, pulse primero Ctrl + A o Ctrl + Mayús + Fin y, a continuación, pulse Alt + ; para seleccionar sólo las celdas visibles ignorando las filas ocultas.
Si tiene dificultades para recordar tantos atajos, utilice esta forma visual: seleccione toda la lista única / distinta y, a continuación, vaya a la opción Ficha Inicio > Buscar & Seleccionar > Ir a Especial y seleccione Sólo células visibles .
Copiar valores únicos o distintos en otra ubicación
Para copiar una lista de valores únicos en otra ubicación, basta con hacer lo siguiente:
- Seleccione los valores filtrados utilizando el ratón o los atajos mencionados anteriormente.
- Pulse Ctrl + C para copiar los valores seleccionados.
- Seleccione la celda superior izquierda del rango de destino (puede estar en la misma hoja o en otra diferente) y pulse Ctrl + V para pegar los valores.
Cómo resaltar valores únicos y distintos en Excel
Siempre que necesite resaltar algo en Excel basándose en una determinada condición, vaya directamente a la función Formato condicional. A continuación encontrará información más detallada y ejemplos.
Resaltar valores únicos en una columna (regla integrada)
La forma más rápida y sencilla de resaltar valores únicos en Excel es aplicar la regla de formato condicional incorporada:
- Seleccione la columna de datos en la que desea resaltar los valores únicos.
- En el Inicio en la pestaña Estilos grupo, haga clic en Formato condicional > Resaltar celdas Reglas > Duplicar valores...
Consejo: si no está satisfecho con alguno de los formatos predefinidos, haga clic en Formato personalizado... (el último elemento de la lista desplegable) y establezca el color de relleno y/o de fuente a su gusto.
Como puede ver, resaltar valores únicos en Excel es la tarea más fácil que uno pueda imaginar. Sin embargo, la regla incorporada de Excel sólo funciona para los elementos que aparecen en la lista una sola vez. Si necesita resaltar valores distintos - únicos y 1a ocurrencia duplicada - tendrá que crear su propia regla basada en una fórmula. También tendría que crear una regla personalizada para resaltar filas únicas basada en la fórmulaen una o varias columnas.
Resaltar valores únicos y distintos en Excel (regla personalizada)
Para resaltar valores únicos o distintos en una columna, seleccione los datos sin encabezado de columna (no querrá que se resalte el encabezado, ¿verdad?) y cree una regla de formato condicional con una de las siguientes fórmulas.
Resaltar valores únicos
Para resaltar una sola vez los valores que aparecen en una lista, utilice la siguiente fórmula:
=COUNTIF($A$2:$A$10,$A2)=1
Donde A2 es la primera y A10 es la última celda del rango aplicado.
Resaltar valores distintos
Para resaltar todos los valores diferentes de una columna, es decir, los valores únicos y el primer duplicado, utilice la siguiente fórmula:
=COUNTIF($A$2:$A2,$A2)=1
Donde A2 es la celda superior del rango.
Cómo crear una regla basada en una fórmula
Para crear una regla de formato condicional basada en una fórmula, haga lo siguiente:
- Ir a la Inicio tab> Estilos y haga clic en Formato condicional > Nueva regla> Utilizar una fórmula para determinar qué celdas formatear .
- Introduzca su fórmula en el campo Formatear los valores en los que esta fórmula es verdadera caja.
- Haga clic en el botón Formato... y elija el color de relleno y/o el color de fuente que desee.
- Por último, haga clic en el botón OK para aplicar la regla.
Para obtener pasos más detallados con capturas de pantalla, consulte el siguiente tutorial: Cómo crear una regla de formato condicional de Excel basada en el valor de otra celda.
La siguiente captura de pantalla muestra ambas reglas en acción:
Resaltar filas enteras basándose en valores únicos / distintos en una columna
Para resaltar filas enteras basándose en valores únicos de una columna específica, utilice las fórmulas para valores únicos y distintos que utilizamos en el ejemplo anterior, pero aplica tu regla a toda la tabla en lugar de a una sola columna.
La siguiente captura de pantalla muestra la regla que resalta las filas en función de números distintos en la columna A:
Cómo resaltar filas únicas en Excel
Si desea resaltar filas basándose en los valores de 2 o más columnas, utilice la función COUNTIFS que permite especificar varios criterios en una sola fórmula.
Resaltar filas únicas
=COUNTIFS($A$2:$A$10,$A2, $B$2:$B$10,$B2)=1
Resaltar las filas distintas (únicas + 1er duplicado)
=COUNTIFS($A$2:$A2,$A2,$B$2:$B2,$B2)=1
Así es como puede encontrar, filtrar y resaltar valores distintos o únicos en Excel. Para consolidar sus conocimientos, puede descargar el libro de trabajo de ejemplo Encontrar valores únicos y realizar ingeniería inversa de las fórmulas para una mejor comprensión.
Una forma rápida y sencilla de encontrar y resaltar valores únicos en Excel
Como acabas de ver, Microsoft Excel proporciona un montón de funciones útiles que pueden ayudarte a identificar y resaltar valores únicos en tus hojas de cálculo. Sin embargo, todas esas soluciones no pueden llamarse intuitivas y fáciles de usar porque requieren memorizar un puñado de fórmulas diferentes. Por supuesto, no es gran cosa para los profesionales de Excel :) Para aquellos usuarios de Excel que quieran ahorrar su tiempoy esfuerzo, permítanme mostrarles una forma rápida y sencilla de encontrar valores únicos en Excel.
En esta sección final de nuestro tutorial de hoy, vamos a utilizar nuestro complemento Duplicate Remover para Excel. Por favor, no se confunda por el nombre de la herramienta. Aparte de los registros duplicados, el complemento puede manejar perfectamente entradas únicas y distintas, y se asegurará de ello en un momento.
- Seleccione cualquier celda de una tabla en la que desee encontrar valores únicos y haga clic en el botón Eliminador de duplicados en el botón Datos de Ablebits en la pestaña Deduplicación grupo.
El asistente se ejecutará y toda la tabla se seleccionará automáticamente. Por lo tanto, basta con hacer clic en Siguiente para pasar al siguiente paso.
Sugerencia: cuando utilice el complemento por primera vez, es aconsejable que compruebe la opción Crear un buzón de copia de seguridad por si acaso.
- Único
- Único +1ª vez (distinto)
En este ejemplo, queremos encontrar nombres únicos basados en los valores de 2 columnas (Nombre y Apellidos), por lo tanto seleccionamos ambas.
Consejo: si su tabla tiene cabeceras, asegúrese de seleccionar la opción Mi tabla tiene cabeceras Y si su tabla puede tener celdas vacías, asegúrese de que la casilla Saltar celdas vacías Ambas opciones se encuentran en la parte superior de la ventana de diálogo y suelen estar seleccionadas por defecto.
- Resalte los valores únicos con colores
- Seleccionar valores únicos
- Identificar en una columna de estado
- Copiar a otra ubicación
Haga clic en el botón Acabado y obtenga el resultado en segundos:
Así es como puede encontrar, seleccionar y resaltar valores únicos en Excel utilizando nuestro complemento Eliminador de duplicados. No puede ser más sencillo, ¿verdad?
Si encontrar valores duplicados y únicos en Excel es una parte habitual de su trabajo diario, pruebe esta herramienta de deduplicación y se sorprenderá con los resultados. Duplicate Remover, así como nuestras otras herramientas de ahorro de tiempo, están incluidas en Ultimate Suite for Excel.
Descargas disponibles
Buscar valores únicos - ejemplos de fórmulas (archivo .xlsx)
Ultimate Suite - versión de prueba (archivo .exe)
