Ce tutoriel montre comment construire un tableau d'amortissement dans Excel pour détailler les paiements périodiques d'un prêt amortissable ou d'une hypothèque.

Un site prêt amortissable est juste une façon élégante de définir un prêt qui est remboursé par versements pendant toute la durée du prêt.

Fondamentalement, tous les prêts sont amortis d'une manière ou d'une autre. Par exemple, un prêt entièrement amorti sur 24 mois donnera lieu à 24 paiements mensuels égaux. Chaque paiement applique un montant au capital et un autre aux intérêts. Pour détailler chaque paiement sur un prêt, vous pouvez établir un tableau d'amortissement du prêt.

Un site tableau d'amortissement est un tableau qui énumère les paiements périodiques d'un prêt ou d'une hypothèque au fil du temps, décompose chaque paiement en capital et intérêts et indique le solde restant après chaque paiement.

Comment créer un tableau d'amortissement d'un prêt dans Excel ?

Pour construire un tableau d'amortissement de prêt ou d'hypothèque dans Excel, nous devrons utiliser les fonctions suivantes :

• Fonction PMT - calcule le montant total d'un paiement périodique. Ce montant reste constant pendant toute la durée du prêt.
• Fonction PPMT - obtient le principal La partie de chaque paiement qui sert à rembourser le principal du prêt, c'est-à-dire le montant que vous avez emprunté. Ce montant augmente lors des paiements suivants.
• Fonction IPMT - trouve le intérêt La partie de chaque paiement qui sert à payer les intérêts. Ce montant diminue à chaque paiement.

Maintenant, passons en revue le processus étape par étape.

1. mettre en place le tableau d'amortissement

Pour commencer, définissez les cellules d'entrée où vous saisirez les composants connus d'un prêt :

• C2 - taux d'intérêt annuel
• C3 - durée du prêt en années
• C4 - nombre de paiements par an
• C5 - montant du prêt

La prochaine chose à faire est de créer un tableau d'amortissement avec les étiquettes ( Période , Paiement , Intérêt , Principal , Balance ) en A7:E7. Dans les Période colonne, entrez une série de chiffres égale au nombre total de paiements (1- 24 dans cet exemple) :

Tous les éléments connus étant en place, passons à la partie la plus intéressante - les formules d'amortissement des prêts.

2. calculer le montant total du paiement (formule PMT)

Le montant du paiement est calculé avec la fonction PMT(rate, nper, pv, [fv], [type]).

Pour gérer correctement les différentes fréquences de paiement (hebdomadaires, mensuelles, trimestrielles, etc.), vous devez être cohérent avec les valeurs fournies pour le champ taux et nper arguments :

• Taux - diviser le taux d'intérêt annuel par le nombre de périodes de paiement par an ($C$2/$C$4).
• Nper - multiplier le nombre d'années par le nombre de périodes de paiement par an ($C$3*$C$4).
• Pour le pv argument, entrez le montant du prêt ($C$5).
• Le site fv et type peuvent être omis puisque leurs valeurs par défaut nous conviennent parfaitement (le solde après le dernier paiement est supposé être 0 ; les paiements sont effectués à la fin de chaque période).

En rassemblant les arguments ci-dessus, nous obtenons cette formule :

=PMT($C$2/$C$4, $C$3*$C$4, $C$5)

Veuillez noter que nous utilisons des références de cellules absolues car cette formule doit être copiée dans les cellules ci-dessous sans aucune modification.

Entrez la formule PMT dans B8, faites-la glisser vers le bas de la colonne, et vous verrez un montant de paiement constant pour toutes les périodes :

3. calculer les intérêts (formule IPMT)

Pour trouver la part d'intérêt de chaque paiement périodique, utilisez la fonction IPMT(rate, per, nper, pv, [fv], [type]) :

=IPMT($C$2/$C$4, A8, $C$3*$C$4, $C$5)

Tous les arguments sont les mêmes que dans la formule PMT, à l'exception de l'argument suivant par Cet argument est fourni sous la forme d'une référence de cellule relative (A8) car il est censé changer en fonction de la position relative d'une ligne dans laquelle la formule est copiée.

Cette formule va en C8, puis vous la copiez vers le bas dans autant de cellules que nécessaire :

4. trouver le principal (formule PPMT)

Pour calculer la partie principale de chaque paiement périodique, utilisez cette formule PPMT :

=PPMT($C$2/$C$4, A8, $C$3*$C$4, $C$5)

La syntaxe et les arguments sont exactement les mêmes que dans la formule IPMT présentée ci-dessus :

Cette formule va dans la colonne D, en commençant par D8 :

Conseil : pour vérifier si vos calculs sont corrects à ce stade, additionnez les nombres dans l'espace de travail. Principal et Intérêt La somme doit être égale à la valeur figurant dans la colonne de gauche. Paiement dans la même ligne.

5. obtenir le solde restant

Pour calculer le solde restant pour chaque période, nous utiliserons deux formules différentes.

Pour trouver le solde après le premier paiement en E8, additionnez le montant du prêt (C5) et le capital de la première période (D8) :

=C5+D8

Le montant du prêt étant un nombre positif et le principal un nombre négatif, le second est en fait soustrait du premier.

Pour la deuxième période et toutes les périodes suivantes, additionnez le solde précédent et le principal de cette période :

=E8+D9

La formule ci-dessus va jusqu'à E9, puis vous la copiez le long de la colonne. Grâce à l'utilisation de références de cellules relatives, la formule s'ajuste correctement pour chaque ligne.

Et voilà, notre tableau d'amortissement mensuel du prêt est terminé :

Conseil : renvoyer les paiements sous forme de nombres positifs

Étant donné qu'un prêt est payé à partir de votre compte bancaire, les fonctions Excel renvoient le paiement, les intérêts et le principal sous forme de les nombres négatifs Par défaut, ces valeurs sont mises en évidence en rouge et entre parenthèses, comme vous pouvez le voir dans l'image ci-dessus.

Si vous préférez avoir tous les résultats en tant que positif mettez un signe moins devant les fonctions PMT, IPMT et PPMT.

Pour le Balance utilisez la soustraction au lieu de l'addition, comme le montre la capture d'écran ci-dessous :

Tableau d'amortissement pour un nombre variable de périodes

Dans l'exemple ci-dessus, nous avons établi un tableau d'amortissement du prêt pour le nombre prédéfini de périodes de paiement. Cette solution rapide et ponctuelle fonctionne bien pour un prêt ou une hypothèque spécifique.

Si vous cherchez à créer un tableau d'amortissement réutilisable avec un nombre variable de périodes, vous devrez adopter une approche plus complète décrite ci-dessous.

1. saisir le nombre maximal de périodes

Dans le Période Vous pouvez tirer parti de la fonction AutoFill d'Excel pour saisir une série de chiffres plus rapidement.

2) Utiliser les instructions IF dans les formules d'amortissement.

Comme vous avez maintenant beaucoup de numéros de période excessifs, vous devez d'une manière ou d'une autre limiter les calculs au nombre réel de paiements pour un prêt particulier. Cela peut être fait en enveloppant chaque formule dans une instruction IF. Le test logique de l'instruction IF vérifie si le numéro de période dans la ligne actuelle est inférieur ou égal au nombre total de paiements. Si le test logique est VRAI, la formule correspondanteest calculé ; si FAUX, une chaîne vide est retournée.

En supposant que Période 1 se trouve à la ligne 8, saisissez les formules suivantes dans les cellules correspondantes, puis copiez-les dans l'ensemble du tableau.

Paiement (B8) :

=IF(A8<=$C$3*$C$4, PMT($C$2/$C$4, $C$3*$C$4, $C$5), "")

Intérêt (C8) :

=IF(A8<=$C$3*$C$4, IPMT($C$2/$C$4, A8, $C$3*$C$4, $C$5), "")

Principal (D8) :

=IF(A8<=$C$3*$C$4,PPMT($C$2/$C$4, A8, $C$3*$C$4, $C$5), "")

Balance :

Pour Période 1 (E8), la formule est la même que dans l'exemple précédent :

=C5+D8

Pour Période 2 (E9) et toutes les périodes suivantes, la formule prend cette forme :

=IF(A9<=$C$3*$C$4, E8+D9, "")

Le résultat est un tableau d'amortissement correctement calculé et un tas de lignes vides avec les numéros de période après le remboursement du prêt.

3. cacher les numéros des périodes supplémentaires

Si vous pouvez vous accommoder d'un tas de numéros de période superflus affichés après le dernier paiement, vous pouvez considérer que le travail est fait et sauter cette étape. Si vous recherchez la perfection, masquez tous les points inutilisés en établissant une règle de formatage conditionnelle qui définit la variable couleur de la police : blanc pour n'importe quelle rangée après que le dernier paiement ait été effectué.

Pour cela, sélectionnez tous les lignes de données si votre tableau d'amortissement (A8:E367 dans notre cas) et cliquez sur Accueil tab> ; Formatage conditionnel > ; Nouvelle règle... > ; Utilisez une formule pour déterminer les cellules à mettre en forme .

Dans la case correspondante, entrez la formule ci-dessous qui vérifie si le numéro de la période dans la colonne A est supérieur au nombre total de paiements :

=$A8>$C$3*$C$4

Remarque importante : pour que la formule de mise en forme conditionnelle fonctionne correctement, veillez à utiliser des références de cellule absolues pour les éléments suivants Durée du prêt et Paiements par an cellules que l'on multiplie ($C$3*$C$4). Le produit est comparé avec les Période 1 cellule, pour laquelle vous utilisez une référence de cellule mixte - colonne absolue et ligne relative ($A8).

Après cela, cliquez sur le bouton Format... et choisissez la couleur de police blanche. C'est fait !

4. faire un résumé du prêt

Pour visualiser les informations récapitulatives de votre prêt d'un seul coup d'œil, ajoutez quelques formules supplémentaires en haut de votre tableau d'amortissement.

Total des paiements (F2) :

=-SUM(B8:B367)

Total des intérêts (F3) :

=-SUM(C8:C367)

Si les paiements sont des nombres positifs, retirez le signe moins des formules ci-dessus.

Voilà, notre tableau d'amortissement du prêt est terminé et prêt à être utilisé !

Télécharger le tableau d'amortissement des prêts pour Excel

Comment établir un tableau d'amortissement d'un prêt avec des paiements supplémentaires en Excel ?

Les tableaux d'amortissement présentés dans les exemples précédents sont faciles à créer et à suivre (espérons-le :). Cependant, ils ne tiennent pas compte d'une caractéristique utile qui intéresse de nombreux emprunteurs : les versements supplémentaires permettant de rembourser un prêt plus rapidement. Dans cet exemple, nous allons voir comment créer un tableau d'amortissement de prêt avec des versements supplémentaires.

1. définir les cellules d'entrée

Comme d'habitude, commencez par configurer les cellules de saisie. Dans ce cas, nommons ces cellules comme indiqué ci-dessous pour faciliter la lecture de nos formules :

• Taux d'intérêt - C2 (taux d'intérêt annuel)
• LoanTerm - C3 (durée du prêt en années)
• Paiements par an - C4 (nombre de paiements par an)
• LoanAmount - C5 (montant total du prêt)
• ExtraPayment - C6 (paiement supplémentaire par période)

2. calculer un paiement programmé

Outre les cellules d'entrée, une autre cellule prédéfinie est nécessaire pour nos calculs ultérieurs : la cellule montant du paiement prévu Ce montant est calculé à l'aide de la formule suivante :

=IFERROR(-PMT(InterestRate/PaymentsPerYear, LoanTerm*PaymentsPerYear, LoanAmount), "")

Veuillez noter que nous avons mis un signe moins avant la fonction PMT pour que le résultat soit un nombre positif. Pour éviter les erreurs dans le cas où certaines des cellules d'entrée sont vides, nous incluons la formule PMT dans la fonction IFERROR.

Entrez cette formule dans une certaine cellule (G2 dans notre cas) et nommez cette cellule ScheduledPayment .

3. mettre en place le tableau d'amortissement

Créez un tableau d'amortissement de prêt avec les en-têtes illustrés dans la capture d'écran ci-dessous. Période saisissez une série de chiffres commençant par zéro (vous pouvez masquer la colonne Période 0 rangée plus tard si nécessaire).

Si vous souhaitez créer un tableau d'amortissement réutilisable, saisissez le nombre maximal possible de périodes de paiement (de 0 à 360 dans cet exemple).

Pour Période 0 (rangée 9 dans notre cas), tirez sur le bouton Balance Toutes les autres cellules de cette ligne resteront vides :

Formule en G9 :

=Montant du prêt

4. construire des formules pour le tableau d'amortissement avec des paiements supplémentaires.

Il s'agit d'une partie essentielle de notre travail. Comme les fonctions intégrées d'Excel ne prévoient pas de paiements supplémentaires, nous devrons faire tous les calculs par nous-mêmes.

Remarque : dans cet exemple, Période 0 est à la ligne 9 et Période 1 Si votre tableau d'amortissement commence à une autre ligne, veillez à adapter les références des cellules en conséquence.

Saisissez les formules suivantes dans la ligne 10 ( Période 1 ), puis les recopier pour toutes les périodes restantes.

Paiement prévu (B10) :

Si le ScheduledPayment (cellule G2) est inférieur ou égal au solde restant (G9), utilisez le paiement programmé. Sinon, ajoutez le solde restant et les intérêts du mois précédent.

=IFERROR(IF(ScheduledPayment<=G9, ScheduledPayment, G9+G9*InterestRate/PaymentsPerYear), "")

Par mesure de précaution supplémentaire, nous enveloppons cette formule et toutes les formules suivantes dans la fonction IFERROR, ce qui permet d'éviter une série d'erreurs diverses si certaines des cellules d'entrée sont vides ou contiennent des valeurs non valides.

Paiement supplémentaire (C10) :

Utilisez une formule IF avec la logique suivante :

Si le ExtraPayment (nommé cellule C6) est inférieur à la différence entre le solde restant et le principal de cette période (G9-E10), retournez ExtraPayment ; sinon, utilisez la différence.

=IFERROR(IF(ExtraPayment

Conseil. Si vous avez paiements supplémentaires variables il suffit de taper les montants individuels directement dans le champ Paiement supplémentaire colonne.

Paiement total (D10)

Il suffit d'ajouter le paiement programmé (B10) et le paiement supplémentaire (C10) pour la période en cours :

=IFERROR(B10+C10, "")

Principal (E10)

Si le paiement programmé pour une période donnée est supérieur à zéro, le système renvoie la plus petite des deux valeurs suivantes : paiement programmé moins les intérêts (B10-F10) ou le solde restant (G9) ; sinon, le système renvoie zéro.

=IFERROR(IF(B10>0, MIN(B10-F10, G9), 0), "")

Veuillez noter que le principal ne comprend que la partie de la paiement à date fixe (pas le paiement supplémentaire !) qui est affecté au capital du prêt.

Intérêt (F10)

Si le paiement échelonné pour une période donnée est supérieur à zéro, divisez le taux d'intérêt annuel (cellule C2) par le nombre de paiements par an (cellule C4) et multipliez le résultat par le solde restant après la période précédente ; sinon, retournez 0.

=IFERROR(IF(B10>0, InterestRate/PaymentsPerYear*G9, 0), "")

Balance (G10)

Si le solde restant (G9) est supérieur à zéro, soustrayez la partie principale du paiement (E10) et le paiement supplémentaire (C10) du solde restant après la période précédente (G9) ; sinon, retournez 0.

=IFERROR(IF(G9>0, G9-E10-C10, 0), "")

Remarque : étant donné que certaines formules se réfèrent les unes aux autres (pas de référence circulaire !), elles peuvent afficher des résultats erronés au cours du processus. Par conséquent, ne commencez pas le dépannage avant d'avoir entré la toute dernière formule dans votre tableau d'amortissement.

Si tout est fait correctement, le tableau d'amortissement de votre prêt à ce stade devrait ressembler à ceci :

5. cacher les périodes supplémentaires

Définissez une règle de mise en forme conditionnelle pour masquer les valeurs des périodes non utilisées, comme expliqué dans cette astuce. couleur de police blanche aux rangs dans lesquels Paiement total (colonne D) et Balance (colonne G) sont égales à zéro ou vides :

=AND(OR($D9=0, $D9=""), OR($G9=0, $G9=""))

Voilà, toutes les lignes avec des valeurs nulles sont cachées de la vue :

6. faire un résumé du prêt

Comme touche finale de perfection, vous pouvez sortir les informations les plus importantes sur un prêt en utilisant ces formules :

Nombre de paiements prévus :

Multipliez le nombre d'années par le nombre de paiements par an :

=Temps du prêt*Paiements par an

Nombre réel de paiements :

Compter les cellules dans le Paiement total qui sont supérieurs à zéro, en commençant par la période 1 :

=COUNTIF(D10:D369,">"&0)

Total des paiements supplémentaires :

Additionnez les cellules dans le Paiement supplémentaire colonne, en commençant par la période 1 :

=SUM(C10:C369)

Intérêt total :

Additionnez les cellules dans le Intérêt colonne, en commençant par la période 1 :

=SUM(F10:F369)

En option, vous pouvez masquer le Période 0 et votre plan d'amortissement du prêt avec des paiements supplémentaires est terminé ! La capture d'écran ci-dessous montre le résultat final :

Télécharger le tableau d'amortissement du prêt avec les paiements supplémentaires

Tableau d'amortissement (modèle Excel)

Pour créer un plan d'amortissement de prêt de qualité en un rien de temps, utilisez les modèles intégrés d'Excel, en cliquant sur le lien suivant Fichier > ; Nouveau , type " tableau d'amortissement "dans le champ de recherche et choisissez le modèle qui vous plaît, par exemple, celui-ci avec des paiements supplémentaires :

Enregistrez ensuite le classeur nouvellement créé comme modèle Excel et réutilisez-le quand vous le souhaitez.

Voilà comment créer un tableau d'amortissement de prêt ou d'hypothèque dans Excel. Je vous remercie de votre lecture et j'espère vous voir sur notre blog la semaine prochaine !

Téléchargements disponibles

Exemples de tableaux d'amortissement (fichier .xlsx)