L'esercitazione mostra come costruire un piano di ammortamento in Excel per dettagliare i pagamenti periodici di un prestito o di un mutuo ammortizzato.

Un prestito ammortizzato è solo un modo elegante per definire un prestito che viene rimborsato a rate per tutta la durata del prestito.

In linea di massima, tutti i prestiti sono ammortizzati in un modo o nell'altro. Ad esempio, un prestito completamente ammortizzato per 24 mesi prevede 24 rate mensili uguali. Ogni rata è destinata in parte al capitale e in parte agli interessi. Per dettagliare ogni rata di un prestito, è possibile costruire un piano di ammortamento del prestito.

Un piano di ammortamento è una tabella che elenca i pagamenti periodici di un prestito o di un mutuo nel tempo, suddividendo ogni pagamento in capitale e interessi e mostrando il saldo residuo dopo ogni pagamento.

Come creare un piano di ammortamento di un prestito in Excel

Per costruire un piano di ammortamento di un prestito o di un mutuo in Excel, è necessario utilizzare le seguenti funzioni:

• Funzione PMT - calcola la importo totale Questo importo rimane costante per tutta la durata del prestito.
• Funzione PPMT - ottiene il valore principale parte di ogni pagamento che va a coprire il capitale del prestito, cioè l'importo preso in prestito. Questo importo aumenta per i pagamenti successivi.
• Funzione IPMT - trova il interesse La parte di ogni pagamento destinata agli interessi, che diminuisce ad ogni pagamento.

Esaminiamo ora il processo passo dopo passo.

1. Impostare la tabella di ammortamento

Per cominciare, definire le celle di input in cui inserire i componenti noti di un prestito:

• C2 - tasso di interesse annuo
• C3 - durata del prestito in anni
• C4 - numero di pagamenti all'anno
• C5 - importo del prestito

La prossima cosa da fare è creare una tabella di ammortamento con le etichette ( Periodo , Pagamento , Interesse , Principale , Equilibrio ) in A7:E7. Nel Periodo inserire una serie di numeri pari al numero totale di pagamenti (1- 24 in questo esempio):

Dopo aver messo a punto tutti i componenti noti, passiamo alla parte più interessante: le formule di ammortamento dei prestiti.

2. Calcolo dell'importo totale del pagamento (formula PMT)

L'importo del pagamento viene calcolato con la funzione PMT(rate, nper, pv, [fv], [type]).

Per gestire correttamente diverse frequenze di pagamento (ad esempio settimanali, mensili, trimestrali, ecc.), è necessario essere coerenti con i valori forniti per il parametro tasso e nper argomenti:

• Tasso - dividere il tasso di interesse annuale per il numero di periodi di pagamento all'anno ($C$2/$C$4).
• Nper - moltiplicare il numero di anni per il numero di periodi di pagamento all'anno ($C$3*$C$4).
• Per il pv inserire l'importo del prestito ($C$5).
• Il fv e tipo possono essere omessi, poiché i loro valori predefiniti vanno bene per noi (il saldo dopo l'ultimo pagamento dovrebbe essere 0; i pagamenti vengono effettuati alla fine di ogni periodo).

Mettendo insieme i ragionamenti precedenti, si ottiene questa formula:

=PMT($C$2/$C$4, $C$3*$C$4, $C$5)

Prestate attenzione al fatto che utilizziamo riferimenti assoluti alle celle perché questa formula deve essere copiata nelle celle sottostanti senza alcuna modifica.

Inserite la formula PMT in B8, trascinatela lungo la colonna e vedrete un importo di pagamento costante per tutti i periodi:

3. Calcolo degli interessi (formula IPMT)

Per trovare la parte di interesse di ogni pagamento periodico, utilizzare la funzione IPMT(rate, per, nper, pv, [fv], [type]):

=IPMT($C$2/$C$4, A8, $C$3*$C$4, $C$5)

Tutti gli argomenti sono gli stessi della formula PMT, tranne il parametro per Questo argomento viene fornito come riferimento di cella relativo (A8) perché si suppone che cambi in base alla posizione relativa di una riga in cui viene copiata la formula.

Questa formula va in C8 e poi viene copiata in tutte le celle necessarie:

4. Trovare il capitale (formula PPMT)

Per calcolare la quota capitale di ogni pagamento periodico, utilizzare la formula PPMT:

=PPMT($C$2/$C$4, A8, $C$3*$C$4, $C$5)

La sintassi e gli argomenti sono esattamente gli stessi della formula IPMT descritta in precedenza:

Questa formula va nella colonna D, a partire da D8:

Suggerimento: per verificare se i calcoli sono corretti a questo punto, sommare i numeri nel campo Principale e Interesse La somma deve essere uguale al valore della colonna Pagamento nella stessa riga.

5. Ottenere il saldo rimanente

Per calcolare il saldo residuo di ogni periodo, utilizzeremo due formule diverse.

Per trovare il saldo dopo il primo pagamento in E8, sommare l'importo del prestito (C5) e il capitale del primo periodo (D8):

=C5+D8

Poiché l'importo del prestito è un numero positivo e il capitale è un numero negativo, il secondo viene effettivamente sottratto dal primo.

Per il secondo e tutti i periodi successivi, sommare il saldo precedente e il capitale di questo periodo:

=E8+D9

La formula di cui sopra va in E9 e poi viene copiata lungo la colonna. Grazie all'uso di riferimenti di cella relativi, la formula si adatta correttamente a ogni riga.

Ecco fatto! Il nostro piano di ammortamento mensile del prestito è pronto:

Suggerimento: restituire i pagamenti come numeri positivi

Poiché un prestito viene pagato dal vostro conto bancario, le funzioni di Excel restituiscono il pagamento, gli interessi e il capitale come numeri negativi Per impostazione predefinita, questi valori sono evidenziati in rosso e racchiusi tra parentesi, come si può vedere nell'immagine precedente.

Se si preferisce avere tutti i risultati come positivo numeri, anteporre un segno meno alle funzioni PMT, IPMT e PPMT.

Per il Equilibrio utilizzare la sottrazione invece dell'addizione, come mostrato nella schermata seguente:

Piano di ammortamento per un numero variabile di periodi

Nell'esempio precedente, abbiamo costruito un piano di ammortamento del prestito per il numero predefinito di periodi di pagamento. Questa rapida soluzione una tantum funziona bene per un prestito o un mutuo specifico.

Se si vuole creare un piano di ammortamento riutilizzabile con un numero variabile di periodi, è necessario adottare un approccio più completo, descritto di seguito.

1. Inserire il numero massimo di periodi

Nel Periodo inserire il numero massimo di pagamenti che si intende consentire per ogni prestito, ad esempio da 1 a 360. È possibile sfruttare la funzione di riempimento automatico di Excel per inserire più rapidamente una serie di numeri.

2. Utilizzare le istruzioni IF nelle formule di ammortamento

Poiché ora si hanno molti numeri di periodo eccessivi, è necessario limitare in qualche modo i calcoli al numero effettivo di pagamenti per un particolare prestito. Questo può essere fatto avvolgendo ogni formula in un'istruzione IF. Il test logico dell'istruzione IF verifica se il numero di periodo nella riga corrente è inferiore o uguale al numero totale di pagamenti. Se il test logico è VERO, il corrispondente numero di periodo è uguale al numero totale di pagamenti.viene calcolata; se è FALSO, viene restituita una stringa vuota.

Supponendo Periodo 1 è nella riga 8, inserire le seguenti formule nelle celle corrispondenti e poi copiarle in tutta la tabella.

Pagamento (B8):

=IF(A8<=$C$3*$C$4, PMT($C$2/$C$4, $C$3*$C$4, $C$5), "")

Interesse (C8):

=IF(A8<=$C$3*$C$4, IPMT($C$2/$C$4, A8, $C$3*$C$4, $C$5), "")

Principale (D8):

=IF(A8<=$C$3*$C$4,PPMT($C$2/$C$4, A8, $C$3*$C$4, $C$5), "")

Equilibrio :

Per Periodo 1 (E8), la formula è la stessa dell'esempio precedente:

=C5+D8

Per Periodo 2 (E9) e tutti i periodi successivi, la formula assume questa forma:

=IF(A9<=$C$3*$C$4, E8+D9, "")

Il risultato è un piano di ammortamento calcolato correttamente e un mucchio di righe vuote con i numeri del periodo dopo l'estinzione del prestito.

3. Nascondere i numeri dei periodi extra

Se si può sopportare un mucchio di numeri di periodi superflui visualizzati dopo l'ultimo pagamento, si può considerare il lavoro fatto e saltare questo passaggio. Se si aspira alla perfezione, allora si possono nascondere tutti i periodi inutilizzati creando una regola di formattazione condizionale che imposti il valore colore del carattere in bianco per tutte le righe successive all'ultimo pagamento.

A tal fine, selezionare tutte le righe di dati se la tabella di ammortamento (A8:E367 nel nostro caso) e fare clic su Casa scheda> Formattazione condizionale > Nuova regola... > Utilizzate una formula per determinare quali celle formattare .

Nella casella corrispondente, inserite la seguente formula che controlla se il numero del periodo nella colonna A è maggiore del numero totale di pagamenti:

=$A8>$C$3*$C$4

Nota importante: affinché la formula di formattazione condizionale funzioni correttamente, assicurarsi di utilizzare i riferimenti assoluti alle celle per il parametro Durata del prestito e Pagamenti all'anno celle che si moltiplicano ($C$3*$C$4). Il prodotto viene confrontato con il valore di $C$3*$4. Periodo 1 cella, per la quale si utilizza un riferimento di cella misto - colonna assoluta e riga relativa ($A8).

Successivamente, fare clic sul pulsante Formato... e scegliere il colore del carattere bianco. Fatto!

4. Fare un riepilogo del prestito

Per visualizzare a colpo d'occhio le informazioni sintetiche sul vostro prestito, aggiungete un paio di formule in cima al piano di ammortamento.

Pagamenti totali (F2):

=-SOMMA(B8:B367)

Interessi totali (F3):

=-SOMMA(C8:C367)

Se i pagamenti sono numeri positivi, rimuovere il segno meno dalle formule precedenti.

Ecco fatto: il nostro piano di ammortamento del prestito è completato e pronto per l'uso!

Scarica il piano di ammortamento dei prestiti per Excel

Come creare un piano di ammortamento del prestito con pagamenti extra in Excel

I piani di ammortamento discussi negli esempi precedenti sono facili da creare e da seguire (si spera :). Tuttavia, tralasciano una caratteristica utile che interessa a molti pagatori di prestiti: i pagamenti aggiuntivi per estinguere il prestito più velocemente. In questo esempio, vedremo come creare un piano di ammortamento del prestito con pagamenti aggiuntivi.

1. Definire le celle di input

Come di consueto, iniziamo con l'impostazione delle celle di input. In questo caso, diamo a queste celle il nome scritto di seguito per facilitare la lettura delle formule:

• Tasso di interesse - C2 (tasso di interesse annuo)
• Termine del prestito - C3 (durata del prestito in anni)
• Pagamenti per anno - C4 (numero di pagamenti all'anno)
• Importo del prestito - C5 (importo totale del prestito)
• Pagamento extra - C6 (pagamento extra per periodo)

2. Calcolare un pagamento programmato

Oltre alle celle di input, per i calcoli successivi è necessaria un'altra cella predefinita, la cella importo del pagamento previsto Questo importo si calcola con la seguente formula: l'importo da pagare sul prestito se non si effettuano pagamenti supplementari:

=IFERROR(-PMT(Interessi/PagamentiPerAnno, DurataPrestito*PagamentiPerAnno, ImportoPrestito), "")

Per evitare errori nel caso in cui alcune celle di input siano vuote, racchiudiamo la formula PMT all'interno della funzione IFERROR.

Inserite questa formula in una cella (G2 nel nostro caso) e assegnatele un nome Pagamento programmato .

3. Impostare la tabella di ammortamento

Creare una tabella di ammortamento del prestito con le intestazioni mostrate nella schermata seguente. Nella tabella Periodo inserire una serie di numeri che iniziano con zero (si può nascondere la colonna Periodo 0 se necessario).

Se si vuole creare un piano di ammortamento riutilizzabile, inserire il numero massimo possibile di periodi di pagamento (da 0 a 360 in questo esempio).

Per Periodo 0 (riga 9 nel nostro caso), tirare il tasto Equilibrio che è pari all'importo del prestito originale. Tutte le altre celle di questa riga rimarranno vuote:

Formula in G9:

=Importo del prestito

4. Creare formule per il piano di ammortamento con pagamenti extra.

Questa è una parte fondamentale del nostro lavoro: poiché le funzioni integrate di Excel non prevedono pagamenti aggiuntivi, dovremo fare tutti i calcoli da soli.

Nota: in questo esempio, Periodo 0 è nella riga 9 e Periodo 1 è nella riga 10. Se la vostra tabella di ammortamento inizia in una riga diversa, assicuratevi di adattare i riferimenti alle celle di conseguenza.

Inserire le seguenti formule nella riga 10 ( Periodo 1 ) e poi ricopiarli per tutti i periodi rimanenti.

Pagamento programmato (B10):

Se il Pagamento programmato (denominato cella G2) è inferiore o uguale al saldo residuo (G9), utilizzare il pagamento programmato, altrimenti sommare il saldo residuo e gli interessi del mese precedente.

=IFERROR(IF(ScheduledPayment<=G9, ScheduledPayment, G9+G9*InterestRate/PaymentsPerYear), "")

Come ulteriore precauzione, avvolgiamo questa e tutte le formule successive nella funzione IFERROR, in modo da evitare una serie di errori vari se alcune delle celle di input sono vuote o contengono valori non validi.

Pagamento extra (C10):

Utilizzare una formula IF con la seguente logica:

Se il Pagamento extra (denominata cella C6) è inferiore alla differenza tra il saldo residuo e il capitale di questo periodo (G9-E10), restituire Pagamento extra altrimenti utilizzare la differenza.

=IFERROR(IF(ExtraPayment

Suggerimento: se avete pagamenti aggiuntivi variabili è sufficiente digitare i singoli importi direttamente nel campo Pagamento extra colonna.

Pagamento totale (D10)

È sufficiente aggiungere il pagamento programmato (B10) e il pagamento extra (C10) per il periodo corrente:

=IFERROR(B10+C10, "")

Principale (E10)

Se il pagamento programmato per un determinato periodo è maggiore di zero, restituisce il più piccolo dei due valori: il pagamento programmato meno gli interessi (B10-F10) o il saldo residuo (G9); altrimenti restituisce zero.

=IFERROR(IF(B10>0, MIN(B10-F10, G9), 0), "")

Si prega di notare che il committente comprende solo la parte di pagamento programmato (non il pagamento extra!) che va a finanziare il capitale del prestito.

Interesse (F10)

Se il pagamento programmato per un determinato periodo è maggiore di zero, dividere il tasso di interesse annuo (denominato cella C2) per il numero di pagamenti all'anno (denominato cella C4) e moltiplicare il risultato per il saldo rimanente dopo il periodo precedente; in caso contrario, restituire 0.

=IFERROR(IF(B10>0, Interessi/PagamentiPerAnno*G9, 0), "")

Equilibrio (G10)

Se il saldo rimanente (G9) è maggiore di zero, sottrarre la quota capitale del pagamento (E10) e il pagamento extra (C10) dal saldo rimanente dopo il periodo precedente (G9); altrimenti restituire 0.

=IFERROR(IF(G9>0, G9-E10-C10, 0), "")

Nota: poiché alcune formule si incrociano tra loro (non si tratta di un riferimento circolare!), è possibile che durante il processo vengano visualizzati risultati errati. Pertanto, non iniziare la risoluzione dei problemi prima di aver inserito l'ultima formula nella tabella di ammortamento.

Se tutto è stato fatto correttamente, a questo punto il piano di ammortamento del prestito dovrebbe essere simile a questo:

5. Nascondere i periodi supplementari

Impostate una regola di formattazione condizionale per nascondere i valori nei periodi non utilizzati, come spiegato in questo suggerimento. La differenza è che questa volta applichiamo il parametro colore del carattere bianco alle righe in cui Pagamento totale (colonna D) e Equilibrio (colonna G) sono uguali a zero o vuoti:

=E(OR($D9=0, $D9=""), OR($G9=0, $G9=""))

Voilà, tutte le righe con valori pari a zero sono nascoste alla vista:

6. Fare un riepilogo del prestito

Come tocco finale di perfezione, è possibile ottenere le informazioni più importanti su un prestito utilizzando queste formule:

Numero di pagamenti programmati:

Moltiplicare il numero di anni per il numero di pagamenti all'anno:

=Termine del prestito*Pagamenti per anno

Numero effettivo di pagamenti:

Conta le cellule nel Pagamento totale che sono maggiori di zero, a partire dal Periodo 1:

=COUNTIF(D10:D369,">"&0)

Totale pagamenti extra:

Sommare le celle della tabella Pagamento extra colonna, a partire dal Periodo 1:

=SOMMA(C10:C369)

Interessi totali:

Sommare le celle della tabella Interesse colonna, a partire dal Periodo 1:

=SOMMA(F10:F369)

Opzionalmente, si può nascondere il campo Periodo 0 e il piano di ammortamento del prestito con pagamenti aggiuntivi è pronto! La schermata seguente mostra il risultato finale:

Scarica il piano di ammortamento del prestito con le rate extra

Modello di piano di ammortamento in Excel

Per creare in poco tempo un piano di ammortamento del prestito di altissimo livello, è possibile utilizzare i modelli integrati di Excel: basta andare su File > Nuovo , tipo " piano di ammortamento " nella casella di ricerca e scegliete il modello che preferite, ad esempio questo con pagamenti extra:

Quindi salvate la cartella di lavoro appena creata come modello di Excel e riutilizzatela quando volete.

Ecco come si crea un piano di ammortamento di un prestito o di un mutuo in Excel. Vi ringrazio per la lettura e spero di vedervi sul nostro blog la prossima settimana!

Download disponibili

Esempi di piani di ammortamento (file .xlsx)