Tento návod ukazuje, ako zostaviť amortizačný plán v programe Excel na podrobné informácie o pravidelných platbách amortizovaného úveru alebo hypotéky.

. amortizovaný úver je len módny spôsob, ako definovať úver, ktorý sa spláca v splátkach počas celej doby splatnosti.

V podstate všetky úvery sú tak či onak amortizované. Napríklad plne amortizovaný úver na 24 mesiacov bude mať 24 rovnakých mesačných splátok. Každá splátka sa použije na istinu a časť na úrok. Ak chcete podrobne opísať každú splátku úveru, môžete si zostaviť amortizačný plán úveru.

. amortizačný plán je tabuľka, v ktorej sú uvedené pravidelné splátky úveru alebo hypotéky v priebehu času, každá splátka je rozdelená na istinu a úrok a po každej splátke je uvedený zostatok.

Ako vytvoriť plán amortizácie úveru v programe Excel

Na zostavenie amortizačného plánu úveru alebo hypotéky v programe Excel budeme musieť použiť nasledujúce funkcie:

• Funkcia PMT - vypočíta celková suma pravidelnej splátky. Táto suma zostáva konštantná počas celého trvania úveru.
• Funkcia PPMT - získava hlavný časť každej splátky, ktorá ide na istinu úveru, t. j. sumu, ktorú ste si požičali. Táto suma sa pri ďalších splátkach zvyšuje.
• Funkcia IPMT - nájde úrok časť každej platby, ktorá ide na úhradu úrokov. Táto suma sa každou platbou znižuje.

Prejdime si teraz tento proces krok za krokom.

1. Nastavte amortizačnú tabuľku

Na začiatok definujte vstupné bunky, do ktorých budete zadávať známe zložky úveru:

• C2 - ročná úroková sadzba
• C3 - doba splatnosti úveru v rokoch
• C4 - počet platieb za rok
• C5 - výška úveru

Ďalej vytvoríte amortizačnú tabuľku s označením ( Obdobie , Platba , Úroky , Hlavná stránka , Bilancia ) v A7:E7. V Obdobie stĺpca zadajte rad čísel rovnajúci sa celkovému počtu platieb (v tomto príklade 1- 24):

Keď máme všetky známe komponenty, prejdime k najzaujímavejšej časti - vzorcom amortizácie úveru.

2. Vypočítajte celkovú sumu platby (vzorec PMT)

Výška platby sa vypočíta pomocou funkcie PMT(rate, nper, pv, [fv], [type]).

Ak chcete správne spracovať rôzne frekvencie platieb (napríklad týždenné, mesačné, štvrťročné atď.), mali by ste byť konzistentní s hodnotami zadanými pre sadzba a nper argumenty:

• Hodnotenie - vydeľte ročnú úrokovú sadzbu počtom splátkových období za rok ($C$2/$C$4).
• Nper - vynásobte počet rokov počtom platobných období za rok ($C$3*$C$4).
• Pre pv argument, zadajte sumu pôžičky ($C$5).
• Stránka fv a typ argumenty môžeme vynechať, pretože ich predvolené hodnoty nám vyhovujú (zostatok po poslednej platbe má byť 0; platby sa vykonávajú na konci každého obdobia).

Ak spojíme vyššie uvedené argumenty, dostaneme tento vzorec:

=PMT($C$2/$C$4, $C$3*$C$4, $C$5)

Dávajte pozor na to, že používame absolútne odkazy na bunky, pretože tento vzorec by sa mal skopírovať do nižšie uvedených buniek bez akýchkoľvek zmien.

Zadajte vzorec PMT do stĺpca B8, potiahnite ho nadol a uvidíte konštantnú sumu platby pre všetky obdobia:

3. Vypočítajte úrok (vzorec IPMT)

Na zistenie úrokovej časti každej periodickej platby použite funkciu IPMT(rate, per, nper, pv, [fv], [type]):

=IPMT($C$2/$C$4, A8, $C$3*$C$4, $C$5)

Všetky argumenty sú rovnaké ako vo vzorci PMT, okrem na argument, ktorý určuje obdobie platby. Tento argument sa dodáva ako relatívny odkaz na bunku (A8), pretože sa má meniť na základe relatívnej polohy riadku, do ktorého sa vzorec kopíruje.

Tento vzorec sa prenesie do bunky C8 a potom ho skopírujete do toľkých buniek, koľko potrebujete:

4. Nájdite istinu (vzorec PPMT)

Na výpočet časti istiny každej pravidelnej platby použite tento vzorec PPMT:

=PPMT($C$2/$C$4, A8, $C$3*$C$4, $C$5)

Syntax a argumenty sú presne rovnaké ako vo vzorci IPMT, o ktorom sme hovorili vyššie:

Tento vzorec prechádza do stĺpca D, začínajúceho v D8:

Tip. Ak chcete skontrolovať, či sú vaše výpočty v tomto bode správne, spočítajte čísla v Hlavná stránka a Úroky Súčet by sa mal rovnať hodnote v stĺpci Platba stĺpec v tom istom riadku.

5. Získajte zostávajúci zostatok

Na výpočet zostatku za každé obdobie použijeme dva rôzne vzorce.

Ak chcete zistiť zostatok po prvej splátke v E8, spočítajte sumu úveru (C5) a istinu za prvé obdobie (D8):

=C5+D8

Keďže suma úveru je kladné číslo a istina je záporné číslo, od prvej sumy sa v skutočnosti odpočíta druhá suma.

Pre druhé a všetky nasledujúce obdobia sčítajte predchádzajúci zostatok a istinu tohto obdobia:

=E8+D9

Vyššie uvedený vzorec prejde do E9 a potom ho skopírujete do stĺpca. Vďaka použitiu relatívnych odkazov na bunky sa vzorec správne upraví pre každý riadok.

To je všetko! Náš mesačný plán amortizácie úveru je hotový:

Tip: Vráťte platby ako kladné čísla

Keďže pôžička sa vypláca z vášho bankového účtu, funkcie programu Excel vrátia platbu, úrok a istinu ako záporné čísla V predvolenom nastavení sú tieto hodnoty zvýraznené červenou farbou a uzavreté v zátvorkách, ako môžete vidieť na obrázku vyššie.

Ak chcete mať všetky výsledky ako pozitívne pred funkcie PMT, IPMT a PPMT vložte znamienko mínus.

Pre Bilancia vzorce, namiesto sčítania použite odčítanie, ako je znázornené na nasledujúcom obrázku:

Amortizačný plán pre premenlivý počet období

V uvedenom príklade sme zostavili splátkový kalendár úveru pre vopred definovaný počet splátkových období. Toto rýchle jednorazové riešenie dobre funguje pre konkrétny úver alebo hypotéku.

Ak chcete vytvoriť opakovane použiteľný amortizačný plán s premenlivým počtom období, budete musieť použiť komplexnejší prístup opísaný nižšie.

1. Zadajte maximálny počet období

V Obdobie stĺpca vložte maximálny počet splátok, ktoré povolíte pre akýkoľvek úver, napríklad od 1 do 360. Na rýchlejšie zadanie radu čísel môžete využiť funkciu automatického vypĺňania programu Excel.

2. Používanie príkazov IF v amortizačných vzorcoch

Keďže teraz máte veľa nadmerných čísel období, musíte výpočty nejakým spôsobom obmedziť na skutočný počet splátok pre konkrétnu pôžičku. To možno urobiť tak, že každý vzorec zabalíte do príkazu IF. Logický test príkazu IF kontroluje, či je číslo obdobia v aktuálnom riadku menšie alebo rovné celkovému počtu splátok. Ak je logický test TRUE, príslušnýfunkcia sa vypočíta; ak je FALSE, vráti sa prázdny reťazec.

Za predpokladu, že Obdobie 1 je v riadku 8, zadajte do príslušných buniek nasledujúce vzorce a potom ich skopírujte do celej tabuľky.

Platba (B8):

=IF(A8<=$C$3*$C$4, PMT($C$2/$C$4, $C$3*$C$4, $C$5), "")

Úroky (C8):

=IF(A8<=$C$3*$C$4, IPMT($C$2/$C$4, A8, $C$3*$C$4, $C$5), "")

Hlavná stránka (D8):

=IF(A8<=$C$3*$C$4,PPMT($C$2/$C$4, A8, $C$3*$C$4, $C$5), "")

Bilancia :

Pre Obdobie 1 (E8), vzorec je rovnaký ako v predchádzajúcom príklade:

=C5+D8

Pre Obdobie 2 (E9) a všetky nasledujúce obdobia má vzorec tento tvar:

=IF(A9<=$C$3*$C$4, E8+D9, "")

Výsledkom je správne vypočítaný amortizačný plán a niekoľko prázdnych riadkov s číslami období po splatení úveru.

3. Skryť ďalšie čísla periód

Ak dokážete žiť s množstvom zbytočných čísiel bodiek zobrazených po poslednej platbe, môžete považovať prácu za hotovú a tento krok preskočiť. Ak sa snažíte o dokonalosť, skryte všetky nepoužívané bodky vytvorením pravidla podmieneného formátovania, ktoré nastaví farba písma na bielu pre všetky riadky po uskutočnení poslednej platby.

Na tento účel vyberte všetky riadky údajov ak je vaša amortizačná tabuľka (v našom prípade A8:E367) a kliknite na Domov karta> Podmienené formátovanie > Nové pravidlo... > Použitie vzorca na určenie buniek, ktoré sa majú formátovať .

Do príslušného poľa zadajte nasledujúci vzorec, ktorý kontroluje, či je číslo obdobia v stĺpci A väčšie ako celkový počet platieb:

=$A8>$C$3*$C$4

Dôležitá poznámka! Aby vzorec podmieneného formátovania fungoval správne, nezabudnite použiť absolútne odkazy na bunky Doba splatnosti úveru a Platby za rok buniek, ktoré vynásobíte ($C$3*$C$4). Súčin sa porovná s Obdobie 1 bunka, pre ktorú používate zmiešaný odkaz na bunku - absolútny stĺpec a relatívny riadok ($A8).

Potom kliknite na Formát... a vyberte bielu farbu písma. Hotovo!

4. Vypracujte prehľad pôžičiek

Ak chcete na prvý pohľad zobraziť súhrnné informácie o svojom úvere, pridajte do hornej časti plánu amortizácie niekoľko ďalších vzorcov.

Celkové platby (F2):

=-SUM(B8:B367)

Celkový úrok (F3):

=-SUM(C8:C367)

Ak máte platby ako kladné čísla, odstráňte z uvedených vzorcov znamienko mínus.

To je všetko! Náš plán amortizácie úveru je hotový a môže sa začať!

Stiahnite si amortizačný plán úveru pre Excel

Ako vytvoriť plán amortizácie úveru s dodatočnými splátkami v programe Excel

Amortizačné plány, o ktorých sme hovorili v predchádzajúcich príkladoch, sa dajú ľahko vytvoriť a dodržiavať (dúfajme :). Vynechávajú však užitočnú funkciu, o ktorú majú mnohí splácatelia úverov záujem - dodatočné splátky na rýchlejšie splatenie úveru. V tomto príklade sa pozrieme na to, ako vytvoriť amortizačný plán úveru s dodatočnými splátkami.

1. Definujte vstupné bunky

Ako zvyčajne začnite s nastavením vstupných buniek. V tomto prípade pomenujme tieto bunky tak, ako je napísané nižšie, aby boli naše vzorce ľahšie čitateľné:

• Úroková sadzba - C2 (ročná úroková sadzba)
• LoanTerm - C3 (doba splatnosti úveru v rokoch)
• Platby za rok - C4 (počet platieb za rok)
• LoanAmount - C5 (celková výška úveru)
• ExtraPayment - C6 (dodatočná platba za obdobie)

2. Vypočítajte plánovanú platbu

Okrem vstupných buniek je pre naše ďalšie výpočty potrebná ešte jedna preddefinovaná bunka - plánovaná výška platby , t. j. suma, ktorú treba zaplatiť za úver, ak sa nevykonajú žiadne dodatočné splátky. Táto suma sa vypočíta podľa nasledujúceho vzorca:

=IFERROR(-PMT(InterestRate/PaymentsPerYear, LoanTerm*PaymentsPerYear, LoanAmount), "")

Dávajte pozor, aby sme pred funkciu PMT vložili znamienko mínus, aby bol výsledok kladné číslo. Aby sme zabránili chybám v prípade, že niektoré vstupné bunky sú prázdne, vzorec PMT uzavrieme do funkcie IFERROR.

Zadajte tento vzorec do niektorej bunky (v našom prípade G2) a pomenujte ju ScheduledPayment .

3. Nastavenie amortizačnej tabuľky

Vytvorte tabuľku amortizácie pôžičky so záhlaviami zobrazenými na snímke obrazovky nižšie. Obdobie stĺpec zadajte sériu čísel začínajúcich nulou (môžete skryť Obdobie 0 riadok neskôr, ak je to potrebné).

Ak chcete vytvoriť opakovane použiteľný plán amortizácie, zadajte maximálny možný počet splátkových období (v tomto príklade 0 až 360).

Pre Obdobie 0 (v našom prípade riadok 9), vytiahnite Bilancia hodnota, ktorá sa rovná pôvodnej výške úveru. Všetky ostatné bunky v tomto riadku zostanú prázdne:

Vzorec v G9:

=Výška pôžičky

4. Zostavte vzorce pre amortizačný plán s dodatočnými platbami

Toto je kľúčová časť našej práce. Keďže vstavané funkcie programu Excel neposkytujú ďalšie platby, budeme musieť všetky výpočty vykonať sami.

Poznámka: V tomto príklade, Obdobie 0 je v riadku 9 a Obdobie 1 je v riadku 10. Ak vaša amortizačná tabuľka začína v inom riadku, nezabudnite zodpovedajúcim spôsobom upraviť odkazy na bunky.

Do riadku 10 zadajte tieto vzorce ( Obdobie 1 ) a potom ich skopírujte pre všetky zostávajúce obdobia.

Plánovaná platba (B10):

Ak sa ScheduledPayment suma (pomenovaná bunka G2) je menšia alebo rovná zostatku (G9), použite plánovanú platbu. V opačnom prípade pripočítajte zostatok a úrok za predchádzajúci mesiac.

=IFERROR(IF(ScheduledPayment<=G9, ScheduledPayment, G9+G9*InterestRate/PaymentsPerYear), "")

Ako dodatočnú prevenciu zabalíme tento a všetky nasledujúce vzorce do funkcie IFERROR. Zabránime tak množstvu rôznych chýb, ak sú niektoré vstupné bunky prázdne alebo obsahujú neplatné hodnoty.

Dodatočná platba (C10):

Použite vzorec IF s nasledujúcou logikou:

Ak sa ExtraPayment suma (označená ako bunka C6) je nižšia ako rozdiel medzi zostatkom a istinou za toto obdobie (G9-E10), vráťte ExtraPayment ; inak použite rozdiel.

=IFERROR(IF(ExtraPayment

Tip. Ak máte variabilné dodatočné platby , stačí zadať jednotlivé sumy priamo do Dodatočná platba stĺpec.

Celková platba (D10)

Jednoducho pripočítajte plánovanú platbu (B10) a mimoriadnu platbu (C10) za aktuálne obdobie:

=IFERROR(B10+C10, "")

Hlavná stránka (E10)

Ak je plánovaná platba za dané obdobie väčšia ako nula, vráti sa menšia z dvoch hodnôt: plánovaná platba mínus úrok (B10-F10) alebo zostatok (G9); inak sa vráti nula.

=IFERROR(IF(B10>0, MIN(B10-F10, G9), 0), "")

Upozorňujeme, že istina zahŕňa len časť plánovaná platba (nie mimoriadnu splátku!), ktorá ide na splácanie istiny úveru.

Úroky (F10)

Ak je splátka rozvrhu pre dané obdobie väčšia ako nula, vydeľte ročnú úrokovú sadzbu (bunka C2) počtom splátok za rok (bunka C4) a výsledok vynásobte zostatkom po predchádzajúcom období; inak vráťte 0.

=IFERROR(IF(B10>0, InterestRate/PaymentsPerYear*G9, 0), "")

Bilancia (G10)

Ak je zostatok (G9) väčší ako nula, od zostatku po predchádzajúcom období (G9) odpočítajte časť istiny (E10) a doplatok (C10); inak vráťte 0.

=IFERROR(IF(G9>0, G9-E10-C10, 0), "")

Poznámka: Keďže niektoré vzorce sa navzájom odkazujú (nie sú to kruhové odkazy!), môžu sa v priebehu procesu zobrazovať nesprávne výsledky. Preto nezačínajte s riešením problémov, kým nezadáte úplne posledný vzorec v amortizačnej tabuľke.

Ak je všetko vykonané správne, váš plán amortizácie úveru by mal v tomto momente vyzerať približne takto:

5. Skryť hodiny navyše

Nastavte pravidlo podmieneného formátovania na skrytie hodnôt v nepoužitých bodkách, ako je vysvetlené v tomto tipe. Rozdiel je v tom, že tentoraz použijeme biela farba písma do riadkov, v ktorých Celková platba (stĺpec D) a Bilancia (stĺpec G) sa rovnajú nule alebo sú prázdne:

=AND(OR($D9=0, $D9=""), OR($G9=0, $G9=""))

Voilà, všetky riadky s nulovými hodnotami sa skryjú:

6. Vypracujte prehľad pôžičiek

Na záver môžete pomocou týchto vzorcov vypísať najdôležitejšie informácie o pôžičke:

Plánovaný počet platieb:

Vynásobte počet rokov počtom platieb za rok:

=LoanTerm*PaymentsPerYear

Skutočný počet platieb:

Počítajte bunky v Celková platba ktoré sú väčšie ako nula, počnúc obdobím 1:

=COUNTIF(D10:D369,">"&0)

Celkové dodatočné platby:

Sčítajte bunky v Dodatočná platba stĺpec, počnúc obdobím 1:

=SUM(C10:C369)

Celkový záujem:

Sčítajte bunky v Úroky stĺpec, počnúc obdobím 1:

=SUM(F10:F369)

Voliteľne skryte Obdobie 0 a váš plán amortizácie úveru s ďalšími splátkami je hotový! Na nasledujúcom obrázku je zobrazený konečný výsledok:

Stiahnite si amortizačný plán úveru s dodatočnými splátkami

Amortizačný plán šablóna Excel

Ak chcete v okamihu vytvoriť špičkový plán amortizácie úveru, využite vstavané šablóny programu Excel. Stačí prejsť na Súbor > Nový , zadajte " amortizačný plán " a vyberte šablónu, ktorá sa vám páči, napríklad túto s dodatočnými platbami:

Potom uložte novovytvorený zošit ako šablónu programu Excel a použite ho kedykoľvek budete chcieť.

Takto si v programe Excel vytvoríte amortizačný plán úveru alebo hypotéky. Ďakujem vám za prečítanie a dúfam, že sa na našom blogu uvidíme budúci týždeň!

Dostupné súbory na stiahnutie

Príklady amortizačného plánu (.xlsx súbor)