Samouczek pokazuje, jak zbudować harmonogram amortyzacji w programie Excel, aby wyszczególnić okresowe płatności z tytułu amortyzowanego kredytu lub pożyczki hipotecznej.

An kredyt amortyzacyjny to tylko wymyślny sposób na określenie kredytu, który jest spłacany w ratach przez cały okres kredytowania.

Zasadniczo, wszystkie pożyczki są amortyzowane w taki czy inny sposób. Na przykład, w pełni amortyzowana pożyczka na 24 miesiące będzie miała 24 równe miesięczne płatności. Każda płatność przeznacza część kwoty na kapitał, a część na odsetki. Aby wyszczególnić każdą płatność pożyczki, można zbudować harmonogram amortyzacji pożyczki.

An harmonogram amortyzacji to tabela, która zawiera listę okresowych płatności z tytułu kredytu lub pożyczki hipotecznej w czasie, dzieli każdą płatność na kapitał i odsetki oraz pokazuje pozostałe saldo po każdej płatności.

Jak stworzyć harmonogram amortyzacji kredytu w Excelu

Aby zbudować w Excelu harmonogram amortyzacji kredytu lub pożyczki hipotecznej, będziemy musieli skorzystać z następujących funkcji:

• Funkcja PMT - oblicza suma Kwota ta jest stała przez cały okres trwania kredytu.
• Funkcja PPMT - otrzymuje. główny część każdej płatności, która jest przeznaczana na pokrycie kapitału pożyczki, czyli kwoty, którą pożyczyłeś. Kwota ta wzrasta przy kolejnych płatnościach.
• Funkcja IPMT - znajduje odsetki część każdej płatności, która idzie na odsetki. Ta kwota zmniejsza się z każdą płatnością.

Teraz przejdźmy przez ten proces krok po kroku.

1) Ustawić tabelę amortyzacji

Na początek zdefiniuj komórki wejściowe, w których będziesz wpisywał znane składniki pożyczki:

• C2 - roczna stopa procentowa
• C3 - okres kredytowania w latach
• C4 - liczba płatności w ciągu roku
• C5 - kwota kredytu

Kolejną czynnością jest stworzenie tabeli amortyzacyjnej z etykietami ( Okres , Płatność , Odsetki , Główny , Saldo ) w A7:E7. W Okres kolumna, wpisz ciąg liczb równy całkowitej liczbie płatności (1- 24 w tym przykładzie):

Mając wszystkie znane składniki, przejdźmy do najciekawszej części - formuł amortyzacji kredytu.

Obliczanie całkowitej kwoty płatności (formuła PMT)

Kwota płatności obliczana jest za pomocą funkcji PMT(rate, nper, pv, [fv], [type]).

Aby poprawnie obsłużyć różne częstotliwości płatności (np. tygodniowe, miesięczne, kwartalne itd.), należy zachować spójność z wartościami podawanymi dla opcji stawka oraz nper argumenty:

• Stawka - podzielić roczną stopę procentową przez liczbę okresów płatności w roku ($C$2/$C$4).
• Nper - pomnożyć liczbę lat przez liczbę okresów płatności w roku ($C$3*$C$4).
• Dla pv argument, wprowadź kwotę pożyczki ($C$5).
• Na stronie fv oraz typ argumenty można pominąć, ponieważ ich domyślne wartości działają dla nas dobrze (saldo po ostatniej płatności ma wynosić 0; płatności są dokonywane na koniec każdego okresu).

Składając powyższe argumenty w całość, otrzymujemy taki oto wzór:

=PMT($C$2/$C$4, $C$3*$C$4, $C$5)

Proszę zwrócić uwagę, że używamy bezwzględnych odwołań do komórek, ponieważ formuła ta powinna skopiować się do poniższych komórek bez żadnych zmian.

Wpisz formułę PMT w B8, przeciągnij ją w dół kolumny, a zobaczysz stałą kwotę płatności dla wszystkich okresów:

3) Obliczanie odsetek (wzór IPMT)

Aby znaleźć część odsetkową każdej płatności okresowej, należy użyć funkcji IPMT(rate, per, nper, pv, [fv], [type]):

=IPMT($C$2/$C$4, A8, $C$3*$C$4, $C$5)

Wszystkie argumenty są takie same jak w formule PMT, z wyjątkiem na Argument ten jest podawany jako względne odwołanie do komórki (A8), ponieważ ma się zmieniać w zależności od względnej pozycji wiersza, do którego kopiowana jest formuła.

Ta formuła trafia do C8, a następnie kopiujesz ją w dół do tylu komórek, ile potrzeba:

4. znaleźć kapitał (wzór PPMT)

Aby obliczyć część kapitałową każdej płatności okresowej, należy użyć tego wzoru PPMT:

=PPMT($C$2/$C$4, A8, $C$3*$C$4, $C$5)

Składnia i argumenty są dokładnie takie same jak w omówionej powyżej formule IPMT:

Formuła ta przechodzi do kolumny D, zaczynając od D8:

Wskazówka. Aby sprawdzić, czy Twoje obliczenia są w tym momencie poprawne, zsumuj liczby w Główny oraz Odsetki Suma powinna być równa wartości w kolumnach. Płatność kolumny w tym samym wierszu.

5) Uzyskać pozostałe saldo

Aby obliczyć pozostałe saldo dla każdego okresu, będziemy używać dwóch różnych formuł.

Aby znaleźć saldo po pierwszej wypłacie w E8, należy zsumować kwotę pożyczki (C5) i kapitał pierwszego okresu (D8):

=C5+D8

Ponieważ kwota pożyczki jest liczbą dodatnią, a kapitał jest liczbą ujemną, ta druga jest w rzeczywistości odejmowana od tej pierwszej.

Dla drugiego i wszystkich kolejnych okresów należy zsumować poprzednie saldo i kapitał tego okresu:

=E8+D9

Powyższa formuła trafia do E9, a następnie kopiujesz ją w dół kolumny. Ze względu na użycie względnych odniesień do komórek, formuła dostosowuje się poprawnie dla każdego wiersza.

To wszystko - nasz miesięczny harmonogram amortyzacji kredytu jest gotowy:

Wskazówka: Zwróć płatności jako liczby dodatnie

Ponieważ pożyczka jest wypłacana z twojego konta bankowego, funkcje Excela zwracają płatność, odsetki i kapitał jako liczby ujemne Domyślnie wartości te są wyróżnione na czerwono i ujęte w nawiasy, jak widać na powyższym obrazku.

Jeśli wolisz mieć wszystkie wyniki jako pozytywny liczb, należy postawić znak minus przed funkcjami PMT, IPMT i PPMT.

Dla Saldo formuły, użyj odejmowania zamiast dodawania, jak pokazano na poniższym zrzucie ekranu:

Harmonogram amortyzacji dla zmiennej liczby okresów

W powyższym przykładzie zbudowaliśmy harmonogram amortyzacji kredytu dla zdefiniowanej wcześniej liczby okresów płatności. To szybkie jednorazowe rozwiązanie sprawdza się w przypadku konkretnego kredytu lub pożyczki hipotecznej.

Jeśli chcesz stworzyć harmonogram amortyzacji wielokrotnego użytku ze zmienną liczbą okresów, będziesz musiał zastosować bardziej kompleksowe podejście opisane poniżej.

1. wprowadzenie maksymalnej liczby okresów

W Okres w kolumnie wpisz maksymalną liczbę płatności, jaką zamierzasz dopuścić dla dowolnego kredytu, powiedzmy od 1 do 360. Możesz wykorzystać funkcję autouzupełniania programu Excel, aby szybciej wprowadzić serię liczb.

2. użycie instrukcji IF w formułach amortyzacyjnych

Ponieważ mamy teraz wiele nadmiernych numerów okresów, musimy w jakiś sposób ograniczyć obliczenia do rzeczywistej liczby płatności dla danego kredytu. Można to zrobić poprzez zawarcie każdej formuły w instrukcji IF. Test logiczny instrukcji IF sprawdza, czy numer okresu w bieżącym wierszu jest mniejszy lub równy całkowitej liczbie płatności. Jeśli test logiczny jest TRUE, odpowiednia formułaobliczana jest funkcja; jeśli FALSE, to zwracany jest pusty łańcuch.

Zakładając, że Okres 1 znajduje się w wierszu 8, wprowadź w odpowiednich komórkach następujące formuły, a następnie skopiuj je do całej tabeli.

Płatność (B8):

=IF(A8<=$C$3*$C$4, PMT($C$2/$C$4, $C$3*$C$4, $C$5), "")

Odsetki (C8):

=IF(A8<=$C$3*$C$4, IPMT($C$2/$C$4, A8, $C$3*$C$4, $C$5), "")

Główny (D8):

=IF(A8<=$C$3*$C$4,PPMT($C$2/$C$4, A8, $C$3*$C$4, $C$5), "")

Saldo :

Dla Okres 1 (E8), wzór jest taki sam jak w poprzednim przykładzie:

=C5+D8

Dla Okres 2 (E9) i wszystkich kolejnych okresów, wzór przyjmuje taki kształt:

=IF(A9<=$C$3*$C$4, E8+D9, "")

W efekcie masz poprawnie wyliczony harmonogram amortyzacji i masę pustych wierszy z numerami okresów po spłacie kredytu.

3) Ukryj numery okresów dodatkowych

Jeśli możesz żyć z kilkoma zbędnymi numerami okresów wyświetlanymi po ostatniej płatności, możesz uznać pracę za wykonaną i pominąć ten krok. Jeśli dążysz do perfekcji, ukryj wszystkie nieużywane okresy, tworząc warunkową regułę formatowania, która ustawia wartość kolor czcionki na biały dla dowolnych wierszy po dokonaniu ostatniej wpłaty.

W tym celu należy wybrać wszystkie rzędy danych jeśli Twoja tabela amortyzacji (w naszym przypadku A8:E367) i kliknij Strona główna tab> Formatowanie warunkowe > Nowa zasada... > Użyj formuły, aby określić, które komórki mają być sformatowane .

W odpowiednim polu wprowadź poniższą formułę, która sprawdza, czy numer okresu w kolumnie A jest większy od całkowitej liczby płatności:

=$A8>$C$3*$C$4

Ważna uwaga! Aby formuła formatowania warunkowego działała poprawnie, należy pamiętać o użyciu bezwzględnych odwołań do komórek dla formuły Okres kredytowania oraz Płatności na rok komórek, które się mnoży ($C$3*$C$4). Iloczyn jest porównywany z Okres 1 komórka, dla której używasz mieszanego odwołania do komórki - bezwzględnej kolumny i względnego wiersza ($A8).

Następnie należy kliknąć przycisk Format... i wybierz biały kolor czcionki. gotowe!

4) Zrób podsumowanie pożyczki

Aby w skrócie wyświetlić informacje zbiorcze na temat Twojego kredytu, dodaj jeszcze kilka formuł na górze harmonogramu amortyzacji.

Płatności ogółem (F2):

=-SUM(B8:B367)

Odsetki ogółem (F3):

=-SUM(C8:C367)

Jeśli masz płatności jako liczby dodatnie, usuń znak minus z powyższych wzorów.

To wszystko, nasz harmonogram amortyzacji kredytu jest ukończony i dobry do pracy!

Pobierz harmonogram amortyzacji kredytu dla Excela

Jak zrobić harmonogram amortyzacji kredytu z dodatkowymi płatnościami w Excelu

Harmonogramy amortyzacji omówione w poprzednich przykładach są łatwe do stworzenia i śledzenia (mam nadzieję :). Pomijają jednak przydatną funkcję, którą interesuje się wielu spłacających kredyt - dodatkowe płatności pozwalające na szybszą spłatę kredytu. W tym przykładzie przyjrzymy się, jak stworzyć harmonogram amortyzacji kredytu z dodatkowymi płatnościami.

1) Zdefiniuj komórki wejściowe

Jak zwykle zacznij od ustawienia komórek wejściowych. W tym przypadku nazwijmy te komórki tak jak napisano poniżej, aby nasze formuły były łatwiejsze do odczytania:

• Stopa procentowa - C2 (roczna stopa procentowa)
• LoanTerm - C3 (okres kredytowania w latach)
• PaymentsPerYear - C4 (liczba płatności w ciągu roku)
• LoanAmount - C5 (całkowita kwota pożyczki)
• ExtraPayment - C6 (dodatkowa płatność za okres)

2. obliczenie planowanej płatności

Oprócz komórek wejściowych, do naszych dalszych obliczeń potrzebna jest jeszcze jedna predefiniowana komórka - planowana kwota płatności czyli kwotę, jaką należy zapłacić za kredyt, jeśli nie dokona się żadnych dodatkowych płatności. Kwotę tę oblicza się za pomocą następującego wzoru:

=IFERROR(-PMT(InterestRate/PaymentsPerYear, LoanTerm*PaymentsPerYear, LoanAmount), "")

Zwróć uwagę, że przed funkcją PMT stawiamy znak minus, aby wynik był liczbą dodatnią. Aby uniknąć błędów w przypadku, gdy niektóre komórki wejściowe są puste, formułę PMT umieszczamy w funkcji IFERROR.

Wpisz tę formułę do jakiejś komórki (w naszym przypadku G2) i nadaj jej nazwę ScheduledPayment .

3) Ustawienie tabeli amortyzacyjnej

Utwórz tabelę amortyzacji kredytu z nagłówkami pokazanymi na poniższym zrzucie ekranu.W Okres w kolumnie wpisz serię liczb zaczynających się od zera (możesz ukryć Okres 0 wiersz później w razie potrzeby).

Jeśli chcesz stworzyć harmonogram amortyzacji wielokrotnego użytku, wprowadź maksymalną możliwą liczbę okresów płatności (w tym przykładzie od 0 do 360).

Dla Okres 0 (w naszym przypadku wiersz 9), przeciągnąć Saldo Wszystkie pozostałe komórki w tym wierszu pozostaną puste:

Wzór w G9:

=LoanAmount

4. zbuduj formuły dla harmonogramu amortyzacji z dodatkowymi płatnościami

Jest to kluczowa część naszej pracy. Ponieważ wbudowane funkcje Excela nie przewidują dodatkowych płatności, będziemy musieli wykonać całą matematykę na własną rękę.

Uwaga: w tym przykładzie, Okres 0 jest w rzędzie 9, a Okres 1 jest w wierszu 10. Jeśli tabela amortyzacji zaczyna się w innym wierszu, proszę pamiętać o odpowiednim dostosowaniu odniesień do komórek.

W wierszu 10 wprowadź następujące formuły ( Okres 1 ), a następnie skopiować je dla wszystkich pozostałych okresów.

Planowana płatność (B10):

Jeśli ScheduledPayment Kwota (nazwana komórką G2) jest mniejsza lub równa pozostałemu saldu (G9), użyj zaplanowanej płatności. W przeciwnym razie dodaj pozostałe saldo i odsetki za poprzedni miesiąc.

=IFERROR(IF(ScheduledPayment<=G9, ScheduledPayment, G9+G9*InterestRate/PaymentsPerYear), "")

Jako dodatkowe zabezpieczenie, zawijamy tę i wszystkie kolejne formuły w funkcję IFERROR. Zapobiegnie to powstawaniu szeregu różnych błędów, jeśli niektóre komórki wejściowe są puste lub zawierają nieprawidłowe wartości.

Dodatkowa płatność (C10):

Użyj formuły JEŻELI z następującą logiką:

Jeśli ExtraPayment (nazwana komórka C6) jest mniejsza niż różnica między pozostałym saldem a kapitałem tego okresu (G9-E10), zwróć ExtraPayment ; w przeciwnym razie wykorzystaj różnicę.

=IFERROR(IF(ExtraPayment

Wskazówka. Jeśli masz zmienne płatności dodatkowe , wystarczy wpisać poszczególne kwoty bezpośrednio w Dodatkowa płatność kolumna.

Płatność całkowita (D10)

Wystarczy dodać płatność planowaną (B10) i płatność dodatkową (C10) za bieżący okres:

=IFERROR(B10+C10, "")

Główna (E10)

Jeżeli planowana płatność za dany okres jest większa od zera, to zwracana jest mniejsza z dwóch wartości: planowana płatność minus odsetki (B10-F10) lub pozostałe saldo (G9); w przeciwnym razie zwracane jest zero.

=IFERROR(IF(B10>0, MIN(B10-F10, G9), 0), "")

Należy pamiętać, że zleceniodawca obejmuje tylko część planowana płatność (nie dodatkowej płatności!), która idzie na kapitał pożyczki.

Odsetki (F10)

Jeśli płatność harmonogramu dla danego okresu jest większa od zera, należy podzielić roczną stopę procentową (nazwaną komórką C2) przez liczbę płatności w roku (nazwaną komórką C4) i pomnożyć wynik przez saldo pozostałe po poprzednim okresie; w przeciwnym razie zwrócić 0.

=IFERROR(IF(B10>0, InterestRate/PaymentsPerYear*G9, 0), "")

Saldo (G10)

Jeśli pozostałe saldo (G9) jest większe od zera, to od salda pozostałego po poprzednim okresie (G9) odejmij część główną płatności (E10) i płatność dodatkową (C10); w przeciwnym razie zwróć 0.

=IFERROR(IF(G9>0, G9-E10-C10, 0), "")

Uwaga: Ponieważ niektóre formuły odwołują się do siebie (nie są to odwołania kołowe!), mogą one wyświetlać błędne wyniki w procesie. Dlatego proszę nie rozpoczynać rozwiązywania problemów, dopóki nie wprowadzisz ostatniej formuły do swojej tabeli amortyzacyjnej.

Jeśli wszystko zostało zrobione poprawnie, Twój harmonogram amortyzacji kredytu w tym momencie powinien wyglądać coś takiego:

5. ukryć dodatkowe okresy

Skonfiguruj regułę formatowania warunkowego, aby ukryć wartości w nieużywanych okresach, jak wyjaśniono w tej poradzie. Różnica polega na tym, że tym razem zastosujemy regułę biały kolor czcionki do rzędów, w których Płatność całkowita (kolumna D) oraz Saldo (kolumna G) są równe zero lub puste:

=AND(OR($D9=0, $D9=""), OR($G9=0, $G9=""))

Voilà, wszystkie wiersze z wartościami zerowymi są ukryte przed widokiem:

6) Zrób podsumowanie pożyczki

Jako wykończenie doskonałości, możesz wyprowadzić najważniejsze informacje o kredycie za pomocą tych formuł:

Zaplanowana liczba płatności:

Pomnóż liczbę lat przez liczbę płatności w roku:

=LoanTerm*PaymentsPerYear

Rzeczywista liczba płatności:

Policz komórki w Płatność całkowita kolumny, które są większe od zera, począwszy od okresu 1:

=COUNTIF(D10:D369,">"&0)

Łącznie z dodatkowymi płatnościami:

Zsumuj komórki w Dodatkowa płatność kolumna, zaczynając od okresu 1:

=SUM(C10:C369)

Łączne odsetki:

Zsumuj komórki w Odsetki kolumna, zaczynając od okresu 1:

=SUM(F10:F369)

Opcjonalnie, ukryj Okres 0 wiersz, a twój harmonogram amortyzacji kredytu z dodatkowymi płatnościami jest zrobiony! Poniższy zrzut ekranu pokazuje ostateczny wynik:

Pobierz harmonogram amortyzacji kredytu z dodatkowymi płatnościami

Harmonogram amortyzacji szablon Excel

Aby w krótkim czasie stworzyć najwyższej klasy harmonogram amortyzacji kredytu, skorzystaj z wbudowanych szablonów Excela.Wystarczy przejść do Plik > Nowy , typu " harmonogram amortyzacji " w polu wyszukiwania i wybierz szablon, który Ci się podoba, na przykład ten z dodatkowymi płatnościami:

Następnie zapisz nowo utworzony skoroszyt jako szablon programu Excel i używaj go ponownie, kiedy tylko chcesz.

Tak właśnie tworzysz harmonogram amortyzacji kredytu lub pożyczki hipotecznej w Excelu. Dziękuję za przeczytanie i mam nadzieję, że zobaczymy się na naszym blogu za tydzień!

Dostępne pliki do pobrania

Przykłady harmonogramu amortyzacji (plik .xlsx)