Šajā pamācībā ir parādīts, kā programmā Excel izveidot amortizācijas grafiku, lai detalizēti aprakstītu periodiskos maksājumus par amortizējamu aizdevumu vai hipotēku.

An amortizējošs aizdevums tā ir tikai iedomāts veids, kā definēt aizdevumu, kas tiek atmaksāts pa daļām visā aizdevuma termiņā.

Būtībā visi aizdevumi ir tādā vai citādā veidā amortizējami. Piemēram, pilnībā amortizējamam aizdevumam uz 24 mēnešiem būs 24 vienādi ikmēneša maksājumi. Katrā maksājumā daļa summas tiek novirzīta pamatsummai un daļa - procentiem. Lai detalizēti aprakstītu katru aizdevuma maksājumu, varat izveidot aizdevuma amortizācijas grafiku.

An amortizācijas grafiks ir tabula, kurā ir uzskaitīti periodiskie maksājumi par aizdevumu vai hipotēku laika gaitā, katrs maksājums sadalīts pamatsummā un procentos un norādīts atlikums pēc katra maksājuma.

Kā izveidot aizdevuma amortizācijas grafiku programmā Excel

Lai izveidotu aizdevuma vai hipotēkas amortizācijas grafiku programmā Excel, mums būs jāizmanto šādas funkcijas:

• PMT funkcija - aprēķina kopējā summa Šī summa ir nemainīga visā aizdevuma darbības laikā.
• PPMT funkcija - iegūst galvenais katra maksājuma daļu, kas tiek novirzīta aizdevuma pamatsummai, t. i., aizņēmuma summai. Šī summa palielinās nākamajiem maksājumiem.
• IPMT funkcija - atrod procenti katra maksājuma daļa, kas tiek novirzīta procentu maksājumiem. Šī summa samazinās ar katru maksājumu.

Tagad soli pa solim izstaigāsim šo procesu.

1. Amortizācijas tabulas iestatīšana

Vispirms definējiet ievades šūnas, kurās ievadīsiet zināmās aizdevuma sastāvdaļas:

• C2 - gada procentu likme
• C3 - aizdevuma termiņš gados
• C4 - maksājumu skaits gadā
• C5 - aizdevuma summa

Nākamais uzdevums ir izveidot amortizācijas tabulu ar uzrakstiem ( Periods , Maksājums , Procenti , Galvenais , Līdzsvars ) A7:E7. Periods ailē ievadiet skaitļu virkni, kas vienāda ar kopējo maksājumu skaitu (šajā piemērā 1- 24):

Kad visas zināmās sastāvdaļas ir ieviestas, ķersimies pie interesantākās daļas - aizdevuma amortizācijas formulām.

2. Aprēķiniet kopējo maksājuma summu (PMT formula).

Maksājuma summu aprēķina, izmantojot funkciju PMT(rate, nper, pv, [fv], [type]).

Lai pareizi apstrādātu dažādus maksājumu biežumus (piemēram, iknedēļas, mēneša, ceturkšņa u. c.), jums vajadzētu būt konsekventiem ar vērtībām, kas norādītas parametrā likme un nper argumenti:

• Novērtējiet - daliet gada procentu likmi ar maksājumu periodu skaitu gadā ($C$2/$C$4).
• Nper - reiziniet gadu skaitu ar maksājumu periodu skaitu gadā ($C$3*$C$4).
• Par pv argumentu, ievadiet aizdevuma summu ($C$5).
• Portāls fv un tips argumentus var izlaist, jo to noklusējuma vērtības mums ir piemērotas (atlikumam pēc pēdējā maksājuma jābūt 0; maksājumi tiek veikti katra perioda beigās).

Saliekot iepriekš minētos argumentus kopā, iegūstam šādu formulu:

=PMT($C$2/$C$4, $C$3*$C$4, $C$5)

Lūdzu, pievērsiet uzmanību, ka mēs izmantojam absolūtās šūnu atsauces, jo šai formulai ir jākopē uz zemāk esošajām šūnām bez jebkādām izmaiņām.

Ievadiet PMT formulu B8, velciet to uz leju pa kolonnu, un jūs redzēsiet nemainīgu maksājuma summu visiem periodiem:

3. Aprēķināt procentus (IPMT formula)

Lai noteiktu katra periodiskā maksājuma procentu daļu, izmantojiet funkciju IPMT(rate, per, nper, pv, [fv], [type]):

=IPMT($C$2/$C$4, A8, $C$3*$C$4, $C$5)

Visi argumenti ir tādi paši kā PMT formulā, izņemot argumentu uz Šis arguments tiek sniegts kā relatīva šūnas atsauce (A8), jo tas ir jāmaina atkarībā no rindas relatīvās pozīcijas, uz kuru tiek kopēta formula.

Šī formula tiek ievietota C8, un pēc tam to kopējiet uz leju uz tik daudzām šūnām, cik nepieciešams:

4. Atrodiet pamatsummu (PPMT formula)

Lai aprēķinātu katra periodiskā maksājuma pamatsummas daļu, izmantojiet šo PPMT formulu:

=PPMT($C$2/$C$4, A8, $C$3*$C$4, $C$5)

Sintakse un argumenti ir tieši tādi paši kā iepriekš minētajā IPMT formulā:

Šī formula attiecas uz kolonnu D, sākot ar D8:

Padoms. Lai pārbaudītu, vai jūsu aprēķini šajā brīdī ir pareizi, saskaitiet skaitļus, kas norādīti Galvenais un Procenti slejās. Summai jābūt vienādai ar vērtību, kas norādīta ailē Maksājums slejā tajā pašā rindā.

5. Iegūstiet atlikušo atlikumu

Lai aprēķinātu katra perioda atlikumu, mēs izmantosim divas dažādas formulas.

Lai noteiktu atlikumu pēc pirmā maksājuma E8, saskaitiet aizdevuma summu (C5) un pirmā perioda pamatsummu (D8):

=C5+D8

Tā kā aizdevuma summa ir pozitīvs skaitlis, bet pamatsumma ir negatīvs skaitlis, no pirmās summas faktiski tiek atņemta pamatsumma.

Otrajam un visiem nākamajiem periodiem saskaitiet iepriekšējā perioda atlikumu un šī perioda pamatsummu:

=E8+D9

Iepriekšminētā formula tiek ievietota E9, un pēc tam to kopējiet uz leju pa kolonnu. Pateicoties relatīvo šūnu atsauču izmantošanai, formula tiek pareizi pielāgota katrai rindai.

Tas ir viss! Mūsu ikmēneša aizdevuma amortizācijas grafiks ir gatavs:

Padoms: Atgrieziet maksājumus kā pozitīvus skaitļus

Tā kā aizdevums tiek maksāts no jūsu bankas konta, Excel funkcijas atgriež maksājumu, procentus un pamatsummu kā. negatīvie skaitļi Pēc noklusējuma šīs vērtības ir izceltas sarkanā krāsā un ieliktas iekavās, kā redzams attēlā iepriekš.

Ja vēlaties, lai visi rezultāti būtu pozitīvs pirms PMT, IPMT un PPMT funkcijām ielieciet mīnusa zīmi.

Par Līdzsvars formulas, saskaitīšanas vietā izmantojiet atņemšanu, kā parādīts zemāk redzamajā ekrāna attēlā:

Amortizācijas grafiks mainīgam periodu skaitam

Iepriekš minētajā piemērā mēs izveidojām aizdevuma amortizācijas grafiku iepriekš noteiktam maksājumu periodu skaitam. Šis ātrais vienreizējais risinājums labi darbojas konkrēta aizdevuma vai hipotēkas gadījumā.

Ja vēlaties izveidot atkārtoti lietojamu amortizācijas grafiku ar mainīgu periodu skaitu, jums būs jāizmanto plašāka pieeja, kas aprakstīta tālāk.

1. Ievadiet maksimālo periodu skaitu

In the Periods ailē ierakstiet maksimālo maksājumu skaitu, ko gatavojaties atļaut jebkuram aizdevumam, piemēram, no 1 līdz 360. Varat izmantot Excel automātiskās aizpildīšanas funkciju, lai ātrāk ievadītu skaitļu virkni.

2. Amortizācijas formulās izmantojiet IF izteikumus.

Tā kā tagad jums ir daudzi pārmērīgi lieli periodu numuri, jums ir kaut kā jāierobežo aprēķini līdz faktiskajam maksājumu skaitam konkrētajam aizdevumam. To var izdarīt, katru formulu ietinot IF izteikumā. IF izteikuma loģiskais tests pārbauda, vai perioda numurs pašreizējā rindā ir mazāks vai vienāds ar kopējo maksājumu skaitu. Ja loģiskais tests ir TRUE, tad atbilstošaisfunkcija tiek aprēķināta; ja FALSE, tiek atgriezta tukša virkne.

Pieņemot, ka 1. periods ir 8. rindā, attiecīgajās šūnās ievadiet šādas formulas un pēc tam kopējiet tās visā tabulā.

Maksājums (B8):

=IF(A8<=$C$3*$C$4, PMT($C$2/$C$4, $C$3*$C$4, $C$5), "")

Procenti (C8):

=IF(A8<=$C$3*$C$4, IPMT($C$2/$C$4, A8, $C$3*$C$4, $C$5), "")

Galvenais (D8):

=IF(A8<=$C$3*$C$4,PPMT($C$2/$C$4, A8, $C$3*$C$4, $C$5), "")

Līdzsvars :

Vietnei 1. periods (E8), formula ir tāda pati kā iepriekšējā piemērā:

=C5+D8

Vietnei 2. periods (E9) un visos turpmākajos periodos formula ir šāda:

=IF(A9<=$C$3*$C$4, E8+D9, "")

Rezultātā jums ir pareizi aprēķināts amortizācijas grafiks un virkne tukšu rindu ar periodu numuriem pēc aizdevuma nomaksas.

3. Paslēpt papildu periodu numurus

Ja varat sadzīvot ar vairākiem liekiem periodu skaitļiem, kas tiek rādīti pēc pēdējā maksājuma, varat uzskatīt, ka darbs ir paveikts, un šo soli izlaist. Ja cenšaties sasniegt pilnību, paslēpiet visus neizmantotos periodus, izveidojot nosacījuma formatēšanas noteikumu, kas nosaka fonta krāsu uz baltu par visām rindām pēc pēdējā maksājuma veikšanas.

Šim nolūkam atlasiet visus datu rindas ja jūsu amortizācijas tabula (mūsu gadījumā A8:E367) un noklikšķiniet uz Sākums cilne> Nosacījumu formatēšana > Jauni noteikumi... > Izmantojiet formulu, lai noteiktu, kuras šūnas formatēt .

Attiecīgajā lodziņā ievadiet tālāk norādīto formulu, kas pārbauda, vai perioda numurs A slejā ir lielāks par kopējo maksājumu skaitu:

=$A8>$C$3*$C$4

Svarīga piezīme! Lai nosacītā formatēšanas formula darbotos pareizi, pārliecinieties, ka šūnās Aizdevuma termiņš un Maksājumi gadā šūnas, ko reizināt ($C$3*$C$4). Iegūtais reizinājums tiek salīdzināts ar Periods 1 šūna, kurai tiek izmantota jaukta šūnas atsauce - absolūtā sleja un relatīvā rinda ($A8).

Pēc tam noklikšķiniet uz Formāts... un izvēlieties balto fonta krāsu. Gatavs!

4. Sagatavojiet aizdevuma kopsavilkumu

Lai īsumā apskatītu kopsavilkuma informāciju par savu aizdevumu, amortizācijas grafika augšpusē pievienojiet vēl pāris formulas.

Maksājumu kopsumma (F2):

=-SUM(B8:B367)

Procentu kopsumma (F3):

=-SUM(C8:C367)

Ja maksājumi ir pozitīvi skaitļi, izņemiet mīnusa zīmi no iepriekš minētajām formulām.

Tas ir viss! Mūsu aizdevuma amortizācijas grafiks ir pabeigts un gatavs darbam!

Lejupielādēt aizdevuma amortizācijas grafiku programmā Excel

Kā izveidot aizdevuma amortizācijas grafiku ar papildu maksājumiem programmā Excel

Iepriekšējos piemēros aplūkotos amortizācijas grafikus ir viegli izveidot un ievērot (cerams :). Tomēr tajos nav iekļauta noderīga funkcija, kas interesē daudzus aizdevumu maksātājus, - papildu maksājumi, lai aizdevumu atmaksātu ātrāk. Šajā piemērā aplūkosim, kā izveidot aizdevuma amortizācijas grafiku ar papildu maksājumiem.

1. Definējiet ievades šūnas

Kā parasti, sāciet ar ievades šūnu iestatīšanu. Šajā gadījumā nosauksim šīs šūnas, kā rakstīts tālāk, lai mūsu formulas būtu vieglāk lasāmas:

• Procentu likme - C2 (gada procentu likme)
• LoanTerm - C3 (aizdevuma termiņš gados)
• Maksājumi gadā - C4 (maksājumu skaits gadā)
• LoanAmount - C5 (kopējā aizdevuma summa)
• ExtraPayment - C6 (papildu maksājums par periodu)

2. Aprēķiniet plānoto maksājumu

Papildus ievades šūnām mūsu turpmākajiem aprēķiniem ir nepieciešama vēl viena iepriekš definēta šūna - šūna plānotā maksājuma summa t. i., summa, kas jāmaksā par aizdevumu, ja netiek veikti papildu maksājumi. Šo summu aprēķina pēc šādas formulas:

=IFERROR(-PMT(Procentu likme/maksājumi gadā, Aizdevuma termiņš*maksājumi gadā, Aizdevuma summa), "")

Lūdzu, pievērsiet uzmanību tam, ka pirms PMT funkcijas mēs ieliekam mīnusa zīmi, lai rezultāts būtu pozitīvs skaitlis. Lai novērstu kļūdas gadījumā, ja dažas ievades šūnas ir tukšas, PMT formulu iekļaujam IFERROR funkcijā.

Ievadiet šo formulu kādā šūnā (mūsu gadījumā G2) un nosauciet šo šūnu. ScheduledPayment .

3. Amortizācijas tabulas iestatīšana

Izveidojiet aizdevuma amortizācijas tabulu ar zemāk attēlotajā ekrānšāviņā redzamajām galvenēm. Periods slejā ievadiet virkni skaitļu, kas sākas ar nulli (varat paslēpt 0 periods rindā vēlāk, ja nepieciešams).

Ja vēlaties izveidot atkārtoti lietojamu amortizācijas grafiku, ievadiet maksimālo iespējamo maksājumu periodu skaitu (šajā piemērā no 0 līdz 360).

Vietnei 0 periods (mūsu gadījumā - 9. rinda), velciet Līdzsvars vērtība, kas ir vienāda ar sākotnējo aizdevuma summu. Visas pārējās šūnas šajā rindā paliks tukšas:

Formula G9:

=LoanAmount

4. Izveidojiet amortizācijas grafika formulas ar papildu maksājumiem

Tā kā Excel iebūvētās funkcijas neparedz papildu maksājumus, mums būs jāveic visi aprēķini pašiem.

Piezīme. Šajā piemērā, 0 periods ir 9. rindā un 1. periods Ja amortizācijas tabula sākas citā rindā, lūdzu, attiecīgi pielāgojiet šūnu atsauces.

10. rindā ievadiet šādas formulas ( 1. periods ) un pēc tam nokopējiet tos uz leju visiem atlikušajiem periodiem.

Plānotais maksājums (B10):

Ja ScheduledPayment summa (šūna G2) ir mazāka vai vienāda ar atlikušo atlikumu (G9), izmantojiet plānoto maksājumu. Pretējā gadījumā pieskaitiet atlikušo atlikumu un iepriekšējā mēneša procentus.

=IFERROR(IF(ScheduledPayment<=G9, ScheduledPayment, G9+G9*InterestRate/PaymentsPerYear), "")

Papildus piesardzības nolūkā šo un visas turpmākās formulas ietērpjam funkcijā IFERROR. Tas novērsīs dažādas kļūdas, ja dažas ievades šūnas ir tukšas vai satur nederīgas vērtības.

Papildu maksājums (C10):

Izmantojiet IF formulu ar šādu loģiku:

Ja ExtraPayment summa (šūnā C6) ir mazāka par starpību starp atlikušo atlikumu un šī perioda pamatsummu (G9-E10), atdod atpakaļ ExtraPayment ; citādi izmantojiet starpību.

=IFERROR(IF(ExtraPayment

Padoms. Ja jums ir mainīgie papildu maksājumi , vienkārši ievadiet atsevišķas summas tieši Papildu maksājums sleja.

Kopējais maksājums (D10)

Vienkārši pieskaitiet kārtējā perioda plānoto maksājumu (B10) un papildu maksājumu (C10):

=IFERROR(B10+C10, "")

Galvenais (E10)

Ja grafika maksājums konkrētajam periodam ir lielāks par nulli, atgriež mazāko no divām vērtībām: plānotais maksājums mīnus procenti (B10-F10) vai atlikums (G9); pretējā gadījumā atgriež nulli.

=IFERROR(IF(B10>0, MIN(B10-F10, G9), 0), "")

Lūdzu, ņemiet vērā, ka pamatsumma ietver tikai to daļu no plānotais maksājums (nevis papildu maksājums!), kas tiek novirzīts aizdevuma pamatsummai.

Procenti (F10)

Ja grafika maksājums konkrētajam periodam ir lielāks par nulli, daliet gada procentu likmi (šūna C2) ar maksājumu skaitu gadā (šūna C4) un reiziniet rezultātu ar atlikumu, kas palicis pēc iepriekšējā perioda; pretējā gadījumā atgrieziet 0.

=IFERROR(IF(B10>0, InterestRate/PaymentsPerYear*G9, 0), "")

Līdzsvars (G10)

Ja atlikums (G9) ir lielāks par nulli, no atlikuma, kas palicis pēc iepriekšējā perioda (G9), atņem maksājuma pamatsummas daļu (E10) un papildu maksājumu (C10); pretējā gadījumā atgriež 0.

=IFERROR(IF(G9>0, G9-E10-C10, 0), "")

Piezīme. Tā kā dažas formulas savstarpēji atsaucas viena uz otru (nevis cirkulāra atsauce!), tās var parādīt nepareizus rezultātus. Tāpēc nesāciet novērst problēmas, kamēr amortizācijas tabulā neievadāt pēdējo formulu.

Ja viss ir izdarīts pareizi, jūsu aizdevuma amortizācijas grafikam šajā brīdī vajadzētu izskatīties apmēram šādi:

5. Paslēpt papildu periodus

Iestatiet nosacījuma formatēšanas noteikumu, lai paslēptu vērtības neizmantotajos periodos, kā paskaidrots šajā padomā. Atšķirība ir tāda, ka šoreiz mēs piemērojam balta burtu krāsa rindās, kurās Kopējais maksājums (D aile) un Līdzsvars (sleja G) ir vienādas ar nulli vai tukšas:

=UN(VAI(VAI($D9=0, $D9=""), VAI($G9=0, $G9=""))

Voilà, visas rindas ar nulles vērtībām tiek paslēptas no skata:

6. Sagatavojiet aizdevuma kopsavilkumu

Lai panāktu pilnību, varat izvadīt svarīgāko informāciju par aizdevumu, izmantojot šīs formulas:

Plānotais maksājumu skaits:

Reiziniet gadu skaitu ar maksājumu skaitu gadā:

=LoanTerm*PaymentsPerYear

Faktiskais maksājumu skaits:

Skaitīt šūnas Kopējais maksājums slejā, kas ir lielākas par nulli, sākot ar 1. periodu:

=COUNTIF(D10:D369,">"&0)

Papildu maksājumu kopsumma:

Saskaitiet šūnas Papildu maksājums slejā, sākot ar 1. periodu:

=SUM(C10:C369)

Kopējie procenti:

Saskaitiet šūnas Procenti slejā, sākot ar 1. periodu:

=SUM(F10:F369)

Pēc izvēles paslēpiet 0 periods rindu, un aizdevuma amortizācijas grafiks ar papildu maksājumiem ir izveidots! Ekrānšā attēlā redzams galīgais rezultāts:

Lejupielādēt aizdevuma amortizācijas grafiku ar papildu maksājumiem

Amortizācijas grafiks Excel veidne

Lai īsā laikā sastādītu kvalitatīvu aizdevuma amortizācijas grafiku, izmantojiet Excel iebūvētās veidnes. Vienkārši dodieties uz Faili > Jauns , tips " amortizācijas grafiks " meklēšanas lodziņā un izvēlieties sev tīkamu veidni, piemēram, šo ar papildu maksājumiem:

Pēc tam saglabājiet jaunizveidoto darbgrāmatu kā Excel veidni un izmantojiet to atkārtoti, kad vien vēlaties.

Lūk, kā Excel programmā izveidot aizdevuma vai hipotēkas amortizācijas grafiku. Paldies, ka izlasījāt, un ceru, ka nākamnedēļ tiksimies mūsu blogā!

Pieejamās lejupielādes

Amortizācijas grafika piemēri (.xlsx fails)