Acest tutorial arată cum se construiește un grafic de amortizare în Excel pentru a detalia plățile periodice ale unui împrumut sau ipotecă cu amortizare.

Un împrumut cu amortizare este doar un mod sofisticat de a defini un împrumut care este rambursat în rate pe întreaga durată a împrumutului.

Practic, toate împrumuturile sunt amortizante într-un fel sau altul. De exemplu, un împrumut cu amortizare completă pe 24 de luni va avea 24 de plăți lunare egale. Fiecare plată aplică o anumită sumă pentru principal și o parte pentru dobândă. Pentru a detalia fiecare plată a unui împrumut, puteți construi un grafic de amortizare a împrumutului.

Un grafic de amortizare este un tabel care enumeră plățile periodice ale unui împrumut sau ale unei ipoteci de-a lungul timpului, defalcă fiecare plată în principal și dobândă și arată soldul rămas după fiecare plată.

Cum se creează un program de amortizare a împrumuturilor în Excel

Pentru a construi un grafic de amortizare a unui împrumut sau a unei ipoteci în Excel, va trebui să folosim următoarele funcții:

• Funcția PMT - calculează suma totală Această sumă rămâne constantă pe întreaga durată a împrumutului.
• Funcția PPMT - obține principal partea din fiecare plată care se alocă principalului împrumutului, adică suma pe care ați împrumutat-o. Această sumă crește la plățile ulterioare.
• Funcția IPMT - găsește dobândă partea din fiecare plată care este destinată dobânzilor. Această sumă scade la fiecare plată.

Acum, haideți să parcurgem procesul pas cu pas.

1. Configurați tabelul de amortizare

Pentru început, definiți celulele de intrare în care veți introduce componentele cunoscute ale unui împrumut:

• C2 - rata anuală a dobânzii
• C3 - durata împrumutului în ani
• C4 - numărul de plăți pe an
• C5 - valoarea împrumutului

Următorul lucru pe care trebuie să-l faceți este să creați un tabel de amortizare cu etichetele ( Perioada , Plata , Dobânda , Principal , Balanță ) în A7:E7. În Perioada introduceți o serie de numere egale cu numărul total de plăți (1- 24 în acest exemplu):

Având în vedere toate componentele cunoscute, să trecem la partea cea mai interesantă - formulele de amortizare a creditelor.

2. Calculați suma totală de plată (formula PMT)

Suma de plată se calculează cu ajutorul funcției PMT(rate, nper, pv, [fv], [type]).

Pentru a gestiona corect diferite frecvențe de plată (cum ar fi săptămânală, lunară, trimestrială etc.), trebuie să fiți consecvent cu valorile furnizate pentru parametrii rata și nper argumente:

• Tarif - împărțiți rata anuală a dobânzii la numărul de perioade de plată pe an ($C$2/$C$4).
• Nper - se înmulțește numărul de ani cu numărul de perioade de plată pe an ($C$3*$C$4).
• Pentru pv introduceți suma împrumutului ($C$5).
• The fv și tip pot fi omise, deoarece valorile lor implicite funcționează foarte bine pentru noi (soldul după ultima plată ar trebui să fie 0; plățile sunt efectuate la sfârșitul fiecărei perioade).

Punând cap la cap argumentele de mai sus, obținem această formulă:

=PMT($C$2/$C$4, $C$3*$C$4, $C$5)

Vă rugăm să fiți atenți la faptul că folosim referințe absolute de celule, deoarece această formulă trebuie să fie copiată în celulele de mai jos fără nicio modificare.

Introduceți formula PMT în B8, trageți-o în josul coloanei și veți vedea o sumă de plată constantă pentru toate perioadele:

3. Calculați dobânda (formula IPMT)

Pentru a afla partea de dobândă a fiecărei plăți periodice, utilizați funcția IPMT(rate, per, nper, pv, [fv], [type]):

=IPMT($C$2/$C$4, A8, $C$3*$C$4, $C$5)

Toate argumentele sunt aceleași ca în formula PMT, cu excepția pe care specifică perioada de plată. Acest argument este furnizat ca referință de celulă relativă (A8), deoarece se presupune că se modifică în funcție de poziția relativă a unui rând în care este copiată formula.

Această formulă merge în C8, iar apoi o copiați în câte celule sunt necesare:

4. Găsiți principalul (formula PPMT)

Pentru a calcula partea de principal a fiecărei plăți periodice, utilizați această formulă PPMT:

=PPMT($C$2/$C$4, A8, $C$3*$C$4, $C$5)

Sintaxa și argumentele sunt exact aceleași ca în formula IPMT discutată mai sus:

Această formulă merge în coloana D, începând cu D8:

Sfat. Pentru a verifica dacă calculele dvs. sunt corecte în acest moment, adunați numerele din Principal și Dobânda Suma trebuie să fie egală cu valoarea din coloana Plata din același rând.

5. Obțineți soldul rămas

Pentru a calcula soldul rămas pentru fiecare perioadă, vom folosi două formule diferite.

Pentru a afla soldul după prima plată din E8, adunați suma împrumutului (C5) și principalul din prima perioadă (D8):

=C5+D8

Deoarece suma împrumutului este un număr pozitiv, iar principalul este un număr negativ, acesta din urmă este de fapt scăzut din primul.

Pentru a doua perioadă și pentru toate perioadele următoare, adunați soldul precedent și principalul din această perioadă:

=E8+D9

Formula de mai sus ajunge la E9, apoi o copiați în josul coloanei. Datorită utilizării referințelor relative la celule, formula se ajustează corect pentru fiecare rând.

Gata! Programul nostru lunar de amortizare a împrumutului este gata:

Sfat: Returnați plățile ca numere pozitive

Deoarece un împrumut este plătit din contul bancar, funcțiile Excel returnează plata, dobânda și principalul ca numere negative În mod implicit, aceste valori sunt evidențiate cu roșu și incluse între paranteze, după cum puteți vedea în imaginea de mai sus.

Dacă preferați să aveți toate rezultatele ca pozitiv se pune semnul minus înaintea funcțiilor PMT, IPMT și PPMT.

Pentru Balanță formule, utilizați scăderea în loc de adunare, așa cum se arată în imaginea de mai jos:

Schema de amortizare pentru un număr variabil de perioade

În exemplul de mai sus, am construit un grafic de amortizare a împrumutului pentru numărul predefinit de perioade de plată. Această soluție rapidă și unică funcționează bine pentru un anumit împrumut sau ipotecă.

Dacă doriți să creați un program de amortizare reutilizabil cu un număr variabil de perioade, va trebui să adoptați o abordare mai cuprinzătoare, descrisă mai jos.

1. Introduceți numărul maxim de perioade

În Perioada coloana , introduceți numărul maxim de plăți pe care îl veți permite pentru orice împrumut, de exemplu, de la 1 la 360. Puteți profita de funcția AutoFill a Excel pentru a introduce mai rapid o serie de numere.

2. Utilizați declarațiile IF în formulele de amortizare

Deoarece acum aveți multe numere de perioade excesive, trebuie să limitați cumva calculele la numărul real de plăți pentru un anumit împrumut. Acest lucru poate fi realizat prin includerea fiecărei formule într-o instrucțiune IF. Testul logic al instrucțiunii IF verifică dacă numărul perioadei din rândul curent este mai mic sau egal cu numărul total de plăți. Dacă testul logic este TRUE, se va aplica instrucțiunea corespunzătoareeste calculată; dacă este FALSE, se returnează un șir gol.

Presupunând că Perioada 1 se află în rândul 8, introduceți următoarele formule în celulele corespunzătoare și apoi copiați-le în întregul tabel.

Plata (B8):

=IF(A8<=$C$3*$C$4, PMT($C$2/$C$4, $C$3*$C$4, $C$5), "")

Dobânda (C8):

=IF(A8<=$C$3*$C$4, IPMT($C$2/$C$4, A8, $C$3*$C$4, $C$5), "")

Principal (D8):

=IF(A8<=$C$3*$C$4,PPMT($C$2/$C$4, A8, $C$3*$C$4, $C$5), "")

Balanță :

Pentru Perioada 1 (E8), formula este aceeași ca în exemplul anterior:

=C5+D8

Pentru Perioada 2 (E9) și pentru toate perioadele următoare, formula are următoarea formă:

=IF(A9<=$C$3*$C$4, E8+D9, "")

Ca rezultat, aveți un grafic de amortizare calculat corect și o mulțime de rânduri goale cu numerele perioadelor după ce împrumutul este achitat.

3. Ascundeți numerele perioadelor suplimentare

Dacă puteți trăi cu o grămadă de numere de perioade superflue afișate după ultima plată, puteți considera că munca este gata și puteți sări peste acest pas. Dacă vă străduiți să atingeți perfecțiunea, atunci ascundeți toate perioadele nefolosite prin crearea unei reguli de formatare condiționată care să seteze valoarea culoarea fontului să fie alb pentru orice rând după efectuarea ultimei plăți.

Pentru aceasta, selectați toate rânduri de date dacă tabelul de amortizare (A8:E367 în cazul nostru) și faceți clic pe Acasă tab> Formatare condiționată > Noua regulă... > Utilizați o formulă pentru a determina ce celule trebuie formatate .

În caseta corespunzătoare, introduceți formula de mai jos care verifică dacă numărul perioadei din coloana A este mai mare decât numărul total de plăți:

=$A8>$C$3*$C$4

Notă importantă! Pentru ca formula de formatare condiționată să funcționeze corect, asigurați-vă că utilizați referințe absolute de celulă pentru Termen de împrumut și Plăți pe an celulele pe care le înmulțiți ($C$3*$C$4). Produsul este comparat cu Perioada 1 celulă, pentru care se utilizează o referință de celulă mixtă - coloană absolută și rând relativ ($A8).

După aceea, faceți clic pe butonul Format... și alegeți culoarea albă a fontului. Gata!

4. Faceți un rezumat al împrumutului

Pentru a vizualiza dintr-o privire informațiile sumare despre creditul dumneavoastră, adăugați câteva formule în partea de sus a graficului de amortizare.

Total plăți (F2):

=-SUM(B8:B367)

Dobânda totală (F3):

=-SUM(C8:C367)

În cazul în care plățile sunt numere pozitive, eliminați semnul minus din formulele de mai sus.

Gata, graficul de amortizare a creditului nostru este gata și gata de plecare!

Descărcați programul de amortizare a împrumuturilor pentru Excel

Cum se face un grafic de amortizare a împrumuturilor cu plăți suplimentare în Excel

Planurile de amortizare discutate în exemplele anterioare sunt ușor de creat și de urmărit (sperăm :). Cu toate acestea, ele nu includ o caracteristică utilă de care sunt interesați mulți dintre cei care plătesc împrumuturi - plăți suplimentare pentru a achita mai repede un împrumut. În acest exemplu, vom vedea cum să creăm un plan de amortizare a unui împrumut cu plăți suplimentare.

1. Definiți celulele de intrare

Ca de obicei, începeți cu configurarea celulelor de intrare. În acest caz, să denumim aceste celule așa cum este scris mai jos pentru a face formulele noastre mai ușor de citit:

• Rata dobânzii - C2 (rata anuală a dobânzii)
• Termen de împrumut - C3 (durata împrumutului în ani)
• Plăți pe an - C4 (numărul de plăți pe an)
• LoanAmount - C5 (valoarea totală a împrumutului)
• ExtraPayment - C6 (plată suplimentară pe perioadă)

2. Calculați o plată programată

În afară de celulele de intrare, mai este necesară încă o celulă predefinită pentru calculele noastre ulterioare - celula suma de plată programată , adică suma care va fi plătită pentru un împrumut dacă nu se fac plăți suplimentare. Această sumă se calculează cu următoarea formulă:

=IFERROR(-PMT(rata dobânzii/plăți/an, durata împrumutului*plăți/an, suma împrumutului), "")

Vă rugăm să fiți atenți la faptul că am pus semnul minus înaintea funcției PMT pentru ca rezultatul să fie un număr pozitiv. Pentru a preveni erorile în cazul în care unele dintre celulele de intrare sunt goale, includem formula PMT în cadrul funcției IFERROR.

Introduceți această formulă într-o anumită celulă (G2 în cazul nostru) și denumiți acea celulă Plată programată .

3. Configurați tabelul de amortizare

Creați un tabel de amortizare a creditului cu rubricile prezentate în captura de ecran de mai jos. În tabelul Perioada introduceți o serie de numere începând cu zero (puteți ascunde coloana Perioada 0 rând mai târziu, dacă este necesar).

Dacă doriți să creați un plan de amortizare reutilizabil, introduceți numărul maxim posibil de perioade de plată (de la 0 la 360 în acest exemplu).

Pentru Perioada 0 (rândul 9, în cazul nostru), trageți de butonul Balanță care este egală cu suma inițială a împrumutului. Toate celelalte celule din acest rând vor rămâne goale:

Formula din G9:

=Suma împrumutului

4. Construiți formulele pentru programul de amortizare cu plăți suplimentare

Aceasta este o parte esențială a activității noastre. Deoarece funcțiile încorporate în Excel nu prevăd plăți suplimentare, va trebui să facem toate calculele pe cont propriu.

Notă. în acest exemplu, Perioada 0 se află la rândul 9 și Perioada 1 se află în rândul 10. Dacă tabelul de amortizare începe într-un alt rând, vă rugăm să vă asigurați că ajustați corespunzător referințele celulelor.

Introduceți următoarele formule în rândul 10 ( Perioada 1 ), apoi copiați-le pentru toate perioadele rămase.

Plată programată (B10):

În cazul în care Plată programată suma (numită celula G2) este mai mică sau egală cu soldul rămas (G9), utilizați plata programată. În caz contrar, adăugați soldul rămas și dobânda pentru luna precedentă.

=IFERROR(IF(ScheduledPayment<=G9, ScheduledPayment, G9+G9*InterestRate/PaymentsPerYear), "")

Ca o măsură de precauție suplimentară, această formulă și toate formulele ulterioare sunt incluse în funcția IFERROR. Acest lucru va preveni o serie de erori diverse în cazul în care unele dintre celulele de intrare sunt goale sau conțin valori invalide.

Plată suplimentară (C10):

Utilizați o formulă IF cu următoarea logică:

În cazul în care ExtraPayment suma (numită celula C6) este mai mică decât diferența dintre soldul rămas și principalul din această perioadă (G9-E10), returnați ExtraPayment ; în caz contrar, utilizați diferența.

=IFERROR(IF(ExtraPayment

Sfat: Dacă aveți plăți suplimentare variabile , trebuie doar să introduceți sumele individuale direct în Plată suplimentară coloană.

Plata totală (D10)

Pur și simplu, adăugați plata programată (B10) și plata suplimentară (C10) pentru perioada curentă:

=IFERROR(B10+C10, "")

Principal (E10)

În cazul în care plata programată pentru o anumită perioadă este mai mare decât zero, se returnează cea mai mică dintre cele două valori: plata programată minus dobânda (B10-F10) sau soldul rămas (G9); în caz contrar, se returnează zero.

=IFERROR(IF(B10>0, MIN(B10-F10, G9), 0), "")

Vă rugăm să rețineți că principalul include doar partea de plata programată (nu plata suplimentară!) care se alocă pentru principalul împrumutului.

Dobânda (F10)

În cazul în care plata programată pentru o anumită perioadă este mai mare decât zero, se împarte rata anuală a dobânzii (denumită celula C2) la numărul de plăți pe an (denumită celula C4) și se înmulțește rezultatul cu soldul rămas după perioada anterioară; în caz contrar, se returnează 0.

=IFERROR(IF(B10>0, InterestRate/PaymentsPerYear*G9, 0), "")

Balanță (G10)

În cazul în care soldul rămas (G9) este mai mare decât zero, se scade din soldul rămas după perioada precedentă (G9) partea de principal a plății (E10) și plata suplimentară (C10); în caz contrar, se returnează 0.

=IFERROR(IF(G9>0, G9-E10-C10, 0), "")

Notă: Deoarece unele dintre formule fac trimitere încrucișată între ele (nu trimitere circulară!), este posibil ca acestea să afișeze rezultate eronate în timpul procesului. Așadar, nu începeți rezolvarea problemelor până când nu introduceți ultima formulă în tabelul de amortizare.

Dacă totul s-a făcut corect, programul de amortizare a împrumutului în acest moment ar trebui să arate cam așa:

5. Ascundeți perioadele suplimentare

Configurați o regulă de formatare condiționată pentru a ascunde valorile din perioadele nefolosite, așa cum am explicat în acest sfat. Diferența este că de data aceasta aplicăm regula culoarea fontului alb la rândurile în care Plata totală (coloana D) și Balanță (coloana G) sunt egale cu zero sau goale:

=AND(OR($D9=0, $D9=""), OR($G9=0, $G9="")))

Iată, toate rândurile cu valori zero sunt ascunse:

6. Faceți un rezumat al împrumutului

Ca o notă de perfecțiune, puteți obține cele mai importante informații despre un împrumut folosind aceste formule:

Numărul programat de plăți:

Înmulțiți numărul de ani cu numărul de plăți pe an:

=Termen de împrumut*PaymentsPerYear

Numărul efectiv de plăți:

Numărați celulele din Plata totală care sunt mai mari decât zero, începând cu perioada 1:

=COUNTIF(D10:D369,">"&0)

Total plăți suplimentare:

Adunați celulele din Plată suplimentară coloana, începând cu perioada 1:

=SUM(C10:C369)

Dobânda totală:

Adunați celulele din Dobânda coloana, începând cu perioada 1:

=SUM(F10:F369)

Opțional, ascundeți caseta Perioada 0 și programul de amortizare a creditului cu plăți suplimentare este gata! Captura de ecran de mai jos arată rezultatul final:

Descărcați graficul de amortizare a creditului cu plăți suplimentare

Schema de amortizare șablon Excel

Pentru a realiza un grafic de amortizare a creditului de top în cel mai scurt timp, folosiți șabloanele încorporate în Excel. Trebuie doar să accesați Fișier > Nou , tip " grafic de amortizare " în caseta de căutare și alegeți șablonul care vă place, de exemplu, acesta cu plăți suplimentare:

Apoi salvați registrul de lucru nou creat ca șablon Excel și reutilizați-l oricând doriți.

Iată cum se creează un grafic de amortizare a unui împrumut sau a unui credit ipotecar în Excel. Vă mulțumesc pentru lectură și sper să ne revedem pe blog săptămâna viitoare!

Descărcări disponibile

Exemple de scheme de amortizare (fișier .xlsx)