I handledningen visas hur man bygger ett amorteringsschema i Excel för att beskriva periodiska betalningar på ett amorterande lån eller hypotekslån.

En amorterande lån är bara ett fint sätt att definiera ett lån som betalas tillbaka i delbetalningar under hela lånetiden.

I princip är alla lån amorterande på ett eller annat sätt. Ett lån med full amortering på 24 månader har till exempel 24 lika stora månadsbetalningar. Varje betalning avser en del av amorteringen och en del av räntan. För att få en detaljerad beskrivning av varje betalning på ett lån kan du skapa ett amorteringsschema för lånet.

En avskrivningsschema är en tabell som listar periodiska betalningar på ett lån eller hypotekslån över tiden, delar upp varje betalning i kapital och ränta och visar det återstående saldot efter varje betalning.

Hur man skapar ett schema för amortering av lån i Excel

För att skapa ett amorteringsschema för lån eller hypotekslån i Excel behöver vi använda följande funktioner:

• PMT-funktion - beräknar totalt belopp Detta belopp är konstant under hela lånets löptid.
• PPMT-funktion - hämtar huvudman En del av varje betalning som går till lånets kapital, dvs. det belopp du lånat. Detta belopp ökar för efterföljande betalningar.
• IPMT-funktion - hittar den ränta Den del av varje betalning som går till ränta. Detta belopp minskar med varje betalning.

Låt oss gå igenom processen steg för steg.

1. Ställ in amorteringstabellen

Till att börja med definierar du de inmatningsceller där du ska ange de kända komponenterna i ett lån:

• C2 - årlig ränta
• C3 - lånetid i år
• C4 - antal betalningar per år
• C5 - lånebelopp

Nästa steg är att skapa en amorteringstabell med etiketterna ( Period , Betalning , Ränta , Huvudansvarig , Balans ) i A7:E7. I Period kolumnen en serie siffror som motsvarar det totala antalet betalningar (1- 24 i det här exemplet):

Med alla kända komponenter på plats kan vi komma till den mest intressanta delen - formlerna för amortering av lån.

2. Beräkna det totala betalningsbeloppet (PMT-formeln).

Betalningsbeloppet beräknas med funktionen PMT(rate, nper, pv, [fv], [type]).

För att hantera olika betalningsfrekvenser korrekt (t.ex. veckovis, månadsvis, kvartalsvis osv.) bör du vara konsekvent med de värden som anges för kurs och nper argument:

• Räkna med - dividera den årliga räntan med antalet betalningsperioder per år ($C$2/$C$4).
• Nper - multiplicera antalet år med antalet betalningsperioder per år ($C$3*$C$4).
• För pv argument, ange lånebeloppet ($C$5).
• fv och typ argumenten kan utelämnas eftersom deras standardvärden fungerar bra för oss (saldot efter den sista betalningen ska vara 0; betalningarna görs i slutet av varje period).

Genom att sammanföra ovanstående argument får vi denna formel:

=PMT($C$2/$C$4, $C$3*$C$4, $C$5)

Observera att vi använder absoluta cellreferenser eftersom formeln ska kopieras till nedanstående celler utan några ändringar.

Ange PMT-formeln i B8, dra den nedåt i kolumnen och du kommer att se ett konstant betalningsbelopp för alla perioder:

3. Beräkna ränta (IPMT-formeln).

För att hitta räntedelen för varje periodisk betalning använder du funktionen IPMT(rate, per, nper, pv, [fv], [type]):

=IPMT($C$2/$C$4, A8, $C$3*$C$4, $C$5)

Alla argument är desamma som i PMT-formeln, utom per Argumentet anger betalningsperioden. Argumentet anges som en relativ cellreferens (A8) eftersom det är meningen att det ska ändras beroende på den relativa positionen på den rad som formeln kopieras till.

Formeln placeras i C8, och sedan kopierar du den ner till så många celler som behövs:

4. Hitta huvudmannen (PPMT-formeln)

För att beräkna kapitaldelen av varje periodisk betalning använder du denna PPMT-formel:

=PPMT($C$2/$C$4, A8, $C$3*$C$4, $C$5)

Syntaxen och argumenten är exakt desamma som i IPMT-formeln som diskuterades ovan:

Denna formel används i kolumn D, med början i D8:

Tips: Om du vill kontrollera om dina beräkningar är korrekta i det här skedet kan du lägga ihop siffrorna i Huvudansvarig och Ränta kolumnerna. Summan ska vara lika med värdet i kolumnen Betalning kolumnen i samma rad.

5. Få det återstående beloppet.

För att beräkna det återstående saldot för varje period använder vi två olika formler.

För att hitta saldot efter den första betalningen i E8, addera lånebeloppet (C5) och kapitalet för den första perioden (D8):

=C5+D8

Eftersom lånebeloppet är ett positivt tal och amorteringen ett negativt tal, dras det sistnämnda av från det förstnämnda.

För den andra perioden och alla följande perioder summerar du det tidigare saldot och den här periodens kapitalbelopp:

=E8+D9

Formeln ovan går till E9 och sedan kopierar du den nedåt i kolumnen. Tack vare användningen av relativa cellreferenser justeras formeln korrekt för varje rad.

Så är det! Vårt månatliga amorteringsprogram är klart:

Tips: Återge betalningar som positiva tal

Eftersom ett lån betalas från ditt bankkonto, returnerar Excel-funktionerna betalningen, räntan och kapitalet som negativa tal Som standard är dessa värden markerade med rött och omslutna av parenteser, som du kan se i bilden ovan.

Om du föredrar att få alla resultat som positiv siffror, sätt ett minustecken före funktionerna PMT, IPMT och PPMT.

För Balans formler, använd subtraktion i stället för addition som i skärmbilden nedan:

Avskrivningsplan för ett variabelt antal perioder

I exemplet ovan byggde vi en amorteringsplan för lånet för det fördefinierade antalet betalningsperioder. Denna snabba engångslösning fungerar bra för ett specifikt lån eller hypotekslån.

Om du vill skapa ett återanvändbart avskrivningsschema med ett variabelt antal perioder måste du använda en mer omfattande metod som beskrivs nedan.

1. Ange det maximala antalet perioder.

I Period kolumnen anger du det maximala antalet betalningar som du kommer att tillåta för varje lån, till exempel från 1 till 360. Du kan utnyttja Excels funktion för automatisk ifyllning för att skriva in en rad siffror snabbare.

2. Använd IF-uttalanden i amorteringsformler.

Eftersom du nu har många för stora periodnummer måste du på något sätt begränsa beräkningarna till det faktiska antalet betalningar för ett visst lån. Detta kan göras genom att linda in varje formel i ett IF-uttalande. Det logiska testet i IF-uttalandet kontrollerar om periodnumret i den aktuella raden är mindre än eller lika med det totala antalet betalningar. Om det logiska testet är TRUE, kommer motsvarandeOm den är FALSK återges en tom sträng.

Om man utgår från Period 1 finns på rad 8, skriv in följande formler i motsvarande celler och kopiera dem sedan över hela tabellen.

Betalning (B8):

=IF(A8<=$C$3*$C$4, PMT($C$2/$C$4, $C$3*$C$4, $C$5), "")

Ränta (C8):

=IF(A8<=$C$3*$C$4, IPMT($C$2/$C$4, A8, $C$3*$C$4, $C$5), "")

Huvudansvarig (D8):

=IF(A8<=$C$3*$C$4,PPMT($C$2/$C$4, A8, $C$3*$C$4, $C$5), "")

Balans :

För Period 1 (E8) är formeln densamma som i det föregående exemplet:

=C5+D8

För Period 2 (E9) och alla följande perioder har formeln följande form:

=IF(A9<=$C$3*$C$4, E8+D9, "")

Resultatet är att du har ett korrekt beräknat amorteringsschema och en massa tomma rader med periodsiffrorna efter att lånet har betalats av.

3. Dölj extra perioder

Om du kan leva med en massa överflödiga periodnummer som visas efter den sista betalningen kan du betrakta arbetet som gjort och hoppa över det här steget. Om du strävar efter perfektion kan du dölja alla oanvända perioder genom att göra en villkorlig formateringsregel som anger typsnittsfärg till vit för alla rader efter det att den sista betalningen har gjorts.

För att göra detta väljer du alla rader med uppgifter om din amorteringstabell (A8:E367 i vårt fall) och klicka på Hem flik> Villkorlig formatering > Ny regel... > Använd en formel för att bestämma vilka celler som ska formateras .

I motsvarande ruta anger du nedanstående formel som kontrollerar om periodnumret i kolumn A är större än det totala antalet betalningar:

=$A8>$C$3*$C$4

Viktigt att notera: För att formeln för villkorlig formatering ska fungera korrekt måste du se till att använda absoluta cellreferenser för Lånetid och Betalningar per år celler som du multiplicerar ($C$3*$C$4). Produkten jämförs med den Period 1 cell, för vilken du använder en blandad cellreferens - absolut kolumn och relativ rad ($A8).

Klicka sedan på Format... och välj den vita typsnittsfärgen. Klart!

4. Gör en sammanfattning av lånet

Om du vill se den sammanfattande informationen om ditt lån i en överblick kan du lägga till ytterligare ett par formler överst i amorteringsschemat.

Totala betalningar (F2):

=-SUM(B8:B367)

Totala räntor (F3):

=-SUM(C8:C367)

Om du har betalningar som positiva tal tar du bort minustecknet från ovanstående formler.

Det var allt! Vår amorteringsplan för lånet är klar och redo att användas!

Ladda ner amorteringsschema för lån för Excel

Hur man gör en amorteringsplan för lån med extra betalningar i Excel

De amorteringsscheman som diskuterades i de tidigare exemplen är lätta att skapa och följa (förhoppningsvis :). De utelämnar dock en användbar funktion som många lånebetalare är intresserade av - extra betalningar för att betala av lånet snabbare. I det här exemplet tittar vi på hur man skapar ett amorteringsschema för ett lån med extra betalningar.

1. Definiera inmatningsceller

Som vanligt börjar du med att ställa in inmatningscellerna. I det här fallet kan vi namnge cellerna på följande sätt för att göra våra formler lättare att läsa:

• Räntesats - C2 (årlig ränta)
• Lånetid - C3 (lånetid i år)
• Betalningar per år - C4 (antal betalningar per år)
• LoanAmount - C5 (totalt lånebelopp)
• ExtraPayment - C6 (extra betalning per period)

2. Beräkna en planerad betalning

Förutom inmatningscellerna behövs ytterligare en fördefinierad cell för våra fortsatta beräkningar - planerat betalningsbelopp. , dvs. det belopp som ska betalas på lånet om inga extra betalningar görs. Beloppet beräknas med följande formel:

=IFERROR(-PMT(InterestRate/PaymentsPerYear, LoanTerm*PaymentsPerYear, LoanAmount), "")

Observera att vi sätter ett minustecken före PMT-funktionen för att resultatet ska bli ett positivt tal. För att förhindra fel om några av inmatningscellerna är tomma, omsluter vi PMT-formeln i IFERROR-funktionen.

Skriv in formeln i en cell (G2 i vårt fall) och namnge den cellen. Planerad betalning .

3. Ställ in amorteringstabellen

Skapa en amorteringstabell för lån med de rubriker som visas i skärmdumpen nedan. I tabellen Period kolumnen anger du en serie siffror som börjar med noll (du kan dölja Period 0 rad senare om det behövs).

Om du vill skapa en återanvändbar amorteringsplan anger du det högsta möjliga antalet betalningsperioder (0 till 360 i det här exemplet).

För Period 0 (rad 9 i vårt fall), dra i Balans Värdet är lika med det ursprungliga lånebeloppet. Alla andra celler på denna rad förblir tomma:

Formel i G9:

=LoanAmount

4. Bygg formler för amorteringsplan med extra betalningar.

Detta är en viktig del av vårt arbete. Eftersom Excels inbyggda funktioner inte ger möjlighet till ytterligare betalningar måste vi göra all matematik på egen hand.

Observera: I det här exemplet, Period 0 står på rad 9 och Period 1 är på rad 10. Om din amorteringstabell börjar på en annan rad, se till att justera cellreferenserna i enlighet med detta.

Ange följande formler på rad 10 ( Period 1 ), och sedan skriva av dem för alla de återstående perioderna.

Planerad betalning (B10):

Om den Planerad betalning Om beloppet (som anges i cell G2) är mindre än eller lika med det återstående saldot (G9), använd den planerade betalningen. I annat fall läggs det återstående saldot och räntan för föregående månad till.

=IFERROR(IF(ScheduledPayment<=G9, ScheduledPayment, G9+G9*InterestRate/PaymentsPerYear), "")

Som en extra försiktighetsåtgärd lindar vi in denna och alla efterföljande formler i funktionen IFERROR. Detta förhindrar en massa olika fel om några av inmatningscellerna är tomma eller innehåller ogiltiga värden.

Extra betalning (C10):

Använd en IF-formel med följande logik:

Om den ExtraPayment beloppet (cell C6) är mindre än skillnaden mellan det återstående saldot och periodens kapital (G9-E10), återge ExtraPayment ; annars använder du skillnaden.

=IFERROR(IF(ExtraPayment

Tips. Om du har rörliga tilläggsbetalningar skriver du bara de enskilda beloppen direkt i fältet Extra betalning kolumn.

Total betalning (D10)

Lägg helt enkelt till den schemalagda betalningen (B10) och den extra betalningen (C10) för den aktuella perioden:

=IFERROR(B10+C10, "")

Huvudansvarig (E10)

Om den planerade betalningen för en viss period är större än noll, ska du returnera det minsta av de två värdena: planerad betalning minus ränta (B10-F10) eller resterande saldo (G9), annars ska du returnera noll.

=IFERROR(IF(B10>0, MIN(B10-F10, G9), 0), "")

Observera att huvudmannen endast omfattar den del av den planerad betalning (inte den extra betalningen!) som går till lånets kapital.

Ränta (F10)

Om den schemalagda betalningen för en viss period är större än noll ska du dividera den årliga räntan (cell C2) med antalet betalningar per år (cell C4) och multiplicera resultatet med det återstående saldot efter föregående period, annars ska du returnera 0.

=IFERROR(IF(B10>0, InterestRate/PaymentsPerYear*G9, 0), "")

Balans (G10)

Om det återstående saldot (G9) är större än noll, subtrahera betalningens huvuddel (E10) och den extra betalningen (C10) från det återstående saldot efter föregående period (G9); i annat fall återges 0.

=IFERROR(IF(G9>0, G9-E10-C10, 0), "")

Observera: Eftersom vissa av formlerna hänvisar till varandra (inte cirkulära hänvisningar!) kan de visa felaktiga resultat under processen. Börja därför inte felsöka förrän du anger den allra sista formeln i din amorteringstabell.

Om allt har gjorts på rätt sätt bör ditt låns amorteringsplan vid denna tidpunkt se ut ungefär så här:

5. Dölj extra perioder.

Skapa en regel för villkorlig formatering för att dölja värdena i oanvända perioder som förklaras i det här tipset. Skillnaden är att vi den här gången tillämpar vit teckensnittsfärg till de rader där Total betalning (kolumn D) och Balans (kolumn G) är lika med noll eller tomma:

=AND(OR($D9=0, $D9=""), OR($G9=0, $G9=""))

Voilà, alla rader med nollvärden är dolda:

6. Gör en sammanfattning av lånet

Som en sista touch av perfektion kan du få ut den viktigaste informationen om ett lån med hjälp av dessa formler:

Planerat antal betalningar:

Multiplicera antalet år med antalet betalningar per år:

=LoanTerm*PaymentsPerYear

Faktiskt antal betalningar:

Räkna celler i Total betalning som är större än noll, med början i period 1:

=COUNTIF(D10:D369,">"&0)

Totalt antal extra betalningar:

Lägg ihop cellerna i Extra betalning kolumnen, med början i period 1:

=SUMMA(C10:C369)

Total ränta:

Lägg ihop cellerna i Ränta kolumnen, med början i period 1:

=SUM(F10:F369)

Du kan också dölja Period 0 rad, och din amorteringsplan med ytterligare betalningar är klar! Skärmdumpen nedan visar slutresultatet:

Ladda ner amorteringsschema för lån med extra betalningar

Avskrivningsschema Excel-mall

Om du vill göra ett förstklassigt amorteringsschema för lån på nolltid kan du använda Excels inbyggda mallar. Gå till Fil > Ny , typ " avskrivningsschema " i sökrutan och välj den mall du vill ha, till exempel den här mallen med extra betalningar:

Spara sedan den nyskapade arbetsboken som en Excel-mall och återanvänd den när du vill.

Så skapar du ett amorteringsschema för lån eller hypotekslån i Excel. Tack för att du läste och hoppas att vi ses på vår blogg nästa vecka!

Tillgängliga nedladdningar

Exempel på avskrivningsschema (.xlsx-fil)