Tutorial menunjukkan cara membina jadual pelunasan dalam Excel untuk memperincikan pembayaran berkala bagi pinjaman pelunasan atau gadai janji.

pinjaman pelunasan hanyalah satu rekaan cara untuk menentukan pinjaman yang dibayar balik secara ansuran sepanjang tempoh pinjaman.

Pada asasnya, semua pinjaman dilunaskan dalam satu cara atau yang lain. Sebagai contoh, pinjaman pelunasan penuh selama 24 bulan akan mempunyai 24 bayaran bulanan yang sama. Setiap pembayaran menggunakan beberapa amaun terhadap prinsipal dan sebahagian lagi terhadap faedah. Untuk memperincikan setiap pembayaran bagi pinjaman, anda boleh membina jadual pelunasan pinjaman.

jadual pelunasan ialah jadual yang menyenaraikan bayaran berkala bagi pinjaman atau gadai janji dari semasa ke semasa, memecahkan setiap pembayaran ke dalam prinsipal dan faedah, dan menunjukkan baki yang tinggal selepas setiap pembayaran.

Cara membuat jadual pelunasan pinjaman dalam Excel

Untuk membina jadual pelunasan pinjaman atau gadai janji dalam Excel, kita perlu menggunakan fungsi berikut:

• Fungsi PMT - mengira jumlah keseluruhan pembayaran berkala. Amaun ini kekal malar sepanjang tempoh pinjaman.
• Fungsi PPMT - mendapat bahagian prinsipal bagi setiap pembayaran yang diberikan kepada prinsipal pinjaman, iaitu amaun yang anda pinjam. Jumlah ini meningkat untuk pembayaran seterusnya.
• Fungsi IPMT - mencari bahagian faedah setiap pembayaran yang menuju ke arah faedah.mempunyai pembayaran tambahan yang berubah-ubah , hanya taip amaun individu terus dalam lajur Pembayaran Tambahan .

  Jumlah Bayaran (D10)

  Cuma, tambahkan bayaran berjadual (B10) dan bayaran tambahan (C10) untuk tempoh semasa:

  =IFERROR(B10+C10, "")

  Principal (E10)

  Jika bayaran jadual untuk tempoh tertentu adalah lebih besar daripada sifar, pulangkan nilai yang lebih kecil daripada dua nilai: bayaran berjadual tolak faedah (B10-F10) atau baki selebihnya (G9); jika tidak pulangkan sifar.

  =IFERROR(IF(B10>0, MIN(B10-F10, G9), 0), "")

  Sila ambil perhatian bahawa prinsipal hanya termasuk bahagian bayaran berjadual (bukan bayaran tambahan!) yang digunakan untuk prinsipal pinjaman.

  Faedah (F10)

  Jika jadual pembayaran untuk tempoh tertentu lebih besar daripada sifar, bahagikan kadar faedah tahunan (dinamakan sel C2) dengan bilangan pembayaran setahun (bernama sel C4) dan darabkan hasilnya dengan baki yang tinggal selepas tempoh sebelumnya; jika tidak, kembalikan 0.

  =IFERROR(IF(B10>0, InterestRate/PaymentsPerYear*G9, 0), "")

  Baki (G10)

  Jika baki selebihnya (G9) lebih besar daripada sifar, tolak bahagian utama daripada pembayaran (E10) dan bayaran tambahan (C10) daripada baki yang tinggal selepas tempoh sebelumnya (G9); sebaliknya kembalikan 0.

  =IFERROR(IF(G9 >0, G9-E10-C10, 0), "")

  Nota. Oleh kerana sesetengah formula merujuk silang antara satu sama lain (bukan rujukan bulat!), ia mungkin memaparkan hasil yang salah dalam proses. Jadi, sila jangan mulakan penyelesaian masalah sehingga anda masukformula terakhir dalam jadual pelunasan anda.

  Jika semuanya dilakukan dengan betul, jadual pelunasan pinjaman anda pada ketika ini sepatutnya kelihatan seperti ini:

  5. Sembunyikan tempoh tambahan

  Sediakan peraturan pemformatan bersyarat untuk menyembunyikan nilai dalam tempoh yang tidak digunakan seperti yang dijelaskan dalam petua ini. Perbezaannya ialah kali ini kita menggunakan warna fon putih pada baris yang Jumlah Pembayaran (lajur D) dan Baki (lajur G) adalah sama dengan sifar atau kosong:

  =AND(OR($D9=0, $D9=""), OR($G9=0, $G9=""))

  Voilà, semua baris dengan nilai sifar disembunyikan daripada paparan:

  6. Buat ringkasan pinjaman

  Sebagai sentuhan akhir kesempurnaan, anda boleh mengeluarkan maklumat paling penting tentang pinjaman dengan menggunakan formula ini:

  Bilangan pembayaran yang dijadualkan:

  Darab bilangan tahun dengan bilangan pembayaran setahun:

  =LoanTerm*PaymentsPerYear

  Bilangan pembayaran sebenar:

  Kira sel dalam lajur Jumlah Pembayaran yang lebih besar daripada sifar, bermula dengan Tempoh 1:

  =COUNTIF(D10:D369,">"&0)

  Jumlah bayaran tambahan:

  Tambahkan sel dalam lajur Pembayaran Tambahan , bermula dengan Tempoh 1:

  =SUM(C10:C369)

  Jumlah faedah:

  Tambah sehingga sel dalam lajur Faedah , bermula dengan Tempoh 1:

  =SUM(F10:F369)

  Secara pilihan, sembunyikan baris Tempoh 0 dan jadual pelunasan pinjaman anda dengan bayaran tambahan selesai! Tangkapan skrin di bawah menunjukkan keputusan akhir:

  Muat turun pelunasan pinjamanjadual dengan bayaran tambahan

  Jadual pelunasan Templat Excel

  Untuk membuat jadual pelunasan pinjaman terkemuka dalam masa yang singkat, gunakan templat terbina dalam Excel. Hanya pergi ke Fail > Baharu , taip " jadual pelunasan " dalam kotak carian dan pilih templat yang anda suka, contohnya, yang ini dengan bayaran tambahan :

  Kemudian simpan buku kerja yang baru dibuat sebagai templat Excel dan gunakan semula pada bila-bila masa anda mahu.

  Begitulah anda membuat jadual pelunasan pinjaman atau gadai janji dalam Excel. Saya berterima kasih kerana membaca dan berharap dapat berjumpa anda di blog kami minggu hadapan!

  Muat turun yang tersedia

  Contoh Jadual Pelunasan (fail.xlsx)

  Jumlah ini berkurangan dengan setiap pembayaran.

Sekarang, mari kita lalui proses langkah demi langkah.

1. Sediakan jadual pelunasan

Sebagai permulaan, tentukan sel input tempat anda akan memasukkan komponen pinjaman yang diketahui:

• C2 - kadar faedah tahunan
• C3 - tempoh pinjaman dalam tahun
• C4 - bilangan pembayaran setahun
• C5 - jumlah pinjaman

Perkara seterusnya yang anda lakukan ialah membuat jadual pelunasan dengan label ( Tempoh , Pembayaran , Faedah , Principal , Baki ) dalam A7:E7. Dalam lajur Tempoh , masukkan satu siri nombor yang sama dengan jumlah pembayaran (1- 24 dalam contoh ini):

Dengan semua komponen yang diketahui tersedia, mari kita pergi ke bahagian paling menarik - formula pelunasan pinjaman.

2. Kira jumlah pembayaran (formula PMT)

Amaun pembayaran dikira dengan fungsi PMT(kadar, nper, pv, [fv], [jenis]).

Untuk mengendalikan kekerapan pembayaran yang berbeza dengan betul (seperti mingguan, bulanan, suku tahunan, dsb.), anda harus konsisten dengan nilai yang dibekalkan untuk argumen kadar dan nper :

• Kadar - bahagikan kadar faedah tahunan dengan bilangan tempoh pembayaran setahun ($C$2/$C$4).
• Nper - darabkan bilangan tahun dengan bilangan tempoh pembayaran setahun ($C$3*$C$4).
• Untuk hujah pv , masukkan jumlah pinjaman ($C$5).
• TheArgumen fv dan type boleh ditinggalkan kerana nilai lalainya berfungsi dengan baik untuk kami (baki selepas pembayaran terakhir sepatutnya 0; pembayaran dibuat pada penghujung setiap tempoh) .

Menggabungkan argumen di atas, kami mendapat formula ini:

=PMT($C$2/$C$4, $C$3*$C$4, $C$5)

Sila ambil perhatian, bahawa kami menggunakan rujukan sel mutlak kerana formula ini harus disalin ke sel di bawah tanpa sebarang perubahan.

Masukkan formula PMT dalam B8, seret ke bawah lajur dan anda akan melihat amaun bayaran tetap untuk semua tempoh:

3. Kira faedah (formula IPMT)

Untuk mencari bahagian faedah setiap pembayaran berkala, gunakan fungsi IPMT(kadar, setiap, nper, pv, [fv], [jenis]):

=IPMT($C$2/$C$4, A8, $C$3*$C$4, $C$5)

Semua argumen adalah sama seperti dalam formula PMT, kecuali argumen setiap yang menentukan tempoh pembayaran. Argumen ini dibekalkan sebagai rujukan sel relatif (A8) kerana ia sepatutnya berubah berdasarkan kedudukan relatif baris yang formula disalin.

Formula ini pergi ke C8, dan kemudian anda menyalinnya kepada seberapa banyak sel yang diperlukan:

4. Cari prinsipal (formula PPMT)

Untuk mengira bahagian pokok setiap pembayaran berkala, gunakan formula PPMT ini:

=PPMT($C$2/$C$4, A8, $C$3*$C$4, $C$5)

Sintaks dan hujah adalah sama seperti dalam formula IPMT yang dibincangkan di atas:

Formula ini pergi ke lajur D, bermula dari D8:

Petua. Untuk menyemak sama ada andapengiraan adalah betul pada ketika ini, tambahkan nombor dalam lajur Pengetua dan Minat . Jumlahnya hendaklah sama dengan nilai dalam lajur Pembayaran dalam baris yang sama.

5. Dapatkan baki yang tinggal

Untuk mengira baki yang tinggal bagi setiap tempoh, kami akan menggunakan dua formula yang berbeza.

Untuk mencari baki selepas pembayaran pertama dalam E8, tambah jumlah pinjaman (C5) dan prinsipal bagi tempoh pertama (D8):

=C5+D8

Oleh kerana jumlah pinjaman adalah nombor positif dan prinsipal ialah nombor negatif, yang terakhir sebenarnya ditolak daripada yang pertama .

Untuk tempoh kedua dan semua tempoh seterusnya, tambahkan baki sebelumnya dan prinsipal tempoh ini:

=E8+D9

Formula di atas pergi ke E9, dan kemudian anda menyalinnya ke bawah lajur. Disebabkan oleh penggunaan rujukan sel relatif, formula melaraskan dengan betul untuk setiap baris.

Itu sahaja! Jadual pelunasan pinjaman bulanan kami telah selesai:

Petua: Pemulangan bayaran sebagai nombor positif

Oleh kerana pinjaman dibayar daripada akaun bank anda, Excel berfungsi mengembalikan bayaran, faedah dan prinsipal sebagai nombor negatif . Secara lalai, nilai ini diserlahkan dalam warna merah dan disertakan dalam kurungan seperti yang anda boleh lihat dalam imej di atas.

Jika anda lebih suka mempunyai semua keputusan sebagai nombor positif , letakkan tanda tolak sebelum fungsi PMT, IPMT dan PPMT.

Untuk Baki formula, gunakan penolakan dan bukannya penambahan seperti yang ditunjukkan dalam tangkapan skrin di bawah:

Jadual pelunasan untuk bilangan tempoh yang berubah-ubah

Dalam contoh di atas, kami membina jadual pelunasan pinjaman untuk bilangan yang telah ditetapkan tempoh pembayaran. Penyelesaian cepat sekali ini berfungsi dengan baik untuk pinjaman atau gadai janji tertentu.

Jika anda ingin membuat jadual pelunasan boleh guna semula dengan bilangan tempoh yang berubah-ubah, anda perlu mengambil pendekatan yang lebih komprehensif yang diterangkan di bawah.

1. Masukkan bilangan maksimum tempoh

Dalam lajur Tempoh , masukkan bilangan maksimum pembayaran yang akan anda benarkan untuk sebarang pinjaman, misalnya, daripada 1 hingga 360. Anda boleh memanfaatkan AutoIsi Excel ciri untuk memasukkan siri nombor dengan lebih pantas.

2. Gunakan penyata IF dalam formula pelunasan

Oleh kerana anda kini mempunyai banyak nombor tempoh yang berlebihan, anda perlu mengehadkan pengiraan kepada bilangan pembayaran sebenar untuk pinjaman tertentu. Ini boleh dilakukan dengan membungkus setiap formula ke dalam pernyataan IF. Ujian logik penyata IF menyemak sama ada nombor tempoh dalam baris semasa adalah kurang daripada atau sama dengan jumlah pembayaran. Jika ujian logik adalah BENAR, fungsi yang sepadan dikira; jika FALSE, rentetan kosong dikembalikan.

Dengan mengandaikan Tempoh 1 berada dalam baris 8, masukkan formula berikut dalam sel yang sepadan, kemudian salinnya merentasseluruh jadual.

Pembayaran (B8):

=IF(A8<=$C$3*$C$4, PMT($C$2/$C$4, $C$3*$C$4, $C$5), "")

Faedah (C8):

=IF(A8<=$C$3*$C$4, IPMT($C$2/$C$4, A8, $C$3*$C$4, $C$5), "")

Pengetua (D8):

=IF(A8<=$C$3*$C$4,PPMT($C$2/$C$4, A8, $C$3*$C$4, $C$5), "")

Baki :

Untuk Tempoh 1 (E8), formula adalah sama seperti dalam contoh sebelumnya:

=C5+D8

Untuk Tempoh 2 (E9) dan semua tempoh berikutnya, formula mengambil bentuk ini:

=IF(A9<=$C$3*$C$4, E8+D9, "")

Hasilnya, anda mempunyai jadual pelunasan yang dikira dengan betul dan sekumpulan baris kosong dengan nombor tempoh selepas pinjaman dilunaskan.

3. Sembunyikan nombor tempoh tambahan

Jika anda boleh hidup dengan sekumpulan nombor tempoh yang tidak diperlukan dipaparkan selepas pembayaran terakhir, anda boleh mempertimbangkan kerja yang telah dilakukan dan melangkau langkah ini. Jika anda berusaha untuk mencapai kesempurnaan, kemudian sembunyikan semua tempoh yang tidak digunakan dengan membuat peraturan pemformatan bersyarat yang menetapkan warna fon kepada putih untuk mana-mana baris selepas pembayaran terakhir dibuat.

Untuk ini, pilih semua baris data jika jadual pelunasan anda (A8:E367 dalam kes kami) dan klik tab Laman Utama > Pemformatan bersyarat > Peraturan Baharu… > Gunakan formula untuk menentukan sel mana yang hendak diformatkan .

Dalam kotak yang sepadan, masukkan formula di bawah yang menyemak sama ada nombor tempoh dalam lajur A lebih besar daripada jumlah bilangan pembayaran:

=$A8>$C$3*$C$4

Nota penting! Untuk formula pemformatan bersyarat berfungsi dengan betul, pastikan anda menggunakan rujukan sel mutlak untuk Tempoh pinjaman dan Pembayaran setahun sel yang anda darabkan ($C$3*$C$4). Produk dibandingkan dengan sel Tempoh 1, yang mana anda menggunakan rujukan sel bercampur - lajur mutlak dan baris relatif ($A8).

Selepas itu, klik Format… butang dan pilih warna fon putih. Selesai!

4. Buat ringkasan pinjaman

Untuk melihat maklumat ringkasan tentang pinjaman anda sepintas lalu, tambah beberapa lagi formula di bahagian atas jadual pelunasan anda.

Jumlah pembayaran ( F2):

=-SUM(B8:B367)

Jumlah faedah (F3):

=-SUM(C8:C367)

Jika anda mempunyai pembayaran sebagai nombor positif, alih keluar tanda tolak daripada formula di atas.

Itu sahaja! Jadual pelunasan pinjaman kami telah siap dan boleh digunakan!

Muat turun jadual pelunasan pinjaman untuk Excel

Cara membuat jadual pelunasan pinjaman dengan bayaran tambahan dalam Excel

Jadual pelunasan yang dibincangkan dalam contoh sebelumnya mudah dibuat dan diikuti (semoga :). Walau bagaimanapun, mereka meninggalkan ciri berguna yang ramai pembayar pinjaman berminat - bayaran tambahan untuk membayar pinjaman dengan lebih cepat. Dalam contoh ini, kita akan melihat cara membuat jadual pelunasan pinjaman dengan bayaran tambahan.

1. Tentukan sel input

Seperti biasa, mulakan dengan menyediakan sel input. Dalam kes ini, mari kita namakan sel-sel ini seperti yang ditulis di bawah untuk menjadikan formula kita lebih mudah dibaca:

• Kadar Faedah - C2 (faedah tahunankadar)
• Tempoh Pinjaman - C3 (tempoh pinjaman dalam tahun)
• PembayaranSetahun - C4 (bilangan pembayaran setahun)
• Jumlah Pinjaman - C5 (jumlah pinjaman)
• Bayaran Tambahan - C6 (bayaran tambahan setiap tempoh)

2. Kira bayaran berjadual

Selain daripada sel input, satu lagi sel pratakrif diperlukan untuk pengiraan lanjut kami - jumlah pembayaran berjadual , iaitu amaun yang perlu dibayar untuk pinjaman jika tiada tambahan pembayaran dibuat. Jumlah ini dikira dengan formula berikut:

=IFERROR(-PMT(InterestRate/PaymentsPerYear, LoanTerm*PaymentsPerYear, LoanAmount), "")

Sila ambil perhatian bahawa kami meletakkan tanda tolak sebelum fungsi PMT untuk mendapatkan hasilnya sebagai nombor positif. Untuk mengelakkan ralat sekiranya sesetengah sel input kosong, kami sertakan formula PMT dalam fungsi IFERROR.

Masukkan formula ini dalam beberapa sel (G2 dalam kes kami) dan namakan sel itu ScheduledPayment .

3. Sediakan jadual pelunasan

Buat jadual pelunasan pinjaman dengan pengepala ditunjukkan dalam tangkapan skrin di bawah. Dalam lajur Tempoh masukkan siri nombor yang bermula dengan sifar (anda boleh menyembunyikan baris Tempoh 0 kemudian jika perlu).

Jika anda berhasrat untuk mencipta yang boleh digunakan semula jadual pelunasan, masukkan bilangan maksimum tempoh pembayaran yang mungkin (0 hingga 360 dalam contoh ini).

Untuk Tempoh 0 (baris 9 dalam kes kami), tarik Baki nilai, yang sama dengan jumlah pinjaman asal. Semua yang lainsel dalam baris ini akan kekal kosong:

Formula dalam G9:

=LoanAmount

4. Bina formula untuk jadual pelunasan dengan bayaran tambahan

Ini ialah bahagian penting dalam kerja kami. Oleh kerana fungsi terbina dalam Excel tidak menyediakan pembayaran tambahan, kami perlu melakukan semua pengiraan sendiri.

Nota. Dalam contoh ini, Tempoh 0 berada di baris 9 dan Tempoh 1 berada di baris 10. Jika jadual pelunasan anda bermula dalam baris yang berbeza, sila pastikan anda melaraskan rujukan sel dengan sewajarnya.

Masukkan formula berikut dalam baris 10 ( Tempoh 1 ), dan kemudian salin ke bawah untuk semua tempoh yang tinggal.

Bayaran Berjadual (B10):

Jika amaun ScheduledPayment (bernama sel G2) adalah kurang daripada atau sama dengan baki yang tinggal (G9), gunakan pembayaran berjadual. Jika tidak, tambahkan baki yang tinggal dan faedah untuk bulan sebelumnya.

=IFERROR(IF(ScheduledPayment<=G9, ScheduledPayment, G9+G9*InterestRate/PaymentsPerYear), "")

Sebagai langkah berjaga-jaga tambahan, kami membalut formula ini dan semua formula berikutnya dalam fungsi IFERROR. Ini akan menghalang sekumpulan pelbagai ralat jika beberapa sel input kosong atau mengandungi nilai tidak sah.

Pembayaran Tambahan (C10):

Gunakan formula IF dengan logik berikut:

Jika amaun ExtraPayment (bernama sel C6) adalah kurang daripada perbezaan antara baki yang tinggal dan prinsipal tempoh ini (G9-E10), pulangkan ExtraPayment ; sebaliknya gunakan perbezaan.

=IFERROR(IF(ExtraPayment

Petua. Jika awak