V učbeniku je prikazano, kako v Excelu sestaviti amortizacijski načrt za podrobne podatke o rednih plačilih amortizacijskega posojila ali hipoteke.

Na spletni strani amortizacijsko posojilo je le lep izraz za posojilo, ki se odplačuje v obrokih ves čas trajanja posojila.

Vsa posojila se tako ali drugače amortizirajo. Na primer, posojilo, ki se v celoti amortizira za 24 mesecev, ima 24 enakih mesečnih plačil. Vsako plačilo se delno nanaša na glavnico, delno pa na obresti. Za podrobne podatke o vsakem plačilu posojila lahko sestavite amortizacijski načrt posojila.

Na spletni strani amortizacijski načrt je tabela, v kateri so navedena periodična plačila posojila ali hipoteke v določenem časovnem obdobju, vsako plačilo je razdeljeno na glavnico in obresti ter prikazano preostalo stanje po vsakem plačilu.

Kako ustvariti amortizacijski načrt posojila v Excelu

Za izdelavo amortizacijskega načrta posojila ali hipoteke v Excelu bomo morali uporabiti naslednje funkcije:

• Funkcija PMT - izračuna skupni znesek Ta znesek je konstanten ves čas trajanja posojila.
• Funkcija PPMT - pridobi glavni del vsakega plačila, ki se nameni za glavnico posojila, tj. znesek, ki ste si ga izposodili. Ta znesek se pri naslednjih plačilih povečuje.
• Funkcija IPMT - poišče obresti del vsakega plačila, ki gre za obresti. Ta znesek se z vsakim plačilom zmanjša.

Sedaj si postopek oglejmo korak za korakom.

1. Nastavite amortizacijsko tabelo

Za začetek določite vnosne celice, v katere boste vnesli znane sestavine posojila:

• C2 - letna obrestna mera
• C3 - trajanje posojila v letih
• C4 - število plačil na leto
• C5 - znesek posojila

Nato ustvarite amortizacijsko tabelo z oznakami ( Obdobje , Plačilo , Obresti , Glavni , Bilanca ) v A7:E7. V Obdobje vnesite niz številk, enak skupnemu številu plačil (1- 24 v tem primeru):

Ko so vsi znani sestavni deli na voljo, se lotimo najbolj zanimivega dela - formul amortizacije posojila.

2. Izračunajte skupni znesek plačila (formula PMT)

Znesek plačila se izračuna s funkcijo PMT(rate, nper, pv, [fv], [type]).

Za pravilno obdelavo različnih frekvenc plačil (kot so tedenska, mesečna, četrtletna itd.) morate biti dosledni pri vrednostih, ki jih navedete v polju stopnja in . nper argumenti:

• Stopnja - letno obrestno mero delite s številom plačilnih obdobij na leto ($C$2/$C$4).
• Nper - pomnožite število let s številom plačilnih obdobij na leto ($C$3*$C$4).
• Za pv vnesite znesek posojila ($C$5).
• Spletna stran fv in . vrsta argumente lahko izpustimo, saj nam njihove privzete vrednosti ustrezajo (stanje po zadnjem plačilu naj bi bilo 0; plačila se izvedejo ob koncu vsakega obdobja).

Če zgornje trditve združimo, dobimo tole formulo:

=PMT($C$2/$C$4, $C$3*$C$4, $C$5)

Bodite pozorni, da uporabljamo absolutne reference na celice, saj se mora ta formula kopirati v spodnje celice brez kakršnih koli sprememb.

Vnesite formulo PMT v polje B8, povlecite jo navzdol po stolpcu in videli boste konstanten znesek plačila za vsa obdobja:

3. Izračunajte obresti (formula IPMT)

Za iskanje obrestnega dela vsakega periodičnega plačila uporabite funkcijo IPMT(rate, per, nper, pv, [fv], [type]):

=IPMT($C$2/$C$4, A8, $C$3*$C$4, $C$5)

Vsi argumenti so enaki kot v formuli PMT, razen na Ta argument je naveden kot relativni sklic na celico (A8), ker naj bi se spreminjal glede na relativni položaj vrstice, v katero se kopira formula.

To formulo prenesite v C8, nato pa jo kopirajte v poljubno število celic:

4. Poiščite glavnico (formula PPMT)

Za izračun glavnice vsakega periodičnega plačila uporabite to formulo PPMT:

=PPMT($C$2/$C$4, A8, $C$3*$C$4, $C$5)

Sintaksa in argumenti so popolnoma enaki kot v formuli IPMT, ki smo jo obravnavali zgoraj:

Ta formula se uporablja v stolpcu D, ki se začne v D8:

Nasvet: Če želite preveriti, ali so vaši izračuni na tej točki pravilni, seštejte številke v Glavni in . Obresti Vsota mora biti enaka vrednosti v stolpcu Plačilo stolpec v isti vrstici.

5. Pridobite preostali znesek.

Za izračun preostalega zneska za vsako obdobje bomo uporabili dve različni formuli.

Za ugotovitev stanja po prvem plačilu v E8 seštejte znesek posojila (C5) in glavnico prvega obdobja (D8):

=C5+D8

Ker je znesek posojila pozitivno število, glavnica pa negativno, se slednja dejansko odšteje od prve.

Za drugo in vsa naslednja obdobja seštejte prejšnje stanje in glavnico tega obdobja:

=E8+D9

Zgornja formula se prenese v vrstico E9, nato pa jo kopirate navzdol po stolpcu. Zaradi uporabe relativnih sklicev na celice se formula pravilno prilagodi za vsako vrstico.

To je to! Naš mesečni amortizacijski načrt je pripravljen:

Nasvet: Vrnite plačila kot pozitivna števila

Ker se posojilo plačuje z vašega bančnega računa, funkcije programa Excel vrnejo plačilo, obresti in glavnico kot negativna števila Privzeto so te vrednosti označene z rdečo barvo in zaprte v oklepajih, kot je prikazano na zgornji sliki.

Če želite, da so vsi rezultati prikazani kot pozitivno pred funkcijami PMT, IPMT in PPMT postavite znak minus.

Za Bilanca formule, namesto seštevanja uporabite odštevanje, kot je prikazano na spodnji sliki zaslona:

Amortizacijski načrt za spremenljivo število obdobij

V zgornjem primeru smo sestavili amortizacijski načrt posojila za vnaprej določeno število plačilnih obdobij. Ta hitra enkratna rešitev je primerna za določeno posojilo ali hipoteko.

Če želite ustvariti amortizacijski načrt za večkratno uporabo s spremenljivim številom obdobij, boste morali uporabiti celovitejši pristop, opisan v nadaljevanju.

1. Vnesite največje število obdobij

V Obdobje v stolpec vstavite največje število plačil, ki jih boste dovolili za katero koli posojilo, na primer od 1 do 360. Za hitrejši vnos niza številk lahko uporabite Excelovo funkcijo samodejnega izpolnjevanja.

2. Uporaba izjav IF v formulah za amortizacijo

Ker imate zdaj veliko prevelikih številk obdobij, morate izračune nekako omejiti na dejansko število plačil za določeno posojilo. To lahko storite tako, da vsako formulo zavijete v izjavo IF. Logični test izjave IF preveri, ali je številka obdobja v trenutni vrstici manjša ali enaka skupnemu številu plačil. Če je logični test TRUE, se ustrezna formulafunkcija se izračuna; če je FALSE, se vrne prazen niz.

Ob predpostavki, da je Obdobje 1 je v vrstici 8, v ustrezne celice vnesite naslednje formule in jih nato kopirajte v celotno tabelo.

Plačilo (B8):

=IF(A8<=$C$3*$C$4, PMT($C$2/$C$4, $C$3*$C$4, $C$5), "")

Obresti (C8):

=IF(A8<=$C$3*$C$4, IPMT($C$2/$C$4, A8, $C$3*$C$4, $C$5), "")

Glavni (D8):

=IF(A8<=$C$3*$C$4,PPMT($C$2/$C$4, A8, $C$3*$C$4, $C$5), "")

Bilanca :

Za Obdobje 1 (E8), formula je enaka kot v prejšnjem primeru:

=C5+D8

Za Obdobje 2 (E9) in vseh naslednjih obdobjih je formula takšna:

=IF(A9<=$C$3*$C$4, E8+D9, "")

Rezultat tega je pravilno izračunan amortizacijski načrt in množica praznih vrstic s številkami obdobij po odplačilu posojila.

3. Skrijte številke dodatnih obdobij

Če lahko živite s kopico odvečnih številk obdobij, ki se prikažejo po zadnjem plačilu, lahko delo štejete za opravljeno in preskočite ta korak. Če si prizadevate za popolnost, skrijte vsa neuporabljena obdobja tako, da naredite pravilo pogojnega oblikovanja, ki nastavi barvo pisave na belo za vse vrstice po zadnjem plačilu.

Pri tem izberite vse podatkovne vrstice če je vaša amortizacijska tabela (v našem primeru A8:E367) in kliknite Domov zavihek> Pogojno oblikovanje > Novo pravilo... > S formulo določite, katere celice je treba oblikovati .

V ustrezno polje vnesite spodnjo formulo, ki preveri, ali je številka obdobja v stolpcu A večja od skupnega števila plačil:

=$A8>$C$3*$C$4

Pomembna opomba! Da bo formula pogojnega oblikovanja delovala pravilno, se prepričajte, da uporabljate absolutne reference na celice za Trajanje posojila in . Plačila na leto celic, ki jih pomnožite ($C$3*$C$4). Produkt se primerja z Obdobje 1 celica, za katero uporabljate mešano sklicevanje na celico - absolutni stolpec in relativna vrstica ($A8).

Nato kliknite Format... in izberite belo barvo pisave. Končano!

4. Naredite povzetek posojila

Če si želite na prvi pogled ogledati zbirne informacije o posojilu, dodajte še nekaj formul na vrh amortizacijskega načrta.

Skupna plačila (F2):

=-SUM(B8:B367)

Skupne obresti (F3):

=-SUM(C8:C367)

Če so plačila pozitivna števila, iz zgornjih formul odstranite znak minus.

To je to! Naš načrt amortizacije posojila je pripravljen in velja!

Prenesite amortizacijski načrt posojila za Excel

Kako narediti amortizacijski načrt posojila z dodatnimi plačili v Excelu

Amortizacijske načrte, obravnavane v prejšnjih primerih, je preprosto ustvariti in jim slediti (upajmo :). Vendar pa izpuščajo koristno funkcijo, ki zanima številne plačnike posojil - dodatna plačila za hitrejše odplačilo posojila. V tem primeru si bomo ogledali, kako ustvariti amortizacijski načrt posojila z dodatnimi plačili.

1. Opredelite vhodne celice

Kot običajno začnite z nastavljanjem vhodnih celic. V tem primeru poimenujmo te celice, kot je zapisano spodaj, da bodo naše formule lažje berljive:

• Obrestna mera - C2 (letna obrestna mera)
• LoanTerm - C3 (trajanje posojila v letih)
• Plačila na leto - C4 (število plačil na leto)
• LoanAmount - C5 (skupni znesek posojila)
• ExtraPayment - C6 (dodatno plačilo na obdobje)

2. Izračunajte načrtovano plačilo

Poleg vhodnih celic je za nadaljnje izračune potrebna še ena vnaprej določena celica - načrtovani znesek plačila , tj. znesek, ki ga je treba plačati za posojilo, če se ne izvedejo dodatna plačila. Ta znesek se izračuna z naslednjo formulo:

=IFERROR(-PMT(Obresti/plačila na leto, PosojiloTerm*Plačila na leto, PosojiloZnesek), "")

Bodite pozorni, da pred funkcijo PMT postavimo znak minus, da bo rezultat pozitivno število. Da bi preprečili napake v primeru, da so nekatere vhodne celice prazne, formulo PMT vključimo v funkcijo IFERROR.

To formulo vnesite v neko celico (v našem primeru G2) in jo poimenujte ScheduledPayment .

3. Nastavite amortizacijsko tabelo

Ustvarite amortizacijsko tabelo posojila z naslovi, prikazanimi na spodnji sliki zaslona. Obdobje vnesite niz številk, ki se začnejo z ničlo (lahko skrijete Obdobje 0 vrstico pozneje, če je potrebno).

Če želite ustvariti amortizacijski načrt za večkratno uporabo, vnesite največje možno število plačilnih obdobij (v tem primeru od 0 do 360).

Za Obdobje 0 (v našem primeru v vrstici 9), povlecite Bilanca ki je enaka prvotnemu znesku posojila. Vse druge celice v tej vrstici ostanejo prazne:

Formula v G9:

=Znesek posojila

4. Oblikujte formule za amortizacijski načrt z dodatnimi plačili

To je ključni del našega dela. Ker vgrajene funkcije programa Excel ne omogočajo dodatnih plačil, bomo morali vse matematične izračune opraviti sami.

Opomba: V tem primeru, Obdobje 0 je v vrstici 9 in Obdobje 1 je v vrstici 10. Če se vaša amortizacijska tabela začne v drugi vrstici, ustrezno prilagodite sklicevanja na celice.

V vrstico 10 vnesite naslednje formule ( Obdobje 1 ), nato pa jih prepišite za vsa preostala obdobja.

Načrtovano plačilo (B10):

Če je ScheduledPayment znesek (poimenovan v celici G2) je manjši ali enak preostalemu stanju (G9), uporabite načrtovano plačilo. V nasprotnem primeru prištejte preostalo stanje in obresti za prejšnji mesec.

=IFERROR(IF(ScheduledPayment<=G9, ScheduledPayment, G9+G9*InterestRate/PaymentsPerYear), "")

To in vse naslednje formule zavijemo v funkcijo IFERROR. Tako preprečimo različne napake, če so nekatere vhodne celice prazne ali vsebujejo neveljavne vrednosti.

Dodatno plačilo (C10):

Uporabite formulo IF z naslednjo logiko:

Če je ExtraPayment znesek (poimenovan v celici C6) je manjši od razlike med preostalim zneskom in glavnico za to obdobje (G9-E10), vrnite ExtraPayment ; sicer uporabite razliko.

=IFERROR(IF(ExtraPayment

Nasvet. Če imate spremenljiva dodatna plačila , vnesite posamezne zneske neposredno v polje Dodatno plačilo stolpec.

Skupno plačilo (D10)

Preprosto dodajte načrtovano plačilo (B10) in dodatno plačilo (C10) za tekoče obdobje:

=IFERROR(B10+C10, "")

Glavni (E10)

Če je plačilo po razporedu za določeno obdobje večje od nič, vrnite manjšo od dveh vrednosti: plačilo po razporedu minus obresti (B10-F10) ali preostali znesek (G9); v nasprotnem primeru vrnite nič.

=IFERROR(IF(B10>0, MIN(B10-F10, G9), 0), "")

Upoštevajte, da glavnica vključuje samo del načrtovano plačilo (ne dodatnega plačila!), ki se nameni za glavnico posojila.

Obresti (F10)

Če je plačilo po urniku za določeno obdobje večje od nič, delimo letno obrestno mero (celica C2) s številom plačil na leto (celica C4) in rezultat pomnožimo s preostankom po prejšnjem obdobju; v nasprotnem primeru vrnemo 0.

=IFERROR(IF(B10>0, InterestRate/PaymentsPerYear*G9, 0), "")

Bilanca (G10)

Če je preostalo stanje (G9) večje od nič, odštejemo glavnico plačila (E10) in dodatno plačilo (C10) od preostalega stanja po prejšnjem obdobju (G9); v nasprotnem primeru vrnemo 0.

=IFERROR(IF(G9>0, G9-E10-C10, 0), "")

Opomba: Ker se nekatere formule navzkrižno sklicujejo druga na drugo (ne krožno!), lahko med postopkom prikažejo napačne rezultate. Zato ne začnite odpravljati težav, dokler ne vnesete zadnje formule v amortizacijsko tabelo.

Če je vse pravilno izvedeno, bi moral biti vaš amortizacijski načrt na tej točki videti nekako takole:

5. Skrijte dodatna obdobja

Nastavite pravilo pogojnega oblikovanja za skrivanje vrednosti v neuporabljenih obdobjih, kot je razloženo v tem nasvetu. Razlika je v tem, da tokrat uporabimo pravilo bela barva pisave v vrstice, v katerih Skupno plačilo (stolpec D) in Bilanca (stolpec G) so enaki nič ali prazni:

=AND(OR($D9=0, $D9=""), OR($G9=0, $G9=""))

Voilà, vse vrstice z ničelnimi vrednostmi so skrite pred pogledom:

6. Naredite povzetek posojila

Za zaključek popolnosti lahko s temi formulami izpišete najpomembnejše informacije o posojilu:

Načrtovano število plačil:

Število let pomnožite s številom plačil na leto:

=Term posojila*Plačila na leto

Dejansko število plačil:

Preštejte celice v Skupno plačilo ki so večje od nič, začenši z obdobjem 1:

=COUNTIF(D10:D369,">"&0)

Skupna dodatna plačila:

Seštejte celice v Dodatno plačilo stolpec, začenši z obdobjem 1:

=SUM(C10:C369)

Skupne obresti:

Seštejte celice v Obresti stolpec, začenši z obdobjem 1:

=SUM(F10:F369)

Po želji skrijte Obdobje 0 in vaš amortizacijski načrt z dodatnimi plačili je pripravljen! Spodnja zaslonska slika prikazuje končni rezultat:

Prenos amortizacijskega načrta posojila z dodatnimi plačili

Amortizacijski načrt Excelova predloga

Če želite v hipu pripraviti vrhunski načrt amortizacije posojila, uporabite vgrajene predloge programa Excel. Pojdite na Datoteka > Novo , tip " amortizacijski načrt " v iskalno polje in izberite predlogo, ki vam je všeč, na primer to z dodatnimi plačili:

Nato novo ustvarjeni delovni zvezek shranite kot Excelovo predlogo in ga ponovno uporabite, kadar koli želite.

Tako v Excelu ustvarite amortizacijski načrt posojila ali hipoteke. Zahvaljujem se vam za branje in upam, da se naslednji teden vidimo na našem blogu!

Razpoložljivi prenosi

Primeri amortizacijskega načrta (.xlsx datoteka)