В урока е показано как да съставите амортизационен график в Excel, за да детайлизирате периодичните плащания по амортизируем заем или ипотека.

Един Амортизиращ се заем е просто красив начин да се определи заем, който се изплаща на вноски през целия срок на заема.

По принцип всички заеми се амортизират по един или друг начин. Например напълно амортизиран заем за 24 месеца ще има 24 равни месечни плащания. При всяко плащане част от сумата се отнася за главницата, а друга част - за лихвата. За да опишете подробно всяко плащане по заема, можете да съставите график за амортизация на заема.

Един Амортизационен план е таблица, в която се посочват периодичните плащания по заем или ипотека във времето, всяко плащане се разделя на главница и лихва и се показва оставащият баланс след всяко плащане.

Как да създадете амортизационен график на заем в Excel

За да съставим амортизационен график на заем или ипотека в Excel, ще трябва да използваме следните функции:

• Функция PMT - изчислява обща сума на периодично плащане. Тази сума остава постоянна за целия срок на кредита.
• Функция PPMT - получава Основен част от всяко плащане, която отива за покриване на главницата по кредита, т.е. сумата, която сте взели назаем. Тази сума се увеличава при следващите плащания.
• Функция IPMT - намира лихва част от всяко плащане, която отива за покриване на лихвите. Тази сума намалява с всяко плащане.

Сега нека преминем през процеса стъпка по стъпка.

1. Създаване на амортизационната таблица

Като начало дефинирайте входните клетки, в които ще въвеждате известните компоненти на кредита:

• C2 - годишен лихвен процент
• C3 - срок на заема в години
• C4 - брой плащания годишно
• C5 - размер на заема

Следващото нещо, което трябва да направите, е да създадете амортизационна таблица с етикетите ( Период , Плащане , Лихви , Основен , Баланс ) в A7:E7. В Период колона, въведете поредица от числа, равна на общия брой плащания (1- 24 в този пример):

След като всички известни компоненти са налице, нека преминем към най-интересната част - формулите за амортизация на кредита.

2. Изчисляване на общия размер на плащането (формула PMT)

Сумата на плащането се изчислява с функцията PMT(rate, nper, pv, [fv], [type]).

За да се обработват правилно различните честоти на плащане (например седмично, месечно, тримесечно и т.н.), трябва да се съобразявате със стойностите, предоставени за ставка и nper аргументи:

• Оценка - разделете годишния лихвен процент на броя на периодите на плащане за година ($C$2/$C$4).
• Nper - умножете броя на годините по броя на периодите на плащане за година ($C$3*$C$4).
• За pv въведете сумата на заема ($C$5).
• Сайтът fv и тип аргументите могат да бъдат пропуснати, тъй като стойностите им по подразбиране работят добре за нас (балансът след последното плащане трябва да бъде 0; плащанията се извършват в края на всеки период).

Ако съберем горните аргументи, ще получим тази формула:

=PMT($C$2/$C$4, $C$3*$C$4, $C$5)

Обърнете внимание, че използваме абсолютни препратки към клетките, тъй като тази формула трябва да се копира в долните клетки без никакви промени.

Въведете формулата PMT в B8, плъзнете я надолу по колоната и ще видите постоянна сума за плащане за всички периоди:

3. Изчисляване на лихвата (формула IPMT)

За намиране на лихвената част на всяко периодично плащане използвайте функцията IPMT(rate, per, nper, pv, [fv], [type]):

=IPMT($C$2/$C$4, A8, $C$3*$C$4, $C$5)

Всички аргументи са същите като във формулата PMT, с изключение на на Този аргумент се предоставя като относителна референция към клетка (A8), тъй като се очаква да се променя в зависимост от относителната позиция на реда, в който се копира формулата.

Формулата се пренася в C8 и след това се копира надолу в толкова клетки, колкото е необходимо:

4. Намиране на главницата (формула PPMT)

За да изчислите частта от главницата на всяко периодично плащане, използвайте тази формула PPMT:

=PPMT($C$2/$C$4, A8, $C$3*$C$4, $C$5)

Синтаксисът и аргументите са абсолютно същите като при формулата IPMT, разгледана по-горе:

Тази формула се отнася за колона D, започвайки от D8:

Съвет. За да проверите дали изчисленията ви са правилни в този момент, съберете числата в Основен и Лихви Сумата трябва да е равна на стойността в Плащане колона в същия ред.

5. Вземете остатъка от сумата

За да изчислим остатъчния баланс за всеки период, ще използваме две различни формули.

За да откриете салдото след първото плащане в E8, съберете сумата на кредита (C5) и главницата от първия период (D8):

=C5+D8

Тъй като размерът на кредита е положително число, а главницата е отрицателно число, последното всъщност се изважда от първото.

За втория и всички следващи периоди съберете предишното салдо и главницата за този период:

=E8+D9

Горната формула отива в E9 и след това я копирате надолу по колоната. Благодарение на използването на относителни препратки към клетките формулата се настройва правилно за всеки ред.

Това е всичко! Графикът за месечна амортизация на кредита е готов:

Съвет: Връщайте плащанията като положителни числа

Тъй като заемът се изплаща от банковата ви сметка, функциите на Excel връщат плащането, лихвата и главницата като отрицателни числа По подразбиране тези стойности са подчертани в червено и са затворени в скоби, както можете да видите на изображението по-горе.

Ако предпочитате да получите всички резултати като положителен числа, поставете знак минус пред функциите PMT, IPMT и PPMT.

За Баланс формулите, използвайте изваждане вместо събиране, както е показано на снимката по-долу:

Амортизационен план за променлив брой периоди

В горния пример създадохме амортизационен график на заема за предварително определения брой периоди на плащане. Това бързо еднократно решение работи добре за конкретен заем или ипотека.

Ако искате да създадете амортизационен график за многократна употреба с променлив брой периоди, ще трябва да приложите по-обстоен подход, описан по-долу.

1. Въведете максималния брой периоди

В Период колона, въведете максималния брой плащания, които ще разрешите за всеки заем, например от 1 до 360. Можете да използвате функцията за автоматично попълване на Excel, за да въведете поредица от числа по-бързо.

2. Използване на оператори IF във формулите за амортизация

Тъй като сега имате много прекомерни номера на периоди, трябва по някакъв начин да ограничите изчисленията до действителния брой плащания за даден заем. Това може да стане, като всяка формула се обгърне в изявление IF. Логическият тест на изявлението IF проверява дали номерът на периода в текущия ред е по-малък или равен на общия брой плащания. Ако логическият тест е TRUE, съответнотосе изчислява функцията; ако е FALSE, се връща празен низ.

Ако приемем, че Период 1 е в ред 8, въведете следните формули в съответните клетки и след това ги копирайте в цялата таблица.

Плащане (B8):

=IF(A8<=$C$3*$C$4, PMT($C$2/$C$4, $C$3*$C$4, $C$5), "")

Лихви (C8):

=IF(A8<=$C$3*$C$4, IPMT($C$2/$C$4, A8, $C$3*$C$4, $C$5), "")

Основен (D8):

=IF(A8<=$C$3*$C$4,PPMT($C$2/$C$4, A8, $C$3*$C$4, $C$5), "")

Баланс :

За Период 1 (E8), формулата е същата като в предишния пример:

=C5+D8

За Период 2 (E9) и всички следващи периоди, формулата придобива следния вид:

=IF(A9<=$C$3*$C$4, E8+D9, "")

В резултат на това имате правилно изчислен амортизационен план и куп празни редове с номерата на периодите след изплащането на кредита.

3. Скриване на номерата на допълнителните периоди

Ако можете да живеете с куп излишни цифри на периодите, показвани след последното плащане, можете да считате работата за свършена и да пропуснете тази стъпка. Ако се стремите към съвършенство, скрийте всички неизползвани периоди, като създадете правило за условно форматиране, което задава цвят на шрифта на бял за всички редове след извършване на последното плащане.

За тази цел изберете всички редове с данни ако вашата амортизационна таблица (A8:E367 в нашия случай) и щракнете върху Начало tab> Условно форматиране > Ново правило... > Използвайте формула, за да определите кои клетки да форматирате .

В съответното поле въведете следната формула, която проверява дали номерът на периода в колона А е по-голям от общия брой плащания:

=$A8>$C$3*$C$4

Важна забележка! За да работи правилно формулата за условно форматиране, не забравяйте да използвате абсолютни препратки към клетките за Срок на заема и Плащания на година клетки, които умножавате ($C$3*$C$4). Произведението се сравнява с Период 1 клетка, за която се използва смесена референция към клетка - абсолютна колона и относителен ред ($A8).

След това щракнете върху Формат... и изберете бял цвят на шрифта. Готово!

4. Направете резюме на заема

За да видите от пръв поглед обобщената информация за вашия заем, добавете още няколко формули в горната част на амортизационния график.

Общо плащания (F2):

=-SUM(B8:B367)

Обща лихва (F3):

=-SUM(C8:C367)

Ако плащанията са положителни числа, премахнете знака минус от горните формули.

Графикът за амортизация на кредита е завършен и готов за работа!

Изтегляне на график за амортизация на кредита за Excel

Как да съставите амортизационен график на заем с допълнителни плащания в Excel

Амортизационните графици, разгледани в предишните примери, са лесни за създаване и следване (надявам се :). В тях обаче е пропусната една полезна функция, от която се интересуват много кредитополучатели - допълнителни плащания за по-бързо погасяване на кредита. В този пример ще разгледаме как да създадем амортизационен график на кредит с допълнителни плащания.

1. Определяне на входните клетки

Както обикновено, започнете с настройката на входните клетки. В този случай нека наименуваме тези клетки, както е написано по-долу, за да направим формулите си по-лесни за четене:

• Лихвен процент - C2 (годишен лихвен процент)
• LoanTerm - C3 (срок на заема в години)
• Плащания на година - C4 (брой плащания годишно)
• LoanAmount - C5 (общ размер на заема)
• ExtraPayment - C6 (допълнително плащане за период)

2. Изчисляване на планирано плащане

Освен входните клетки, за по-нататъшните ни изчисления е необходима още една предварително дефинирана клетка - размер на планираното плащане , т.е. сумата, която трябва да се плати по кредита, ако не се правят допълнителни плащания. Тази сума се изчислява по следната формула:

=IFERROR(-PMT(InterestRate/PaymentsPerYear, LoanTerm*PaymentsPerYear, LoanAmount), "")

Обърнете внимание, че преди функцията PMT поставяме знак минус, за да бъде резултатът положително число. За да се предотвратят грешки, в случай че някои от входните клетки са празни, ние включваме формулата PMT във функцията IFERROR.

Въведете тази формула в някоя клетка (в нашия случай G2) и дайте име на тази клетка ScheduledPayment .

3. Създаване на амортизационната таблица

Създайте таблица за амортизацията на заема със заглавията, показани на екранната снимка по-долу. Период колона въведете поредица от числа, започващи с нула (можете да скриете Период 0 ред по-късно, ако е необходимо).

Ако искате да създадете амортизационен график за многократно използване, въведете максималния възможен брой периоди на плащане (от 0 до 360 в този пример).

За Период 0 (ред 9 в нашия случай), издърпайте Баланс Всички останали клетки в този ред ще останат празни:

Формула в G9:

=Стойност на заема

4. Изграждане на формули за амортизационен график с допълнителни плащания

Това е ключова част от работата ни. Тъй като вградените функции на Excel не предвиждат допълнителни плащания, ще трябва да направим всички изчисления сами.

Забележка. В този пример, Период 0 е в ред 9, а Период 1 е в ред 10. Ако вашата амортизационна таблица започва от друг ред, не забравяйте да коригирате съответно препратките към клетките.

Въведете следните формули в ред 10 ( Период 1 ), а след това ги препишете за всички останали периоди.

Планирано плащане (B10):

Ако ScheduledPayment сумата (посочена в клетка G2) е по-малка или равна на остатъчното салдо (G9), използвайте планираното плащане. В противен случай добавете остатъчното салдо и лихвата за предходния месец.

=IFERROR(IF(ScheduledPayment<=G9, ScheduledPayment, G9+G9*InterestRate/PaymentsPerYear), "")

Като допълнителна предпазна мярка тази и всички следващи формули са обвити във функцията IFERROR. Това ще предотврати появата на множество различни грешки, ако някои от входните клетки са празни или съдържат невалидни стойности.

Допълнително плащане (C10):

Използвайте формула IF със следната логика:

Ако ExtraPayment сумата (посочена в клетка C6) е по-малка от разликата между остатъка и главницата за този период (G9-E10), върнете ExtraPayment ; в противен случай използвайте разликата.

=IFERROR(IF(ExtraPayment

Съвет. Ако имате променливи допълнителни плащания , просто въведете отделните суми директно в Допълнително плащане колона.

Общо плащане (D10)

Просто добавете планираното плащане (B10) и допълнителното плащане (C10) за текущия период:

=IFERROR(B10+C10, "")

Основен (E10)

Ако плащането по график за даден период е по-голямо от нула, се връща по-малката от двете стойности: плащането по график минус лихвата (B10-F10) или остатъчното салдо (G9); в противен случай се връща нула.

=IFERROR(IF(B10>0, MIN(B10-F10, G9), 0), "")

Моля, обърнете внимание, че главницата включва само частта от планирано плащане (а не допълнителната вноска!), която отива за покриване на главницата по кредита.

Лихви (F10)

Ако плащането по графика за даден период е по-голямо от нула, разделете годишния лихвен процент (клетка C2) на броя на плащанията за година (клетка C4) и умножете резултата по салдото, оставащо след предходния период; в противен случай върнете 0.

=IFERROR(IF(B10>0, InterestRate/PaymentsPerYear*G9, 0), "")

Баланс (G10)

Ако оставащият баланс (G9) е по-голям от нула, извадете частта от главницата на плащането (E10) и допълнителното плащане (C10) от баланса, останал след предходния период (G9); в противен случай върнете 0.

=IFERROR(IF(G9>0, G9-E10-C10, 0), "")

Забележка: Тъй като някои от формулите се препращат една към друга (а не кръгова препратка!), те могат да покажат грешни резултати в процеса. Затова, моля, не започвайте да отстранявате проблеми, докато не въведете последната формула във вашата амортизационна таблица.

Ако всичко е направено правилно, амортизационният график на кредита ви в този момент трябва да изглежда по следния начин:

5. Скриване на допълнителни часове

Създайте правило за условно форматиране, за да скриете стойностите в неизползваните периоди, както е обяснено в този съвет. Разликата е, че този път прилагаме бял цвят на шрифта към редовете, в които Общо плащане (колона D) и Баланс (колона G) са равни на нула или са празни:

=AND(OR($D9=0, $D9=""), OR($G9=0, $G9="")

Voilà, всички редове с нулеви стойности са скрити от погледа:

6. Направете обобщение на заема

Като завършек на съвършенството можете да изведете най-важната информация за даден заем, като използвате тези формули:

Планиран брой плащания:

Умножете броя на годините по броя на плащанията на година:

=Срок на заема*Плащания за година

Действителен брой плащания:

Пребройте клетките в Общо плащане колона, които са по-големи от нула, като се започне от период 1:

=COUNTIF(D10:D369,">"&0)

Общо допълнителни плащания:

Съберете клетките в Допълнително плащане колона, като се започне от период 1:

=SUM(C10:C369)

Общ интерес:

Съберете клетките в Лихви колона, като се започне от период 1:

=SUM(F10:F369)

По желание скрийте Период 0 и вашият график за амортизация на кредита с допълнителни плащания е готов! Крайният резултат е показан на снимката по-долу:

Изтегляне на амортизационен график на кредита с допълнителни плащания

Амортизационен план Excel шаблон

За да съставите за нула време първокласен график за амортизация на заема, използвайте вградените шаблони на Excel. Просто отидете на Файл > Нов , тип " Амортизационен план " в полето за търсене и изберете шаблона, който ви харесва, например този с допълнителни плащания:

След това запазете новосъздадената работна книга като шаблон на Excel и я използвайте отново, когато пожелаете.

Ето как създавате амортизационен график на заем или ипотека в Excel. Благодаря ви за прочитането и се надявам да се видим в нашия блог следващата седмица!

Налични изтегляния

Примери за амортизационен план (.xlsx файл)