У навчальному посібнику показано, як побудувати графік амортизації в Excel для деталізації періодичних платежів за кредитом або іпотекою, що амортизується.

An амортизаційний кредит це просто модний спосіб визначення кредиту, який погашається частинами протягом усього терміну кредитування.

В основному, всі кредити так чи інакше амортизуються. Наприклад, кредит, що повністю амортизується протягом 24 місяців, матиме 24 рівних щомісячних платежі. Кожен платіж відноситься до основної суми, а частина - до відсотків. Щоб деталізувати кожен платіж за кредитом, можна побудувати графік амортизації кредиту.

An графік амортизації це таблиця, в якій перераховані періодичні платежі за кредитом або іпотекою в часі, кожен платіж розбитий на основну суму та відсотки, а також показаний залишок після кожного платежу.

Як створити графік амортизації кредиту в Excel

Для побудови графіка амортизації кредиту або іпотеки в Excel нам знадобиться скористатися наступними функціями:

• Функція PMT - розраховує загальна сума Ця сума залишається незмінною протягом усього терміну дії кредиту.
• Функція PPMT - отримує головний частина кожного платежу, яка йде на погашення тіла кредиту, тобто суми, яку ви взяли в борг. Ця сума збільшується при наступних платежах.
• Функція IPMT - знаходить інтерес частина кожного платежу, яка йде на сплату відсотків. Ця сума зменшується з кожним платежем.

Тепер давайте пройдемо цей процес крок за кроком.

1. налаштувати таблицю амортизації

Для початку визначте комірки, в які ви будете вводити відомі компоненти кредиту:

• С2 - річна процентна ставка
• С3 - строк кредиту в роках
• C4 - кількість платежів на рік
• С5 - сума кредиту

Наступне, що потрібно зробити, це створити таблицю амортизації з мітками ( Період , Оплата , Відсотки , Директор , Баланс ) на A7:E7. У Період введіть ряд чисел, що дорівнює загальній кількості платежів (1- 24 у даному прикладі):

Маючи всі відомі складові, перейдемо до найцікавішого - формули амортизації кредитів.

2. розрахувати загальну суму платежу (формула PMT)

Сума платежу розраховується за допомогою функції ПМТ(ставка, nпер, pv, [fv], [тип]).

Для коректної обробки різних частот платежів (наприклад, щотижневих, щомісячних, щоквартальних і т.д.) слід дотримуватися значень, вказаних для ставка і nper аргументи:

• Ставка - розділити річну процентну ставку на кількість платіжних періодів у році ($C$2/$C$4).
• Nper - помножити кількість років на кількість платіжних періодів у році ($C$3*$C$4).
• Для pv аргумент, введіть суму кредиту ($C$5).
• На сьогоднішній день, на жаль, це не так. fv і тип можна опустити, оскільки їх значення за замовчуванням для нас чудово працюють (баланс після останнього платежу передбачається рівним 0; платежі здійснюються в кінці кожного періоду).

Склавши наведені вище аргументи докупи, отримуємо таку формулу:

=PMT($C$2/$C$4, $C$3*$C$4, $C$5)

Зверніть увагу, що ми використовуємо абсолютні посилання на комірки, оскільки ця формула повинна копіюватися в наступні комірки без будь-яких змін.

Введіть формулу PMT в B8, перетягніть її вниз по стовпчику, і ви побачите постійну суму платежу для всіх періодів:

3. розрахунок відсотків (формула IPMT)

Для знаходження процентної частини кожного періодичного платежу використовується функція ИПМТ(ставка, per, nper, pv, [fv], [тип]):

=IPMT($C$2/$C$4, A8, $C$3*$C$4, $C$5)

Всі аргументи такі ж, як і у формулі ПМТ, за винятком за аргумент, що визначає період платежу. Цей аргумент подається у вигляді відносного посилання на комірку (А8), оскільки передбачається, що він змінюється залежно від відносного положення рядка, в який копіюється формула.

Ця формула потрапляє в комірку С8, а потім ви копіюєте її вниз у стільки комірок, скільки потрібно:

4. знайти основну суму (формула PPMT)

Для розрахунку основної частини кожного періодичного платежу використовуйте цю формулу PPMT:

=PPMT($C$2/$C$4, A8, $C$3*$C$4, $C$5)

Синтаксис і аргументи точно такі ж, як і у формулі IPMT, розглянутій вище:

Ця формула переходить до колонки D, починаючи з D8:

Порада: щоб перевірити, чи правильні ваші розрахунки на даному етапі, складіть цифри в Директор і Відсотки Сума повинна дорівнювати значенню в колонці Оплата стовпчик у тому ж рядку.

5. отримати залишок коштів

Для розрахунку залишків для кожного періоду ми будемо використовувати дві різні формули.

Щоб знайти залишок після першого платежу в E8, складіть суму кредиту (C5) та основну суму боргу першого періоду (D8):

=C5+D8

Оскільки сума кредиту є додатним числом, а основна сума боргу - від'ємним, остання фактично віднімається від першої.

Для другого та всіх наступних періодів необхідно скласти попередній залишок та основну суму боргу за цей період:

=E8+D9

Наведена вище формула переходить в Е9, а потім копіюється вниз по стовпчику. Завдяки використанню відносних посилань на комірки, формула коректно підлаштовується під кожен рядок.

Все, графік щомісячного погашення кредиту виконано:

Порада: повертайте платежі позитивними числами

Оскільки кредит виплачується з вашого банківського рахунку, функції Excel повертають платіж, відсотки та основну суму боргу у вигляді від'ємні числа За замовчуванням ці значення виділені червоним кольором і взяті в круглі дужки, як ви можете бачити на зображенні вище.

Якщо Ви бажаєте отримати всі результати у вигляді позитивний перед функціями PMT, IPMT та PPMT ставлять знак мінус.

Для Баланс у формулах використовуйте віднімання замість додавання, як показано на скріншоті нижче:

Графік амортизації зі змінною кількістю періодів

У наведеному вище прикладі ми побудували графік амортизації кредиту на заздалегідь визначену кількість платіжних періодів. Це швидке одноразове рішення добре працює для конкретного кредиту або іпотеки.

Якщо ви хочете створити багаторазовий графік амортизації зі змінною кількістю періодів, вам доведеться застосувати більш комплексний підхід, описаний нижче.

1. введіть максимальну кількість періодів

В рамках проекту Період введіть максимальну кількість платежів, яку ви збираєтеся дозволити для будь-якого кредиту, скажімо, від 1 до 360. Ви можете скористатися функцією автозаповнення Excel, щоб швидше ввести ряд чисел.

2. використовувати оператори IF у формулах амортизації

Оскільки тепер у вас є багато зайвих номерів періодів, необхідно якось обмежити розрахунки до фактичної кількості платежів по конкретному кредиту. Це можна зробити, обернувши кожну формулу в оператор ЕСЛИ. Логічний тест оператора ЕСЛИ перевіряє, чи номер періоду в поточному рядку менше або дорівнює загальній кількості платежів. Якщо логічний тест має значення ІСТИНА, то відповідна функціяобчислюється функція, якщо FALSE, то повертається пустий рядок.

Припускаючи, що Період 1 знаходиться в рядку 8, введіть наступні формули у відповідні комірки, а потім скопіюйте їх по всій таблиці.

Оплата (B8):

=IF(A8<=$C$3*$C$4, PMT($C$2/$C$4, $C$3*$C$4, $C$5), "")

Відсотки (C8):

=IF(A8<=$C$3*$C$4, IPMT($C$2/$C$4, A8, $C$3*$C$4, $C$5), "")

Директор (D8):

=IF(A8<=$C$3*$C$4,PPMT($C$2/$C$4, A8, $C$3*$C$4, $C$5), "")

Баланс :

За Період 1 (E8), формула така ж, як і в попередньому прикладі:

=C5+D8

За Період 2 (E9) та всіх наступних періодів формула набуває такого вигляду:

=IF(A9<=$C$3*$C$4, E8+D9, "")

В результаті ви маєте правильно розрахований графік амортизації і купу порожніх рядків з номерами періодів після погашення кредиту.

3. приховати зайві номери періодів

Якщо ви можете жити з купою зайвих номерів періодів, що відображаються після останньої оплати, то можете вважати роботу виконаною і пропустити цей крок. Якщо ж ви прагнете до досконалості, то приховайте всі невикористані періоди, зробивши умовне правило форматування, яке задає колір шрифту - білий для будь-яких рядків після здійснення останнього платежу.

Для цього необхідно вибрати всі рядки даних якщо ваша таблиця амортизації (A8:E367 в нашому випадку) і натисніть Головна сторінка вкладка> Умовне форматування > Нове правило... > Використовуйте формулу, щоб визначити, які клітинки форматувати .

У відповідному полі введіть наведену нижче формулу, яка перевіряє, чи є номер періоду в колонці А більшим за загальну кількість платежів:

=$A8>$C$3*$C$4

Щоб формула умовного форматування працювала коректно, обов'язково використовуйте абсолютні посилання на комірки для Строк кредитування і Платежі на рік клітинок, які ви перемножуєте ($C$3*$C$4). Добуток порівнюється з Період 1 комірка, для якої використовується змішане посилання на комірку - абсолютний стовпець і відносний рядок ($A8).

Після цього натисніть кнопку Формат... та оберіть білий колір шрифту. Готово!

4. скласти резюме по кредиту

Щоб переглянути зведену інформацію про ваш кредит з першого погляду, додайте ще кілька формул у верхній частині графіка амортизації.

Загальна сума виплат (F2):

=-SUM(B8:B367)

Загальна сума відсотків (F3):

=-SUM(C8:C367)

Якщо у Вас платежі є додатними числами, приберіть знак "мінус" з наведених вище формул.

Ось і все, графік амортизації кредиту завершено, і ми готові до роботи!

Завантажити графік амортизації кредиту в Excel

Як скласти графік амортизації кредиту з доплатами в Excel

Графіки амортизації, розглянуті в попередніх прикладах, прості у створенні та виконанні (сподіваємось :)). Однак вони не враховують корисну функцію, яка цікавить багатьох платників кредитів - додаткові платежі для швидшого погашення кредиту. У цьому прикладі ми розглянемо, як створити графік амортизації кредиту з додатковими платежами.

1. визначте вхідні комірки

Як завжди, почнемо з налаштування комірок введення. В даному випадку назвемо ці комірки так, як написано нижче, щоб наші формули було легше читати:

• Відсоткова ставка - С2 (річна процентна ставка)
• Строк кредитування - С3 (строк кредиту в роках)
• Виплати за рік - C4 (кількість платежів на рік)
• Сума кредиту - С5 (загальна сума кредиту)
• Додаткова оплата - С6 (доплата за період)

2. розрахувати плановий платіж

Окрім вхідних комірок, для подальших розрахунків необхідна ще одна попередньо визначена комірка - комірка запланована сума платежу тобто сума, яку необхідно сплатити за кредитом без додаткових платежів. Ця сума розраховується за наступною формулою:

=IFERROR(-PMT(InterestRate/PaymentsPer Year, LoanTerm*PaymentsPer Year, LoanAmount), "")

Зверніть увагу, що перед функцією PMT ми ставимо знак мінус, щоб результат був позитивним числом. Для запобігання помилок у випадку, якщо деякі з вхідних комірок порожні, формулу PMT ми помістили у функцію IFERROR.

Введіть цю формулу в деяку комірку (в нашому випадку G2) і дайте їй ім'я Плановий платіж .

3. налаштувати таблицю амортизації

Створіть таблицю амортизації кредиту із заголовками, як показано на скріншоті нижче. Період введіть ряд чисел, починаючи з нуля (можна приховати стовпчик Період 0 за необхідності, рядок пізніше).

Якщо ви маєте на меті створити багаторазовий графік амортизації, введіть максимально можливу кількість платіжних періодів (від 0 до 360 у цьому прикладі).

За Період 0 (в нашому випадку 9-й рядок), потягніть за Баланс значення, яке дорівнює початковій сумі кредиту. Всі інші комірки цього рядка залишаються порожніми:

Формула в G9:

=Сума кредиту

4. побудувати формули для амортизаційного графіку з доплатами

Це ключова частина нашої роботи. Оскільки вбудовані функції Excel не передбачають додаткових платежів, нам доведеться робити всі розрахунки самостійно.

Примітка. У цьому прикладі, Період 0 знаходиться в рядку 9 і Період 1 знаходиться в рядку 10. Якщо Ваша таблиця амортизації починається з іншого рядка, будь ласка, обов'язково змініть посилання на комірки відповідним чином.

У рядку 10 введіть наступні формули ( Період 1 ), а потім скопіювати їх для всіх інших періодів.

Плановий платіж (B10):

У разі, якщо Плановий платіж сума (комірка G2) менша або дорівнює залишку (G9), скористайтеся плановим платежем. В іншому випадку додайте залишок та проценти за попередній місяць.

=IFERROR(IF(ScheduledPayment<=G9, ScheduledPayment, G9+G9*InterestRate/PaymentsPerYear), "")

В якості додаткової обережності ми обертаємо цю і всі наступні формули у функцію ЕСЛИ. Це дозволить уникнути купи різноманітних помилок, якщо деякі з вхідних комірок будуть порожніми або міститимуть невірні значення.

Додаткова оплата (C10):

Використовуйте формулу ЯКЩО з наступною логікою:

У разі, якщо Додаткова оплата сума (комірка С6) менша за різницю між залишком та основною сумою боргу за цей період (G9-E10), повернення Додаткова оплата інакше використовуйте різницю.

=IFERROR(IF(ExtraPayment

Порада. Якщо у вас є змінні додаткові виплати просто введіть окремі суми безпосередньо в поле Додаткова оплата колонка.

Загальна сума платежу (D10)

Просто додайте плановий платіж (B10) та додатковий платіж (C10) за поточний період:

=IFERROR(B10+C10, "")

Директор (E10)

Якщо плановий платіж за даний період більше нуля, повернути менше з двох значень: плановий платіж мінус відсотки (B10-F10) або залишок (G9); в іншому випадку повернути нуль.

=IFERROR(IF(B10>0, MIN(B10-F10, G9), 0), "")

Звертаємо Вашу увагу, що основна сума включає в себе лише частину плановий платіж (не додатковий платіж!), що йде на погашення основної суми кредиту.

Відсотки (F10)

Якщо графічний платіж за даний період більше нуля, розділіть річну процентну ставку (назва комірки С2) на кількість платежів на рік (назва комірки С4) і помножте результат на залишок, що залишився після попереднього періоду; в іншому випадку поверніть 0.

=IFERROR(IF(B10>0, InterestRate/PaymentsPerYear*G9, 0), "")

Баланс (G10)

Якщо залишок (G9) більше нуля, від залишку, що залишився після попереднього періоду (G9), відняти основну частину платежу (E10) та додатковий платіж (C10); в іншому випадку повернути 0.

=IFERROR(IF(G9>0, G9-E10-C10, 0), "")

Примітка: Оскільки деякі формули мають перехресні посилання одна на одну (не циклічні!), вони можуть показувати неправильні результати в процесі роботи. Тому, будь ласка, не починайте пошук несправностей, поки не введете останню формулу в таблицю амортизації.

Якщо все зроблено правильно, графік амортизації вашого кредиту на цьому етапі повинен виглядати приблизно так:

5. приховування зайвих періодів

Налаштуйте правило умовного форматування, щоб приховати значення в невикористаних періодах, як описано в цій підказці. Різниця полягає в тому, що цього разу ми застосуємо правило білий колір шрифту до рядків, в яких Загальна сума платежу (колонка D) та Баланс (колонка G) дорівнюють нулю або є порожніми:

=AND(OR($D9=0, $D9=""), OR($G9=0, $G9=""))

Вуаля, всі рядки з нульовими значеннями приховані від перегляду:

6. скласти резюме по кредиту

Як останній штрих досконалості, за допомогою цих формул можна вивести найважливішу інформацію про кредит:

Запланована кількість виплат:

Помножте кількість років на кількість платежів на рік:

= Строк кредитування*Платежі на рік

Фактична кількість платежів:

Порахувати клітинки в комірці Загальна сума платежу стовпчику, що є більшими за нуль, починаючи з Періоду 1:

=COUNTIF(D10:D369,">"&0)

Загальна сума доплат:

Підсумуйте клітинки в комірці Додаткова оплата стовпчик, починаючи з Періоду 1:

=SUM(C10:C369)

Загальний інтерес:

Підсумуйте клітинки в комірці Відсотки стовпчик, починаючи з Періоду 1:

=SUM(F10:F369)

За бажанням, приховати Період 0 і Ваш графік амортизації кредиту з додатковими платежами готовий! На скріншоті нижче показано кінцевий результат:

Завантажити графік погашення кредиту з доплатами

Шаблон графіка амортизації Excel

Щоб швидко і якісно скласти графік амортизації кредиту, скористайтеся вбудованими шаблонами Excel. Просто перейдіть за посиланням Файл > Новий введіть " графік амортизації " у вікні пошуку та оберіть вподобаний шаблон, наприклад, цей з доплатами:

Потім збережіть новостворену книгу як шаблон Excel і використовуйте її повторно, коли захочете.

Ось так створюється графік амортизації кредиту або іпотеки в Excel. Дякую за прочитання і сподіваюся побачити Вас на нашому блозі наступного тижня!

Доступні для завантаження

Приклади графіків амортизації (файл .xlsx)