Ipinapakita ng tutorial kung paano bumuo ng iskedyul ng amortization sa Excel para i-detalye ang mga pana-panahong pagbabayad sa isang amortizing loan o mortgage.

Ang isang amortizing loan ay isa lamang magarbong paraan para tukuyin ang isang loan na binabayaran nang installment sa buong termino ng loan.

Sa pangkalahatan, lahat ng loan ay nag-amortize sa isang paraan o iba pa. Halimbawa, ang isang ganap na amortizing loan para sa 24 na buwan ay magkakaroon ng 24 na pantay na buwanang pagbabayad. Ang bawat pagbabayad ay naglalapat ng ilang halaga sa prinsipal at ang ilan sa interes. Upang i-detalye ang bawat pagbabayad sa isang loan, maaari kang bumuo ng iskedyul ng amortization ng loan.

Ang isang iskedyul ng amortization ay isang talahanayan na naglilista ng mga pana-panahong pagbabayad sa isang loan o mortgage sa paglipas ng panahon, pinaghiwa-hiwalay ang bawat pagbabayad sa punong-guro at interes, at ipinapakita ang natitirang balanse pagkatapos ng bawat pagbabayad.

Paano gumawa ng iskedyul ng amortization ng loan sa Excel

Upang bumuo ng iskedyul ng amortization ng loan o mortgage sa Excel, kakailanganin naming gamitin ang mga sumusunod na function:

• PMT function - kinakalkula ang kabuuang halaga ng isang pana-panahong pagbabayad. Ang halagang ito ay nananatiling pare-pareho sa buong tagal ng loan.
• PPMT function - nakukuha ang principal na bahagi ng bawat pagbabayad na napupunta sa loan principal, ibig sabihin, ang halagang iyong hiniram. Ang halagang ito ay tumataas para sa mga kasunod na pagbabayad.
• IPMT function - hinahanap ang interes na bahagi ng bawat pagbabayad na napupunta sa interes.may variable na karagdagang mga pagbabayad , i-type lang ang mga indibidwal na halaga nang direkta sa column na Extra Payment .

  Kabuuang Bayad (D10)

  Simple lang, idagdag ang nakaiskedyul na pagbabayad (B10) at ang dagdag na pagbabayad (C10) para sa kasalukuyang panahon:

  =IFERROR(B10+C10, "")

  Principal (E10)

  Kung ang iskedyul ng pagbabayad para sa isang partikular na panahon ay higit sa zero, ibalik ang mas maliit sa dalawang halaga: naka-iskedyul na pagbabayad na binawasan ang interes (B10-F10) o ang natitirang balanse (G9); kung hindi, ibalik ang zero.

  =IFERROR(IF(B10>0, MIN(B10-F10, G9), 0), "")

  Pakitandaan na kasama lang ng prinsipal ang bahagi ng nakaiskedyul na pagbabayad (hindi ang dagdag na bayad!) na napupunta sa punong-guro ng pautang.

  Interes (F10)

  Kung ang iskedyul ng pagbabayad para sa isang partikular na panahon ay higit sa zero, hatiin ang taunang rate ng interes (pinangalanang cell C2) sa bilang ng mga pagbabayad bawat taon (pinangalanang cell C4) at i-multiply ang resulta sa natitirang balanse pagkatapos ng nakaraang panahon; kung hindi, ibalik ang 0.

  =IFERROR(IF(B10>0, InterestRate/PaymentsPerYear*G9, 0), "")

  Balanse (G10)

  Kung ang natitirang balanse (G9) ay mas malaki sa zero, ibawas ang pangunahing bahagi ng pagbabayad (E10) at ang dagdag na pagbabayad (C10) mula sa natitirang balanse pagkatapos ng nakaraang panahon (G9); kung hindi, ibalik ang 0.

  =IFERROR(IF(G9 >0, G9-E10-C10, 0), "")

  Tandaan. Dahil ang ilan sa mga formula ay nag-cross reference sa isa't isa (hindi circular reference!), maaari silang magpakita ng mga maling resulta sa proseso. Kaya, mangyaring huwag simulan ang pag-troubleshoot hanggang sa pumasok kaang pinakahuling formula sa iyong amortization table.

  Kung ang lahat ay nagawa nang tama, ang iyong loan amortization schedule sa puntong ito ay dapat magmukhang ganito:

  5. Itago ang mga dagdag na tuldok

  Mag-set up ng kondisyonal na tuntunin sa pag-format upang itago ang mga halaga sa mga hindi nagamit na panahon gaya ng ipinaliwanag sa tip na ito. Ang kaibahan ay sa pagkakataong ito inilapat namin ang puting kulay ng font sa mga row kung saan ang Kabuuang Pagbabayad (column D) at Balance (column G) ay katumbas ng zero o walang laman:

  =AND(OR($D9=0, $D9=""), OR($G9=0, $G9=""))

  Voilà, nakatago sa view ang lahat ng row na may zero na value:

  6. Gumawa ng buod ng loan

  Bilang isang pagtatapos ng pagiging perpekto, maaari mong ilabas ang pinakamahalagang impormasyon tungkol sa isang loan sa pamamagitan ng paggamit ng mga formula na ito:

  Nakaiskedyul na bilang ng mga pagbabayad:

  I-multiply ang bilang ng mga taon sa bilang ng mga pagbabayad bawat taon:

  =LoanTerm*PaymentsPerYear

  Akwal na bilang ng mga pagbabayad:

  Bilangin ang mga cell sa column na Kabuuang Pagbabayad na higit sa zero, simula sa Panahon 1:

  =COUNTIF(D10:D369,">"&0)

  Kabuuang mga karagdagang pagbabayad:

  Magdagdag ng mga cell sa column na Karagdagang Pagbabayad , simula sa Panahon 1:

  =SUM(C10:C369)

  Kabuuang interes:

  Magdagdag up ng mga cell sa column na Interes , simula sa Panahon 1:

  =SUM(F10:F369)

  Opsyonal, itago ang hilera ng Panahon 0 , at ang iyong iskedyul ng amortization ng utang tapos na ang mga karagdagang bayad! Ipinapakita ng screenshot sa ibaba ang huling resulta:

  I-download ang amortization ng loaniskedyul na may mga dagdag na pagbabayad

  Iskedyul ng amortisasyon Excel template

  Upang makagawa ng nangungunang iskedyul ng amortization ng pautang sa lalong madaling panahon, gamitin ang mga inbuilt na template ng Excel. Pumunta lang sa File > Bago , i-type ang " iskedyul ng amortization " sa box para sa paghahanap at piliin ang template na gusto mo, halimbawa, ito na may mga karagdagang bayad :

  Pagkatapos ay i-save ang bagong likhang workbook bilang template ng Excel at muling gamitin kung kailan mo gusto.

  Ganyan ka gumawa ng iskedyul ng loan o mortgage amortization sa Excel. Salamat sa pagbabasa at umaasa akong makita ka sa aming blog sa susunod na linggo!

  Mga available na download

  Mga halimbawa ng Amortization Schedule (.xlsx file)

  Bumababa ang halagang ito sa bawat pagbabayad.

Ngayon, gawin natin ang proseso nang sunud-sunod.

1. I-set up ang amortization table

Para sa mga panimula, tukuyin ang mga input cell kung saan mo ilalagay ang mga kilalang bahagi ng isang loan:

• C2 - taunang rate ng interes
• C3 - termino ng pautang sa mga taon
• C4 - bilang ng mga pagbabayad bawat taon
• C5 - halaga ng pautang

Ang susunod na gagawin mo ay gumawa ng talahanayan ng amortization na may mga label ( Panahon , Pagbabayad , Interes , Principal , Balanse ) sa A7:E7. Sa column na Panahon , maglagay ng serye ng mga numero na katumbas ng kabuuang bilang ng mga pagbabayad (1- 24 sa halimbawang ito):

Kapag nakalagay ang lahat ng kilalang bahagi, pumunta tayo sa pinakakawili-wiling bahagi - mga formula ng amortization ng pautang.

2. Kalkulahin ang kabuuang halaga ng bayad (PMT formula)

Kinakalkula ang halaga ng pagbabayad gamit ang PMT(rate, nper, pv, [fv], [type]) function.

Upang pangasiwaan ang iba't ibang frequency ng pagbabayad nang tama (gaya ng lingguhan, buwanan, quarterly, atbp.), dapat ay naaayon ka sa mga value na ibinigay para sa rate at nper na mga argumento:

• Rate - hatiin ang taunang rate ng interes sa bilang ng mga panahon ng pagbabayad bawat taon ($C$2/$C$4).
• Nper - i-multiply ang bilang ng mga taon sa pamamagitan ng bilang ng mga panahon ng pagbabayad bawat taon ($C$3*$C$4).
• Para sa argumentong pv , ilagay ang halaga ng utang ($C$5).
• AngMaaaring tanggalin ang mga argumento ng fv at type dahil ang kanilang mga default na halaga ay gumagana nang maayos para sa amin (ang balanse pagkatapos ng huling pagbabayad ay dapat na 0; ang mga pagbabayad ay ginagawa sa katapusan ng bawat panahon) .

Pagsasama-sama ng mga argumento sa itaas, makukuha natin ang formula na ito:

=PMT($C$2/$C$4, $C$3*$C$4, $C$5)

Pakipansin, na gumagamit kami ng mga ganap na sanggunian sa cell dahil dapat kopyahin ang formula na ito sa ang mga cell sa ibaba nang walang anumang pagbabago.

Ilagay ang PMT formula sa B8, i-drag ito pababa sa column, at makakakita ka ng pare-parehong halaga ng pagbabayad para sa lahat ng panahon:

3. Kalkulahin ang interes (IPMT formula)

Upang mahanap ang bahagi ng interes ng bawat pana-panahong pagbabayad, gamitin ang function na IPMT(rate, per, nper, pv, [fv], [type]):

=IPMT($C$2/$C$4, A8, $C$3*$C$4, $C$5)

Ang lahat ng argumento ay kapareho ng sa PMT formula, maliban sa per argument na tumutukoy sa panahon ng pagbabayad. Ang argument na ito ay ibinibigay bilang isang relative cell reference (A8) dahil dapat itong magbago batay sa relatibong posisyon ng isang row kung saan kinopya ang formula.

Ang formula na ito ay mapupunta sa C8, at pagkatapos ay kopyahin mo ito hanggang sa pinakamaraming cell kung kinakailangan:

4. Maghanap ng punong-guro (PPMT formula)

Upang kalkulahin ang pangunahing bahagi ng bawat pana-panahong pagbabayad, gamitin itong PPMT formula:

=PPMT($C$2/$C$4, A8, $C$3*$C$4, $C$5)

Ang syntax at argumento ay eksaktong kapareho ng sa ang IPMT formula na tinalakay sa itaas:

Ang formula na ito ay papunta sa column D, simula sa D8:

Tip. Upang suriin kung ang iyongtama ang mga kalkulasyon sa puntong ito, pagsamahin ang mga numero sa mga column na Principal at Interes . Ang kabuuan ay dapat na katumbas ng halaga sa column na Pagbabayad sa parehong row.

5. Kunin ang natitirang balanse

Upang kalkulahin ang natitirang balanse para sa bawat panahon, gagamit kami ng dalawang magkaibang formula.

Upang mahanap ang balanse pagkatapos ng unang pagbabayad sa E8, dagdagan ang halaga ng pautang (C5) at ang prinsipal ng unang yugto (D8):

=C5+D8

Dahil ang halaga ng pautang ay positibong numero at ang prinsipal ay negatibong numero, ang huli ay talagang ibinabawas sa dating .

Para sa pangalawa at lahat ng kasunod na yugto, pagsamahin ang nakaraang balanse at ang prinsipal ng panahong ito:

=E8+D9

Ang formula sa itaas ay mapupunta sa E9, at pagkatapos ay kopyahin mo ito pababa sa hanay. Dahil sa paggamit ng mga kamag-anak na sanggunian sa cell, ang formula ay nagsasaayos nang tama para sa bawat hilera.

Iyon lang! Ang aming buwanang iskedyul ng amortization ng pautang ay tapos na:

Tip: Ibalik ang mga pagbabayad bilang mga positibong numero

Dahil ang isang loan ay binabayaran mula sa iyong bank account, ang Excel function ay nagbabalik ng bayad, interes at prinsipal bilang negatibong numero . Bilang default, ang mga halagang ito ay naka-highlight sa pula at nakapaloob sa mga panaklong gaya ng makikita mo sa larawan sa itaas.

Kung mas gusto mong magkaroon ng lahat ng resulta bilang positibo na mga numero, maglagay ng minus sign bago ang PMT, IPMT at PPMT function.

Para sa Balanse mga formula, gumamit ng pagbabawas sa halip na karagdagan tulad ng ipinapakita sa screenshot sa ibaba:

Iskedyul ng amortization para sa isang variable na bilang ng mga panahon

Sa halimbawa sa itaas, bumuo kami ng iskedyul ng amortization ng pautang para sa paunang natukoy na bilang ng mga panahon ng pagbabayad. Ang mabilis na isang beses na solusyong ito ay mahusay na gumagana para sa isang partikular na loan o mortgage.

Kung naghahanap ka upang lumikha ng isang magagamit muli na iskedyul ng amortisasyon na may variable na bilang ng mga panahon, kakailanganin mong gumawa ng mas komprehensibong diskarte na inilalarawan sa ibaba.

1. Ilagay ang maximum na bilang ng mga panahon

Sa column na Panahon , ilagay ang maximum na bilang ng mga pagbabayad na papayagan mo para sa anumang loan, halimbawa, mula 1 hanggang 360. Maaari mong gamitin ang AutoFill ng Excel feature na magpasok ng serye ng mga numero nang mas mabilis.

2. Gumamit ng mga IF statement sa mga formula ng amortization

Dahil marami ka na ngayong mga sobrang numero ng panahon, kailangan mong limitahan ang mga kalkulasyon sa aktwal na bilang ng mga pagbabayad para sa isang partikular na loan. Magagawa ito sa pamamagitan ng pagbabalot ng bawat formula sa isang IF statement. Sinusuri ng lohikal na pagsubok ng IF statement kung ang numero ng panahon sa kasalukuyang row ay mas mababa o katumbas ng kabuuang bilang ng mga pagbabayad. Kung ang lohikal na pagsubok ay TRUE, ang kaukulang function ay kinakalkula; kung FALSE, isang walang laman na string ang ibabalik.

Ipagpalagay na ang Pero 1 ay nasa row 8, ilagay ang mga sumusunod na formula sa kaukulang mga cell, at pagkatapos ay kopyahin ang mga ito sa kabuuanang buong talahanayan.

Pagbabayad (B8):

=IF(A8<=$C$3*$C$4, PMT($C$2/$C$4, $C$3*$C$4, $C$5), "")

Interes (C8):

=IF(A8<=$C$3*$C$4, IPMT($C$2/$C$4, A8, $C$3*$C$4, $C$5), "")

Principal (D8):

=IF(A8<=$C$3*$C$4,PPMT($C$2/$C$4, A8, $C$3*$C$4, $C$5), "")

Balanse :

Para sa Panahon 1 (E8), ang formula ay kapareho ng sa nakaraang halimbawa:

=C5+D8

Para sa Panahon 2 (E9) at lahat ng kasunod na panahon, ganito ang hugis ng formula:

=IF(A9<=$C$3*$C$4, E8+D9, "")

Bilang resulta, mayroon kang wastong nakalkulang iskedyul ng amortization at isang grupo ng mga walang laman na row na may mga numero ng panahon pagkatapos mabayaran ang loan.

3. Itago ang mga numero ng dagdag na panahon

Kung maaari kang mamuhay nang may maraming mga hindi kinakailangang numero ng panahon na ipinapakita pagkatapos ng huling pagbabayad, maaari mong isaalang-alang ang gawaing tapos na at laktawan ang hakbang na ito. Kung nagsusumikap ka para sa pagiging perpekto, pagkatapos ay itago ang lahat ng hindi nagamit na panahon sa pamamagitan ng paggawa ng kondisyonal na tuntunin sa pag-format na nagtatakda ng kulay ng font sa puti para sa anumang mga hilera pagkatapos maisagawa ang huling pagbabayad.

Para dito, piliin lahat ng data row kung ang iyong amortization table (A8:E367 sa aming kaso) at i-click ang Home tab > Conditional formatting > Bagong Panuntunan… > Gumamit ng formula upang matukoy kung aling mga cell ang ipo-format .

Sa kaukulang kahon, ilagay ang formula sa ibaba na tumitingin kung ang numero ng tuldok sa column A ay mas malaki kaysa sa kabuuan bilang ng mga pagbabayad:

=$A8>$C$3*$C$4

Mahalagang paalala! Para gumana nang tama ang conditional formatting formula, tiyaking gumamit ng absolute cell reference para sa Loan term at Mga pagbabayad bawat taon na mga cell na iyong pinaparami ($C$3*$C$4). Ang produkto ay inihambing sa Panahon 1 cell, kung saan gumagamit ka ng pinaghalong cell reference - absolute column at relative row ($A8).

Pagkatapos noon, i-click ang Format… na button at piliin ang puting kulay ng font. Tapos na!

4. Gumawa ng buod ng loan

Upang tingnan ang buod ng impormasyon tungkol sa iyong loan sa isang sulyap, magdagdag ng ilang formula sa itaas ng iyong iskedyul ng amortization.

Kabuuang mga pagbabayad ( F2):

=-SUM(B8:B367)

Kabuuang interes (F3):

=-SUM(C8:C367)

Kung mayroon kang mga pagbabayad bilang positibong numero, alisin ang minus sign mula sa mga formula sa itaas.

Iyon na! Ang aming iskedyul ng amortization ng pautang ay nakumpleto at handa na!

I-download ang iskedyul ng amortization ng pautang para sa Excel

Paano gumawa ng iskedyul ng amortization ng pautang na may mga karagdagang pagbabayad sa Excel

Ang mga iskedyul ng amortisasyon na tinalakay sa mga nakaraang halimbawa ay madaling gawin at sundin (sana :). Gayunpaman, nag-iiwan sila ng isang kapaki-pakinabang na tampok na interesado sa maraming nagbabayad ng pautang - mga karagdagang pagbabayad upang mabayaran ang isang pautang nang mas mabilis. Sa halimbawang ito, titingnan natin kung paano gumawa ng iskedyul ng amortization ng pautang na may mga karagdagang pagbabayad.

1. Tukuyin ang mga input cell

Gaya ng dati, magsimula sa pag-set up ng mga input cell. Sa kasong ito, pangalanan natin ang mga cell na ito tulad ng nakasulat sa ibaba upang gawing mas madaling basahin ang ating mga formula:

• InterestRate - C2 (taunang interesrate)
• LoanTerm - C3 (termino ng pautang sa mga taon)
• PaymentsPerYear - C4 (bilang ng mga pagbabayad bawat taon)
• Halaga ng Loan - C5 (kabuuang halaga ng pautang)
• ExtraPayment - C6 (dagdag na bayad sa bawat panahon)

2. Kalkulahin ang nakaiskedyul na pagbabayad

Bukod sa mga input cell, kailangan ng isa pang paunang natukoy na cell para sa aming mga karagdagang kalkulasyon - ang naka-iskedyul na halaga ng pagbabayad , ibig sabihin, ang halagang babayaran sa isang loan kung walang dagdag ang mga pagbabayad ay ginawa. Ang halagang ito ay kinakalkula gamit ang sumusunod na formula:

=IFERROR(-PMT(InterestRate/PaymentsPerYear, LoanTerm*PaymentsPerYear, LoanAmount), "")

Pakipansin na naglalagay kami ng minus sign bago ang PMT function upang magkaroon ng resulta bilang positibong numero. Upang maiwasan ang mga error kung sakaling ang ilan sa mga input cell ay walang laman, isinama namin ang PMT formula sa loob ng IFERROR function.

Ilagay ang formula na ito sa ilang cell (G2 sa aming kaso) at pangalanan ang cell na iyon ScheduledPayment .

3. I-set up ang amortization table

Gumawa ng loan amortization table na may mga header na ipinapakita sa screenshot sa ibaba. Sa column na Panahon maglagay ng serye ng mga numero na nagsisimula sa zero (maaari mong itago ang row na Panahon 0 sa ibang pagkakataon kung kinakailangan).

Kung layunin mong lumikha ng magagamit muli iskedyul ng amortization, ilagay ang maximum na posibleng bilang ng mga panahon ng pagbabayad (0 hanggang 360 sa halimbawang ito).

Para sa Panahon 0 (row 9 sa aming kaso), hilahin ang Balanse halaga, na katumbas ng orihinal na halaga ng pautang. Lahat ng iba pamananatiling walang laman ang mga cell sa row na ito:

Formula sa G9:

=LoanAmount

4. Bumuo ng mga formula para sa iskedyul ng amortization na may mga karagdagang pagbabayad

Ito ay isang mahalagang bahagi ng ating gawain. Dahil ang mga built-in na function ng Excel ay hindi nagbibigay ng mga karagdagang pagbabayad, kakailanganin naming gawin ang lahat ng matematika nang mag-isa.

Tandaan. Sa halimbawang ito, ang Period 0 ay nasa row 9 at Period 1 ay nasa row 10. Kung ang iyong amortization table ay magsisimula sa ibang row, pakitiyak na isaayos ang mga cell reference nang naaayon.

Ilagay ang mga sumusunod na formula sa row 10 ( Panahon 1 ), at pagkatapos ay kopyahin ang mga ito para sa lahat ng natitirang panahon.

Naka-iskedyul na Pagbabayad (B10):

Kung ang halaga ng ScheduledPayment (pinangalanang cell G2) ay mas mababa sa o katumbas ng natitirang balanse (G9), gamitin ang nakaiskedyul na pagbabayad. Kung hindi, idagdag ang natitirang balanse at ang interes para sa nakaraang buwan.

=IFERROR(IF(ScheduledPayment<=G9, ScheduledPayment, G9+G9*InterestRate/PaymentsPerYear), "")

Bilang karagdagang pag-iingat, binabalot namin ito at lahat ng kasunod na formula sa function na IFERROR. Pipigilan nito ang isang grupo ng iba't ibang mga error kung ang ilan sa mga input cell ay walang laman o naglalaman ng mga di-wastong halaga.

Karagdagang Pagbabayad (C10):

Gumamit ng IF formula na may ang sumusunod na lohika:

Kung ang halaga ng ExtraPayment (pinangalanang cell C6) ay mas mababa sa pagkakaiba sa pagitan ng natitirang balanse at ang prinsipal sa panahong ito (G9-E10), ibalik ang ExtraPayment ; kung hindi, gamitin ang pagkakaiba.

=IFERROR(IF(ExtraPayment

Tip. kung ikaw