Το σεμινάριο δείχνει πώς να δημιουργήσετε ένα χρονοδιάγραμμα απόσβεσης στο Excel για να περιγράψετε λεπτομερώς τις περιοδικές πληρωμές σε ένα δάνειο ή υποθήκη με απόσβεση.

Ένα δάνειο με απόσβεση είναι απλώς ένας φανταχτερός τρόπος για να ορίσουμε ένα δάνειο που αποπληρώνεται σε δόσεις καθ' όλη τη διάρκεια του δανείου.

Βασικά, όλα τα δάνεια αποσβένονται με τον ένα ή τον άλλο τρόπο. Για παράδειγμα, ένα δάνειο με πλήρη απόσβεση για 24 μήνες θα έχει 24 ίσες μηνιαίες πληρωμές. Κάθε πληρωμή χρησιμοποιεί κάποιο ποσό για το κεφάλαιο και κάποιο για τους τόκους. Για να περιγράψετε λεπτομερώς κάθε πληρωμή ενός δανείου, μπορείτε να δημιουργήσετε ένα πρόγραμμα απόσβεσης δανείου.

Ένα χρονοδιάγραμμα απόσβεσης είναι ένας πίνακας που απαριθμεί τις περιοδικές πληρωμές ενός δανείου ή υποθήκης με την πάροδο του χρόνου, αναλύει κάθε πληρωμή σε κεφάλαιο και τόκους και δείχνει το υπόλοιπο που απομένει μετά από κάθε πληρωμή.

Πώς να δημιουργήσετε ένα χρονοδιάγραμμα απόσβεσης δανείου στο Excel

Για να δημιουργήσουμε ένα χρονοδιάγραμμα απόσβεσης δανείου ή υποθήκης στο Excel, θα πρέπει να χρησιμοποιήσουμε τις ακόλουθες συναρτήσεις:

• Λειτουργία PMT - υπολογίζει το συνολικό ποσό Το ποσό αυτό παραμένει σταθερό για όλη τη διάρκεια του δανείου.
• Λειτουργία PPMT - παίρνει το κύριος μέρος κάθε πληρωμής που πηγαίνει προς το κεφάλαιο του δανείου, δηλαδή το ποσό που δανειστήκατε. Το ποσό αυτό αυξάνεται για τις επόμενες πληρωμές.
• Λειτουργία IPMT - βρίσκει το ενδιαφέρον μέρος κάθε πληρωμής που πηγαίνει σε τόκους. Το ποσό αυτό μειώνεται με κάθε πληρωμή.

Τώρα, ας δούμε τη διαδικασία βήμα προς βήμα.

1. Ρύθμιση του πίνακα αποσβέσεων

Για αρχή, ορίστε τα κελιά εισόδου όπου θα εισάγετε τα γνωστά στοιχεία ενός δανείου:

• C2 - ετήσιο επιτόκιο
• C3 - διάρκεια δανείου σε έτη
• C4 - αριθμός πληρωμών ανά έτος
• C5 - ποσό δανείου

Το επόμενο πράγμα που κάνετε είναι να δημιουργήσετε έναν πίνακα αποσβέσεων με τις ετικέτες ( Περίοδος , Πληρωμή , Τόκος , Κύριος , Υπόλοιπο ) σε A7:E7. Στο Περίοδος στη στήλη, πληκτρολογήστε μια σειρά αριθμών ίσων με το συνολικό αριθμό πληρωμών (1- 24 σε αυτό το παράδειγμα):

Με όλα τα γνωστά στοιχεία στη θέση τους, ας περάσουμε στο πιο ενδιαφέρον μέρος - τους τύπους απόσβεσης των δανείων.

2. Υπολογίστε το συνολικό ποσό πληρωμής (τύπος PMT)

Το ποσό πληρωμής υπολογίζεται με τη συνάρτηση PMT(rate, nper, pv, [fv], [type]).

Για να χειρίζεστε σωστά τις διαφορετικές συχνότητες πληρωμών (όπως εβδομαδιαίες, μηνιαίες, τριμηνιαίες κ.λπ.), θα πρέπει να είστε συνεπείς με τις τιμές που παρέχονται για το πεδίο ποσοστό και nper επιχειρήματα:

• Βαθμολογήστε - διαιρέστε το ετήσιο επιτόκιο με τον αριθμό των περιόδων πληρωμής ανά έτος ($C$2/$C$4).
• Nper - πολλαπλασιάστε τον αριθμό των ετών επί τον αριθμό των περιόδων πληρωμής ανά έτος ($C$3*$C$4).
• Για το pv πληκτρολογήστε το ποσό του δανείου ($C$5).
• Το fv και τύπος μπορούν να παραλειφθούν, καθώς οι προεπιλεγμένες τιμές τους λειτουργούν μια χαρά για εμάς (το υπόλοιπο μετά την τελευταία πληρωμή υποτίθεται ότι είναι 0- οι πληρωμές γίνονται στο τέλος κάθε περιόδου).

Συνδυάζοντας τα παραπάνω επιχειρήματα, έχουμε αυτόν τον τύπο:

=PMT($C$2/$C$4, $C$3*$C$4, $C$5)

Προσέξτε, ότι χρησιμοποιούμε απόλυτες αναφορές κελιών, επειδή αυτός ο τύπος θα πρέπει να αντιγραφεί στα παρακάτω κελιά χωρίς καμία αλλαγή.

Εισάγετε τον τύπο PMT στο B8, σύρετέ τον προς τα κάτω στη στήλη και θα δείτε ένα σταθερό ποσό πληρωμής για όλες τις περιόδους:

3. Υπολογίστε τους τόκους (τύπος IPMT)

Για να βρείτε το μέρος του τόκου κάθε περιοδικής πληρωμής, χρησιμοποιήστε τη συνάρτηση IPMT(rate, per, nper, pv, [fv], [type]):

=IPMT($C$2/$C$4, A8, $C$3*$C$4, $C$5)

Όλα τα ορίσματα είναι τα ίδια όπως στον τύπο PMT, εκτός από το ανά Το όρισμα αυτό παρέχεται ως σχετική αναφορά κελιού (A8), επειδή υποτίθεται ότι αλλάζει με βάση τη σχετική θέση της γραμμής στην οποία αντιγράφεται ο τύπος.

Αυτός ο τύπος πηγαίνει στο C8 και στη συνέχεια τον αντιγράφετε σε όσα κελιά χρειάζεται:

4. Βρείτε τον κύριο (τύπος PPMT)

Για να υπολογίσετε το μέρος του κεφαλαίου κάθε περιοδικής πληρωμής, χρησιμοποιήστε αυτόν τον τύπο PPMT:

=PPMT($C$2/$C$4, A8, $C$3*$C$4, $C$5)

Η σύνταξη και τα ορίσματα είναι ακριβώς τα ίδια με τον τύπο IPMT που συζητήθηκε παραπάνω:

Αυτός ο τύπος πηγαίνει στη στήλη D, ξεκινώντας από τη D8:

Συμβουλή. Για να ελέγξετε αν οι υπολογισμοί σας είναι σωστοί σε αυτό το σημείο, προσθέστε τους αριθμούς στο πεδίο Κύριος και Τόκος Το άθροισμα θα πρέπει να είναι ίσο με την τιμή στην στήλη Πληρωμή στήλη στην ίδια σειρά.

5. Πάρτε το υπόλοιπο ποσό

Για να υπολογίσουμε το υπόλοιπο για κάθε περίοδο, θα χρησιμοποιήσουμε δύο διαφορετικούς τύπους.

Για να βρείτε το υπόλοιπο μετά την πρώτη πληρωμή στο E8, προσθέστε το ποσό του δανείου (C5) και το κεφάλαιο της πρώτης περιόδου (D8):

=C5+D8

Επειδή το ποσό του δανείου είναι ένας θετικός αριθμός και το κεφάλαιο είναι ένας αρνητικός αριθμός, το τελευταίο αφαιρείται από το πρώτο.

Για τη δεύτερη και όλες τις επόμενες περιόδους, προσθέστε το προηγούμενο υπόλοιπο και το κεφάλαιο αυτής της περιόδου:

=E8+D9

Ο παραπάνω τύπος πηγαίνει στο E9 και στη συνέχεια τον αντιγράφετε προς τα κάτω στη στήλη. Λόγω της χρήσης σχετικών αναφορών κελιών, ο τύπος προσαρμόζεται σωστά για κάθε γραμμή.

Αυτό ήταν! Το μηνιαίο πρόγραμμα απόσβεσης του δανείου μας είναι έτοιμο:

Συμβουλή: Επιστρέψτε τις πληρωμές ως θετικούς αριθμούς

Επειδή ένα δάνειο πληρώνεται από τον τραπεζικό σας λογαριασμό, οι συναρτήσεις του Excel επιστρέφουν την πληρωμή, τους τόκους και το κεφάλαιο ως αρνητικοί αριθμοί Από προεπιλογή, οι τιμές αυτές επισημαίνονται με κόκκινο χρώμα και περικλείονται σε παρενθέσεις, όπως μπορείτε να δείτε στην παραπάνω εικόνα.

Αν προτιμάτε να έχετε όλα τα αποτελέσματα ως θετικό αριθμούς, βάλτε ένα σύμβολο μείον πριν από τις λειτουργίες PMT, IPMT και PPMT.

Για το Υπόλοιπο τύπους, χρησιμοποιήστε αφαίρεση αντί για πρόσθεση, όπως φαίνεται στο παρακάτω στιγμιότυπο:

Πρόγραμμα απόσβεσης για μεταβλητό αριθμό περιόδων

Στο παραπάνω παράδειγμα, δημιουργήσαμε ένα πρόγραμμα απόσβεσης δανείου για τον προκαθορισμένο αριθμό περιόδων πληρωμής. Αυτή η γρήγορη εφάπαξ λύση λειτουργεί καλά για ένα συγκεκριμένο δάνειο ή υποθήκη.

Αν θέλετε να δημιουργήσετε ένα επαναχρησιμοποιήσιμο χρονοδιάγραμμα απόσβεσης με μεταβλητό αριθμό περιόδων, θα πρέπει να ακολουθήσετε μια πιο ολοκληρωμένη προσέγγιση που περιγράφεται παρακάτω.

1. Εισαγωγή του μέγιστου αριθμού περιόδων

Στο Περίοδος στήλη, εισάγετε τον μέγιστο αριθμό πληρωμών που πρόκειται να επιτρέψετε για κάθε δάνειο, π.χ. από 1 έως 360. Μπορείτε να αξιοποιήσετε τη λειτουργία αυτόματης συμπλήρωσης του Excel για να εισαγάγετε μια σειρά αριθμών πιο γρήγορα.

2. Χρήση δηλώσεων IF σε τύπους απόσβεσης

Επειδή τώρα έχετε πολλούς υπερβολικούς αριθμούς περιόδων, πρέπει με κάποιο τρόπο να περιορίσετε τους υπολογισμούς στον πραγματικό αριθμό πληρωμών για ένα συγκεκριμένο δάνειο. Αυτό μπορεί να γίνει με το να τυλίξετε κάθε τύπο σε μια δήλωση IF. Ο λογικός έλεγχος της δήλωσης IF ελέγχει αν ο αριθμός περιόδου στην τρέχουσα γραμμή είναι μικρότερος ή ίσος με το συνολικό αριθμό πληρωμών. Αν ο λογικός έλεγχος είναι TRUE, η αντίστοιχηυπολογίζεται- αν είναι FALSE, επιστρέφεται μια κενή συμβολοσειρά.

Υποθέτοντας Περίοδος 1 βρίσκεται στη γραμμή 8, εισαγάγετε τους ακόλουθους τύπους στα αντίστοιχα κελιά και, στη συνέχεια, αντιγράψτε τους σε ολόκληρο τον πίνακα.

Πληρωμή (B8):

=IF(A8<=$C$3*$C$4, PMT($C$2/$C$4, $C$3*$C$4, $C$5), "")

Τόκος (C8):

=IF(A8<=$C$3*$C$4, IPMT($C$2/$C$4, A8, $C$3*$C$4, $C$5), "")

Κύριος (D8):

=IF(A8<=$C$3*$C$4,PPMT($C$2/$C$4, A8, $C$3*$C$4, $C$5), "")

Υπόλοιπο :

Για το Περίοδος 1 (E8), ο τύπος είναι ο ίδιος όπως στο προηγούμενο παράδειγμα:

=C5+D8

Για το Περίοδος 2 (E9) και όλες τις επόμενες περιόδους, ο τύπος παίρνει την εξής μορφή:

=IF(A9<=$C$3*$C$4, E8+D9, "")

Ως αποτέλεσμα, έχετε ένα σωστά υπολογισμένο χρονοδιάγραμμα απόσβεσης και ένα σωρό κενές γραμμές με τους αριθμούς των περιόδων μετά την αποπληρωμή του δανείου.

3. Απόκρυψη αριθμών επιπλέον περιόδων

Αν μπορείτε να ζήσετε με ένα σωρό περιττούς αριθμούς περιόδων που εμφανίζονται μετά την τελευταία πληρωμή, μπορείτε να θεωρήσετε ότι η εργασία έχει γίνει και να παραλείψετε αυτό το βήμα. Αν επιδιώκετε την τελειότητα, τότε κρύψτε όλες τις αχρησιμοποίητες περιόδους κάνοντας έναν κανόνα μορφοποίησης υπό όρους που θέτει το χρώμα γραμματοσειράς σε λευκό για οποιεσδήποτε σειρές μετά την τελευταία πληρωμή.

Για το σκοπό αυτό, επιλέξτε όλα τα γραμμές δεδομένων αν ο πίνακας απόσβεσης (A8:E367 στην περίπτωσή μας) και κάντε κλικ στο κουμπί Αρχική σελίδα tab>, Μορφοποίηση υπό όρους >, Νέος κανόνας... >, Χρησιμοποιήστε έναν τύπο για να καθορίσετε ποια κελιά θα μορφοποιήσετε .

Στο αντίστοιχο πλαίσιο, εισαγάγετε τον παρακάτω τύπο που ελέγχει αν ο αριθμός περιόδου στη στήλη Α είναι μεγαλύτερος από τον συνολικό αριθμό πληρωμών:

=$A8>$C$3*$C$4

Σημαντική σημείωση! Για να λειτουργήσει σωστά ο τύπος μορφοποίησης υπό όρους, βεβαιωθείτε ότι χρησιμοποιείτε απόλυτες αναφορές κελιών για το Διάρκεια δανείου και Πληρωμές ανά έτος κελιά που πολλαπλασιάζετε ($C$3*$C$4). Το γινόμενο συγκρίνεται με το Περίοδος 1 κελί, για το οποίο χρησιμοποιείτε μια μικτή αναφορά κελιού - απόλυτη στήλη και σχετική γραμμή ($A8).

Μετά από αυτό, κάντε κλικ στο Μορφή... και επιλέξτε το λευκό χρώμα γραμματοσειράς. Έγινε!

4. Κάντε μια περίληψη δανείου

Για να δείτε τις συνοπτικές πληροφορίες για το δάνειό σας με μια ματιά, προσθέστε μερικούς ακόμη τύπους στην κορυφή του προγράμματος απόσβεσης.

Σύνολο πληρωμών (F2):

=-SUM(B8:B367)

Συνολικός τόκος (F3):

=-SUM(C8:C367)

Εάν έχετε τις πληρωμές ως θετικούς αριθμούς, αφαιρέστε το σύμβολο μείον από τους παραπάνω τύπους.

Αυτό ήταν! Το πρόγραμμα απόσβεσης του δανείου μας ολοκληρώθηκε και είναι έτοιμο!

Κατεβάστε το χρονοδιάγραμμα απόσβεσης δανείου για το Excel

Πώς να φτιάξετε ένα πρόγραμμα απόσβεσης δανείου με επιπλέον πληρωμές στο Excel

Τα χρονοδιαγράμματα απόσβεσης που συζητήθηκαν στα προηγούμενα παραδείγματα είναι εύκολο να δημιουργηθούν και να ακολουθηθούν (ελπίζουμε :). Ωστόσο, παραλείπουν ένα χρήσιμο χαρακτηριστικό που ενδιαφέρει πολλούς δανειολήπτες - τις πρόσθετες πληρωμές για την ταχύτερη αποπληρωμή ενός δανείου. Σε αυτό το παράδειγμα, θα εξετάσουμε πώς να δημιουργήσουμε ένα χρονοδιάγραμμα απόσβεσης δανείου με πρόσθετες πληρωμές.

1. Ορισμός κελιών εισόδου

Ως συνήθως, ξεκινήστε με τη ρύθμιση των κελιών εισόδου. Σε αυτή την περίπτωση, ας ονομάσουμε αυτά τα κελιά όπως γράφεται παρακάτω για να είναι πιο ευανάγνωστοι οι τύποι μας:

• Επιτόκιο - C2 (ετήσιο επιτόκιο)
• LoanTerm - C3 (διάρκεια δανείου σε έτη)
• PaymentsPerYear - C4 (αριθμός πληρωμών ανά έτος)
• LoanAmount - C5 (συνολικό ποσό δανείου)
• ExtraPayment - C6 (επιπλέον πληρωμή ανά περίοδο)

2. Υπολογίστε μια προγραμματισμένη πληρωμή

Εκτός από τα κελιά εισόδου, ένα ακόμη προκαθορισμένο κελί απαιτείται για τους περαιτέρω υπολογισμούς μας - το προγραμματισμένο ποσό πληρωμής , δηλαδή το ποσό που πρέπει να καταβληθεί για ένα δάνειο εάν δεν γίνουν επιπλέον πληρωμές. Το ποσό αυτό υπολογίζεται με τον ακόλουθο τύπο:

=IFERROR(-PMT(InterestRate/PaymentsPerYear, LoanTerm*PaymentsPerYear, LoanAmount), "")

Προσέξτε ότι βάζουμε ένα μείον πριν από τη συνάρτηση PMT για να έχουμε το αποτέλεσμα ως θετικό αριθμό. Για να αποφύγουμε σφάλματα σε περίπτωση που κάποια από τα κελιά εισόδου είναι κενά, περικλείουμε τον τύπο PMT μέσα στη συνάρτηση IFERROR.

Εισάγετε αυτόν τον τύπο σε κάποιο κελί (το G2 στην περίπτωσή μας) και ονομάστε το κελί αυτό ScheduledPayment .

3. Ορίστε τον πίνακα αποσβέσεων

Δημιουργήστε έναν πίνακα απόσβεσης δανείου με τις επικεφαλίδες που φαίνονται στο παρακάτω στιγμιότυπο οθόνης. Στο πεδίο Περίοδος στήλη εισάγετε μια σειρά αριθμών που αρχίζουν από το μηδέν (μπορείτε να αποκρύψετε το Περίοδος 0 σειρά αργότερα αν χρειαστεί).

Εάν σκοπεύετε να δημιουργήσετε ένα επαναχρησιμοποιήσιμο χρονοδιάγραμμα απόσβεσης, εισαγάγετε τον μέγιστο δυνατό αριθμό περιόδων πληρωμής (0 έως 360 σε αυτό το παράδειγμα).

Για το Περίοδος 0 (σειρά 9 στην περίπτωσή μας), τραβήξτε το Υπόλοιπο τιμή, η οποία ισούται με το αρχικό ποσό του δανείου. Όλα τα άλλα κελιά σε αυτή τη γραμμή θα παραμείνουν κενά:

Τύπος στο G9:

=LoanAmount

4. Κατασκευάστε τύπους για το χρονοδιάγραμμα απόσβεσης με επιπλέον πληρωμές

Επειδή οι ενσωματωμένες συναρτήσεις του Excel δεν προβλέπουν πρόσθετες πληρωμές, θα πρέπει να κάνουμε μόνοι μας όλα τα μαθηματικά.

Σημείωση. Σε αυτό το παράδειγμα, Περίοδος 0 είναι στη σειρά 9 και Περίοδος 1 βρίσκεται στη γραμμή 10. Εάν ο πίνακας απόσβεσης αρχίζει σε διαφορετική γραμμή, φροντίστε να προσαρμόσετε τις αναφορές κελιών αναλόγως.

Εισάγετε τους ακόλουθους τύπους στη γραμμή 10 ( Περίοδος 1 ), και στη συνέχεια αντιγράψτε τα για όλες τις υπόλοιπες περιόδους.

Προγραμματισμένη πληρωμή (B10):

Εάν η ScheduledPayment ποσό (που ονομάζεται κελί G2) είναι μικρότερο ή ίσο με το υπόλοιπο (G9), χρησιμοποιήστε την προγραμματισμένη πληρωμή. Διαφορετικά, προσθέστε το υπόλοιπο και τους τόκους του προηγούμενου μήνα.

=IFERROR(IF(ScheduledPayment<=G9, ScheduledPayment, G9+G9*InterestRate/PaymentsPerYear), "")

Ως πρόσθετη προφύλαξη, τυλίγουμε αυτόν και όλους τους επόμενους τύπους στη συνάρτηση IFERROR. Αυτό θα αποτρέψει ένα σωρό διάφορα σφάλματα εάν κάποια από τα κελιά εισόδου είναι κενά ή περιέχουν άκυρες τιμές.

Πρόσθετη πληρωμή (C10):

Χρησιμοποιήστε έναν τύπο IF με την ακόλουθη λογική:

Εάν η ExtraPayment ποσό (που ονομάζεται κελί C6) είναι μικρότερο από τη διαφορά μεταξύ του υπολοίπου και του κεφαλαίου αυτής της περιόδου (G9-E10), επιστρέψτε ExtraPayment ; διαφορετικά χρησιμοποιήστε τη διαφορά.

=IFERROR(IF(ExtraPayment

Συμβουλή. Αν έχετε μεταβλητές πρόσθετες πληρωμές , απλά πληκτρολογήστε τα επιμέρους ποσά απευθείας στο πεδίο Πρόσθετη πληρωμή στήλη.

Συνολική πληρωμή (D10)

Απλά, προσθέστε την προγραμματισμένη πληρωμή (B10) και την επιπλέον πληρωμή (C10) για την τρέχουσα περίοδο:

=IFERROR(B10+C10, "")

Κύριος (E10)

Εάν η προγραμματισμένη πληρωμή για μια δεδομένη περίοδο είναι μεγαλύτερη από το μηδέν, επιστρέφεται η μικρότερη από τις δύο τιμές: προγραμματισμένη πληρωμή μείον τους τόκους (B10-F10) ή το υπόλοιπο (G9)- διαφορετικά επιστρέφεται το μηδέν.

=IFERROR(IF(B10>0, MIN(B10-F10, G9), 0), "")

Σημειώστε ότι ο κύριος περιλαμβάνει μόνο το μέρος του προγραμματισμένη πληρωμή (όχι την επιπλέον πληρωμή!) που πηγαίνει προς το κεφάλαιο του δανείου.

Τόκος (F10)

Εάν η πληρωμή του προγράμματος για μια δεδομένη περίοδο είναι μεγαλύτερη του μηδενός, διαιρέστε το ετήσιο επιτόκιο (που ονομάζεται κελί C2) με τον αριθμό των πληρωμών ανά έτος (που ονομάζεται κελί C4) και πολλαπλασιάστε το αποτέλεσμα με το υπόλοιπο που απομένει μετά την προηγούμενη περίοδο- διαφορετικά, επιστρέψτε 0.

=IFERROR(IF(B10>0, InterestRate/PaymentsPerYear*G9, 0), "")

Υπόλοιπο (G10)

Εάν το υπόλοιπο (G9) είναι μεγαλύτερο του μηδενός, αφαιρέστε το μέρος του κεφαλαίου της πληρωμής (E10) και την επιπλέον πληρωμή (C10) από το υπόλοιπο που απομένει μετά την προηγούμενη περίοδο (G9), διαφορετικά επιστρέψτε 0.

=IFERROR(IF(G9>0, G9-E10-C10, 0), "")

Σημείωση. Επειδή ορισμένοι από τους τύπους παραπέμπουν ο ένας στον άλλο (όχι κυκλική αναφορά!), ενδέχεται να εμφανίσουν λανθασμένα αποτελέσματα κατά τη διαδικασία. Επομένως, μην αρχίσετε την αντιμετώπιση προβλημάτων πριν εισαγάγετε τον τελευταίο τύπο στον πίνακα αποσβέσεων.

Αν όλα έχουν γίνει σωστά, το πρόγραμμα απόσβεσης του δανείου σας σε αυτό το σημείο θα πρέπει να μοιάζει κάπως έτσι:

5. Απόκρυψη επιπλέον περιόδων

Ρυθμίστε έναν κανόνα μορφοποίησης υπό όρους για να αποκρύψετε τις τιμές σε αχρησιμοποίητες περιόδους, όπως εξηγείται σε αυτή τη συμβουλή. Η διαφορά είναι ότι αυτή τη φορά εφαρμόζουμε το λευκό χρώμα γραμματοσειράς στις σειρές στις οποίες Συνολική πληρωμή (στήλη Δ) και Υπόλοιπο (στήλη G) είναι ίσες με μηδέν ή κενές:

=AND(OR($D9=0, $D9=""), OR($G9=0, $G9=""))

Ορίστε, όλες οι γραμμές με μηδενικές τιμές αποκρύπτονται από την προβολή:

6. Κάντε μια περίληψη δανείου

Ως τελική πινελιά τελειότητας, μπορείτε να εξάγετε τις πιο σημαντικές πληροφορίες σχετικά με ένα δάνειο χρησιμοποιώντας αυτούς τους τύπους:

Προγραμματισμένος αριθμός πληρωμών:

Πολλαπλασιάστε τον αριθμό των ετών επί τον αριθμό των πληρωμών ανά έτος:

=LoanTerm*PaymentsPerYear

Πραγματικός αριθμός πληρωμών:

Μετρήστε τα κύτταρα στο Συνολική πληρωμή που είναι μεγαλύτερες από το μηδέν, αρχής γενομένης από την περίοδο 1:

=COUNTIF(D10:D369,">"&0)

Συνολικές πρόσθετες πληρωμές:

Προσθέστε τα κελιά στο Πρόσθετη πληρωμή στήλη, ξεκινώντας από την περίοδο 1:

=SUM(C10:C369)

Συνολικός τόκος:

Προσθέστε τα κελιά στο Τόκος στήλη, ξεκινώντας από την περίοδο 1:

=SUM(F10:F369)

Προαιρετικά, αποκρύψτε το Περίοδος 0 γραμμή, και το πρόγραμμα απόσβεσης του δανείου σας με τις πρόσθετες πληρωμές είναι έτοιμο! Το παρακάτω στιγμιότυπο οθόνης δείχνει το τελικό αποτέλεσμα:

Κατεβάστε το χρονοδιάγραμμα απόσβεσης του δανείου με επιπλέον πληρωμές

Πρότυπο χρονοδιαγράμματος απόσβεσης Excel

Για να φτιάξετε ένα κορυφαίο χρονοδιάγραμμα απόσβεσης δανείου σε χρόνο μηδέν, χρησιμοποιήστε τα ενσωματωμένα πρότυπα του Excel. Απλώς μεταβείτε στη διεύθυνση Αρχείο >, Νέο , τύπος " χρονοδιάγραμμα απόσβεσης " στο πλαίσιο αναζήτησης και επιλέξτε το πρότυπο που σας αρέσει, για παράδειγμα, αυτό με τις επιπλέον πληρωμές:

Στη συνέχεια, αποθηκεύστε το νεοσύστατο βιβλίο εργασίας ως πρότυπο Excel και επαναχρησιμοποιήστε το όποτε θέλετε.

Έτσι μπορείτε να δημιουργήσετε ένα πρόγραμμα απόσβεσης δανείου ή υποθήκης στο Excel. Σας ευχαριστώ για την ανάγνωση και ελπίζω να σας δω στο blog μας την επόμενη εβδομάδα!

Διαθέσιμες λήψεις

Παραδείγματα χρονοδιαγράμματος απόσβεσης (.xlsx αρχείο)