Ohjeessa näytetään, miten Excelissä laaditaan kuoletuskaavio, joka sisältää yksityiskohtaiset tiedot jaksoittaisista maksuista kuoletettavasta lainasta tai asuntolainasta.

An jaksotettava laina on vain hieno tapa määritellä laina, joka maksetaan takaisin erissä koko laina-ajan.

Periaatteessa kaikki lainat ovat tavalla tai toisella lyhennyskelpoisia. Esimerkiksi 24 kuukauden ajan täysin lyhennyskelpoinen laina sisältää 24 samansuuruista kuukausimaksua. Jokaisesta maksusta osa käytetään lainan pääomaan ja osa korkoihin. Voit laatia lainan lyhennysaikataulun, josta näet yksityiskohtaisesti lainan jokaisen maksun.

An kuolettamisaikataulu on taulukko, jossa luetellaan lainan tai asuntolainan jaksoittaiset maksut ajan mittaan, jaetaan kukin maksu pääomaan ja korkoihin ja esitetään kunkin maksun jälkeen jäljellä oleva saldo.

Miten luodaan lainan lyhennysaikataulu Excelissä?

Lainan tai asuntolainan lyhennysaikataulun laatimiseksi Excelissä on käytettävä seuraavia funktioita:

• PMT-toiminto - laskee kokonaismäärä Tämä määrä pysyy vakiona koko laina-ajan.
• PPMT-toiminto - saa pääasiallinen osa jokaisesta maksusta, joka käytetään lainan pääomaan eli lainamäärään. Tämä määrä kasvaa seuraavissa maksuissa.
• IPMT-toiminto - löytää korko osa jokaisesta maksusta, joka menee korkoihin. Tämä määrä pienenee jokaisen maksun yhteydessä.

Käydään prosessi läpi vaihe vaiheelta.

1. Aseta kuoletusluettelo.

Määrittele aluksi syöttösolut, joihin syötät lainan tunnetut osat:

• C2 - vuotuinen korko
• C3 - laina-aika vuosina
• C4 - maksujen määrä vuodessa
• C5 - lainan määrä

Seuraavaksi luodaan kuolettamistaulukko, jossa on merkinnät ( Jakso , Maksu , Korko , Pääjohtaja , Balance ) A7:E7:ssä. Jakso sarakkeeseen kirjoitetaan maksujen kokonaismäärää vastaava numerosarja (tässä esimerkissä 1- 24):

Kun kaikki tunnetut osatekijät ovat tiedossa, siirrytään mielenkiintoisimpaan osaan - lainan lyhennyskaavoihin.

2. Laske maksun kokonaismäärä (PMT-kaava).

Maksun määrä lasketaan funktiolla PMT(rate, nper, pv, [fv], [type]).

Jotta voit käsitellä eri maksutaajuuksia oikein (kuten viikoittaiset, kuukausittaiset, neljännesvuosittaiset jne.), sinun on noudatettava johdonmukaisesti arvoja, jotka annetaan parametrille hinta ja nper argumentit:

• Arvioi - jaa vuotuinen korko maksujaksojen lukumäärällä vuodessa ($C$2/$C$4).
• Nper - kerrotaan vuosien lukumäärä maksujaksojen lukumäärällä vuodessa ($C$3*$C$4).
• Sillä pv argumentti, anna lainan määrä ($C$5).
• The fv ja tyyppi argumentit voidaan jättää pois, koska niiden oletusarvot toimivat meille hyvin (viimeisen maksun jälkeisen saldon oletetaan olevan 0; maksut suoritetaan kunkin jakson lopussa).

Yhdistämällä edellä esitetyt väitteet saamme seuraavan kaavan:

=PMT($C$2/$C$4, $C$3*$C$4, $C$5)

Huomaa, että käytämme absoluuttisia soluviittauksia, koska tämän kaavan pitäisi kopioitua alla oleviin soluihin ilman muutoksia.

Kirjoita PMT-kaava kohtaan B8, vedä se alaspäin sarakkeessa, ja näet vakiomaksun määrän kaikille jaksoille:

3. Laske korko (IPMT-kaava).

Kunkin jaksoittaisen maksun korko-osuuden määrittämiseen käytetään funktiota IPMT(rate, per, nper, pv, [fv], [type]):

=IPMT($C$2/$C$4, A8, $C$3*$C$4, $C$5)

Kaikki argumentit ovat samat kuin PMT-kaavassa, lukuun ottamatta argumenttia per Tämä argumentti annetaan suhteellisena soluviittauksena (A8), koska sen on tarkoitus muuttua sen rivin suhteellisen sijainnin perusteella, johon kaava kopioidaan.

Tämä kaava siirretään C8:aan, ja kopioi se sitten niin moneen soluun kuin tarvitaan:

4. Etsi pääoma (PPMT-kaava).

Voit laskea kunkin jaksottaisen maksun pääomaosuuden käyttämällä tätä PPMT-kaavaa:

=PPMT($C$2/$C$4, A8, $C$3*$C$4, $C$5)

Syntaksi ja argumentit ovat täsmälleen samat kuin edellä käsitellyssä IPMT-kaavassa:

Tämä kaava siirtyy sarakkeeseen D, joka alkaa sarakkeesta D8:

Vihje. Voit tarkistaa, ovatko laskelmasi tässä vaiheessa oikein, laskemalla yhteen numerot kentässä Pääjohtaja ja Korko Summan on oltava yhtä suuri kuin arvo sarakkeessa Maksu sarake samalla rivillä.

5. Hanki jäljellä oleva saldo

Kunkin jakson jäljellä olevan saldon laskemiseen käytetään kahta eri kaavaa.

Löydät saldon ensimmäisen maksuerän E8 jälkeen laskemalla yhteen lainan määrän (C5) ja ensimmäisen jakson pääoman (D8):

=C5+D8

Koska lainasumma on positiivinen luku ja pääoma on negatiivinen luku, jälkimmäinen vähennetään edellisestä.

Toisen ja kaikkien seuraavien kausien osalta lasketaan yhteen edellisen kauden saldo ja tämän kauden pääoma:

=E8+D9

Yllä oleva kaava siirtyy kohtaan E9, ja kopioit sen sitten saraketta alaspäin. Koska käytetään suhteellisia soluviittauksia, kaava mukautuu oikein jokaisella rivillä.

Siinä se! Kuukausittainen lainan lyhennysaikataulumme on valmis:

Vihje: Palauta maksut positiivisina lukuina

Koska laina maksetaan pankkitililtäsi, Excelin funktiot palauttavat maksun, koron ja pääoman muodossa. negatiiviset luvut Oletusarvoisesti nämä arvot on korostettu punaisella ja suljettu sulkuihin, kuten yllä olevassa kuvassa näkyy.

Jos haluat saada kaikki tulokset positiivinen numerot, laita miinusmerkki ennen PMT-, IPMT- ja PPMT-funktioita.

Sillä Tasapaino kaavat, käytä yhteenlaskun sijasta vähennystä, kuten alla olevassa kuvakaappauksessa:

Kuoletuskaavio vaihtelevalle määrälle jaksoja

Yllä olevassa esimerkissä rakensimme lainan lyhennysaikataulun ennalta määritetylle määrälle maksujaksoja. Tämä nopea kertaratkaisu toimii hyvin tietyn lainan tai kiinnityksen osalta.

Jos haluat luoda uudelleenkäytettävän kuoletusohjelman, jossa on vaihteleva määrä jaksoja, sinun on käytettävä jäljempänä kuvattua kattavampaa lähestymistapaa.

1. Syötä jaksojen enimmäismäärä

Vuonna Jakso sarakkeeseen voit lisätä maksujen enimmäismäärän, jonka aiot sallia mille tahansa lainalle, esimerkiksi 1:stä 360:een. Voit hyödyntää Excelin automaattista täyttötoimintoa syöttääksesi numerosarjan nopeammin.

2. Käytä IF-lausekkeita kuoletuskaavoissa.

Koska sinulla on nyt monia liian suuria jaksonumeroita, sinun on jotenkin rajoitettava laskelmat tietyn lainan todelliseen maksujen määrään. Tämä voidaan tehdä kietomalla jokainen kaava IF-lauseeseen. IF-lauseen looginen testi tarkistaa, onko nykyisen rivin jaksonumero pienempi tai yhtä suuri kuin maksujen kokonaismäärä. Jos looginen testi on TRUE, vastaavafunktio lasketaan; jos FALSE, palautetaan tyhjä merkkijono.

Olettaen, että Jakso 1 on rivillä 8, kirjoita seuraavat kaavat vastaaviin soluihin ja kopioi ne sitten koko taulukkoon.

Maksu (B8):

=IF(A8<=$C$3*$C$4, PMT($C$2/$C$4, $C$3*$C$4, $C$5), "")

Korko (C8):

=IF(A8<=$C$3*$C$4, IPMT($C$2/$C$4, A8, $C$3*$C$4, $C$5), "")

Pääjohtaja (D8):

=IF(A8<=$C$3*$C$4,PPMT($C$2/$C$4, A8, $C$3*$C$4, $C$5), "")

Tasapaino :

Osoitteessa Jakso 1 (E8), kaava on sama kuin edellisessä esimerkissä:

=C5+D8

Osoitteessa Jakso 2 (E9) ja kaikki seuraavat kaudet, kaava on seuraavanlainen:

=IF(A9<=$C$3*$C$4, E8+D9, "")

Tuloksena sinulla on oikein laskettu lyhennysaikataulu ja joukko tyhjiä rivejä, joilla on lainan lyhennyksen jälkeiset jaksonumerot.

3. Piilota ylimääräiset jaksonumerot

Jos voit elää sen kanssa, että viimeisen maksun jälkeen näytetään joukko turhia jaksonumeroita, voit pitää työtäsi tehtynä ja ohittaa tämän vaiheen. Jos tavoittelet täydellisyyttä, piilota kaikki käyttämättömät jaksot tekemällä ehdollinen muotoilusääntö, joka asettaa arvoksi fontin väri valkoiseksi minkä tahansa rivin osalta sen jälkeen, kun viimeinen maksu on suoritettu.

Valitse tätä varten kaikki tietorivit jos lyhennystaulukkosi (meidän tapauksessamme A8:E367) ja napsauta painiketta Etusivu tab> Ehdollinen muotoilu > Uusi sääntö... > Määritä muotoiltavat solut kaavan avulla .

Kirjoita vastaavaan ruutuun alla oleva kaava, jolla tarkistetaan, onko sarakkeessa A oleva jakson numero suurempi kuin maksujen kokonaismäärä:

= $A8>$C$3*$C$4

Tärkeä huomautus: Jotta ehdollisen muotoilun kaava toimisi oikein, muista käyttää absoluuttisia soluviittauksia soluviittauksissa. Laina-aika ja Maksut vuodessa solut, jotka kerrotaan ($C$3*$C$4). Tuotosta verrataan seuraavaan arvoon Jakso 1 solu, jonka soluviittauksessa käytetään sekalaista soluviittausta - absoluuttinen sarake ja suhteellinen rivi ($A8).

Napsauta sen jälkeen Formaatti... painiketta ja valitse valkoinen fontin väri. Valmis!

4. Tee lainasta yhteenveto

Jos haluat tarkastella lainasi yhteenvetotietoja yhdellä silmäyksellä, lisää lyhennysaikataulusi yläosaan pari kaavaa.

Maksut yhteensä (F2):

=-SUM(B8:B367)

Korko yhteensä (F3):

=-SUM(C8:C367)

Jos maksut ovat positiivisia lukuja, poista miinusmerkki yllä olevista kaavoista.

Lainan lyhennysaikataulumme on valmis ja valmis!

Lataa lainan lyhennysaikataulu Excelille

Miten tehdä lainan lyhennysaikataulu ylimääräisillä maksuilla Excelissä?

Edellisissä esimerkeissä käsitellyt lyhennysaikataulut ovat helppoja luoda ja noudattaa (toivottavasti :). Niistä on kuitenkin jätetty pois hyödyllinen ominaisuus, josta monet lainanmaksajat ovat kiinnostuneita - lisämaksut lainan nopeamman takaisinmaksun mahdollistamiseksi. Tässä esimerkissä tarkastelemme, miten luodaan lainan lyhennysaikataulu lisämaksuineen.

1. Määritä syöttösolut

Aloita tavalliseen tapaan syöttösolujen määrittäminen. Tässä tapauksessa nimetään solut alla olevan mukaisesti, jotta kaavoja olisi helpompi lukea:

• InterestRate - C2 (vuotuinen korko)
• LoanTerm - C3 (laina-aika vuosina)
• PaymentsPerYear - C4 (maksujen määrä vuodessa)
• LoanAmount - C5 (lainan kokonaismäärä)
• ExtraPayment - C6 (lisämaksu jaksoa kohti)

2. Laske aikataulun mukainen maksu

Syöttösolujen lisäksi tarvitaan vielä yksi valmiiksi määritelty solu, jota tarvitaan jatkolaskelmissa - solu aikataulun mukainen maksusumma eli lainasta maksettava määrä, jos lisämaksuja ei suoriteta. Tämä määrä lasketaan seuraavalla kaavalla:

=IFERROR(-PMT(Korkoprosentti/MaksutVuosi, Laina-aika*MaksutVuosi, Lainamäärä), "")

Huomaa, että laitamme miinusmerkin ennen PMT-funktiota, jotta tulos olisi positiivinen luku. Estääksemme virheet siinä tapauksessa, että jotkin syöttösoluista ovat tyhjiä, liitämme PMT-kaavan IFERROR-funktioon.

Kirjoita tämä kaava johonkin soluun (meidän tapauksessamme G2) ja nimeä kyseinen solu seuraavasti ScheduledPayment .

3. Aseta kuoletusluettelo.

Luo lainan lyhennystaulukko, jonka otsikot näkyvät alla olevassa kuvakaappauksessa. Kohdassa Jakso sarakkeeseen kirjoitetaan sarja numeroita, jotka alkavat nollasta (voit piilottaa sarakkeen Jakso 0 rivi tarvittaessa myöhemmin).

Jos haluat luoda uudelleenkäytettävän lyhennysaikataulun, anna maksujaksojen suurin mahdollinen määrä (tässä esimerkissä 0-360).

Osoitteessa Jakso 0 (meidän tapauksessamme rivi 9), vedä rivin Balance arvo, joka on yhtä suuri kuin alkuperäinen lainasumma. Kaikki muut solut tällä rivillä pysyvät tyhjinä:

Kaava G9:ssä:

=Lainamäärä

4. Rakenna kaavoja kuoletuskaavioon lisämaksujen kanssa.

Tämä on keskeinen osa työtämme. Koska Excelin sisäänrakennetut toiminnot eivät tarjoa lisämaksuja, meidän on tehtävä kaikki laskutoimitukset itse.

Huomautus: Tässä esimerkissä, Jakso 0 on rivillä 9 ja Jakso 1 on rivillä 10. Jos lyhennystaulukkosi alkaa eri riviltä, muista mukauttaa soluviittaukset vastaavasti.

Kirjoita seuraavat kaavat riville 10 ( Jakso 1 ) ja kopioi ne sitten kaikkien jäljellä olevien jaksojen osalta.

Aikataulun mukainen maksu (B10):

Jos ScheduledPayment (nimetty solu G2) on pienempi tai yhtä suuri kuin jäljellä oleva saldo (G9), käytä aikataulun mukaista maksua. Muussa tapauksessa lisää jäljellä oleva saldo ja edellisen kuukauden korot.

=IFERROR(IF(ScheduledPayment<=G9, ScheduledPayment, G9+G9*InterestRate/PaymentsPerYear), "")

Lisävarotoimena tämä ja kaikki seuraavat kaavat kääritään IFERROR-funktioon. Näin estetään erilaisten virheiden syntyminen, jos jotkin syöttösoluista ovat tyhjiä tai sisältävät virheellisiä arvoja.

Lisämaksu (C10):

Käytä IF-kaavaa seuraavalla logiikalla:

Jos ExtraPayment määrä (nimetty solu C6) on pienempi kuin jäljellä olevan saldon ja tämän kauden pääoman (G9-E10) erotus, palauta seuraavat tiedot ExtraPayment ; muutoin käytä erotusta.

=IFERROR(IF(ExtraPayment

Vihje. Jos sinulla on muuttuvat lisämaksut , kirjoita yksittäiset summat suoraan kenttään Lisämaksu sarake.

Kokonaismaksu (D10)

Lisää yksinkertaisesti kuluvan kauden maksusuunnitelma (B10) ja ylimääräinen maksu (C10):

=IFERROR(B10+C10, "")

Pääjohtaja (E10)

Jos tietyn jakson maksuaikataulu on suurempi kuin nolla, palautetaan pienempi kahdesta arvosta: maksuaikataulu miinus korot (B10-F10) tai jäljellä oleva saldo (G9); muussa tapauksessa palautetaan nolla.

=IFERROR(IF(B10>0, MIN(B10-F10, G9), 0), "")

Huomaa, että päämies sisältää vain sen osan erääntynyt maksu (ei lisämaksua!), joka menee lainan pääomaan.

Korko (F10)

Jos tietyn jakson maksuaikataulun mukainen maksu on suurempi kuin nolla, jaa vuotuinen korko (solu C2) vuosittaisten maksujen lukumäärällä (solu C4) ja kerro tulos edellisen jakson jälkeen jäljellä olevalla saldolla; muussa tapauksessa palautetaan 0.

=IFERROR(IF(B10>0, InterestRate/PaymentsPerYear*G9, 0), "")

Tasapaino (G10)

Jos jäljellä oleva saldo (G9) on suurempi kuin nolla, vähennä maksun pääomaosuus (E10) ja lisämaksu (C10) edellisen jakson jälkeen jäljellä olevasta saldosta (G9); muussa tapauksessa palauta 0.

=IFERROR(IF(G9>0, G9-E10-C10, 0), "")

Huomautus: Koska jotkin kaavoista viittaavat toisiinsa ristiin (ei ympyräviittaus!), ne saattavat näyttää vääriä tuloksia prosessin aikana. Aloita siis vianmääritys vasta, kun olet syöttänyt viimeisen kaavan lyhennystaulukkoon.

Jos kaikki on tehty oikein, lainan lyhennysaikataulun pitäisi tässä vaiheessa näyttää suunnilleen tältä:

5. Piilota ylimääräiset jaksot

Määritä ehdollinen muotoilusääntö, joka piilottaa käyttämättömien jaksojen arvot, kuten tässä vinkissä on selitetty. Erona on, että tällä kertaa käytämme ehtoa valkoinen fontin väri riveille, joilla Kokonaismaksu (sarake D) ja Balance (sarake G) ovat nolla tai tyhjä:

=AND(OR($D9=0, $D9=""), OR($G9=0, $G9=""))

Voilà, kaikki rivit, joilla on nolla-arvoja, piilotetaan näkyvistä:

6. Tee lainojen yhteenveto

Täydellisyyden viimeistelemiseksi voit tulostaa lainan tärkeimmät tiedot käyttämällä näitä kaavoja:

Maksujen suunniteltu määrä:

Kerro vuosien lukumäärä vuotuisten maksujen määrällä:

=Laina-aika*MaksutVuosittain

Maksujen todellinen määrä:

Laske solut Kokonaismaksu sarakkeessa, jotka ovat suurempia kuin nolla, alkaen jaksosta 1:

=COUNTIF(D10:D369,">"&0)

Lisämaksut yhteensä:

Laske yhteen solut Lisämaksu sarakkeessa, alkaen jaksosta 1:

=SUM(C10:C369)

Kokonaiskorko:

Laske yhteen solut Korko sarakkeessa, alkaen jaksosta 1:

=SUM(F10:F369)

Voit halutessasi piilottaa Jakso 0 rivi, ja lainan lyhennysaikataulu lisämaksuineen on valmis! Alla olevassa kuvakaappauksessa näkyy lopputulos:

Lataa lainan lyhennysaikataulu lisämaksujen kanssa

Kuoletusaikataulu Excel-malli

Jos haluat tehdä huippuluokan lainan lyhennysaikataulun hetkessä, käytä Excelin sisäänrakennettuja malleja. Mene vain osoitteeseen Tiedosto > Uusi , tyyppi " kuolettamisaikataulu " hakukenttään ja valitse haluamasi malli, esimerkiksi tämä, jossa on lisämaksuja:

Tallenna sitten juuri luotu työkirja Excel-mallina ja käytä sitä uudelleen milloin haluat.

Näin luot lainan tai asuntolainan lyhennysaikataulun Excelissä. Kiitos lukemisesta ja toivottavasti tapaamme blogissamme ensi viikolla!

Saatavilla olevat lataukset

Esimerkkejä kuoletuskaavioista (.xlsx-tiedosto)