Õpetus näitab, kuidas koostada Excelis amortisatsiooniplaan, et kirjeldada üksikasjalikult amortiseeruva laenu või hüpoteegi perioodilisi makseid.

An amortiseeruv laen on lihtsalt väljamõeldud viis määratleda laenu, mida makstakse tagasi osamaksetena kogu laenuperioodi jooksul.

Põhimõtteliselt on kõik laenud ühel või teisel viisil amortiseeruvad. Näiteks 24 kuu jooksul täielikult amortiseeruva laenu puhul on 24 võrdset igakuist makset. Iga makse läheb osaliselt põhisummale ja osaliselt intressile. Iga laenumakse täpsustamiseks saate koostada laenu amortisatsiooniplaani.

An amortisatsiooniplaan on tabel, milles on loetletud laenu või hüpoteegi perioodilised maksed aja jooksul, mis jaotab iga makse põhisummaks ja intressiks ning näitab pärast iga makset järelejäänud saldot.

Kuidas luua laenu amortisatsiooniplaan Excelis

Laenu või hüpoteegi amortisatsiooniplaani koostamiseks Excelis peame kasutama järgmisi funktsioone:

• PMT funktsioon - arvutab kogusumma perioodiline makse. See summa jääb kogu laenuperioodi jooksul samaks.
• PPMT funktsioon - saab peamine osa igast maksest, mis läheb laenu põhiosa, st laenusumma katteks. See summa suureneb järgnevate maksete puhul.
• IPMT funktsioon - leiab huvi osa igast maksest, mis läheb intressiks. See summa väheneb iga maksega.

Käime nüüd protsessi samm-sammult läbi.

1. Seadistage amortisatsioonitabel

Alustuseks määratlege sisendruudud, kuhu sisestate laenu teadaolevad komponendid:

• C2 - aastane intressimäär
• C3 - laenutähtaeg aastates
• C4 - maksete arv aastas
• C5 - laenusumma

Järgmisena tuleb luua amortisatsioonitabel koos siltidega ( Ajavahemik , Maksmine , Intressid , Peamine , Saldo ) A7:E7. In Ajavahemik veergu sisestage numbrite rida, mis on võrdne maksete koguarvuga (antud näites 1- 24):

Kui kõik teadaolevad komponendid on paigas, jõuame kõige huvitavama osa juurde - laenude amortisatsioonivalemite juurde.

2. Arvutage makse kogusumma (PMT valem).

Maksesumma arvutatakse funktsiooniga PMT(rate, nper, pv, [fv], [type]).

Selleks, et käsitleda korrektselt erinevaid maksesagedusi (näiteks iganädalane, igakuine, kvartaalne jne), peaksite olema järjepidevad väärtuste suhtes, mis on antud väärtuste jaoks määr ja nper argumendid:

• Hinda - jagage aastane intressimäär makseperioodide arvuga aastas ($C$2/$C$4).
• Nper - korrutage aastate arv maksetähtaegade arvuga aastas ($C$3*$C$4).
• Sest pv argument, sisestage laenusumma ($C$5).
• The fv ja tüüp argumendid võib ära jätta, kuna nende vaikeväärtused toimivad meie jaoks suurepäraselt (saldo pärast viimast makset peaks olema 0; maksed tehakse iga perioodi lõpus).

Ühendades ülaltoodud argumendid kokku, saame järgmise valemi:

=PMT($C$2/$C$4, $C$3*$C$4, $C$5)

Palun pöörake tähelepanu, et me kasutame absoluutseid lahtriviiteid, sest see valem peaks kopeeruma allpool olevatesse lahtritesse ilma muudatusteta.

Sisestage PMT valem B8, lohistage see veerus alla ja te näete kõikide perioodide jaoks konstantset maksesummat:

3. Arvutage intressi (IPMT valem)

Iga perioodilise makse intressiosa leidmiseks kasutage funktsiooni IPMT(rate, per, nper, pv, [fv], [type]):

=IPMT($C$2/$C$4, A8, $C$3*$C$4, $C$5)

Kõik argumendid on samad, mis PMT valemis, välja arvatud argumendi aadressil argument, mis määrab makseperioodi. See argument esitatakse suhtelise lahtriviidetena (A8), sest see peaks muutuma vastavalt rea suhtelisele positsioonile, kuhu valem kopeeritakse.

See valem läheb C8 ja seejärel kopeerite selle nii paljudesse lahtritesse kui vaja:

4. Leia peamine (PPMT valem)

Iga perioodilise makse põhiosa arvutamiseks kasutage järgmist PPMT valemit:

=PPMT($C$2/$C$4, A8, $C$3*$C$4, $C$5)

Süntaks ja argumendid on täpselt samad, mis eespool käsitletud IPMT valemis:

See valem läheb veerus D, alustades D8-st:

Vihje. Selleks, et kontrollida, kas teie arvutused on siinkohal õiged, liita kokku numbrid lahtris Peamine ja Intressid Summa peaks olema võrdne väärtusega, mis on esitatud lahtris Maksmine veerus samas reas.

5. Hangi järelejäänud saldo

Iga perioodi järelejäänud saldo arvutamiseks kasutame kahte erinevat valemit.

Saldo leidmiseks pärast esimest makset E8, liita kokku laenusumma (C5) ja esimese perioodi põhisumma (D8):

=C5+D8

Kuna laenusumma on positiivne arv ja põhisumma on negatiivne arv, siis on viimane tegelikult esimesest maha arvatud.

Teise ja kõigi järgnevate perioodide puhul liita kokku eelmise perioodi saldo ja selle perioodi põhisumma:

=E8+D9

Ülaltoodud valem läheb veergu E9 ja seejärel kopeerite selle veeru alla. Tänu suhteliste lahtriviidete kasutamisele kohandub valem iga rea puhul õigesti.

See on kõik! Meie igakuine laenu amortisatsiooniplaan on valmis:

Vihje: tagastage maksed positiivsete numbritena

Kuna laenu makstakse välja teie pangakontolt, siis Exceli funktsioonid tagastavad makse, intressi ja põhisumma kui negatiivsed numbrid Vaikimisi on need väärtused rõhutatud punase värviga ja suletud sulgudesse, nagu näete ülaltoodud pildil.

Kui eelistate, et kõik tulemused oleksid positiivne numbrid, pange miinusmärk enne funktsioone PMT, IPMT ja PPMT.

Sest Saldo valemeid, kasutage liitmise asemel lahutamist, nagu on näidatud alloleval ekraanipildil:

Muutuva arvu perioodide amortisatsioonikava

Ülaltoodud näites ehitasime laenu amortisatsiooniplaani eelnevalt määratud arvu makseperioodide jaoks. See kiire ühekordne lahendus töötab hästi konkreetse laenu või hüpoteegi puhul.

Kui soovite luua korduvkasutatavat amortisatsiooniplaani muutuva perioodide arvuga, peate kasutama allpool kirjeldatud põhjalikumat lähenemisviisi.

1. Sisestage maksimaalne perioodide arv

In the Ajavahemik veergu sisestage maksimaalne maksete arv, mida lubate mis tahes laenu puhul, näiteks vahemikus 1 kuni 360. Võite kasutada Exceli AutoFill-funktsiooni, et sisestada numbrite rida kiiremini.

2. Kasutage IF avaldusi amortisatsioonivalemites

Kuna teil on nüüd palju ülemääraseid perioodide numbreid, peate kuidagi piirama arvutusi konkreetse laenu tegeliku maksete arvuga. Seda saab teha, mähkimaks iga valemit IF avaldisse. IF avaldise loogiline test kontrollib, kas jooksva rea perioodide arv on väiksem või võrdne maksete koguarvuga. Kui loogiline test on TRUE, siis vastavatfunktsioon arvutatakse; kui FALSE, tagastatakse tühi string.

Eeldades, et Periood 1 on real 8, sisestage järgmistesse lahtritesse järgmised valemid ja kopeerige need seejärel kogu tabelisse.

Maksmine (B8):

=IF(A8<=$C$3*$C$4, PMT($C$2/$C$4, $C$3*$C$4, $C$5), "")

Intressid (C8):

=IF(A8<=$C$3*$C$4, IPMT($C$2/$C$4, A8, $C$3*$C$4, $C$5), "")

Peamine (D8):

=IF(A8<=$C$3*$C$4,PPMT($C$2/$C$4, A8, $C$3*$C$4, $C$5), "")

Saldo :

Sest Periood 1 (E8) on valem sama, mis eelmises näites:

=C5+D8

Sest Periood 2 (E9) ja kõigi järgnevate perioodide puhul on valem järgmine:

=IF(A9<=$C$3*$C$4, E8+D9, "")

Tulemuseks on õigesti arvutatud amortisatsiooniplaan ja hunnik tühje ridu perioodide numbritega pärast laenu tagasimaksmist.

3. Peida lisaperioodide numbrid

Kui saate elada koos hunniku üleliigsete perioodide numbritega, mis kuvatakse pärast viimast makset, võite lugeda töö tehtuks ja jätta selle sammu vahele. Kui te püüdlete täiuslikkuse poole, siis peita kõik kasutamata perioodid, tehes tingimusliku vormindamise reegli, mis seab väärtuse kirjavärv valgeteks mis tahes ridade puhul pärast viimase makse tegemist.

Selleks valige kõik andmete read kui teie amortisatsioonitabel (meie puhul A8:E367) ja klõpsake nuppu Kodu tab> Tingimuslik vormindamine > Uus reegel... > Kasutage valemit, et määrata, millised lahtrid tuleb vormindada .

Sisestage vastavasse lahtrisse alljärgnev valem, mis kontrollib, kas veerus A olev perioodi number on suurem kui maksete koguarv:

=$A8>$C$3*$C$4

Oluline märkus! Selleks, et tingimusliku vormingu valem töötaks õigesti, tuleb kindlasti kasutada absoluutseid lahtriviiteid lahtrile. Laenutähtaeg ja Maksed aastas rakud, mida korrutatakse ($C$3*$C$4). Toodangut võrreldakse Ajavahemik 1 lahter, mille puhul kasutate segaviidet - absoluutne veerg ja suhteline rida ($A8).

Pärast seda klõpsake nuppu Formaat... nuppu ja valige valge kirjavärv. Valmis!

4. Tehke laenude kokkuvõte

Selleks, et vaadata ülevaatlikku teavet oma laenu kohta, lisage veel paar valemit amortisatsiooniplaani ülaossa.

Maksed kokku (F2):

=-SUM(B8:B367)

Intressid kokku (F3):

=-SUM(C8:C367)

Kui teil on maksed positiivsete arvudena, eemaldage miinusmärk ülaltoodud valemitest.

See ongi kõik! Meie laenu amortisatsiooniplaan on valmis ja valmis!

Laadige alla laenu amortisatsiooniplaan Exceli jaoks

Kuidas koostada laenu amortisatsiooniplaan koos lisamaksetega Excelis

Eelmistes näidetes käsitletud amortisatsioonigraafikuid on lihtne koostada ja järgida (loodetavasti :). Siiski jätavad nad välja ühe kasuliku funktsiooni, millest paljud laenumaksjad on huvitatud - lisamaksed laenu kiiremaks tagasimaksmiseks. Selles näites vaatleme, kuidas luua laenu amortisatsioonigraafikut koos lisamaksetega.

1. Määrake sisendrakud

Nagu tavaliselt, alustame sisendruutude seadistamisega. Sel juhul nimetame need lahtrid nagu allpool kirjutatud, et meie valemeid oleks lihtsam lugeda:

• InterestRate - C2 (aastane intressimäär)
• LoanTerm - C3 (laenu tähtaeg aastates)
• PaymentsPerYear - C4 (maksete arv aastas)
• LoanAmount - C5 (laenu kogusumma)
• ExtraPayment - C6 (lisamakse perioodi kohta)

2. Arvutage graafikujärgne makse

Lisaks sisendruutudele on meie edasiste arvutuste jaoks vaja veel ühte ettemääratud lahtrit - lahtrit kavandatud maksesumma , st summa, mis tuleb laenule maksta, kui lisamakseid ei tehta. See summa arvutatakse järgmise valemiga:

=IFERROR(-PMT(InterestRate/PaymentsPerYear, LoanTerm*PaymentsPerYear, LoanAmount), "")

Pöörake tähelepanu sellele, et me paneme miinusmärgi enne funktsiooni PMT, et tulemus oleks positiivne number. Et vältida vigu juhul, kui mõni sisendruut on tühi, lisame PMT valemi funktsiooni IFERROR sisse.

Sisestage see valem mõnda lahtrisse (meie puhul G2) ja andke sellele lahtrile nimi ScheduledPayment .

3. Seadistage amortisatsioonitabel

Looge laenu amortisatsioonitabel, mille pealkirjad on näidatud allpool oleval ekraanipildil. In the Ajavahemik veergu sisestada numbrite seeria, mis algab nulliga (saate varjata numbri Periood 0 rida hiljem, kui vaja).

Kui teie eesmärk on luua korduvkasutatav amortisatsiooniplaan, sisestage maksimaalne võimalik makseperioodide arv (antud näites 0 kuni 360).

Sest Periood 0 (meie puhul rida 9), tõmmake välja Saldo väärtus, mis on võrdne esialgse laenusummaga. Kõik muud lahtrid selles reas jäävad tühjaks:

Valem G9:

=LoanAmount

4. Koostage amortisatsiooniplaani valemid koos lisamaksetega.

See on meie töö oluline osa. Kuna Exceli sisseehitatud funktsioonid ei näe ette täiendavaid makseid, peame kõik arvutused ise tegema.

Märkus. Selles näites, Periood 0 on 9. reas ja Periood 1 on reas 10. Kui teie amortisatsioonitabel algab teisest reast, kohandage lahtriviited vastavalt.

Sisestage järgmised valemid reale 10 ( Periood 1 ) ja seejärel kopeerige need kõigi ülejäänud perioodide kohta.

Planeeritud makse (B10):

Kui ScheduledPayment summa (nimega lahter G2) on väiksem või võrdne järelejäänud saldoga (G9), kasutage graafikujärgset makset. Vastasel juhul lisage järelejäänud saldo ja eelmise kuu intressid.

=IFERROR(IF(ScheduledPayment<=G9, ScheduledPayment, G9+G9*InterestRate/PaymentsPerYear), "")

Täiendava ettevaatusabinõuna mähime selle ja kõik järgmised valemid funktsiooniga IFERROR. See hoiab ära hulga erinevaid vigu, kui mõni sisendruut on tühi või sisaldab kehtetuid väärtusi.

Lisatasu (C10):

Kasutage IF-valemit järgmise loogikaga:

Kui ExtraPayment summa (nimega lahter C6) on väiksem kui järelejäänud saldo ja selle perioodi põhisumma (G9-E10) vahe, tagastatakse ExtraPayment ; muidu kasutage erinevust.

=IFERROR(IF(ExtraPayment

Vihje. Kui teil on muutuv lisamaksed , lihtsalt sisestage üksikud summad otse Lisatasu veerus.

Kogumaksumus (D10)

Lisage lihtsalt jooksva perioodi plaaniline makse (B10) ja lisamakse (C10):

=IFERROR(B10+C10, "")

Peamine (E10)

Kui antud perioodi graafikujärgne makse on suurem kui null, tagastatakse väiksem kahest väärtusest: graafikujärgne makse miinus intressid (B10-F10) või jääk (G9); vastasel juhul tagastatakse null.

=IFERROR(IF(B10>0, MIN(B10-F10, G9), 0), "")

Palun pange tähele, et peamine hõlmab ainult osa graafikujärgne makse (mitte lisamakse!), mis läheb laenu põhiosa katteks.

Intressid (F10)

Kui antud perioodi maksegraafiku makse on suurem kui null, jagage aastane intressimäär (lahter C2) maksete arvuga aastas (lahter C4) ja korrutage tulemus eelmise perioodi järelejäänud jäägiga; vastasel juhul tagastage 0.

=IFERROR(IF(B10>0, InterestRate/PaymentsPerYear*G9, 0), "")

Saldo (G10)

Kui järelejäänud saldo (G9) on suurem kui null, lahutatakse eelmisest perioodist (G9) järelejäänud saldost (E10) põhisumma (E10) ja lisamakse (C10); vastasel juhul tagastatakse 0.

=IFERROR(IF(G9>0, G9-E10-C10, 0), "")

Märkus. Kuna mõned valemid viitavad üksteisele (mitte ringviited!), võivad need protsessi käigus kuvada valesid tulemusi. Seega ärge alustage veaotsingut enne, kui sisestate amortisatsioonitabelisse kõige viimase valemi.

Kui kõik on tehtud õigesti, peaks teie laenu amortisatsioonikava sel hetkel välja nägema umbes nii:

5. Piiluta lisaperioodid

Seadistame tingimusliku vormindamise reegli, et varjata kasutamata perioodide väärtused, nagu on selgitatud selles näpunäites. Erinevus on selles, et seekord rakendame tingimusliku vormindamise reeglit valge kirjavärv ridadele, kus Kogumaksumus (veerg D) ja Saldo (veerg G) on võrdne nulliga või tühi:

=AND(OR($D9=0, $D9=""), OR($G9=0, $G9=""))

Voilà, kõik nullväärtustega read on varjatud:

6. Tehke laenude kokkuvõte

Täiuslikkuse viimistluseks saate nende valemite abil väljastada kõige olulisemad andmed laenu kohta:

Planeeritud maksete arv:

Korrutage aastate arv maksete arvuga aastas:

=LoanTerm*PaymentsPerYear

Tegelik maksete arv:

Loendage rakke Kogumaksumus veerus, mis on suuremad kui null, alates perioodist 1:

=COUNTIF(D10:D369,">"&0)

Täiendavad maksed kokku:

Lisage lahtrid kokku Lisatasu veerus, alustades perioodist 1:

=SUM(C10:C369)

Kogu huvi:

Lisage lahtrid kokku Intressid veerus, alustades perioodist 1:

=SUM(F10:F369)

Valikuliselt peitke Periood 0 rida ja teie laenu amortisatsiooniplaan koos lisamaksetega on valmis! Allpool olev ekraanipilt näitab lõpptulemust:

Laadige alla laenu tagasimaksegraafik koos lisamaksetega

Amortisatsiooniplaani Exceli mall

Selleks, et koostada tipptasemel laenu amortisatsiooniplaan kiiresti, kasutage Exceli sisseehitatud malle. Lihtsalt minge aadressile Faili > Uus , tüüp " amortisatsiooniplaan " otsingukasti ja valige endale meelepärane mall, näiteks see, millel on lisamaksed:

Seejärel salvestage äsja loodud töövihik Exceli mallina ja kasutage seda igal ajal uuesti.

Nii saate Excelis luua laenu või hüpoteegi amortisatsiooniplaani. Tänan teid lugemise eest ja loodan, et näeme teid järgmisel nädalal meie blogis!

Saadaolevad allalaadimised

Amortisatsiooniplaani näited (.xlsx fail)