De handleiding laat zien hoe u een afschrijvingsschema in Excel maakt om de periodieke betalingen van een aflossingsvrije lening of hypotheek in detail te beschrijven.

Een amortiserende lening is gewoon een mooie manier om een lening te definiëren die in termijnen wordt terugbetaald gedurende de gehele looptijd van de lening.

In principe zijn alle leningen op een of andere manier amortiserend. Bijvoorbeeld, een volledig amortiserende lening voor 24 maanden heeft 24 gelijke maandelijkse betalingen. Bij elke betaling gaat een deel naar de hoofdsom en een deel naar de rente. Om elke betaling van een lening in detail te bekijken, kunt u een aflossingsschema opstellen.

Een afschrijvingsschema is een tabel met de periodieke betalingen voor een lening of hypotheek in de tijd, waarbij elke betaling wordt uitgesplitst in hoofdsom en rente, en het resterende saldo na elke betaling wordt weergegeven.

Hoe maak je een aflossingsschema voor een lening in Excel?

Om een aflossingsschema voor een lening of hypotheek in Excel op te stellen, moeten we de volgende functies gebruiken:

• PMT-functie - berekent de totaalbedrag Dit bedrag blijft constant gedurende de gehele looptijd van de lening.
• PPMT-functie - krijgt de principal een deel van elke betaling dat naar de hoofdsom van de lening gaat, d.w.z. het bedrag dat u hebt geleend. Dit bedrag stijgt bij volgende betalingen.
• IPMT-functie - vindt de rente een deel van elke betaling dat naar de rente gaat. Dit bedrag neemt bij elke betaling af.

Laten we het proces stap voor stap doorlopen.

1. Stel de afschrijvingstabel op

Om te beginnen definieert u de invoercellen waar u de bekende componenten van een lening invoert:

• C2 - jaarlijkse rentevoet
• C3 - looptijd van de lening in jaren
• C4 - aantal betalingen per jaar
• C5 - leningsbedrag

Vervolgens maakt u een aflossingstabel met de labels ( Periode , Betaling , Rente , Belangrijkste , Balans ) in A7:E7. In de Periode kolom een reeks getallen invullen die gelijk zijn aan het totale aantal betalingen (1- 24 in dit voorbeeld):

Met alle bekende componenten op hun plaats, komen we bij het meest interessante deel - de aflossingsformules voor leningen.

2. Bereken het totale betalingsbedrag (PMT-formule)

Het betalingsbedrag wordt berekend met de functie PMT(rate, nper, pv, [fv], [type]).

Om verschillende betalingsfrequenties correct te verwerken (zoals wekelijks, maandelijks, driemaandelijks, enz.), moet u consequent zijn met de waarden die u opgeeft voor de tarief en nper argumenten:

• Beoordeel - deel de jaarlijkse rentevoet door het aantal betalingsperioden per jaar ($C$2/$C$4).
• Nper - vermenigvuldig het aantal jaren met het aantal betalingsperioden per jaar ($C$3*$C$4).
• Voor de pv argument, voer het bedrag van de lening in ($C$5).
• De fv en type argumenten kunnen worden weggelaten, omdat hun standaardwaarden voor ons prima werken (saldo na de laatste betaling wordt geacht 0 te zijn; betalingen worden gedaan aan het eind van elke periode).

Als we bovenstaande argumenten samenvoegen, krijgen we deze formule:

=PMT($C$2/$C$4, $C$3*$C$4, $C$5)

Let erop dat wij absolute celverwijzingen gebruiken, want deze formule moet ongewijzigd naar de onderstaande cellen worden gekopieerd.

Voer de PMT-formule in B8 in, sleep hem naar beneden in de kolom, en u ziet een constant betalingsbedrag voor alle perioden:

3. Rente berekenen (IPMT-formule)

Om het rentegedeelte van elke periodieke betaling te vinden, gebruikt u de functie IPMT(rate, per, nper, pv, [fv], [type]):

=IPMT($C$2/$C$4, A8, $C$3*$C$4, $C$5)

Alle argumenten zijn dezelfde als in de PMT-formule, behalve de per Dit argument wordt geleverd als een relatieve celverwijzing (A8) omdat het geacht wordt te veranderen op basis van de relatieve positie van een rij waarnaar de formule wordt gekopieerd.

Deze formule gaat naar C8, en dan kopieert u hem naar zoveel cellen als nodig:

4. Vind de hoofdsom (PPMT-formule)

Om de hoofdsom van elke periodieke betaling te berekenen, gebruikt u deze PPMT-formule:

=PPMT($C$2/$C$4, A8, $C$3*$C$4, $C$5)

De syntaxis en de argumenten zijn precies dezelfde als in de hierboven besproken IPMT-formule:

Deze formule gaat naar kolom D, beginnend bij D8:

Tip. Om te controleren of uw berekeningen op dit punt juist zijn, telt u de getallen in het Belangrijkste en Rente kolommen. De som moet gelijk zijn aan de waarde in de Betaling kolom in dezelfde rij.

5. Ontvang het resterende saldo

Om het resterende saldo voor elke periode te berekenen, gebruiken we twee verschillende formules.

Om het saldo na de eerste betaling in E8 te vinden, telt u het bedrag van de lening (C5) en de hoofdsom van de eerste periode (D8) bij elkaar op:

=C5+D8

Omdat het bedrag van de lening een positief getal is en de hoofdsom een negatief getal, wordt de hoofdsom afgetrokken van de hoofdsom.

Voor de tweede en alle volgende perioden telt u het vorige saldo en de hoofdsom van deze periode op:

=E8+D9

De bovenstaande formule gaat naar E9, en dan kopieert u hem naar beneden in de kolom. Door het gebruik van relatieve celverwijzingen past de formule zich voor elke rij correct aan.

Dat is het! Ons maandelijks aflossingsschema is klaar:

Tip: Stuur betalingen terug als positieve getallen

Omdat een lening van uw bankrekening wordt betaald, geven Excel-functies de betaling, rente en hoofdsom terug als negatieve getallen Standaard zijn deze waarden rood gemarkeerd en tussen haakjes geplaatst, zoals u kunt zien in de afbeelding hierboven.

Als u liever alle resultaten als positief nummers, zet een minteken vóór de PMT-, IPMT- en PPMT-functies.

Voor de Balans formules, gebruik aftrekken in plaats van optellen zoals in de onderstaande schermafbeelding:

Afschrijvingsschema voor een variabel aantal perioden

In het bovenstaande voorbeeld hebben we een aflossingsschema voor de lening gemaakt voor het vooraf gedefinieerde aantal betalingsperioden. Deze snelle eenmalige oplossing werkt goed voor een specifieke lening of hypotheek.

Als u een herbruikbaar afschrijvingsschema wilt maken met een variabel aantal perioden, moet u een uitgebreidere aanpak volgen, die hieronder wordt beschreven.

1. Voer het maximum aantal perioden in

In de Periode kolom voert u het maximum aantal betalingen in dat u voor elke lening wilt toestaan, bijvoorbeeld van 1 tot 360. U kunt de functie Automatisch invullen van Excel gebruiken om sneller een reeks getallen in te voeren.

2. IF statements gebruiken in afschrijvingsformules

Omdat u nu veel excessieve periodegetallen hebt, moet u de berekeningen op de een of andere manier beperken tot het werkelijke aantal betalingen voor een bepaalde lening. Dit kan worden gedaan door elke formule in een IF-statement te verpakken. De logische test van het IF-statement controleert of het periodegetal in de huidige rij kleiner of gelijk is aan het totale aantal betalingen. Als de logische test TRUE is, wordt het corresponderendefunctie wordt berekend; indien FALSE, wordt een lege string geretourneerd.

Uitgaande van Periode 1 staat in rij 8, voer de volgende formules in de overeenkomstige cellen in, en kopieer ze dan over de hele tabel.

Betaling (B8):

=IF(A8<=$C$3*$C$4, PMT($C$2/$C$4, $C$3*$C$4, $C$5), "")

Rente (C8):

=IF(A8<=$C$3*$C$4, IPMT($C$2/$C$4, A8, $C$3*$C$4, $C$5), "")

Belangrijkste (D8):

=IF(A8<=$C$3*$C$4,PPMT($C$2/$C$4, A8, $C$3*$C$4, $C$5), "")

Balans :

Voor Periode 1 (E8), is de formule dezelfde als in het vorige voorbeeld:

=C5+D8

Voor Periode 2 (E9) en alle volgende perioden, krijgt de formule deze vorm:

=IF(A9<=$C$3*$C$4, E8+D9, "")

Het resultaat is een correct berekend aflossingsschema en een heleboel lege rijen met de periodecijfers nadat de lening is afbetaald.

3. Verberg extra perioden nummers

Als u kunt leven met een hoop overbodige periodegetallen die na de laatste betaling worden weergegeven, kunt u het werk als gedaan beschouwen en deze stap overslaan. Als u perfectie nastreeft, verberg dan alle ongebruikte perioden door een voorwaardelijke opmaakregel te maken die de letterkleur naar wit voor alle rijen na de laatste betaling.

Selecteer hiervoor alle gegevensrijen als uw aflossingstabel (A8:E367 in ons geval) en klik op Home tab> Voorwaardelijke opmaak > Nieuwe regel... > Gebruik een formule om te bepalen welke cellen moeten worden opgemaakt .

Voer in het overeenkomstige vak de onderstaande formule in die controleert of het aantal perioden in kolom A groter is dan het totale aantal betalingen:

=$A8>$C$3*$C$4

Belangrijke opmerking! Om de voorwaardelijke opmaakformule correct te laten werken, moet u absolute celverwijzingen gebruiken voor de Leningstermijn en Betalingen per jaar cellen die je vermenigvuldigt ($C$3*$C$4). Het product wordt vergeleken met de Periode 1 cel, waarvoor u een gemengde celverwijzing gebruikt - absolute kolom en relatieve rij ($A8).

Klik daarna op de Formaat... en kies de witte letterkleur. Klaar!

4. Maak een leningsoverzicht

Om de samenvattende informatie over uw lening in één oogopslag te zien, voegt u nog een paar formules toe bovenaan uw aflossingsschema.

Totaal betalingen (F2):

=-SUM(B8:B367)

Totale rente (F3):

=-SUM(C8:C367)

Als u betalingen als positieve getallen heeft, verwijdert u het minteken uit de bovenstaande formules.

Dat is het! Ons aflossingsschema voor de lening is voltooid en klaar!

Download het aflossingsschema voor leningen in Excel

Hoe maak je een aflossingsschema voor een lening met extra betalingen in Excel?

De in de vorige voorbeelden besproken aflossingsschema's zijn gemakkelijk te maken en te volgen (hopelijk :). Ze laten echter een nuttige functie weg waarin veel leningsbetalers geïnteresseerd zijn - extra betalingen om een lening sneller af te betalen. In dit voorbeeld bekijken we hoe we een aflossingsschema voor een lening met extra betalingen kunnen maken.

1. Ingangscellen definiëren

Zoals gewoonlijk beginnen we met het instellen van de invoercellen. In dit geval geven we deze cellen een naam zoals hieronder geschreven om onze formules gemakkelijker leesbaar te maken:

• Rente - C2 (jaarlijkse rentevoet)
• LeningTerm - C3 (looptijd van de lening in jaren)
• Betalingen per jaar - C4 (aantal betalingen per jaar)
• LoanAmount - C5 (totaal leningbedrag)
• ExtraBetaling - C6 (extra betaling per periode)

2. Bereken een geplande betaling

Naast de invoercellen is er nog één voorgedefinieerde cel nodig voor onze verdere berekeningen - de gepland betalingsbedrag d.w.z. het bedrag dat op een lening moet worden betaald als er geen extra betalingen worden gedaan. Dit bedrag wordt berekend met de volgende formule:

=IFERROR(-PMT(InterestRate/PaymentsPerYear, LoanTerm*PaymentsPerYear, LoanAmount), "")

Let erop dat we een minteken voor de PMT-functie plaatsen om het resultaat als een positief getal te krijgen. Om fouten te voorkomen wanneer sommige van de invoercellen leeg zijn, sluiten we de PMT-formule in binnen de IFERROR-functie.

Voer deze formule in een cel in (G2 in ons geval) en geef die cel een naam ScheduledPayment .

3. Stel de afschrijvingstabel op

Maak een aflossingstabel voor een lening met de koppen in de schermafbeelding hieronder. In de tabel Periode kolom een reeks getallen invoeren die beginnen met nul (u kunt de Periode 0 rij later indien nodig).

Als u een herbruikbaar aflossingsschema wilt maken, voer dan het maximaal mogelijke aantal betalingsperioden in (0 tot 360 in dit voorbeeld).

Voor Periode 0 (rij 9 in ons geval), trek de Balans Alle andere cellen in deze rij blijven leeg:

Formule in G9:

=LoanAmount

4. Formules opstellen voor aflossingsschema met extra betalingen

Omdat de ingebouwde functies van Excel niet voorzien in extra betalingen, zullen we alle wiskunde zelf moeten doen.

Opmerking. In dit voorbeeld, Periode 0 staat in rij 9 en Periode 1 staat in rij 10. Als uw aflossingstabel in een andere rij begint, moet u de celverwijzingen dienovereenkomstig aanpassen.

Voer in rij 10 de volgende formules in ( Periode 1 ), en kopieer ze dan voor alle resterende perioden.

Geplande betaling (B10):

Als de ScheduledPayment bedrag (genoemd in cel G2) kleiner of gelijk is aan het resterende saldo (G9), gebruikt u de geplande betaling. Anders telt u het resterende saldo en de rente van de vorige maand op.

=IFERROR(IF(ScheduledPayment<=G9, ScheduledPayment, G9+G9*InterestRate/PaymentsPerYear), "")

Als extra voorzorgsmaatregel wikkelen we deze en alle volgende formules in de IFERROR-functie. Dit voorkomt een hoop verschillende fouten als sommige van de invoercellen leeg zijn of ongeldige waarden bevatten.

Extra betaling (C10):

Gebruik een IF-formule met de volgende logica:

Als de ExtraBetaling bedrag (cel C6 genoemd) lager is dan het verschil tussen het resterende saldo en de hoofdsom van deze periode (G9-E10), retourneer ExtraBetaling gebruik anders het verschil.

=IFERROR(IF(ExtraPayment

Tip. Als u variabele extra betalingen typ de individuele bedragen rechtstreeks in de Extra betaling column.

Totale betaling (D10)

Voeg gewoon de geplande betaling (B10) en de extra betaling (C10) voor de huidige periode toe:

=IFERROR(B10+C10, "")

Belangrijkste (E10)

Indien de geplande betaling voor een bepaalde periode groter is dan nul, wordt de kleinste van de twee waarden geretourneerd: geplande betaling minus rente (B10-F10) of het resterende saldo (G9); anders wordt nul geretourneerd.

=IFERROR(IF(B10>0, MIN(B10-F10, G9), 0), "")

Merk op dat de opdrachtgever alleen het deel van de geplande betaling (niet de extra betaling!) die naar de hoofdsom van de lening gaat.

Rente (F10)

Indien de geplande betaling voor een bepaalde periode groter is dan nul, deelt u het jaarlijkse rentepercentage (cel C2 genaamd) door het aantal betalingen per jaar (cel C4 genaamd) en vermenigvuldigt u de uitkomst met het saldo dat overblijft na de vorige periode; zo niet, geeft u 0 terug.

=IFERROR(IF(B10>0, InterestRate/PaymentsPerYear*G9, 0), "")

Balans (G10)

Als het resterende saldo (G9) groter is dan nul, trekt u het hoofddeel van de betaling (E10) en de extra betaling (C10) af van het saldo dat overblijft na de vorige periode (G9); anders geeft u 0 terug.

=IFERROR(IF(G9>0, G9-E10-C10, 0), "")

Opmerking. Omdat sommige van de formules elkaar kruisen (geen cirkelvormige verwijzing!), kunnen ze tijdens het proces verkeerde resultaten weergeven. Begin dus pas met het oplossen van problemen als u de allerlaatste formule in uw aflossingstabel invoert.

Als alles correct verloopt, zou het aflossingsschema van uw lening er nu ongeveer zo uit moeten zien:

5. Verberg extra perioden

Stel een voorwaardelijke opmaakregel in om de waarden in ongebruikte periodes te verbergen, zoals uitgelegd in deze tip. Het verschil is dat we deze keer het witte letterkleur naar de rijen waarin Totale betaling (kolom D) en Balans (kolom G) zijn gelijk aan nul of leeg:

=AND(OR($D9=0, $D9=""), OR($G9=0, $G9=""))

Voilà, alle rijen met nulwaarden worden aan het zicht onttrokken:

6. Maak een leningsoverzicht

Als finishing touch van perfectie kunt u met deze formules de belangrijkste informatie over een lening weergeven:

Gepland aantal betalingen:

Vermenigvuldig het aantal jaren met het aantal betalingen per jaar:

=LoanTerm*PaymentsPerYear

Werkelijk aantal betalingen:

Tel de cellen in de Totale betaling kolom die groter zijn dan nul, te beginnen met periode 1:

=COUNTIF(D10:D369,">"&0)

Totaal extra betalingen:

Tel de cellen in de Extra betaling kolom, te beginnen met periode 1:

=SUM(C10:C369)

Totale rente:

Tel de cellen in de Rente kolom, te beginnen met periode 1:

=SUM(F10:F369)

Verberg optioneel de Periode 0 rij, en uw aflossingsschema met extra betalingen is klaar! De schermafbeelding hieronder toont het eindresultaat:

Download het aflossingsschema van de lening met extra betalingen

Afschrijvingsschema Excel sjabloon

Om in een mum van tijd een top aflossingsschema voor een lening te maken, kunt u gebruik maken van de ingebouwde sjablonen van Excel. Ga naar Bestand > Nieuw , type " afschrijvingsschema " in het zoekvak en kies de sjabloon die u bevalt, bijvoorbeeld deze met extra betalingen:

Sla vervolgens de nieuw gemaakte werkmap op als een Excel-sjabloon en hergebruik deze wanneer u maar wilt.

Zo maakt u een aflossingsschema voor een lening of hypotheek in Excel. Ik dank u voor het lezen en hoop u volgende week op onze blog te zien!

Beschikbare downloads

Voorbeelden van afschrijvingsschema's (.xlsx-bestand)