Bu eğitimde, amortismanlı bir kredi veya ipoteğe ilişkin periyodik ödemeleri detaylandırmak için Excel'de bir amortisman planının nasıl oluşturulacağı gösterilmektedir.

Bir amortismanlı kredi kredinin tüm vadesi boyunca taksitler halinde geri ödenen bir krediyi tanımlamanın süslü bir yoludur.

Temel olarak, tüm krediler bir şekilde amorti edilir. Örneğin, 24 ay boyunca tamamen amorti edilen bir kredinin 24 eşit aylık ödemesi olacaktır. Her ödeme, bir miktar anaparaya ve bir miktar faize uygulanır. Bir kredideki her ödemeyi detaylandırmak için bir kredi amortisman planı oluşturabilirsiniz.

Bir amorti̇sman plani bir kredi veya ipoteğe ilişkin periyodik ödemeleri zaman içinde listeleyen, her ödemeyi anapara ve faiz olarak ayıran ve her ödemeden sonra kalan bakiyeyi gösteren bir tablodur.

Excel'de kredi amortisman tablosu nasıl oluşturulur

Excel'de bir kredi veya ipotek amortisman tablosu oluşturmak için aşağıdaki fonksiyonları kullanmamız gerekecektir:

• PMT fonksiyonu - hesaplar toplam tutar Bu tutar, kredinin tüm süresi boyunca sabit kalır.
• PPMT işlevi - şu değerleri alır müdür Her ödemenin kredi anaparasına, yani borç aldığınız miktara giden kısmı. Bu miktar sonraki ödemeler için artar.
• IPMT işlevi - aşağıdakileri bulur ilgi Her ödemenin faize giden kısmı. Bu miktar her ödemede azalır.

Şimdi, süreci adım adım gözden geçirelim.

1. Amortisman tablosunu ayarlayın

Yeni başlayanlar için, bir kredinin bilinen bileşenlerini gireceğiniz giriş hücrelerini tanımlayın:

• C2 - yıllık faiz oranı
• C3 - yıl cinsinden kredi vadesi
• C4 - yıllık ödeme sayısı
• C5 - kredi tutarı

Yapacağınız bir sonraki şey, etiketlerle birlikte bir amortisman tablosu oluşturmaktır ( Dönem , Ödeme , Faiz , Müdür , Denge ) A7:E7'de. Dönem sütununa, toplam ödeme sayısına eşit bir sayı dizisi girin (bu örnekte 1- 24):

Bilinen tüm bileşenleri yerine koyduktan sonra en ilginç kısma gelelim - kredi amortisman formülleri.

2. Toplam ödeme tutarını hesaplayın (PMT formülü)

Ödeme tutarı PMT(rate, nper, pv, [fv], [type]) fonksiyonu ile hesaplanır.

Farklı ödeme sıklıklarını (haftalık, aylık, üç aylık vb.) doğru bir şekilde işlemek için oran ve nper Argümanlar:

• Oran - Yıllık faiz oranını yıllık ödeme dönemi sayısına bölün ($C$2/$C$4).
• Nper - yıl sayısını yıllık ödeme dönemi sayısı ile çarpın ($C$3*$C$4).
• için pv argümanını kullanarak kredi tutarını girin ($C$5).
• Bu fv ve tip argümanları atlanabilir çünkü varsayılan değerleri bizim için gayet iyi çalışır (son ödemeden sonraki bakiyenin 0 olması gerekir; ödemeler her dönemin sonunda yapılır).

Yukarıdaki argümanları bir araya getirdiğimizde bu formülü elde ederiz:

=PMT($C$2/$C$4, $C$3*$C$4, $C$5)

Lütfen mutlak hücre referansları kullandığımıza dikkat edin, çünkü bu formül herhangi bir değişiklik yapmadan aşağıdaki hücrelere kopyalanmalıdır.

PMT formülünü B8'e girin, sütundan aşağı sürükleyin ve tüm dönemler için sabit bir ödeme tutarı göreceksiniz:

3. Faizi hesaplayın (IPMT formülü)

Her periyodik ödemenin faiz kısmını bulmak için IPMT(rate, per, nper, pv, [fv], [type]) fonksiyonunu kullanın:

=IPMT($C$2/$C$4, A8, $C$3*$C$4, $C$5)

Tüm argümanlar PMT formülündeki ile aynıdır, ancak başına Bu bağımsız değişken, formülün kopyalandığı satırın göreli konumuna göre değişmesi gerektiğinden göreli hücre başvurusu (A8) olarak sağlanır.

Bu formül C8'e gider ve ardından gerektiği kadar hücreye kopyalarsınız:

4. Anaparayı bulun (PPMT formülü)

Her bir periyodik ödemenin anapara kısmını hesaplamak için bu PPMT formülünü kullanın:

=PPMT($C$2/$C$4, A8, $C$3*$C$4, $C$5)

Sözdizimi ve bağımsız değişkenler yukarıda tartışılan IPMT formülündeki ile tamamen aynıdır:

Bu formül D8'den başlayarak D sütununa gider:

İpucu: Bu noktada hesaplamalarınızın doğru olup olmadığını kontrol etmek için Müdür ve Faiz sütunlarındaki değere eşit olmalıdır. Ödeme aynı satırdaki sütun.

5. Kalan bakiyeyi alın

Her dönem için kalan bakiyeyi hesaplamak için iki farklı formül kullanacağız.

E8'deki ilk ödemeden sonraki bakiyeyi bulmak için kredi tutarını (C5) ve ilk dönemin anaparasını (D8) toplayın:

=C5+D8

Kredi tutarı pozitif bir sayı, anapara ise negatif bir sayı olduğundan, kredi tutarı aslında ilkinden çıkarılır.

İkinci ve sonraki tüm dönemler için, önceki bakiyeyi ve bu dönemin anaparasını toplayın:

=E8+D9

Yukarıdaki formül E9'a gider ve sonra bunu sütundan aşağı kopyalarsınız. Göreli hücre referanslarının kullanılması nedeniyle, formül her satır için doğru şekilde ayarlanır.

İşte bu! Aylık kredi amortisman planımız tamamlandı:

İpucu: Ödemeleri pozitif sayı olarak döndürün

Bir kredi banka hesabınızdan ödendiği için, Excel işlevleri ödemeyi, faizi ve anaparayı şu şekilde döndürür negatif sayılar Varsayılan olarak, bu değerler kırmızı ile vurgulanır ve yukarıdaki resimde görebileceğiniz gibi parantez içine alınır.

Tüm sonuçları aşağıdaki gibi almayı tercih ederseniz pozitif sayıları için PMT, IPMT ve PPMT işlevlerinin önüne eksi işareti koyun.

için Denge formüllerinde, aşağıdaki ekran görüntüsünde gösterildiği gibi toplama yerine çıkarma işlemini kullanın:

Değişken sayıda dönem için amortisman planı

Yukarıdaki örnekte, önceden tanımlanmış ödeme dönemi sayısı için bir kredi amortisman planı oluşturduk. Bu tek seferlik hızlı çözüm, belirli bir kredi veya ipotek için iyi çalışır.

Değişken sayıda dönem içeren yeniden kullanılabilir bir amortisman planı oluşturmak istiyorsanız, aşağıda açıklanan daha kapsamlı bir yaklaşımı benimsemeniz gerekecektir.

1. Maksimum dönem sayısını girin

İçinde Dönem sütununa, herhangi bir kredi için izin vereceğiniz maksimum ödeme sayısını girin, örneğin 1'den 360'a kadar. Bir dizi sayıyı daha hızlı girmek için Excel'in Otomatik Doldurma özelliğinden yararlanabilirsiniz.

2. Amortisman formüllerinde EĞER ifadelerini kullanın

Artık çok fazla dönem numaranız olduğundan, hesaplamaları bir şekilde belirli bir kredi için gerçek ödeme sayısıyla sınırlamanız gerekir. Bu, her formülü bir EĞER deyimine sararak yapılabilir. EĞER deyiminin mantıksal testi, geçerli satırdaki dönem numarasının toplam ödeme sayısından küçük veya eşit olup olmadığını kontrol eder. Mantıksal test DOĞRU ise, ilgiliişlevi hesaplanır; FALSE ise boş bir dize döndürülür.

Varsayalım ki Dönem 1 8. satırda ise, ilgili hücrelere aşağıdaki formülleri girin ve ardından bunları tüm tabloya kopyalayın.

Ödeme (B8):

=IF(A8<=$C$3*$C$4, PMT($C$2/$C$4, $C$3*$C$4, $C$5), "")

Faiz (C8):

=IF(A8<=$C$3*$C$4, IPMT($C$2/$C$4, A8, $C$3*$C$4, $C$5), "")

Müdür (D8):

=IF(A8<=$C$3*$C$4,PPMT($C$2/$C$4, A8, $C$3*$C$4, $C$5), "")

Denge :

İçin Dönem 1 (E8), formül önceki örnektekiyle aynıdır:

=C5+D8

İçin Dönem 2 (E9) ve sonraki tüm dönemler için formül bu şekli alır:

=IF(A9<=$C$3*$C$4, E8+D9, "")

Sonuç olarak, doğru hesaplanmış bir amortisman planınız ve kredi ödendikten sonra dönem numaralarını içeren bir grup boş satırınız olur.

3. Ekstra dönem numaralarını gizleyin

Son ödemeden sonra görüntülenen bir sürü gereksiz dönem numarasıyla yaşayabilirseniz, işin tamamlandığını düşünebilir ve bu adımı atlayabilirsiniz. Mükemmellik için çabalıyorsanız, kullanılmayan tüm dönemleri yazı tipi rengi beyaz son ödeme yapıldıktan sonra herhangi bir satır için.

Bunun için, tüm veri satırları amortisman tablonuz (bizim durumumuzda A8:E367) ise ve Ev tab> Koşullu biçimlendirme > Yeni kural. > Hangi hücrelerin biçimlendirileceğini belirlemek için bir formül kullanma .

İlgili kutuya, A sütunundaki dönem sayısının toplam ödeme sayısından büyük olup olmadığını kontrol eden aşağıdaki formülü girin:

=$A8>$C$3*$C$4

Önemli not! Koşullu biçimlendirme formülünün düzgün çalışması için, mutlak hücre referanslarını kullandığınızdan emin olun. Kredi vadesi ve Yıllık ödemeler Çarpım yaptığınız hücreler ($C$3*$C$4). Dönem 1 hücre için mutlak sütun ve göreli satır ($A8) olmak üzere karışık bir hücre başvurusu kullanırsınız.

Bunun ardından Format... düğmesine basın ve beyaz yazı tipi rengini seçin. Bitti!

4. Bir kredi özeti oluşturun

Kredinizle ilgili özet bilgileri bir bakışta görüntülemek için amortisman planınızın en üstüne birkaç formül daha ekleyin.

Toplam ödemeler (F2):

=-TOPLA(B8:B367)

Toplam faiz (F3):

=-TOPLA(C8:C367)

Ödemeleriniz pozitif sayılar ise, yukarıdaki formüllerden eksi işaretini kaldırın.

İşte bu! Kredi amortisman programımız tamamlandı ve kullanıma hazır!

Excel için kredi amortisman planını indirin

Excel'de ekstra ödemelerle kredi amortisman planı nasıl yapılır

Önceki örneklerde tartışılan amortisman planlarının oluşturulması ve takip edilmesi kolaydır (umarım :). Ancak, birçok kredi ödeyicisinin ilgilendiği yararlı bir özelliği dışarıda bırakırlar - bir krediyi daha hızlı ödemek için ek ödemeler. Bu örnekte, ekstra ödemelerle bir kredi amortisman planının nasıl oluşturulacağına bakacağız.

1. Giriş hücrelerini tanımlayın

Her zamanki gibi, giriş hücrelerini ayarlamakla başlayın. Bu durumda, formüllerimizin okunmasını kolaylaştırmak için bu hücreleri aşağıda yazıldığı gibi adlandıralım:

• Faiz Oranı - C2 (yıllık faiz oranı)
• Kredi Süresi - C3 (yıl cinsinden kredi vadesi)
• Yıl Başına Ödemeler - C4 (yıllık ödeme sayısı)
• KrediMiktarı - C5 (toplam kredi tutarı)
• EkstraÖdeme - C6 (dönem başına ekstra ödeme)

2. Planlanmış bir ödemeyi hesaplayın

Giriş hücrelerinin yanı sıra, daha sonraki hesaplamalarımız için önceden tanımlanmış bir hücre daha gereklidir - planlanan ödeme tutarı yani ekstra ödeme yapılmaması durumunda kredi için ödenecek tutardır. Bu tutar aşağıdaki formülle hesaplanır:

=IFERROR(-PMT(InterestRate/PaymentsPerYear, LoanTerm*PaymentsPerYear, LoanAmount), "")

Sonucun pozitif bir sayı olması için PMT işlevinden önce bir eksi işareti koyduğumuza lütfen dikkat edin. Giriş hücrelerinden bazılarının boş olması durumunda hataları önlemek için PMT formülünü IFERROR işlevi içine alıyoruz.

Bu formülü bir hücreye (bizim durumumuzda G2) girin ve hücreyi adlandırın PlanlanmışÖdeme .

3. Amortisman tablosunu ayarlayın

Aşağıdaki ekran görüntüsünde gösterilen başlıklarla bir kredi amortisman tablosu oluşturun. Dönem sütununa sıfır ile başlayan bir dizi sayı girin (sıfır ile başlayan Dönem 0 gerekirse daha sonra satır).

Yeniden kullanılabilir bir amortisman planı oluşturmayı hedefliyorsanız, mümkün olan maksimum ödeme dönemi sayısını girin (bu örnekte 0 ila 360).

İçin Dönem 0 (bizim durumumuzda 9. satır), çek Denge değeri, orijinal kredi tutarına eşittir. Bu satırdaki diğer tüm hücreler boş kalacaktır:

G9'daki formül:

=Kredi Tutarı

4. Ekstra ödemelerle amortisman planı için formüller oluşturun

Excel'in yerleşik işlevleri ek ödemeler sağlamadığı için, tüm matematiği kendi başımıza yapmamız gerekecek.

Not: Bu örnekte, Dönem 0 9. satırda ve Dönem 1 Amortisman tablonuz farklı bir satırda başlıyorsa, lütfen hücre referanslarını buna göre ayarladığınızdan emin olun.

Satır 10'a aşağıdaki formülleri girin ( Dönem 1 ) ve ardından kalan tüm dönemler için bunları kopyalayın.

Planlanmış Ödeme (B10):

Eğer PlanlanmışÖdeme tutarı (G2 hücresi olarak adlandırılır) kalan bakiyeden (G9) küçük veya eşitse, planlanan ödemeyi kullanın. Aksi takdirde, kalan bakiyeyi ve önceki ayın faizini ekleyin.

=IFERROR(IF(ScheduledPayment<=G9, ScheduledPayment, G9+G9*InterestRate/PaymentsPerYear), "")

Ekstra bir önlem olarak, bunu ve sonraki tüm formülleri IFERROR işlevine sarıyoruz. Bu, giriş hücrelerinden bazılarının boş olması veya geçersiz değerler içermesi durumunda bir dizi çeşitli hatayı önleyecektir.

Ekstra Ödeme (C10):

Aşağıdaki mantığa sahip bir EĞER formülü kullanın:

Eğer EkstraÖdeme tutarının (C6 hücresi olarak adlandırılır) kalan bakiye ile bu dönemin anaparası (G9-E10) arasındaki farktan az olması durumunda EkstraÖdeme aksi takdirde farkı kullanın.

=IFERROR(IF(ExtraPayment

İpucu. değişken ek ödemeler 'ye tek tek tutarları doğrudan yazmanız yeterlidir. Ekstra Ödeme sütun.

Toplam Ödeme (D10)

Basitçe, cari dönem için planlanan ödemeyi (B10) ve ekstra ödemeyi (C10) ekleyin:

=IFERROR(B10+C10, "")

Müdür (E10)

Belirli bir dönem için programlanan ödeme sıfırdan büyükse, iki değerden küçük olanı döndürür: programlanan ödeme eksi faiz (B10-F10) veya kalan bakiye (G9); aksi takdirde sıfır döndürür.

=IFERROR(IF(B10>0, MIN(B10-F10, G9), 0), "")

Lütfen anaparanın sadece aşağıdaki kısımları içerdiğini unutmayın planlı ödeme (ekstra ödeme değil!) bu da kredi anaparasına gider.

Faiz (F10)

Belirli bir dönem için program ödemesi sıfırdan büyükse, yıllık faiz oranını (C2 hücresi olarak adlandırılır) yıllık ödeme sayısına (C4 hücresi olarak adlandırılır) bölün ve sonucu önceki dönemden sonra kalan bakiye ile çarpın; aksi takdirde 0 döndürün.

=IFERROR(IF(B10>0, InterestRate/PaymentsPerYear*G9, 0), "")

Denge (G10)

Kalan bakiye (G9) sıfırdan büyükse, ödemenin anapara kısmını (E10) ve ekstra ödemeyi (C10) önceki dönemden (G9) sonra kalan bakiyeden çıkarın; aksi takdirde 0 döndürün.

=IFERROR(IF(G9>0, G9-E10-C10, 0), "")

Not: Bazı formüller birbirlerine çapraz referans verdiğinden (dairesel referans değil!), işlem sırasında yanlış sonuçlar gösterebilirler. Bu nedenle, lütfen amortisman tablonuzdaki en son formülü girene kadar sorun gidermeye başlamayın.

Her şey doğru yapıldıysa, bu noktada kredi amortisman planınız aşağıdaki gibi görünmelidir:

5. Ekstra süreleri gizleyin

Bu ipucunda açıklandığı gibi kullanılmayan dönemlerdeki değerleri gizlemek için bir koşullu biçimlendirme kuralı oluşturun. Aradaki fark, bu sefer beyaz yazı tipi rengi olduğu satırlara Toplam Ödeme (D sütunu) ve Denge (G sütunu) sıfıra eşit veya boştur:

=AND(OR($D9=0, $D9=""), OR($G9=0, $G9=""))

İşte, sıfır değerine sahip tüm satırlar görünümden gizlenir:

6. Bir kredi özeti oluşturun

Mükemmelliğin son dokunuşu olarak, bu formülleri kullanarak bir kredi hakkındaki en önemli bilgilerin çıktısını alabilirsiniz:

Planlanan ödeme sayısı:

Yıl sayısını yıllık ödeme sayısı ile çarpın:

=Kredi Vadesi*Yıl Başına Ödemeler

Gerçek ödeme sayısı:

İçindeki hücreleri sayın Toplam Ödeme Dönem 1'den başlayarak sıfırdan büyük olan sütun:

=COUNTIF(D10:D369,">"&0)

Toplam ekstra ödemeler:

İçindeki hücreleri topla Ekstra Ödeme sütununda, Dönem 1 ile başlayarak:

=TOPLA(C10:C369)

Toplam faiz:

İçindeki hücreleri topla Faiz sütununda, Dönem 1 ile başlayarak:

=TOPLA(F10:F369)

İsteğe bağlı olarak Dönem 0 satırına tıklayın ve ek ödemelerle birlikte kredi amortisman planınız tamamlandı! Aşağıdaki ekran görüntüsü nihai sonucu göstermektedir:

Ek ödemeli kredi amortisman planını indirin

Amortisman programı Excel şablonu

Kısa sürede birinci sınıf bir kredi amortisman planı hazırlamak için Excel'in dahili şablonlarından yararlanın. Dosya > Yeni , yazın " amorti̇sman plani " arama kutusuna tıklayın ve beğendiğiniz şablonu seçin, örneğin ekstra ödemeli bu şablonu:

Ardından yeni oluşturulan çalışma kitabını bir Excel şablonu olarak kaydedin ve istediğiniz zaman yeniden kullanın.

Excel'de bir kredi veya ipotek amortisman planını bu şekilde oluşturabilirsiniz. Okuduğunuz için teşekkür ediyor ve gelecek hafta blogumuzda görüşmeyi umuyorum!

Mevcut indirmeler

Amortisman Çizelgesi örnekleri (.xlsx dosyası)