В учебном пособии показано, как построить амортизационный график в Excel для детализации периодических платежей по амортизационному кредиту или ипотеке.

An амортизирующий кредит это просто причудливый способ определить кредит, который выплачивается частями в течение всего срока кредитования.

В принципе, все кредиты так или иначе амортизируются. Например, полностью амортизируемый кредит на 24 месяца будет иметь 24 равных ежемесячных платежа. При каждом платеже часть суммы идет на погашение основного долга, а часть - на выплату процентов. Для детализации каждого платежа по кредиту можно построить график амортизации кредита.

An график амортизации это таблица, в которой перечислены периодические платежи по кредиту или ипотеке с течением времени, каждый платеж разбит на основную сумму и проценты и показан остаток после каждого платежа.

Как создать график амортизации кредита в Excel

Чтобы построить график амортизации кредита или ипотеки в Excel, нам потребуется использовать следующие функции:

• Функция PMT - вычисляет общая сумма периодического платежа. Эта сумма остается постоянной в течение всего срока кредита.
• Функция PPMT - получает главный часть каждого платежа, которая идет на погашение основной суммы кредита, т.е. суммы, которую вы взяли в долг. Эта сумма увеличивается при последующих платежах.
• Функция IPMT - находит проценты часть каждого платежа, которая идет на выплату процентов. Эта сумма уменьшается с каждым платежом.

Теперь давайте пройдемся по процессу шаг за шагом.

1. настройка амортизационной таблицы

Для начала определите ячейки ввода, в которые вы будете вводить известные компоненты кредита:

• C2 - годовая процентная ставка
• C3 - срок кредита в годах
• C4 - количество платежей в год
• C5 - сумма кредита

Следующее, что вы делаете, это создаете амортизационную таблицу с метками ( Период , Оплата , Проценты , Главная , Баланс ) в A7:E7. В Период столбце введите ряд чисел, равный общему количеству платежей (1- 24 в данном примере):

Когда все известные компоненты на месте, перейдем к самой интересной части - формулам амортизации кредита.

2. рассчитать общую сумму платежа (формула PMT)

Сумма платежа рассчитывается с помощью функции PMT(rate, nper, pv, [fv], [type]).

Чтобы правильно обрабатывать различные частоты платежей (например, еженедельные, ежемесячные, ежеквартальные и т.д.), вы должны быть последовательны в значениях, задаваемых для параметра тариф и nper аргументы:

• Тариф - разделить годовую процентную ставку на количество платежных периодов в году ($C$2/$C$4).
• Nper - умножьте количество лет на количество периодов выплат в год ($C$3*$C$4).
• Для pv аргумент, введите сумму кредита ($C$5).
• Сайт fv и тип аргументы можно опустить, поскольку их значения по умолчанию работают для нас просто отлично (баланс после последнего платежа должен быть равен 0; платежи производятся в конце каждого периода).

Сложив вышеприведенные аргументы вместе, мы получаем такую формулу:

=PMT($C$2/$C$4, $C$3*$C$4, $C$5)

Обратите внимание, что мы используем абсолютные ссылки на ячейки, потому что эта формула должна копироваться в нижележащие ячейки без каких-либо изменений.

Введите формулу PMT в B8, перетащите ее вниз по столбцу, и вы увидите постоянную сумму платежа для всех периодов:

3. рассчитать проценты (формула IPMT)

Чтобы найти процентную часть каждого периодического платежа, используйте функцию IPMT(rate, per, nper, pv, [fv], [type]):

=IPMT($C$2/$C$4, A8, $C$3*$C$4, $C$5)

Все аргументы те же, что и в формуле PMT, за исключением аргумента на аргумент, задающий период оплаты. Этот аргумент предоставляется в виде относительной ссылки на ячейку (A8), поскольку предполагается, что он будет изменяться в зависимости от относительного положения строки, в которую копируется формула.

Эта формула помещается в ячейку C8, а затем вы копируете ее вниз во столько ячеек, сколько необходимо:

4. Найдите основную сумму (формула PPMT)

Чтобы рассчитать основную часть каждого периодического платежа, используйте эту формулу PPMT:

=PPMT($C$2/$C$4, A8, $C$3*$C$4, $C$5)

Синтаксис и аргументы точно такие же, как и в формуле IPMT, рассмотренной выше:

Эта формула переходит в столбец D, начиная с D8:

Совет. Чтобы проверить правильность ваших расчетов на данном этапе, сложите числа в разделе Главная и Проценты столбцов. Сумма должна быть равна значению в Оплата столбец в той же строке.

5. получить оставшуюся сумму

Для расчета остатка за каждый период мы будем использовать две разные формулы.

Чтобы найти остаток после первого платежа в E8, сложите сумму кредита (C5) и основной долг первого периода (D8):

=C5+D8

Поскольку сумма кредита является положительным числом, а основная сумма - отрицательным, последняя фактически вычитается из первой.

Для второго и всех последующих периодов сложите остаток предыдущего и основную сумму долга за этот период:

=E8+D9

Приведенная выше формула переходит в E9, а затем вы копируете ее вниз по столбцу. Благодаря использованию относительных ссылок на ячейки, формула правильно настраивается для каждой строки.

Вот и все! Наш ежемесячный график амортизации кредита готов:

Совет: Возвращайте платежи в виде положительных чисел

Поскольку кредит выплачивается с вашего банковского счета, функции Excel возвращают платеж, проценты и основную сумму долга как отрицательные числа По умолчанию эти значения выделены красным цветом и заключены в круглые скобки, как показано на рисунке выше.

Если вы предпочитаете получить все результаты в виде позитивный числа, поставьте знак минус перед функциями PMT, IPMT и PPMT.

Для Баланс формулы, используйте вычитание вместо сложения, как показано на скриншоте ниже:

График амортизации для переменного числа периодов

В приведенном выше примере мы построили график амортизации кредита для заданного количества периодов выплат. Это быстрое одноразовое решение хорошо подходит для конкретного кредита или ипотеки.

Если вы хотите создать многократно используемый график амортизации с переменным количеством периодов, вам придется применить более комплексный подход, описанный ниже.

1. введите максимальное количество периодов

В Период В столбце введите максимальное количество платежей, которое вы собираетесь разрешить для любого кредита, скажем, от 1 до 360. Вы можете использовать функцию автозаполнения Excel, чтобы быстрее ввести ряд чисел.

2. использование операторов IF в формулах амортизации

Поскольку у вас теперь много избыточных номеров периодов, вы должны как-то ограничить вычисления фактическим количеством платежей по конкретному кредиту. Это можно сделать, обернув каждую формулу в оператор IF. Логический тест оператора IF проверяет, меньше или равен ли номер периода в текущей строке общему количеству платежей. Если логический тест равен TRUE, то соответствующийвычисляется функция; если FALSE, возвращается пустая строка.

Предполагается, что Период 1 находится в строке 8, введите следующие формулы в соответствующие ячейки, а затем скопируйте их по всей таблице.

Оплата (B8):

=IF(A8<=$C$3*$C$4, PMT($C$2/$C$4, $C$3*$C$4, $C$5), "")

Проценты (C8):

=IF(A8<=$C$3*$C$4, IPMT($C$2/$C$4, A8, $C$3*$C$4, $C$5), "")

Главная (D8):

=IF(A8<=$C$3*$C$4,PPMT($C$2/$C$4, A8, $C$3*$C$4, $C$5), "")

Баланс :

Для Период 1 (E8), формула такая же, как и в предыдущем примере:

=C5+D8

Для Период 2 (E9) и все последующие периоды, формула принимает следующий вид:

=IF(A9<=$C$3*$C$4, E8+D9, "")

В результате у вас есть правильно рассчитанный график амортизации и куча пустых строк с номерами периодов после погашения кредита.

3. Скрыть номера дополнительных периодов

Если вы можете жить с кучей лишних номеров периодов, отображаемых после последнего платежа, то можете считать работу выполненной и пропустить этот шаг. Если вы стремитесь к совершенству, то скройте все неиспользуемые периоды, создав правило условного форматирования, которое устанавливает значение цвет шрифта - белый для любых рядов после осуществления последнего платежа.

Для этого выберите все строки данных если ваша таблица амортизации (A8:E367 в нашем случае) и нажмите кнопку Главная вкладка> Условное форматирование > Новое правило... > Используйте формулу, чтобы определить, какие ячейки форматировать .

В соответствующем поле введите приведенную ниже формулу, которая проверяет, превышает ли номер периода в столбце A общее количество платежей:

=$A8>$C$3*$C$4

Важное замечание! Чтобы формула условного форматирования работала правильно, обязательно используйте абсолютные ссылки на ячейки для Срок кредита и Выплаты в год ячейки, которые вы перемножаете ($C$3*$C$4). Произведение сравнивается с Период 1 ячейка, для которой используется смешанная ссылка на ячейку - абсолютный столбец и относительная строка ($A8).

После этого нажмите кнопку Формат... и выберите белый цвет шрифта. Готово!

4. Составьте сводку по кредитам

Чтобы сразу просмотреть сводную информацию о вашем кредите, добавьте еще несколько формул в верхней части графика амортизации.

Всего платежей (F2):

=-SUM(B8:B367)

Итого проценты (F3):

=-SUM(C8:C367)

Если платежи являются положительными числами, уберите знак минус из приведенных выше формул.

Вот и все! Наш график амортизации кредита завершен и готов к работе!

Скачать график амортизации кредита для Excel

Как составить график амортизации кредита с дополнительными платежами в Excel

Графики амортизации, рассмотренные в предыдущих примерах, легко создавать и следовать им (надеюсь :)). Однако в них отсутствует полезная функция, в которой заинтересованы многие плательщики кредитов - дополнительные платежи, позволяющие быстрее погасить кредит. В этом примере мы рассмотрим, как создать график амортизации кредита с дополнительными платежами.

1. Определите ячейки ввода

Как обычно, начните с настройки ячеек ввода. В данном случае давайте назовем эти ячейки так, как написано ниже, чтобы наши формулы было легче читать:

• Процентная ставка - C2 (годовая процентная ставка)
• Срок кредита - C3 (срок кредита в годах)
• PaymentsPerYear - C4 (количество платежей в год)
• LoanAmount - C5 (общая сумма кредита)
• ExtraPayment - C6 (дополнительная оплата за период)

2. рассчитать плановый платеж

Кроме ячеек ввода, для дальнейших расчетов необходима еще одна предопределенная ячейка - ячейка сумма планового платежа т.е. сумма, которую необходимо выплатить по кредиту, если не делать никаких дополнительных платежей. Эта сумма рассчитывается по следующей формуле:

=IFERROR(-PMT(InterestRate/PaymentsPerYear, LoanTerm*PaymentsPerYear, LoanAmount), "")

Обратите внимание, что перед функцией PMT мы ставим знак минус, чтобы результат был положительным числом. Чтобы предотвратить ошибки в случае, если некоторые из входных ячеек пусты, мы заключили формулу PMT в функцию IFERROR.

Введите эту формулу в некоторую ячейку (в нашем случае G2) и дайте ей имя ScheduledPayment .

3. настройка таблицы амортизации

Создайте таблицу амортизации кредита с заголовками, показанными на скриншоте ниже.В Период столбце введите ряд чисел, начиная с нуля (вы можете скрыть Период 0 ряд позже, если потребуется).

Если вы хотите создать график амортизации многократного использования, введите максимально возможное количество периодов выплат (от 0 до 360 в данном примере).

Для Период 0 (ряд 9 в нашем случае), вытяните Баланс значение, равное первоначальной сумме кредита. Все остальные ячейки в этой строке останутся пустыми:

Формула в G9:

=Сумма кредита

4. построение формул для графика амортизации с дополнительными платежами

Это ключевая часть нашей работы. Поскольку встроенные функции Excel не предусматривают дополнительных выплат, нам придется выполнять все вычисления самостоятельно.

Примечание. В данном примере, Период 0 находится в ряду 9 и Период 1 находится в строке 10. Если ваша таблица амортизации начинается в другой строке, пожалуйста, не забудьте соответствующим образом изменить ссылки на ячейки.

Введите следующие формулы в строку 10 ( Период 1 ), а затем скопируйте их для всех оставшихся периодов.

Плановый платеж (B10):

Если ScheduledPayment сумма (именованная ячейка G2) меньше или равна остатку (G9), используйте запланированный платеж. В противном случае добавьте остаток и проценты за предыдущий месяц.

=IFERROR(IF(ScheduledPayment<=G9, ScheduledPayment, G9+G9*InterestRate/PaymentsPerYear), "")

В качестве дополнительной меры предосторожности мы обернем эту и все последующие формулы в функцию IFERROR. Это позволит избежать кучи различных ошибок, если некоторые из входных ячеек пусты или содержат недопустимые значения.

Дополнительная оплата (C10):

Используйте формулу IF со следующей логикой:

Если ExtraPayment сумма (названная в ячейке C6) меньше разницы между остатком и суммой основного долга за этот период (G9-E10), возврат ExtraPayment ; в противном случае используйте разницу.

=IFERROR(IF(ExtraPayment

Совет. Если у вас переменные дополнительные платежи просто введите отдельные суммы непосредственно в Дополнительная оплата колонна.

Общая сумма оплаты (D10)

Просто добавьте плановый платеж (B10) и дополнительный платеж (C10) за текущий период:

=IFERROR(B10+C10, "")

Главная (E10)

Если плановый платеж за данный период больше нуля, возвращается меньшее из двух значений: плановый платеж минус проценты (B10-F10) или остаток (G9); в противном случае возвращается ноль.

=IFERROR(IF(B10>0, MIN(B10-F10, G9), 0), "")

Обратите внимание, что принципал включает в себя только часть запланированный платёж (не дополнительный платеж!), который идет на погашение основной суммы кредита.

Проценты (F10)

Если платеж по графику для данного периода больше нуля, разделите годовую процентную ставку (ячейка C2) на количество платежей в год (ячейка C4) и умножьте результат на остаток, оставшийся после предыдущего периода; в противном случае верните 0.

=IFERROR(IF(B10>0, InterestRate/PaymentsPerYear*G9, 0), "")

Баланс (G10)

Если остаток (G9) больше нуля, вычтите основную часть платежа (E10) и дополнительный платеж (C10) из остатка, оставшегося после предыдущего периода (G9); в противном случае верните 0.

=IFERROR(IF(G9>0, G9-E10-C10, 0), "")

Примечание. Поскольку некоторые формулы имеют перекрестные ссылки друг на друга (не круговые ссылки!), в процессе работы они могут показывать неверные результаты. Поэтому, пожалуйста, не начинайте поиск неисправностей, пока не введете самую последнюю формулу в свою амортизационную таблицу.

Если все сделано правильно, график амортизации вашего кредита на этом этапе должен выглядеть примерно так:

5. Скрыть дополнительные периоды

Настройте правило условного форматирования для скрытия значений в неиспользуемых периодах, как описано в этом совете. Разница в том, что на этот раз мы применим правило белый цвет шрифта к рядам, в которых Общая сумма оплаты (колонка D) и Баланс (столбец G) равны нулю или пусты:

=AND(OR($D9=0, $D9=""), OR($G9=0, $G9=""))

Вуаля, все строки с нулевыми значениями скрыты от глаз:

6. Составьте сводку по кредитам

В качестве последнего штриха совершенства вы можете вывести наиболее важную информацию о кредите с помощью этих формул:

Плановое количество платежей:

Умножьте количество лет на количество платежей в год:

=Срок кредита*Платежи за год

Фактическое количество платежей:

Подсчитайте клетки в Общая сумма оплаты столбца, которые больше нуля, начиная с Периода 1:

=COUNTIF(D10:D369,">"&0)

Общие дополнительные выплаты:

Сложите ячейки в Дополнительная оплата столбец, начиная с Периода 1:

=SUM(C10:C369)

Общие проценты:

Сложите ячейки в Проценты столбец, начиная с Периода 1:

=SUM(F10:F369)

По желанию скрыть Период 0 row, и ваш график амортизации кредита с дополнительными платежами готов! На скриншоте ниже показан окончательный результат:

Скачать график амортизации кредита с дополнительными платежами

График амортизации шаблон Excel

Чтобы быстро составить первоклассный график амортизации кредита, воспользуйтесь встроенными шаблонами Excel. Просто зайдите в раздел Файл > Новый , тип " график амортизации " в поисковой строке и выберите понравившийся шаблон, например, этот с дополнительными выплатами:

Затем сохраните созданную рабочую книгу как шаблон Excel и используйте ее повторно, когда захотите.

Вот как создать график амортизации кредита или ипотеки в Excel. Благодарю вас за чтение и надеюсь увидеть вас в нашем блоге на следующей неделе!

Доступные загрузки

Примеры графиков амортизации (файл .xlsx)