Tento návod ukazuje, jak v aplikaci Excel sestavit amortizační plán, který podrobně popisuje pravidelné platby amortizovaného úvěru nebo hypotéky.

. amortizující úvěr je jen módní způsob, jak definovat úvěr, který se splácí ve splátkách po celou dobu trvání úvěru.

V podstatě všechny půjčky jsou tak či onak amortizované. Například plně amortizovaná půjčka na 24 měsíců bude mít 24 stejných měsíčních splátek. Každá splátka se vztahuje určitou část na jistinu a určitou část na úrok. Chcete-li podrobně popsat jednotlivé splátky půjčky, můžete sestavit amortizační plán půjčky.

. amortizační plán je tabulka, která uvádí pravidelné splátky úvěru nebo hypotéky v průběhu času, rozděluje každou splátku na jistinu a úrok a ukazuje zbývající zůstatek po každé splátce.

Jak vytvořit amortizační plán úvěru v aplikaci Excel

Pro sestavení amortizačního plánu úvěru nebo hypotéky v aplikaci Excel budeme muset použít následující funkce:

• Funkce PMT - vypočítá celková částka pravidelné splátky. Tato částka zůstává konstantní po celou dobu trvání úvěru.
• Funkce PPMT - získá hlavní část každé splátky, která jde na jistinu úvěru, tj. na částku, kterou jste si půjčili. Tato částka se při dalších splátkách zvyšuje.
• Funkce IPMT - vyhledá úrok část každé splátky, která jde na úhradu úroků. Tato částka se s každou splátkou snižuje.

Nyní si postup projdeme krok za krokem.

1. Nastavení amortizační tabulky

Pro začátek definujte vstupní buňky, do kterých budete zadávat známé součásti úvěru:

• C2 - roční úroková sazba
• C3 - doba trvání úvěru v letech
• C4 - počet plateb za rok
• C5 - výše úvěru

Dále vytvoříte amortizační tabulku se štítky ( Období , Platba , Úroky , Hlavní , Bilance ) v A7:E7. Období zadejte řadu čísel rovnající se celkovému počtu plateb (v tomto příkladu 1- 24):

Když máme všechny známé součásti, přejděme k tomu nejzajímavějšímu - vzorcům pro amortizaci úvěru.

2. Výpočet celkové částky platby (vzorec PMT)

Částka platby se vypočítá pomocí funkce PMT(rate, nper, pv, [fv], [type]).

Pro správné zpracování různých frekvencí plateb (např. týdenní, měsíční, čtvrtletní atd.) je třeba důsledně dodržovat hodnoty zadané pro parametr sazba a nper argumenty:

• Hodnotit - vydělte roční úrokovou sazbu počtem splátkových období za rok ($C$2/$C$4).
• Nper - vynásobte počet let počtem platebních období za rok ($C$3*$C$4).
• Pro pv zadejte částku půjčky ($C$5).
• Na stránkách fv a typ argumenty lze vynechat, protože jejich výchozí hodnoty nám vyhovují (zůstatek po poslední platbě má být 0; platby se provádějí na konci každého období).

Když výše uvedené argumenty spojíme dohromady, dostaneme tento vzorec:

=PMT($C$2/$C$4, $C$3*$C$4, $C$5)

Dejte prosím pozor, že používáme absolutní odkazy na buňky, protože tento vzorec by se měl beze změny zkopírovat do níže uvedených buněk.

Zadejte vzorec PMT do pole B8, přetáhněte jej dolů do sloupce a zobrazí se konstantní částka platby pro všechna období:

3. Výpočet úroků (vzorec IPMT)

Chcete-li zjistit úrokovou část každé periodické platby, použijte funkci IPMT(rate, per, nper, pv, [fv], [type]):

=IPMT($C$2/$C$4, A8, $C$3*$C$4, $C$5)

Všechny argumenty jsou stejné jako ve vzorci PMT, kromě argumentu na argument, který určuje období platby. Tento argument se zadává jako relativní odkaz na buňku (A8), protože se má měnit na základě relativní polohy řádku, do kterého se vzorec kopíruje.

Tento vzorec přejde do C8 a pak jej zkopírujete dolů do tolika buněk, kolik potřebujete:

4. Zjistěte jistinu (vzorec PPMT)

Pro výpočet části jistiny každé pravidelné platby použijte tento vzorec PPMT:

=PPMT($C$2/$C$4, A8, $C$3*$C$4, $C$5)

Syntaxe a argumenty jsou naprosto stejné jako ve výše uvedeném vzorci IPMT:

Tento vzorec přechází do sloupce D, který začíná v D8:

Tip: Chcete-li zkontrolovat, zda jsou vaše výpočty v tomto bodě správné, sečtěte čísla v poli Hlavní a Úroky Součet by se měl rovnat hodnotě v položce Platba ve stejném řádku.

5. Získejte zbývající zůstatek

Pro výpočet zůstatku za každé období použijeme dva různé vzorce.

Chcete-li zjistit zůstatek po první splátce v položce E8, sečtěte částku úvěru (C5) a jistinu za první období (D8):

=C5+D8

Protože částka úvěru je kladné číslo a jistina je záporné číslo, je od první částky odečtena druhá.

Pro druhé a všechna následující období sečtěte předchozí zůstatek a jistinu tohoto období:

=E8+D9

Výše uvedený vzorec přejde do E9 a pak jej zkopírujete dolů do sloupce. Díky použití relativních odkazů na buňky se vzorec správně upraví pro každý řádek.

A je to! Náš měsíční splátkový kalendář je hotov:

Tip: Vracejte platby jako kladná čísla

Vzhledem k tomu, že půjčka je vyplácena z bankovního účtu, funkce aplikace Excel vrací splátku, úrok a jistinu jako záporná čísla Ve výchozím nastavení jsou tyto hodnoty zvýrazněny červeně a uzavřeny v závorkách, jak vidíte na obrázku výše.

Pokud dáváte přednost tomu, aby se všechny výsledky zobrazovaly jako pozitivní před funkce PMT, IPMT a PPMT vložte znaménko minus.

Pro Bilance vzorce, použijte místo sčítání odčítání, jak je znázorněno na obrázku níže:

Amortizační plán pro proměnlivý počet období

Ve výše uvedeném příkladu jsme sestavili splátkový kalendář pro předem definovaný počet splátkových období. Toto rychlé jednorázové řešení dobře funguje pro konkrétní úvěr nebo hypotéku.

Pokud chcete vytvořit opakovaně použitelný amortizační plán s proměnlivým počtem období, budete muset použít komplexnější přístup popsaný níže.

1. Zadejte maximální počet období

V Období sloupci vložte maximální počet splátek, které hodláte povolit pro jakoukoli půjčku, například od 1 do 360. Pro rychlejší zadání řady čísel můžete využít funkci automatického vyplňování aplikace Excel.

2. Použití příkazů IF v amortizačních vzorcích

Protože nyní máte mnoho nadměrných čísel období, musíte nějak omezit výpočty na skutečný počet splátek pro konkrétní půjčku. To lze provést tak, že každý vzorec zabalíte do příkazu IF. Logický test příkazu IF kontroluje, zda číslo období v aktuálním řádku je menší nebo rovno celkovému počtu splátek. Pokud je logický test TRUE, odpovídajícíje vypočítána funkce; pokud je FALSE, je vrácen prázdný řetězec.

Za předpokladu, že Období 1 je v řádku 8, zadejte do příslušných buněk následující vzorce a poté je zkopírujte do celé tabulky.

Platba (B8):

=IF(A8<=$C$3*$C$4, PMT($C$2/$C$4, $C$3*$C$4, $C$5), "")

Úroky (C8):

=IF(A8<=$C$3*$C$4, IPMT($C$2/$C$4, A8, $C$3*$C$4, $C$5), "")

Hlavní (D8):

=IF(A8<=$C$3*$C$4,PPMT($C$2/$C$4, A8, $C$3*$C$4, $C$5), "")

Bilance :

Pro Období 1 (E8), vzorec je stejný jako v předchozím příkladu:

=C5+D8

Pro Období 2 (E9) a všech následujících obdobích má vzorec tento tvar:

=IF(A9<=$C$3*$C$4, E8+D9, "")

Výsledkem je správně vypočítaný splátkový kalendář a spousta prázdných řádků s čísly období po splacení úvěru.

3. Skrýt další čísla období

Pokud se smíříte s tím, že se po poslední platbě zobrazí spousta zbytečných teček, můžete považovat práci za hotovou a tento krok přeskočit. Pokud usilujete o dokonalost, skryjte všechny nepoužívané tečky pomocí pravidla podmíněného formátování, které nastaví hodnotu barvu písma na bílou pro všechny řádky po provedení poslední platby.

Za tímto účelem vyberte všechny datové řádky pokud je vaše amortizační tabulka (v našem případě A8:E367) a klikněte na tlačítko Home karta> Podmíněné formátování > Nové pravidlo... > Pomocí vzorce určete, které buňky se mají formátovat .

Do příslušného pole zadejte níže uvedený vzorec, který kontroluje, zda je číslo období ve sloupci A větší než celkový počet plateb:

=$A8>$C$3*$C$4

Důležitá poznámka! Aby vzorec podmíněného formátování fungoval správně, nezapomeňte použít absolutní odkazy na buňky pro Doba trvání půjčky a Platby za rok buňky, které vynásobíte ($C$3*$C$4). Součin se porovná s hodnotou Období 1 buňka, pro kterou použijete smíšený odkaz na buňku - absolutní sloupec a relativní řádek ($A8).

Poté klikněte na Formát... a vyberte bílou barvu písma. Hotovo!

4. Vytvořte přehled půjček

Chcete-li na první pohled zobrazit souhrnné informace o své půjčce, přidejte do horní části amortizačního plánu několik dalších vzorců.

Celkové platby (F2):

=-SUMA(B8:B367)

Úroky celkem (F3):

=-SUMA(C8:C367)

Pokud máte platby v kladných číslech, odstraňte z výše uvedených vzorců znaménko minus.

A je to! Náš splátkový kalendář je hotov a může se začít používat!

Stáhněte si amortizační plán půjčky pro Excel

Jak vytvořit amortizační plán půjčky s dodatečnými splátkami v aplikaci Excel

Amortizační plány, o kterých jsme hovořili v předchozích příkladech, se snadno vytvářejí a dodržují (doufejme :). Vynechávají však užitečnou funkci, o kterou má mnoho plátců půjček zájem - dodatečné splátky, které umožňují rychlejší splacení půjčky. V tomto příkladu se podíváme na to, jak vytvořit amortizační plán půjčky s dodatečnými splátkami.

1. Definujte vstupní buňky

Jako obvykle začneme nastavením vstupních buněk. V tomto případě pojmenujme tyto buňky, jak je napsáno níže, aby byly naše vzorce lépe čitelné:

• Úroková sazba - C2 (roční úroková sazba)
• LoanTerm - C3 (doba trvání úvěru v letech)
• Platby za rok - C4 (počet plateb za rok)
• LoanAmount - C5 (celková výše úvěru)
• ExtraPayment - C6 (příplatek za období)

2. Výpočet plánované platby

Kromě vstupních buněk je pro naše další výpočty zapotřebí ještě jedna předdefinovaná buňka - buňka plánovaná výše platby , tj. částka, která bude zaplacena na úvěr, pokud nebudou provedeny žádné mimořádné splátky. Tato částka se vypočítá podle následujícího vzorce:

=IFERROR(-PMT(InterestRate/PaymentsPerYear, LoanTerm*PaymentsPerYear, LoanAmount), "")

Věnujte prosím pozornost tomu, že před funkci PMT vkládáme znaménko minus, aby výsledek byl kladné číslo. Abychom zabránili chybám v případě, že některé vstupní buňky jsou prázdné, uzavíráme vzorec PMT do funkce IFERROR.

Zadejte tento vzorec do některé buňky (v našem případě G2) a pojmenujte ji. ScheduledPayment .

3. Nastavení amortizační tabulky

Vytvořte tabulku amortizace půjčky se záhlavími uvedenými na obrázku níže. Období sloupec zadejte řadu čísel začínající nulou (můžete skrýt položku Období 0 řádek později, pokud je to nutné).

Pokud chcete vytvořit opakovaně použitelný splátkový kalendář, zadejte maximální možný počet splátkových období (v tomto příkladu 0 až 360).

Pro Období 0 (v našem případě řádek 9), vytáhněte tlačítko Bilance hodnota, která se rovná původní částce úvěru. Všechny ostatní buňky v tomto řádku zůstanou prázdné:

Vzorec v G9:

=LoanAmount

4. Sestavte vzorce pro amortizační plán s dodatečnými platbami

Jedná se o klíčovou část naší práce. Protože vestavěné funkce aplikace Excel neumožňují další platby, budeme muset všechny výpočty provést sami.

Poznámka: V tomto příkladu, Období 0 je v řádku 9 a Období 1 je v řádku 10. Pokud vaše amortizační tabulka začíná v jiném řádku, nezapomeňte odpovídajícím způsobem upravit odkazy na buňky.

Do řádku 10 zadejte následující vzorce ( Období 1 ) a poté je zkopírujte pro všechna zbývající období.

Plánovaná platba (B10):

Pokud ScheduledPayment částka (pojmenovaná buňka G2) je menší nebo rovna zbývajícímu zůstatku (G9), použijte plánovanou platbu. V opačném případě přičtěte zbývající zůstatek a úroky za předchozí měsíc.

=IFERROR(IF(ScheduledPayment<=G9, ScheduledPayment, G9+G9*InterestRate/PaymentsPerYear), "")

Jako další opatření obalíme tento a všechny následující vzorce funkcí IFERROR. Tím zabráníme spoustě různých chyb, pokud jsou některé vstupní buňky prázdné nebo obsahují neplatné hodnoty.

Příplatek (C10):

Použijte vzorec IF s následující logikou:

Pokud ExtraPayment (buňka C6) je nižší než rozdíl mezi zbývajícím zůstatkem a jistinou za toto období (G9-E10), vraťte částku. ExtraPayment ; jinak použijte rozdíl.

=IFERROR(IF(ExtraPayment

Tip. Pokud máte variabilní dodatečné platby , stačí zadat jednotlivé částky přímo do pole Příplatek sloupec.

Celková platba (D10)

Jednoduše sečtěte plánovanou platbu (B10) a mimořádnou platbu (C10) za aktuální období:

=IFERROR(B10+C10, "")

Hlavní (E10)

Pokud je splátka podle rozvrhu pro dané období větší než nula, vrátí se menší ze dvou hodnot: splátka podle rozvrhu minus úrok (B10-F10) nebo zbývající zůstatek (G9); jinak se vrátí nula.

=IFERROR(IF(B10>0, MIN(B10-F10, G9), 0), "")

Vezměte prosím na vědomí, že jistina zahrnuje pouze část plánovaná platba (nikoliv mimořádnou splátku!), která jde na jistinu úvěru.

Úroky (F10)

Pokud je splátka rozvrhu pro dané období větší než nula, vydělte roční úrokovou sazbu (buňka C2) počtem splátek za rok (buňka C4) a výsledek vynásobte zůstatkem po předchozím období; jinak vraťte 0.

=IFERROR(IF(B10>0, InterestRate/PaymentsPerYear*G9, 0), "")

Bilance (G10)

Pokud je zbývající zůstatek (G9) větší než nula, odečte se od zůstatku po předchozím období (G9) část jistiny (E10) a doplatek (C10); jinak se vrátí 0.

=IFERROR(IF(G9>0, G9-E10-C10, 0), "")

Poznámka: Vzhledem k tomu, že některé vzorce na sebe vzájemně odkazují (nejedná se o kruhový odkaz!), mohou se v průběhu zobrazovat nesprávné výsledky. Proto nezačínejte s řešením problémů, dokud nezadáte úplně poslední vzorec v amortizační tabulce.

Pokud je vše provedeno správně, měl by váš splátkový kalendář v tomto okamžiku vypadat přibližně takto:

5. Skrýt hodiny navíc

Nastavte pravidlo podmíněného formátování pro skrytí hodnot v nepoužívaných tečkách, jak je vysvětleno v tomto tipu. Rozdíl je v tom, že tentokrát použijeme příkaz bílá barva písma do řádků, ve kterých Celková platba (sloupec D) a Bilance (sloupec G) se rovnají nule nebo jsou prázdné:

=AND(OR($D9=0, $D9=""), OR($G9=0, $G9=""))

Voilà, všechny řádky s nulovými hodnotami jsou skryté:

6. Vytvořte přehled půjček

Na závěr můžete vypsat nejdůležitější informace o půjčce pomocí těchto vzorců:

Plánovaný počet plateb:

Vynásobte počet let počtem plateb za rok:

=LoanTerm*PaymentsPerYear

Skutečný počet plateb:

Počítejte buňky v Celková platba které jsou větší než nula, počínaje obdobím 1:

=COUNTIF(D10:D369,">"&0)

Celkové dodatečné platby:

Sečtěte buňky v Příplatek sloupec, počínaje obdobím 1:

=SUMA(C10:C369)

Celkový zájem:

Sečtěte buňky v Úroky sloupec, počínaje obdobím 1:

=SUMA(F10:F369)

Volitelně můžete skrýt Období 0 a váš splátkový kalendář s dalšími splátkami je hotov! Na obrázku níže je zobrazen konečný výsledek:

Stáhněte si splátkový kalendář s mimořádnými splátkami

Amortizační plán šablona Excel

Chcete-li během okamžiku sestavit špičkový amortizační plán půjčky, využijte vestavěné šablony aplikace Excel. Stačí přejít na stránku Soubor > Nový , typ " amortizační plán " ve vyhledávacím poli a vyberte šablonu, která se vám líbí, například tuto s dodatečnými platbami:

Nově vytvořený sešit pak uložte jako šablonu aplikace Excel a kdykoli jej můžete znovu použít.

Takto si v Excelu vytvoříte amortizační plán půjčky nebo hypotéky. Děkuji vám za přečtení a doufám, že se příští týden uvidíme na našem blogu!

Dostupné soubory ke stažení

Příklady amortizačního plánu (.xlsx soubor)