გაკვეთილი გვიჩვენებს, თუ როგორ უნდა ავაშენოთ ამორტიზაციის გრაფიკი Excel-ში, რათა დეტალურად განვახორციელოთ პერიოდული გადახდები ამორტიზაციის სესხზე ან იპოთეკაზე.

ამორტიზაციის სესხი უბრალოდ ლამაზია. გზა განვსაზღვროთ სესხი, რომელიც უბრუნდება განვადებით სესხის მთელი ვადის განმავლობაში.

ძირითადად, ყველა სესხი ამა თუ იმ გზით ამორტირებულია. მაგალითად, სრულად ამორტირებული სესხი 24 თვის განმავლობაში ექნება 24 თანაბარი ყოველთვიური გადასახადი. თითოეული გადახდა ვრცელდება გარკვეულ თანხაზე ძირითადი თანხის მიმართ, ნაწილი კი პროცენტის მიმართ. სესხის თითოეული გადახდის დეტალებისთვის შეგიძლიათ შეადგინოთ სესხის ამორტიზაციის გრაფიკი.

ამორტიზაციის გრაფიკი არის ცხრილი, რომელიც ჩამოთვლის პერიოდულ გადახდებს სესხზე ან იპოთეკაზე დროთა განმავლობაში, ანაწილებს თითოეულ გადახდას. ძირში და პროცენტში და აჩვენებს დარჩენილ ბალანსს ყოველი გადახდის შემდეგ.

როგორ შევქმნათ სესხის ამორტიზაციის გრაფიკი Excel-ში

სესხის ან იპოთეკის ამორტიზაციის გრაფიკის შესაქმნელად Excel, ჩვენ დაგვჭირდება შემდეგი ფუნქციების გამოყენება:

• PMT ფუნქცია - ითვლის მთლიანი თანხა პერიოდული გადახდის. ეს თანხა რჩება უცვლელი სესხის მთელი ხანგრძლივობის განმავლობაში.
• PPMT ფუნქცია - იღებს თითოეული გადახდის ძირი ნაწილს, რომელიც მიდის სესხის ძირზე, ანუ თქვენ მიერ ნასესხებ თანხაზე. ეს თანხა იზრდება შემდგომი გადახდებისთვის.
• IPMT ფუნქცია - პოულობს პროცენტს თითოეული გადახდის ნაწილს, რომელიც მიდის პროცენტზე.გაქვთ ცვლადი დამატებითი გადახდები , უბრალოდ აკრიფეთ ინდივიდუალური თანხები პირდაპირ სვეტში დამატებითი გადახდა .

  სულ გადახდა (D10)

  უბრალოდ, დაამატეთ დაგეგმილი გადახდა (B10) და დამატებითი გადახდა (C10) მიმდინარე პერიოდისთვის:

  =IFERROR(B10+C10, "")

  ძირი (E10)

  თუ გრაფიკის გადახდა მოცემული პერიოდისთვის არის ნულზე მეტი, დააბრუნეთ ორი მნიშვნელობიდან მცირე: დაგეგმილი გადახდა პროცენტის გამოკლებით (B10-F10) ან დარჩენილი ნაშთი (G9); წინააღმდეგ შემთხვევაში დააბრუნეთ ნული.

  =IFERROR(IF(B10>0, MIN(B10-F10, G9), 0), "")

  გთხოვთ, გაითვალისწინოთ, რომ ძირი მოიცავს მხოლოდ გეგმიური გადახდის ნაწილს (და არა დამატებით გადახდას!), რომელიც მიდის სესხის ძირზე.

  პროცენტი (F10)

  თუ მოცემული პერიოდის გადახდის გრაფიკი ნულზე მეტია, გაყავით წლიური საპროცენტო განაკვეთი (სახელად C2 უჯრედი) გადახდების რაოდენობაზე წელიწადში (უჯერი C4) და გაამრავლეთ შედეგი წინა პერიოდის შემდეგ დარჩენილი ნაშთით; წინააღმდეგ შემთხვევაში, დააბრუნეთ 0.

  =IFERROR(IF(B10>0, InterestRate/PaymentsPerYear*G9, 0), "")

  ბალანსი (G10)

  თუ დარჩენილი ნაშთი (G9) ნულზე მეტია, გამოაკელით ძირითადი ნაწილი გადახდის (E10) და დამატებით გადახდას (C10) წინა პერიოდის შემდეგ დარჩენილი ბალანსიდან (G9); წინააღმდეგ შემთხვევაში დააბრუნეთ 0.

  =IFERROR(IF(G9 >0, G9-E10-C10, 0), "")

  შენიშვნა. იმის გამო, რომ ზოგიერთი ფორმულა ერთმანეთზე მიმართავს (არა წრიული მითითება!), მათ შეიძლება აჩვენონ არასწორი შედეგები ამ პროცესში. ასე რომ, გთხოვთ, არ დაიწყოთ პრობლემების მოგვარება, სანამ არ შეხვალთბოლო ფორმულა თქვენს ამორტიზაციის ცხრილში.

  თუ ყველაფერი სწორად გაკეთდა, თქვენი სესხის ამორტიზაციის განრიგი ამ ეტაპზე ასე უნდა გამოიყურებოდეს:

  5. დამატებითი პერიოდების დამალვა

  დააყენეთ პირობითი ფორმატირების წესი მნიშვნელობების დასამალად გამოუყენებელ პერიოდებში, როგორც ეს აღწერილია ამ რჩევაში. განსხვავება ისაა, რომ ამჯერად ჩვენ ვიყენებთ თეთრი შრიფტის ფერს იმ სტრიქონებზე, რომლებშიც სულ გადახდა (სვეტი D) და ბალანსი (სვეტი G) უდრის. ნულოვანი ან ცარიელი:

  =AND(OR($D9=0, $D9=""), OR($G9=0, $G9=""))

  Voilà, ნულოვანი მნიშვნელობების მქონე ყველა მწკრივი დამალულია ხედვისგან:

  6. გააკეთეთ სესხის რეზიუმე

  როგორც სრულყოფილების დამასრულებელი შეხება, შეგიძლიათ გამოაქვეყნოთ ყველაზე მნიშვნელოვანი ინფორმაცია სესხის შესახებ შემდეგი ფორმულების გამოყენებით:

  გადახდების დაგეგმილი რაოდენობა:

  გაამრავლეთ წლების რაოდენობა წელიწადში გადახდების რაოდენობაზე:

  =LoanTerm*PaymentsPerYear

  გადახდების რეალური რაოდენობა:

  უჯრედების დათვლა სვეტში სულ გადახდა , რომლებიც აღემატება ნულს, დაწყებული 1 პერიოდით:

  =COUNTIF(D10:D369,">"&0)

  სულ დამატებითი გადახდები:

  დაამატეთ უჯრედები სვეტში დამატებითი გადახდა , დაწყებული პერიოდი 1:

  =SUM(C10:C369)

  საერთო ინტერესი:

  დამატება ამოიღეთ უჯრედები სვეტში პროცენტი , დაწყებული პერიოდი 1:

  =SUM(F10:F369)

  სურვილისამებრ, დამალეთ პერიოდი 0 მწკრივი და თქვენი სესხის ამორტიზაციის განრიგი დამატებითი გადახდებით კეთდება! ქვემოთ მოცემული სკრინშოტი აჩვენებს საბოლოო შედეგს:

  ჩამოტვირთეთ სესხის ამორტიზაციადაგეგმეთ დამატებითი გადახდებით

  ამორტიზაციის გრაფიკი Excel-ის შაბლონი

  იმისათვის, რომ სწრაფად გააკეთოთ სესხის ამორტიზაციის გრაფიკი, გამოიყენეთ Excel-ის ჩაშენებული შაბლონები. უბრალოდ გადადით ფაილი > სიახლე , აკრიფეთ " ამორტიზაციის გრაფიკი " საძიებო ველში და აირჩიეთ თქვენთვის სასურველი შაბლონი, მაგალითად, ეს დამატებითი გადახდებით. :

  შემდეგ შეინახეთ ახლად შექმნილი სამუშაო წიგნი Excel-ის შაბლონად და ხელახლა გამოიყენეთ, როცა გინდათ.

  ასე ქმნით სესხის ან იპოთეკის ამორტიზაციის გრაფიკს Excel-ში. მადლობას გიხდით წაკითხვისთვის და იმედი მაქვს, რომ მომავალ კვირას გნახავთ ჩვენს ბლოგზე!

  ხელმისაწვდომი ჩამოტვირთვები

  ამორტიზაციის განრიგის მაგალითები (ფაილი .xlsx)

  ეს თანხა მცირდება ყოველი გადახდისას.

ახლა, მოდით გადავიდეთ პროცესი ეტაპობრივად.

1. შექმენით ამორტიზაციის ცხრილი

დაწყებისთვის, განსაზღვრეთ შეყვანის უჯრედები, სადაც შეიყვანთ სესხის ცნობილ კომპონენტებს:

• C2 - წლიური საპროცენტო განაკვეთი
• C3 - სესხის ვადა წლების განმავლობაში
• C4 - გადახდების რაოდენობა წელიწადში
• C5 - სესხის თანხა

შემდეგი, რასაც აკეთებთ არის ამორტიზაციის ცხრილის შექმნა ლეიბლები ( პერიოდი , გადახდა , პროცენტი , ძირი , ბალანსი ) A7:E7-ში. სვეტში პერიოდი შეიყვანეთ რიცხვების სერია, რომელიც ტოლია გადახდების ჯამურ რაოდენობას (ამ მაგალითში 1-24):

ყველა ცნობილი კომპონენტის შემთხვევაში, მოდით გადავიდეთ ყველაზე საინტერესო ნაწილი - სესხის ამორტიზაციის ფორმულები.

2. გადახდის მთლიანი თანხის გამოთვლა (PMT ფორმულა)

გადახდის თანხა გამოითვლება PMT(კურსი, nper, pv, [fv], [ტიპი]) ფუნქციით.

სხვადასხვა გადახდის სიხშირის დასამუშავებლად სწორად (როგორიცაა ყოველკვირეული, ყოველთვიური, კვარტალური და ა.შ.), თქვენ უნდა შეესაბამებოდეს შეფასების და nper არგუმენტების მოწოდებულ მნიშვნელობებს:

• განაკვეთი - წლიური საპროცენტო განაკვეთის გაყოფა გადახდის პერიოდების რაოდენობაზე წელიწადში ($C$2/$C$4).
• Nper - გავამრავლოთ წლების რაოდენობა წელიწადში გადახდის პერიოდების რაოდენობის მიხედვით ($C$3*$C$4).
• არგუმენტისთვის pv , შეიყვანეთ სესხის თანხა ($5C$).
• fv და type არგუმენტები შეიძლება გამოტოვოთ, რადგან მათი ნაგულისხმევი მნიშვნელობები ჩვენთვის კარგად მუშაობს (ბოლო გადახდის შემდეგ ბალანსი უნდა იყოს 0; გადახდა ხდება ყოველი პერიოდის ბოლოს) .

ზემოხსენებული არგუმენტების შეკრებით, მივიღებთ ამ ფორმულას:

=PMT($C$2/$C$4, $C$3*$C$4, $C$5)

გთხოვთ, მიაქციოთ ყურადღება, რომ გამოვიყენოთ უჯრედების აბსოლუტური მითითებები, რადგან ეს ფორმულა უნდა დააკოპიროს ქვემოთ მოცემული უჯრედები ყოველგვარი ცვლილების გარეშე.

შეიყვანეთ PMT ფორმულა B8-ში, გადაიტანეთ იგი სვეტში და დაინახავთ გადახდის მუდმივ თანხას ყველა პერიოდისთვის:

3. გამოთვალეთ პროცენტი (IPMT ფორმულა)

თითოეული პერიოდული გადახდის საპროცენტო ნაწილის საპოვნელად გამოიყენეთ IPMT (განაკვეთი, თითო, nper, pv, [fv], [ტიპი]) ფუნქცია:

=IPMT($C$2/$C$4, A8, $C$3*$C$4, $C$5)

ყველა არგუმენტი იგივეა, რაც PMT ფორმულაში, გარდა არგუმენტისა per , რომელიც განსაზღვრავს გადახდის პერიოდს. ეს არგუმენტი მოწოდებულია როგორც უჯრედის ფარდობითი მითითება (A8), რადგან ის უნდა შეიცვალოს იმ მწკრივის შედარებითი პოზიციის მიხედვით, რომელზედაც დაკოპირებულია ფორმულა.

ეს ფორმულა გადადის C8-ზე და შემდეგ თქვენ დააკოპირებთ მას. იმდენ უჯრედამდე, რამდენიც საჭიროა:

4. იპოვნეთ ძირითადი თანხა (PPMT ფორმულა)

თითოეული პერიოდული გადახდის ძირითადი ნაწილის გამოსათვლელად გამოიყენეთ ეს PPMT ფორმულა:

=PPMT($C$2/$C$4, A8, $C$3*$C$4, $C$5)

სინტაქსი და არგუმენტები ზუსტად იგივეა, რაც ზემოთ განხილული IPMT ფორმულა:

ეს ფორმულა მიდის სვეტში D, იწყება D8-დან:

რჩევა. რათა შეამოწმოთ თუ არა თქვენიგამოთვლები სწორია ამ ეტაპზე, დაამატეთ რიცხვები ძირითადი და პროცენტი სვეტებში. ჯამი უნდა იყოს იმავე მწკრივის გადახდა სვეტის მნიშვნელობის ტოლი.

5. მიიღეთ დარჩენილი ნაშთი

თითო პერიოდისთვის დარჩენილი ნაშთის გამოსათვლელად, ჩვენ გამოვიყენებთ ორ განსხვავებულ ფორმულას.

E8-ში პირველი გადახდის შემდეგ ბალანსის საპოვნელად, დაამატეთ სესხის თანხა (C5) და პირველი პერიოდის ძირი (D8):

=C5+D8

რადგან სესხის თანხა დადებითი რიცხვია, ხოლო ძირი უარყოფითი რიცხვი, ეს უკანასკნელი რეალურად აკლდება პირველს. .

მეორე და ყველა შემდგომი პერიოდისთვის, დაამატეთ წინა ბალანსი და ამ პერიოდის ძირი:

=E8+D9

ზემოხსენებული ფორმულა გადადის E9-ზე და შემდეგ დააკოპირებთ მას სვეტის ქვემოთ. უჯრედების ფარდობითი მითითებების გამოყენების გამო, ფორმულა სწორად რეგულირდება თითოეული მწკრივისთვის.

ესე იგი! ჩვენი ყოველთვიური სესხის ამორტიზაციის გრაფიკი შესრულებულია:

რჩევა: დააბრუნეთ გადახდები დადებითი რიცხვების სახით

რადგან სესხი გადახდილია თქვენი საბანკო ანგარიშიდან, Excel ფუნქციები აბრუნებს გადახდას, პროცენტს და ძირს უარყოფითი რიცხვები . ნაგულისხმევად, ეს მნიშვნელობები მონიშნულია წითლად და ჩასმულია ფრჩხილებში, როგორც ხედავთ ზემოთ მოცემულ სურათზე.

თუ გირჩევნიათ, რომ ყველა შედეგი იყოს დადებითი რიცხვებით, ჩადეთ მინუს ნიშანი. PMT, IPMT და PPMT ფუნქციებამდე.

ბალანსისთვის ფორმულები, გამოიყენეთ გამოკლება დამატების ნაცვლად, როგორც ეს ნაჩვენებია ქვემოთ მოცემულ ეკრანის სურათზე:

ამორტიზაციის გრაფიკი პერიოდების ცვლადი რაოდენობისთვის

ზემოთ მაგალითში, ჩვენ შევქმენით სესხის ამორტიზაციის გრაფიკი წინასწარ განსაზღვრული რაოდენობისთვის. გადახდის პერიოდები. ეს სწრაფი ერთჯერადი გადაწყვეტა კარგად მუშაობს კონკრეტულ სესხზე ან იპოთეკაზე.

თუ თქვენ ცდილობთ შექმნათ მრავალჯერადი ამორტიზაციის გრაფიკი პერიოდების ცვლადი რაოდენობით, თქვენ მოგიწევთ ქვემოთ აღწერილი უფრო ყოვლისმომცველი მიდგომა.

1. შეიყვანეთ პერიოდების მაქსიმალური რაოდენობა

პერიოდი სვეტში ჩაწერეთ გადახდების მაქსიმალური რაოდენობა, რომლის დაშვებაც გსურთ ნებისმიერი სესხისთვის, ვთქვათ, 1-დან 360-მდე. შეგიძლიათ გამოიყენოთ Excel-ის ავტომატური შევსება. რიცხვების სერიის უფრო სწრაფად შეყვანის ფუნქცია.

2. გამოიყენეთ IF ამონაწერები ამორტიზაციის ფორმულებში

რადგან ახლა თქვენ გაქვთ მრავალი გადაჭარბებული პერიოდის რიცხვი, თქვენ როგორმე უნდა შეზღუდოთ გამოთვლები კონკრეტული სესხისთვის გადახდების რეალური რაოდენობით. ეს შეიძლება გაკეთდეს თითოეული ფორმულის IF განცხადებაში შეფუთვით. IF ამონაწერის ლოგიკური ტესტი ამოწმებს, არის თუ არა პერიოდის ნომერი მიმდინარე მწკრივში ნაკლები ან ტოლი გადახდების მთლიან რაოდენობაზე. თუ ლოგიკური ტესტი არის TRUE, გამოითვლება შესაბამისი ფუნქცია; თუ FALSE, ცარიელი სტრიქონი დაბრუნდება.

თუ ვივარაუდებთ, რომ პერიოდი 1 არის მე-8 მწკრივში, შეიყვანეთ შემდეგი ფორმულები შესაბამის უჯრედებში და შემდეგ დააკოპირეთ.მთელი ცხრილი.

გადახდა (B8):

=IF(A8<=$C$3*$C$4, PMT($C$2/$C$4, $C$3*$C$4, $C$5), "")

პროცენტი (C8):

=IF(A8<=$C$3*$C$4, IPMT($C$2/$C$4, A8, $C$3*$C$4, $C$5), "")

ძირითადი (D8):

=IF(A8<=$C$3*$C$4,PPMT($C$2/$C$4, A8, $C$3*$C$4, $C$5), "")

ბალანსი :

პერიოდი 1 (E8), ფორმულა იგივეა, რაც წინა მაგალითში:

=C5+D8

პერიოდისთვის 2 (E9) და ყველა შემდგომი პერიოდისთვის, ფორმულა იღებს ასეთ ფორმას:

=IF(A9<=$C$3*$C$4, E8+D9, "")

შედეგად, თქვენ გაქვთ სწორად გამოთვლილი ამორტიზაციის გრაფიკი და ცარიელი რიგები სესხის დაფარვის შემდეგ პერიოდის ნომრებით.

3. დამატებითი პერიოდების ნომრების დამალვა

თუ შეგიძლიათ იცხოვროთ ბოლო გადახდის შემდეგ ნაჩვენები ზედმეტი პერიოდის ნომრებით, შეგიძლიათ გაითვალისწინოთ შესრულებული სამუშაო და გამოტოვოთ ეს ნაბიჯი. თუ სრულყოფილებისკენ მიისწრაფვით, მაშინ დამალეთ ყველა გამოუყენებელი პერიოდი პირობითი ფორმატირების წესით, რომელიც შრიფტის ფერს აყენებს თეთრზე ნებისმიერი მწკრივისთვის ბოლო გადახდის შემდეგ.

ამისთვის აირჩიეთ ყველა მონაცემთა სტრიქონი თუ თქვენი ამორტიზაციის ცხრილი (ჩვენს შემთხვევაში A8:E367) და დააწკაპუნეთ მთავარი ჩანართზე > პირობითი ფორმატირება > ახალი წესი… > გამოიყენეთ ფორმულა იმის დასადგენად, თუ რომელი უჯრედები უნდა დაფორმატდეს .

შესაბამის ველში შეიყვანეთ ქვემოთ მოცემული ფორმულა, რომელიც ამოწმებს A სვეტის წერტილის რაოდენობა ჯამზე მეტია თუ არა გადახდების რაოდენობა:

=$A8>$C$3*$C$4

მნიშვნელოვანი შენიშვნა! იმისთვის, რომ პირობითი ფორმატირების ფორმულა სწორად იმუშაოს, დარწმუნდით, რომ გამოიყენეთ უჯრედების აბსოლუტური მითითებები სესხის ტერმინისთვის და გადახდები წელიწადში უჯრედები, რომლებსაც ამრავლებთ ($C$3*$C$4). პროდუქტი შედარებულია პერიოდი 1 უჯრედთან, რისთვისაც იყენებთ უჯრედის შერეულ მითითებას - აბსოლუტურ სვეტს და ფარდობით მწკრივს ($A8).

ამის შემდეგ დააწკაპუნეთ <ღილაკი 1>ფორმატი… და აირჩიეთ შრიფტის თეთრი ფერი. Შესრულებულია!

4. გააკეთეთ სესხის რეზიუმე

თქვენი სესხის შესახებ შემაჯამებელი ინფორმაციის ერთი შეხედვით სანახავად, დაამატეთ კიდევ რამდენიმე ფორმულა თქვენი ამორტიზაციის გრაფიკის ზედა ნაწილში.

სულ გადახდები ( F2):

=-SUM(B8:B367)

საერთო პროცენტი (F3):

=-SUM(C8:C367)

თუ თქვენ გაქვთ გადახდები დადებითი რიცხვების სახით, წაშალეთ მინუს ნიშანი ზემოაღნიშნული ფორმულებიდან.

ესე იგი! ჩვენი სესხის ამორტიზაციის გრაფიკი დასრულებულია და მზად ვართ წავიდეთ!

ჩამოტვირთეთ სესხის ამორტიზაციის გრაფიკი Excel-ისთვის

როგორ შევადგინოთ სესხის ამორტიზაციის გრაფიკი დამატებითი გადახდებით Excel-ში

წინა მაგალითებში განხილული ამორტიზაციის განრიგები მარტივია შექმნა და დაიცვან (იმედია :). თუმცა, ისინი გამოტოვებენ სასარგებლო თვისებას, რომელიც ბევრი სესხის გადამხდელს აინტერესებს - დამატებითი გადასახადები სესხის უფრო სწრაფად დაფარვისთვის. ამ მაგალითში განვიხილავთ როგორ შევქმნათ სესხის ამორტიზაციის გრაფიკი დამატებითი გადახდებით.

1. შეყვანის უჯრედების განსაზღვრა

ჩვეულებისამებრ, დაიწყეთ შეყვანის უჯრედების დაყენებით. ამ შემთხვევაში, მოდით დავასახელოთ ეს უჯრედები, როგორც ქვემოთ დაწერილი, რათა ჩვენი ფორმულები უფრო ადვილად წასაკითხი იყოს:

• პროცენტის განაკვეთი - C2 (წლიური პროცენტიგანაკვეთი)
• სესხის ვადა - C3 (სესხის ვადა წლების მიხედვით)
• გადახდები წელიწადში - C4 (გადახდების რაოდენობა წელიწადში)
• სესხის ოდენობა - C5 (სესხის მთლიანი თანხა)
• დამატებითი გადახდა - C6 (დამატებითი გადახდა პერიოდზე)

2. გამოთვალეთ დაგეგმილი გადახდა

შეყვანის უჯრედების გარდა, ჩვენი შემდგომი გამოთვლებისთვის საჭიროა კიდევ ერთი წინასწარ განსაზღვრული უჯრედი - დაგეგმილი გადახდის თანხა , ანუ თანხა, რომელიც უნდა გადაიხადოთ სესხზე, თუ ზედმეტი არ არის. გადახდები ხდება. ეს თანხა გამოითვლება შემდეგი ფორმულით:

=IFERROR(-PMT(InterestRate/PaymentsPerYear, LoanTerm*PaymentsPerYear, LoanAmount), "")

გთხოვთ ყურადღება მიაქციოთ, რომ PMT ფუნქციის წინ დავაყენოთ მინუს ნიშანი, რომ შედეგი დადებითი რიცხვი იყოს. შეცდომების თავიდან ასაცილებლად, თუ შეყვანის ზოგიერთი უჯრედი ცარიელია, ჩვენ ვამაგრებთ PMT ფორმულას IFERROR ფუნქციაში.

შეიყვანეთ ეს ფორმულა ზოგიერთ უჯრედში (ჩვენს შემთხვევაში G2) და დაასახელეთ ეს უჯრედი ScheduledPayment .

3. შექმენით ამორტიზაციის ცხრილი

შექმენით სესხის ამორტიზაციის ცხრილი ქვემოთ მოცემულ ეკრანის სურათზე ნაჩვენები სათაურებით. სვეტში პერიოდი შეიყვანეთ რიცხვების სერია, რომელიც იწყება ნულით (შეგიძლიათ დამალოთ პერიოდი 0 მწკრივი მოგვიანებით, საჭიროების შემთხვევაში).

თუ თქვენ აპირებთ შექმნათ მრავალჯერადი გამოყენება ამორტიზაციის გრაფიკი, შეიყვანეთ გადახდის პერიოდების მაქსიმალური შესაძლო რაოდენობა (ამ მაგალითში 0-დან 360-მდე).

პერიოდისთვის 0 (ჩვენს შემთხვევაში მე-9 მწკრივი), გაიყვანეთ ბალანსი ღირებულება, რომელიც უდრის სესხის თავდაპირველ თანხას. Ყველა სხვაამ მწკრივის უჯრედები ცარიელი დარჩება:

ფორმულა G9-ში:

=LoanAmount

4. შექმენით ფორმულები ამორტიზაციის გრაფიკისთვის დამატებითი გადახდებით

ეს არის ჩვენი მუშაობის მთავარი ნაწილი. იმის გამო, რომ Excel-ის ჩაშენებული ფუნქციები არ ითვალისწინებს დამატებით გადახდებს, ჩვენ მოგვიწევს ყველა მათემატიკის გაკეთება დამოუკიდებლად.

შენიშვნა. ამ მაგალითში, პერიოდი 0 არის მე-9 მწკრივში და პერიოდი 1 არის მე-10 მწკრივში. თუ თქვენი ამორტიზაციის ცხრილი იწყება სხვა მწკრივში, დარწმუნდით, რომ დაარეგულირეთ უჯრედების მითითებები შესაბამისად.

შეიყვანეთ შემდეგი ფორმულები მე-10 მწკრივში ( პერიოდი 1 ) და შემდეგ დააკოპირეთ ისინი ყველა დარჩენილი პერიოდისთვის.

გეგმიური გადახდა (B10):

თუ ScheduledPayment თანხა (სახელწოდებით G2 უჯრედი) ნაკლებია ან ტოლია დარჩენილ ბალანსზე (G9), გამოიყენეთ დაგეგმილი გადახდა. წინააღმდეგ შემთხვევაში, დაამატეთ დარჩენილი ნაშთი და პროცენტი წინა თვისთვის.

=IFERROR(IF(ScheduledPayment<=G9, ScheduledPayment, G9+G9*InterestRate/PaymentsPerYear), "")

როგორც დამატებითი სიფრთხილის ზომები, ჩვენ ვახვევთ ამ და ყველა შემდგომ ფორმულას IFERROR ფუნქციაში. ეს თავიდან აიცილებს სხვადასხვა შეცდომებს, თუ შეყვანის ზოგიერთი უჯრედი ცარიელია ან შეიცავს არასწორ მნიშვნელობებს.

დამატებითი გადახდა (C10):

გამოიყენეთ IF ფორმულა შემდეგი ლოგიკა:

თუ ExtraPayment თანხა (სახელად C6 უჯრედი) ნაკლებია სხვაობაზე დარჩენილ ბალანსსა და ამ პერიოდის ძირითად თანხას (G9-E10), დააბრუნეთ ExtraPayment ; წინააღმდეგ შემთხვევაში გამოიყენეთ განსხვავება.

=IFERROR(IF(ExtraPayment

რჩევა. Თუ შენ