El tutorial muestra cómo construir un plan de amortización en Excel para detallar los pagos periódicos de un préstamo o hipoteca amortizable.

En préstamo amortizable es sólo una forma elegante de definir un préstamo que se devuelve a plazos durante todo el plazo del préstamo.

Básicamente, todos los préstamos son amortizables de una forma u otra. Por ejemplo, un préstamo totalmente amortizable durante 24 meses tendrá 24 pagos mensuales iguales. Cada pago aplica una cantidad al principal y otra a los intereses. Para detallar cada pago de un préstamo, se puede construir un plan de amortización del préstamo.

En plan de amortización es una tabla que enumera los pagos periódicos de un préstamo o hipoteca a lo largo del tiempo, desglosa cada pago en principal e intereses y muestra el saldo restante después de cada pago.

Cómo crear un plan de amortización de préstamos en Excel

Para construir un plan de amortización de un préstamo o hipoteca en Excel, necesitaremos utilizar las siguientes funciones:

• Función PMT - calcula el importe total de un pago periódico. Este importe se mantiene constante durante toda la duración del préstamo.
• Función PPMT - obtiene el principal parte de cada pago que se destina al principal del préstamo, es decir, a la cantidad que le prestaron. Esta cantidad aumenta en los pagos posteriores.
• Función IPMT - encuentra el interés parte de cada pago que se destina a intereses. Esta cantidad disminuye con cada pago.

Veamos el proceso paso a paso.

1. Establecer el cuadro de amortización

Para empezar, defina las celdas de entrada donde introducirá los componentes conocidos de un préstamo:

• C2 - tipo de interés anual
• C3 - plazo del préstamo en años
• C4 - número de pagos anuales
• C5 - importe del préstamo

Lo siguiente es crear un cuadro de amortización con las etiquetas ( Periodo , Pago , Interés , Principal , Saldo ) en A7:E7. En el Periodo introduzca una serie de números igual al número total de pagos (1- 24 en este ejemplo):

Una vez conocidos todos los componentes, pasemos a la parte más interesante: las fórmulas de amortización de los préstamos.

2. Calcular el importe total del pago (fórmula PMT)

El importe del pago se calcula con la función PMT(rate, nper, pv, [fv], [type]).

Para gestionar correctamente las diferentes frecuencias de pago (como semanal, mensual, trimestral, etc.), debe ser coherente con los valores suministrados para el campo tarifa y nper argumentos:

• Tarifa - divida el tipo de interés anual por el número de periodos de pago al año ($C$2/$C$4).
• Nper - multiplique el número de años por el número de periodos de pago anuales ($C$3*$C$4).
• Para el pv introduzca el importe del préstamo ($C$5).
• En fv y tipo pueden omitirse, ya que sus valores por defecto funcionan bien para nosotros (se supone que el saldo después del último pago es 0; los pagos se realizan al final de cada período).

Uniendo los argumentos anteriores, obtenemos esta fórmula:

=PMT($C$2/$C$4, $C$3*$C$4, $C$5)

Por favor, preste atención, que utilizamos referencias absolutas de celda porque esta fórmula debe copiar a las celdas de abajo sin ningún cambio.

Introduzca la fórmula PMT en B8, arrástrela hacia abajo en la columna y verá un importe de pago constante para todos los períodos:

3. Calcular los intereses (fórmula IPMT)

Para hallar la parte de interés de cada pago periódico, utilice la función IPMT(rate, per, nper, pv, [fv], [type]):

=IPMT($C$2/$C$4, A8, $C$3*$C$4, $C$5)

Todos los argumentos son los mismos que en la fórmula PMT, excepto el argumento por que especifica el período de pago. Este argumento se suministra como una referencia de celda relativa (A8) porque se supone que cambia en función de la posición relativa de una fila a la que se copia la fórmula.

Esta fórmula va a C8, y luego la copias en todas las celdas que necesites:

4. Hallar el capital (fórmula PPMT)

Para calcular la parte de principal de cada pago periódico, utilice esta fórmula PPMT:

=PPMT($C$2/$C$4, A8, $C$3*$C$4, $C$5)

La sintaxis y los argumentos son exactamente los mismos que en la fórmula IPMT comentada anteriormente:

Esta fórmula va a la columna D, empezando en D8:

Consejo: para comprobar si sus cálculos son correctos en este punto, sume los números de la casilla Principal y Interés La suma debe ser igual al valor de la columna Pago columna de la misma fila.

5. Obtener el saldo restante

Para calcular el saldo restante de cada periodo, utilizaremos dos fórmulas diferentes.

Para hallar el saldo después del primer pago en E8, sume el importe del préstamo (C5) y el principal del primer período (D8):

=C5+D8

Dado que el importe del préstamo es un número positivo y el principal es un número negativo, este último se resta del primero.

Para el segundo periodo y todos los siguientes, sume el saldo anterior y el capital de este periodo:

=E8+D9

La fórmula anterior va a E9, y luego se copia hacia abajo en la columna. Debido al uso de referencias relativas de celda, la fórmula se ajusta correctamente para cada fila.

Eso es todo, nuestro plan de amortización mensual del préstamo está hecho:

Consejo: Devuelva los pagos como números positivos

Dado que un préstamo se paga con cargo a su cuenta bancaria, las funciones de Excel devuelven el pago, los intereses y el capital como números negativos Por defecto, estos valores aparecen resaltados en rojo y entre paréntesis, como puede ver en la imagen anterior.

Si prefiere tener todos los resultados como positivo números, anteponga un signo menos a las funciones PMT, IPMT y PPMT.

Para el Saldo fórmulas, utilice la resta en lugar de la suma como se muestra en la siguiente captura de pantalla:

Plan de amortización para un número variable de periodos

En el ejemplo anterior, construimos un plan de amortización de préstamo para el número predefinido de periodos de pago. Esta solución rápida de una sola vez funciona bien para un préstamo o hipoteca específicos.

Si desea crear un plan de amortización reutilizable con un número variable de periodos, tendrá que adoptar un enfoque más exhaustivo que se describe a continuación.

1. Introduzca el número máximo de periodos

En el Periodo introduzca el número máximo de pagos que va a permitir para cualquier préstamo, por ejemplo, de 1 a 360. Puede aprovechar la función Autocompletar de Excel para introducir una serie de números más rápidamente.

2. Utilizar expresiones IF en las fórmulas de amortización

Como ahora tiene muchos números de período excesivos, tiene que limitar de alguna manera los cálculos al número real de pagos de un préstamo concreto. Esto se puede hacer envolviendo cada fórmula en una sentencia IF. La prueba lógica de la sentencia IF comprueba si el número de período de la fila actual es menor o igual que el número total de pagos. Si la prueba lógica es TRUE, la fórmula correspondientesi es FALSE, se devuelve una cadena vacía.

Suponiendo que Período 1 está en la fila 8, introduzca las siguientes fórmulas en las celdas correspondientes y, a continuación, cópielas en toda la tabla.

Pago (B8):

=IF(A8<=$C$3*$C$4, PMT($C$2/$C$4, $C$3*$C$4, $C$5), "")

Interés (C8):

=IF(A8<=$C$3*$C$4, IPMT($C$2/$C$4, A8, $C$3*$C$4, $C$5), "")

Principal (D8):

=IF(A8<=$C$3*$C$4,PPMT($C$2/$C$4, A8, $C$3*$C$4, $C$5), "")

Saldo :

Para Período 1 (E8), la fórmula es la misma que en el ejemplo anterior:

=C5+D8

Para Período 2 (E9) y todos los periodos siguientes, la fórmula adopta esta forma:

=IF(A9<=$C$3*$C$4, E8+D9, "")

Como resultado, se obtiene un plan de amortización correctamente calculado y un montón de filas vacías con los números de los períodos una vez pagado el préstamo.

3. Ocultar los números de los períodos extra

Si puede vivir con un montón de números de período superfluos mostrados después del último pago, puede considerar el trabajo hecho y saltarse este paso. Si busca la perfección, entonces oculte todos los períodos no utilizados creando una regla de formato condicional que establezca el parámetro color de fuente a blanco para las filas posteriores al último pago.

Para ello, seleccione todos los filas de datos si su tabla de amortización (A8:E367 en nuestro caso) y haga clic en Inicio tab> Formato condicional > Nueva norma... > Utilizar una fórmula para determinar qué celdas formatear .

En la casilla correspondiente, introduzca la siguiente fórmula que comprueba si el número de período de la columna A es mayor que el número total de pagos:

=$A8>$C$3*$C$4

Nota importante: para que la fórmula de formato condicional funcione correctamente, asegúrese de utilizar referencias de celda absolutas para los campos Plazo del préstamo y Pagos anuales celdas que se multiplican ($C$3*$C$4). El producto se compara con el Periodo 1 celda, para la que se utiliza una referencia de celda mixta - columna absoluta y fila relativa ($A8).

A continuación, pulse el botón Formato... y elige el color de fuente blanco. ¡Listo!

4. Hacer un resumen del préstamo

Para ver la información resumida sobre su préstamo de un vistazo, añada un par de fórmulas más en la parte superior de su plan de amortización.

Pagos totales (F2):

=-SUMA(B8:B367)

Interés total (F3):

=-SUMA(C8:C367)

Si los pagos son números positivos, elimine el signo menos de las fórmulas anteriores.

Ya está, nuestro plan de amortización del préstamo está completo y listo.

Descargar plan de amortización de préstamos para Excel

Cómo hacer un plan de amortización de un préstamo con pagos extra en Excel

Los planes de amortización descritos en los ejemplos anteriores son fáciles de crear y seguir (ojalá :). Sin embargo, dejan fuera una característica útil que interesa a muchos pagadores de préstamos: los pagos adicionales para liquidar un préstamo más rápidamente. En este ejemplo, veremos cómo crear un plan de amortización de préstamos con pagos adicionales.

1. Definir las celdas de entrada

Como de costumbre, comience por configurar las celdas de entrada. En este caso, vamos a nombrar estas celdas como se escribe a continuación para que nuestras fórmulas sean más fáciles de leer:

• Tipo de interés - C2 (tipo de interés anual)
• Plazo del préstamo - C3 (duración del préstamo en años)
• PagosPorAño - C4 (número de pagos al año)
• ImportePréstamo - C5 (importe total del préstamo)
• PagoExtra - C6 (pago adicional por periodo)

2. Calcular un pago programado

Aparte de las celdas de entrada, se necesita una celda predefinida más para nuestros cálculos posteriores: la celda importe del pago previsto es decir, el importe que se pagará por un préstamo si no se realizan pagos adicionales. Este importe se calcula con la siguiente fórmula:

=IFERROR(-PMT(TipoInterés/PagosAño, PlazoPréstamo*PagosAño, ImportePréstamo), "")

Preste atención a que anteponemos un signo menos a la función PMT para que el resultado sea un número positivo. Para evitar errores en caso de que algunas de las celdas de entrada estén vacías, encerramos la fórmula PMT dentro de la función IFERROR.

Introduce esta fórmula en alguna celda (G2 en nuestro caso) y dale un nombre a esa celda Pago programado .

3. Establecer el cuadro de amortización

Cree una tabla de amortización de préstamos con los encabezados que se muestran en la captura de pantalla siguiente. En la tabla Periodo introduzca una serie de números empezando por cero (puede ocultar la columna Período 0 fila más adelante si es necesario).

Si desea crear un plan de amortización reutilizable, introduzca el número máximo posible de periodos de pago (de 0 a 360 en este ejemplo).

Para Período 0 (fila 9 en nuestro caso), tire del botón Saldo Todas las demás celdas de esta fila permanecerán vacías:

Fórmula en G9:

=Importe del préstamo

4. Construir fórmulas para el plan de amortización con pagos adicionales

Como las funciones integradas de Excel no prevén pagos adicionales, tendremos que hacer todos los cálculos por nuestra cuenta.

Nota: en este ejemplo, Período 0 está en la fila 9 y Período 1 se encuentra en la fila 10. Si su tabla de amortización comienza en una fila diferente, asegúrese de ajustar las referencias de las celdas en consecuencia.

Introduzca las siguientes fórmulas en la fila 10 ( Período 1 ), y luego copiarlos para todos los periodos restantes.

Pago programado (B10):

Si el Pago programado (celda G2) es menor o igual que el saldo restante (G9), utilice el pago programado. De lo contrario, sume el saldo restante y los intereses del mes anterior.

=IFERROR(IF(PagoProgramado<=G9, PagoProgramado, G9+G9*TasaDeInterés/PagosPorAño), "")

Como precaución adicional, envolvemos ésta y todas las fórmulas posteriores en la función IFERROR. Esto evitará un montón de errores diversos si algunas de las celdas de entrada están vacías o contienen valores no válidos.

Pago adicional (C10):

Utilice una fórmula IF con la siguiente lógica:

Si el PagoExtra (indicada en la celda C6) es inferior a la diferencia entre el saldo restante y el principal de este período (G9-E10), devuelva PagoExtra de lo contrario, utilice la diferencia.

=IFERROR(IF(ExtraPago

Consejo: si tiene pagos adicionales variables basta con teclear los importes individuales directamente en el Pago adicional columna.

Pago total (D10)

Simplemente, añada el pago programado (B10) y el pago extra (C10) para el periodo actual:

=IFERROR(B10+C10, "")

Principal (E10)

Si el pago programado para un periodo dado es mayor que cero, devuelve el menor de los dos valores: pago programado menos intereses (B10-F10) o el saldo restante (G9); en caso contrario devuelve cero.

=IFERROR(IF(B10>0, MIN(B10-F10, G9), 0), "")

Tenga en cuenta que el principal sólo incluye la parte del pago programado (¡no el pago extra!) que se destina al principal del préstamo.

Interés (F10)

Si el pago programado para un período dado es mayor que cero, divida la tasa de interés anual (celda C2) por el número de pagos por año (celda C4) y multiplique el resultado por el saldo restante después del período anterior; de lo contrario, devuelva 0.

=IFERROR(IF(B10>0, InterestRate/PaymentsPerYear*G9, 0), "")

Saldo (G10)

Si el saldo restante (G9) es mayor que cero, reste la parte principal del pago (E10) y el pago extra (C10) del saldo restante tras el periodo anterior (G9); en caso contrario, devuelva 0.

=IFERROR(IF(G9>0, G9-E10-C10, 0), "")

Nota: Como algunas de las fórmulas tienen referencias cruzadas entre sí (¡no circulares!), es posible que muestren resultados erróneos durante el proceso. Por lo tanto, no empiece a solucionar el problema hasta que haya introducido la última fórmula de su tabla de amortización.

Si todo se hace correctamente, el plan de amortización del préstamo en este punto debería ser algo parecido a esto:

5. Ocultar periodos extra

Configure una regla de formato condicional para ocultar los valores de los períodos no utilizados como se explica en este consejo. La diferencia es que esta vez aplicamos la regla color de fuente blanco a las filas en las que Pago total (columna D) y Saldo (columna G) son iguales a cero o están vacías:

=AND(OR($D9=0, $D9=""), OR($G9=0, $G9=""))

Voilà, todas las filas con valores cero quedan ocultas a la vista:

6. Hacer un resumen del préstamo

Como toque final de perfección, puede obtener la información más importante sobre un préstamo utilizando estas fórmulas:

Número programado de pagos:

Multiplique el número de años por el número de pagos anuales:

=Plazo del préstamo*Pagos anuales

Número real de pagos:

Contar células en el Pago total que sean mayores que cero, empezando por el Periodo 1:

=COUNTIF(D10:D369,">"&0)

Total pagas extras:

Sume las celdas de la Pago adicional empezando por el período 1:

=SUMA(C10:C369)

Interés total:

Sume las celdas de la Interés empezando por el período 1:

=SUMA(F10:F369)

Opcionalmente, oculte el Período 0 y el plan de amortización de su préstamo con pagos adicionales está listo. La siguiente captura de pantalla muestra el resultado final:

Descargar el cuadro de amortización del préstamo con pagos adicionales

Plan de amortización Plantilla Excel

Para confeccionar un plan de amortización de préstamos de primera clase en un abrir y cerrar de ojos, utilice las plantillas incorporadas de Excel. Sólo tiene que ir a Archivo > Nuevo , tipo " plan de amortización " en el cuadro de búsqueda y elige la plantilla que más te guste, por ejemplo, ésta con pagos extra:

A continuación, guarda el libro recién creado como plantilla de Excel y reutilízalo cuando quieras.

Así es como se crea un plan de amortización de un préstamo o hipoteca en Excel. Gracias por leer y ¡espero verte en nuestro blog la semana que viene!

Descargas disponibles

Ejemplos de planes de amortización (archivo .xlsx)