Tutorial ini menunjukkan cara membuat jadwal amortisasi di Excel untuk merinci pembayaran berkala pada pinjaman atau hipotek amortisasi.

An pinjaman amortisasi hanyalah cara mewah untuk mendefinisikan pinjaman yang dibayar kembali dengan cicilan selama seluruh jangka waktu pinjaman.

Pada dasarnya, semua pinjaman diamortisasi dengan satu atau lain cara. Misalnya, pinjaman yang sepenuhnya diamortisasi selama 24 bulan akan memiliki 24 pembayaran bulanan yang sama. Setiap pembayaran menggunakan sejumlah uang untuk pokok pinjaman dan sebagian lagi untuk bunga. Untuk merinci setiap pembayaran pada pinjaman, Anda dapat membuat jadwal amortisasi pinjaman.

An jadwal amortisasi adalah tabel yang mencantumkan pembayaran berkala atas pinjaman atau hipotek dari waktu ke waktu, memecah setiap pembayaran menjadi pokok dan bunga, dan menunjukkan sisa saldo setelah setiap pembayaran.

Cara membuat jadwal amortisasi pinjaman di Excel

Untuk membuat jadwal amortisasi pinjaman atau hipotek di Excel, kita perlu menggunakan fungsi-fungsi berikut:

• Fungsi PMT - menghitung jumlah total Jumlah ini tetap konstan selama seluruh durasi pinjaman.
• Fungsi PPMT - mendapatkan kepala sekolah Bagian dari setiap pembayaran yang digunakan untuk pokok pinjaman, yaitu jumlah yang Anda pinjam. Jumlah ini meningkat untuk pembayaran berikutnya.
• Fungsi IPMT - menemukan minat Bagian dari setiap pembayaran yang digunakan untuk bunga. Jumlah ini berkurang setiap kali pembayaran.

Sekarang, mari kita lakukan prosesnya selangkah demi selangkah.

1. Siapkan tabel amortisasi

Sebagai permulaan, tentukan sel input di mana Anda akan memasukkan komponen pinjaman yang diketahui:

• C2 - tingkat bunga tahunan
• C3 - jangka waktu pinjaman dalam tahun
• C4 - jumlah pembayaran per tahun
• C5 - jumlah pinjaman

Hal berikutnya yang Anda lakukan adalah membuat tabel amortisasi dengan label ( Periode , Pembayaran , Minat , Kepala Sekolah , Keseimbangan ) dalam A7:E7. Dalam Periode kolom, masukkan serangkaian angka yang sama dengan jumlah total pembayaran (1- 24 dalam contoh ini):

Dengan semua komponen yang diketahui, mari kita ke bagian yang paling menarik - rumus amortisasi pinjaman.

2. Hitung jumlah pembayaran total (rumus PMT)

Jumlah pembayaran dihitung dengan fungsi PMT(rate, nper, pv, [fv], [type]).

Untuk menangani frekuensi pembayaran yang berbeda dengan benar (seperti mingguan, bulanan, triwulanan, dll.), Anda harus konsisten dengan nilai yang diberikan untuk tingkat dan nper argumen:

• Nilai - membagi tingkat bunga tahunan dengan jumlah periode pembayaran per tahun ($C$2/$C$4).
• Nper - kalikan jumlah tahun dengan jumlah periode pembayaran per tahun ($C$3*$C$4).
• Untuk pv argumen, masukkan jumlah pinjaman ($C$5).
• The fv dan jenis argumen dapat dihilangkan karena nilai defaultnya berfungsi dengan baik untuk kita (saldo setelah pembayaran terakhir seharusnya 0; pembayaran dilakukan pada akhir setiap periode).

Menyatukan argumen-argumen di atas, kita mendapatkan rumus ini:

=PMT($C$2/$C$4, $C$3*$C$4, $C$5)

Harap diperhatikan, bahwa kami menggunakan referensi sel absolut karena rumus ini harus menyalin ke sel di bawah ini tanpa perubahan apa pun.

Masukkan rumus PMT di B8, seret ke bawah kolom, dan Anda akan melihat jumlah pembayaran konstan untuk semua periode:

3. Hitung bunga (rumus IPMT)

Untuk menemukan bagian bunga dari setiap pembayaran berkala, gunakan fungsi IPMT(rate, per, nper, pv, [fv], [type]):

=IPMT($C$2/$C$4, A8, $C$3*$C$4, $C$5)

Semua argumennya sama seperti dalam rumus PMT, kecuali per Argumen ini diberikan sebagai referensi sel relatif (A8) karena seharusnya berubah berdasarkan posisi relatif baris tempat rumus disalin.

Rumus ini masuk ke C8, lalu Anda menyalinnya ke sel sebanyak yang diperlukan:

4. Temukan prinsipal (rumus PPMT)

Untuk menghitung bagian pokok dari setiap pembayaran berkala, gunakan rumus PPMT ini:

=PPMT($C$2/$C$4, A8, $C$3*$C$4, $C$5)

Sintaks dan argumennya persis sama seperti pada rumus IPMT yang dibahas di atas:

Rumus ini masuk ke kolom D, dimulai dari D8:

Tip. Untuk mengecek apakah perhitungan Anda sudah benar pada titik ini, jumlahkan angka-angka di dalam Kepala Sekolah dan Minat Jumlahnya harus sama dengan nilai dalam kolom Pembayaran kolom dalam baris yang sama.

5. Dapatkan sisa saldo

Untuk menghitung sisa saldo untuk setiap periode, kita akan menggunakan dua rumus yang berbeda.

Untuk menemukan saldo setelah pembayaran pertama di E8, jumlahkan jumlah pinjaman (C5) dan pokok pinjaman periode pertama (D8):

=C5+D8

Karena jumlah pinjaman adalah angka positif dan pokok pinjaman adalah angka negatif, maka pokok pinjaman sebenarnya dikurangi dari yang pertama.

Untuk periode kedua dan semua periode berikutnya, jumlahkan saldo sebelumnya dan pokok periode ini:

=E8+D9

Rumus di atas masuk ke E9, lalu Anda menyalinnya ke bawah kolom. Karena penggunaan referensi sel relatif, rumus menyesuaikan dengan benar untuk setiap baris.

Itu saja! Jadwal amortisasi pinjaman bulanan kita sudah selesai:

Saran: Kembalikan pembayaran sebagai angka positif

Karena pinjaman dibayarkan dari rekening bank Anda, fungsi Excel mengembalikan pembayaran, bunga dan pokok sebagai angka negatif Secara default, nilai-nilai ini disorot dengan warna merah dan diapit dalam tanda kurung, seperti yang bisa Anda lihat pada gambar di atas.

Jika Anda lebih suka memiliki semua hasil sebagai positif angka, beri tanda minus sebelum fungsi PMT, IPMT dan PPMT.

Untuk Keseimbangan rumus, gunakan pengurangan alih-alih penambahan seperti yang ditunjukkan pada gambar di bawah ini:

Jadwal amortisasi untuk jumlah periode yang bervariasi

Dalam contoh di atas, kami membuat jadwal amortisasi pinjaman untuk jumlah periode pembayaran yang telah ditentukan sebelumnya. Solusi satu kali yang cepat ini bekerja dengan baik untuk pinjaman atau hipotek tertentu.

Jika Anda ingin membuat jadwal amortisasi yang dapat digunakan kembali dengan jumlah periode yang bervariasi, Anda harus mengambil pendekatan yang lebih komprehensif yang dijelaskan di bawah ini.

1. Masukkan jumlah maksimum periode

Dalam Periode kolom, masukkan jumlah pembayaran maksimum yang akan Anda izinkan untuk pinjaman apa pun, katakanlah, dari 1 hingga 360. Anda dapat memanfaatkan fitur IsiOtomatis Excel untuk memasukkan serangkaian angka dengan lebih cepat.

2. Gunakan pernyataan IF dalam rumus amortisasi

Karena Anda sekarang memiliki banyak nomor periode yang berlebihan, Anda harus membatasi kalkulasi pada jumlah pembayaran aktual untuk pinjaman tertentu. Ini dapat dilakukan dengan membungkus setiap rumus ke dalam pernyataan IF. Tes logis dari pernyataan IF memeriksa apakah nomor periode di baris saat ini kurang dari atau sama dengan jumlah total pembayaran. Jika tes logisnya BENAR, makadihitung; jika FALSE, string kosong dikembalikan.

Dengan asumsi Periode 1 berada di baris 8, masukkan rumus berikut dalam sel yang sesuai, kemudian salin di seluruh tabel.

Pembayaran (B8):

=IF(A8<=$C$3*$C$4, PMT($C$2/$C$4, $C$3*$C$4, $C$5), "")

Minat (C8):

=IF(A8<=$C$3*$C$4, IPMT($C$2/$C$4, A8, $C$3*$C$4, $C$5), "")

Kepala Sekolah (D8):

=IF(A8<=$C$3*$C$4,PPMT($C$2/$C$4, A8, $C$3*$C$4, $C$5), "")

Keseimbangan :

Untuk Periode 1 (E8), rumusnya sama seperti pada contoh sebelumnya:

=C5+D8

Untuk Periode 2 (E9) dan semua periode berikutnya, rumusnya berbentuk seperti ini:

=IF(A9<=$C$3*$C$4, E8+D9, "")

Hasilnya, Anda memiliki jadwal amortisasi yang dihitung dengan benar dan sekumpulan baris kosong dengan angka periode setelah pinjaman lunas.

3. Sembunyikan nomor periode tambahan

Jika Anda bisa hidup dengan sekumpulan angka periode berlebihan yang ditampilkan setelah pembayaran terakhir, Anda bisa mempertimbangkan pekerjaan yang telah selesai dan melewatkan langkah ini. Jika Anda berusaha keras untuk kesempurnaan, maka sembunyikan semua periode yang tidak terpakai dengan membuat aturan pemformatan bersyarat yang mengatur warna font menjadi putih untuk setiap baris setelah pembayaran terakhir dilakukan.

Untuk ini, pilih semua baris data jika tabel amortisasi Anda (A8:E367 dalam kasus kami) dan klik Rumah tab> Pemformatan bersyarat > Aturan Baru... > Gunakan formula untuk menentukan sel mana yang akan diformat .

Dalam kotak yang sesuai, masukkan rumus di bawah ini yang memeriksa apakah nomor periode di kolom A lebih besar dari jumlah total pembayaran:

=$A8>$C$3*$C$4

Catatan penting! Agar formula pemformatan bersyarat berfungsi dengan benar, pastikan untuk menggunakan referensi sel absolut untuk Jangka waktu pinjaman dan Pembayaran per tahun sel yang Anda kalikan ($C$3*$C$4). Hasil perkalian tersebut dibandingkan dengan Periode 1 sel, di mana Anda menggunakan referensi sel campuran - kolom absolut dan baris relatif ($A8).

Setelah itu, klik tombol Format... dan pilih warna font putih. Selesai!

4. Membuat ringkasan pinjaman

Untuk melihat ringkasan informasi tentang pinjaman Anda secara sekilas, tambahkan beberapa rumus lagi di bagian atas jadwal amortisasi Anda.

Total pembayaran (F2):

=-SUM(B8:B367)

Total bunga (F3):

=-SUM(C8:C367)

Jika Anda memiliki pembayaran sebagai angka positif, hilangkan tanda minus dari rumus di atas.

Itu saja! Jadwal amortisasi pinjaman kami sudah selesai dan siap digunakan!

Unduh jadwal amortisasi pinjaman untuk Excel

Cara membuat jadwal amortisasi pinjaman dengan pembayaran ekstra di Excel

Jadwal amortisasi yang dibahas dalam contoh-contoh sebelumnya mudah dibuat dan diikuti (semoga :). Namun, mereka meninggalkan fitur berguna yang diminati oleh banyak pembayar pinjaman - pembayaran tambahan untuk melunasi pinjaman lebih cepat. Dalam contoh ini, kita akan melihat cara membuat jadwal amortisasi pinjaman dengan pembayaran ekstra.

1. Tentukan sel input

Seperti biasa, mulailah dengan mengatur sel inputnya. Dalam hal ini, mari kita beri nama sel tersebut seperti yang tertulis di bawah ini agar rumus kita lebih mudah dibaca:

• Suku Bunga - C2 (suku bunga tahunan)
• Jangka Waktu Pinjaman - C3 (jangka waktu pinjaman dalam tahun)
• PembayaranPer Tahun - C4 (jumlah pembayaran per tahun)
• Jumlah Pinjaman - C5 (jumlah total pinjaman)
• Pembayaran Ekstra - C6 (pembayaran ekstra per periode)

2. Menghitung pembayaran terjadwal

Terlepas dari sel input, satu sel predefinisi lagi diperlukan untuk kalkulasi kita lebih lanjut - sel jumlah pembayaran yang dijadwalkan yaitu jumlah yang harus dibayar atas pinjaman jika tidak ada pembayaran ekstra yang dilakukan. Jumlah ini dihitung dengan rumus berikut:

=IFERROR(-PMT(InterestRate/PaymentsPerYear, LoanTerm*PaymentsPerYear, LoanAmount), "")

Harap perhatikan bahwa kita meletakkan tanda minus sebelum fungsi PMT untuk mendapatkan hasil sebagai angka positif. Untuk mencegah kesalahan jika beberapa sel input kosong, kita menyertakan rumus PMT dalam fungsi IFERROR.

Masukkan rumus ini di beberapa sel (G2 dalam kasus kita) dan beri nama sel itu Pembayaran Terjadwal .

3. Siapkan tabel amortisasi

Buat tabel amortisasi pinjaman dengan tajuk yang ditunjukkan pada gambar di bawah ini. Dalam tabel Periode masukkan serangkaian angka yang dimulai dengan nol (Anda bisa menyembunyikan kolom Periode 0 baris kemudian jika diperlukan).

Jika Anda bertujuan untuk membuat jadwal amortisasi yang bisa digunakan kembali, masukkan jumlah maksimum periode pembayaran yang memungkinkan (0 hingga 360 dalam contoh ini).

Untuk Periode 0 (baris 9 dalam kasus kita), tarik Keseimbangan yang sama dengan jumlah pinjaman asli. Semua sel lain dalam baris ini akan tetap kosong:

Formula di G9:

=Jumlah Pinjaman

4. Membuat formula untuk jadwal amortisasi dengan pembayaran ekstra

Ini adalah bagian penting dari pekerjaan kita. Karena fungsi bawaan Excel tidak menyediakan pembayaran tambahan, kita harus melakukan semua perhitungan sendiri.

Catatan. Dalam contoh ini, Periode 0 berada di baris 9 dan Periode 1 berada di baris 10. Jika tabel amortisasi Anda dimulai di baris yang berbeda, pastikan untuk menyesuaikan referensi sel yang sesuai.

Masukkan rumus berikut dalam baris 10 ( Periode 1 ), dan kemudian menyalinnya untuk semua periode yang tersisa.

Pembayaran Terjadwal (B10):

Jika Pembayaran Terjadwal (bernama sel G2) kurang dari atau sama dengan sisa saldo (G9), gunakan pembayaran terjadwal. Jika tidak, tambahkan sisa saldo dan bunga untuk bulan sebelumnya.

=IFERROR(IF(Pembayaran Terjadwal<=G9, Pembayaran Terjadwal, G9+G9*BungaTingkat/PembayaranPer Tahun), "")

Sebagai tindakan pencegahan ekstra, kita membungkus ini dan semua rumus berikutnya dalam fungsi IFERROR. Ini akan mencegah sekumpulan berbagai kesalahan jika beberapa sel input kosong atau berisi nilai yang tidak valid.

Pembayaran Ekstra (C10):

Gunakan rumus IF dengan logika berikut:

Jika Pembayaran Ekstra (bernama sel C6) kurang dari selisih antara sisa saldo dan pokok periode ini (G9-E10), kembalikan Pembayaran Ekstra ; jika tidak, gunakan perbedaannya.

=IFERROR(IF(Pembayaran Ekstra

Tip. Jika Anda memiliki pembayaran tambahan variabel , cukup ketik jumlah individual secara langsung dalam Pembayaran Ekstra kolom.

Total Pembayaran (D10)

Cukup, tambahkan pembayaran terjadwal (B10) dan pembayaran ekstra (C10) untuk periode saat ini:

=IFERROR(B10+C10, "")

Kepala Sekolah (E10)

Jika jadwal pembayaran untuk periode tertentu lebih besar dari nol, kembalikan nilai yang lebih kecil dari dua nilai: pembayaran terjadwal dikurangi bunga (B10-F10) atau sisa saldo (G9); jika tidak, kembalikan nol.

=IFERROR(IF(B10>0, MIN(B10-F10, G9), 0), "")

Harap dicatat bahwa prinsipal hanya mencakup bagian dari pembayaran terjadwal (bukan pembayaran ekstra!) yang digunakan untuk pokok pinjaman.

Minat (F10)

Jika jadwal pembayaran untuk periode tertentu lebih besar dari nol, bagilah tingkat bunga tahunan (dinamai sel C2) dengan jumlah pembayaran per tahun (dinamai sel C4) dan kalikan hasilnya dengan saldo yang tersisa setelah periode sebelumnya; jika tidak, kembalikan 0.

=IFERROR(IF(B10>0, InterestRate/PaymentsPerYear*G9, 0), "")

Keseimbangan (G10)

Jika sisa saldo (G9) lebih besar dari nol, kurangi bagian pokok pembayaran (E10) dan pembayaran ekstra (C10) dari sisa saldo setelah periode sebelumnya (G9); jika tidak, kembalikan 0.

=IFERROR(IF(G9>0, G9-E10-C10, 0), "")

Catatan. Karena beberapa rumus saling referensi silang satu sama lain (bukan referensi melingkar!), rumus-rumus tersebut mungkin menampilkan hasil yang salah dalam prosesnya. Jadi, jangan mulai memecahkan masalah sampai anda memasukkan rumus terakhir dalam tabel amortisasi anda.

Jika semua dilakukan dengan benar, jadwal amortisasi pinjaman Anda pada saat ini akan terlihat seperti ini:

5. Sembunyikan periode tambahan

Siapkan aturan pemformatan bersyarat untuk menyembunyikan nilai dalam periode yang tidak digunakan seperti yang dijelaskan dalam tip ini. Perbedaannya adalah bahwa kali ini kita menerapkan aturan warna font putih ke baris-baris di mana Total Pembayaran (kolom D) dan Keseimbangan (kolom G) sama dengan nol atau kosong:

=AND(OR($D9=0, $D9=""), OR($G9=0, $G9=""))

Voila, semua baris dengan nilai nol disembunyikan dari pandangan:

6. Membuat ringkasan pinjaman

Sebagai sentuhan akhir kesempurnaan, Anda bisa menghasilkan informasi paling penting tentang pinjaman dengan menggunakan rumus-rumus ini:

Jumlah pembayaran yang dijadwalkan:

Kalikan jumlah tahun dengan jumlah pembayaran per tahun:

=Jangka Waktu Pinjaman*Pembayaran Per Tahun

Jumlah pembayaran aktual:

Hitung sel dalam Total Pembayaran yang lebih besar dari nol, dimulai dengan Periode 1:

=COUNTIF(D10:D369,">"&0)

Total pembayaran ekstra:

Menjumlahkan sel-sel dalam Pembayaran Ekstra kolom, dimulai dengan Periode 1:

=SUM(C10:C369)

Total bunga:

Menjumlahkan sel-sel dalam Minat kolom, dimulai dengan Periode 1:

=SUM(F10:F369)

Secara opsional, sembunyikan Periode 0 baris, dan jadwal amortisasi pinjaman Anda dengan pembayaran tambahan sudah selesai! Tangkapan layar di bawah ini menunjukkan hasil akhir:

Unduh jadwal amortisasi pinjaman dengan pembayaran ekstra

Jadwal amortisasi template Excel

Untuk membuat jadwal amortisasi pinjaman terbaik dalam waktu singkat, manfaatkan templat bawaan Excel. Cukup buka Berkas > Baru , ketik " jadwal amortisasi " di kotak pencarian dan pilih templat yang Anda sukai, misalnya, templat ini dengan pembayaran ekstra:

Kemudian simpan buku kerja yang baru dibuat sebagai templat Excel dan gunakan kembali kapan pun Anda mau.

Begitulah cara Anda membuat jadwal amortisasi pinjaman atau hipotek di Excel. Saya berterima kasih telah membaca dan berharap dapat melihat Anda di blog kami minggu depan!

Unduhan yang tersedia

Contoh Jadwal Amortisasi (file .xlsx)