Σε αυτό το σεμινάριο, θα μάθετε πώς να μετράτε μοναδικές τιμές στο Excel με τύπους και πώς να λαμβάνετε μια αυτόματη μέτρηση των ξεχωριστών τιμών σε έναν πίνακα pivot. Θα συζητήσουμε επίσης μια σειρά από παραδείγματα τύπων για την καταμέτρηση μοναδικών ονομάτων, κειμένων, αριθμών, μοναδικών τιμών με ευαισθησία στην πεζότητα και πολλά άλλα.

Όταν εργάζεστε με ένα μεγάλο σύνολο δεδομένων στο Excel, μπορεί συχνά να χρειάζεται να γνωρίζετε πόσες διπλότυπο και μοναδικό Και μερικές φορές, μπορεί να θέλετε να μετρήσετε μόνο τις ξεχωριστό (διαφορετικές) τιμές.

Εάν επισκέπτεστε αυτό το ιστολόγιο σε τακτική βάση, γνωρίζετε ήδη τον τύπο του Excel για την καταμέτρηση των διπλών τιμών. Και σήμερα, θα εξερευνήσουμε διαφορετικούς τρόπους για την καταμέτρηση μοναδικών τιμών στο Excel. Αλλά για λόγους σαφήνειας, ας ορίσουμε πρώτα τους όρους.

• Μοναδικό τιμές - αυτές είναι οι τιμές που εμφανίζονται στη λίστα μόνο μία φορά.
• Διακριτό values - πρόκειται για όλες τις διαφορετικές τιμές της λίστας, δηλαδή μοναδικές τιμές συν την 1η εμφάνιση διπλών τιμών.

Το ακόλουθο στιγμιότυπο οθόνης δείχνει τη διαφορά:

Και τώρα, ας δούμε πώς μπορείτε να μετρήσετε μοναδικές και διακριτές τιμές στο Excel χρησιμοποιώντας τύπους και λειτουργίες του PivotTable.

Πώς να μετρήσετε μοναδικές τιμές στο Excel

Ακολουθεί μια κοινή εργασία που όλοι οι χρήστες του Excel πρέπει να εκτελούν μια στο τόσο. Έχετε μια λίστα δεδομένων και πρέπει να βρείτε τον αριθμό των μοναδικών τιμών σε αυτή τη λίστα. Πώς το κάνετε αυτό; Πιο εύκολα απ' ό,τι νομίζετε :) Παρακάτω θα βρείτε μερικούς τύπους για να μετρήσετε μοναδικές τιμές διαφόρων τύπων.

Καταμέτρηση μοναδικών τιμών σε μια στήλη

Ας υποθέσουμε ότι έχετε μια στήλη με ονόματα στο φύλλο εργασίας του Excel και πρέπει να μετρήσετε τα μοναδικά ονόματα σε αυτή τη στήλη. Η λύση είναι να χρησιμοποιήσετε τη συνάρτηση SUM σε συνδυασμό με τις IF και COUNTIF:

Σημείωση . Αυτός είναι ένας τύπος πίνακα, οπότε φροντίστε να πατήσετε Ctrl + Shift + Enter για να τον ολοκληρώσετε. Μόλις το κάνετε αυτό, το Excel θα περικλείσει αυτόματα τον τύπο σε {καμπύλες αγκύλες} όπως στο παρακάτω στιγμιότυπο. Σε καμία περίπτωση δεν πρέπει να πληκτρολογήσετε τις καμπύλες αγκύλες με το χέρι, αυτό δεν θα λειτουργήσει.

Σε αυτό το παράδειγμα, μετράμε τα μοναδικά ονόματα στην περιοχή A2:A10, οπότε ο τύπος μας παίρνει την ακόλουθη μορφή:

=SUM(IF(COUNTIF(A2:A10,A2:A10)=1,1,0))

Στη συνέχεια αυτού του σεμιναρίου, θα συζητήσουμε μια χούφτα άλλων τύπων για την καταμέτρηση μοναδικών τιμών διαφόρων τύπων. Και επειδή όλοι αυτοί οι τύποι είναι παραλλαγές του βασικού τύπου μοναδικών τιμών του Excel, έχει νόημα να αναλύσουμε τον παραπάνω τύπο, ώστε να κατανοήσετε πλήρως πώς λειτουργεί και να τον προσαρμόσετε στα δεδομένα σας. Αν κάποιος δεν ενδιαφέρεται για τεχνικές λεπτομέρειες, μπορεί να περάσει κατευθείαν στην ενότητατο επόμενο παράδειγμα τύπου.

Πώς λειτουργεί ο τύπος καταμέτρησης μοναδικών τιμών του Excel

Όπως βλέπετε, 3 διαφορετικές συναρτήσεις χρησιμοποιούνται στον τύπο των μοναδικών τιμών μας - SUM, IF και COUNTIF. Κοιτάζοντας από μέσα προς τα έξω, δείτε τι κάνει κάθε συνάρτηση:

• Η συνάρτηση COUNTIF μετράει πόσες φορές εμφανίζεται κάθε μεμονωμένη τιμή στην καθορισμένη περιοχή.

  Σε αυτό το παράδειγμα, COUNTIF(A2:A10,A2:A10) επιστρέφει τον πίνακα {1;2;2;1;2;2;2;1;2} .

• Η συνάρτηση IF αξιολογεί κάθε τιμή στον πίνακα που επιστρέφει η COUNTIF, διατηρεί όλες τις τιμές 1 (μοναδικές τιμές) και αντικαθιστά όλες τις άλλες τιμές με μηδενικά.

  Έτσι, η συνάρτηση IF(COUNTIF(A2:A10,A2:A10)=1,1,0) γίνεται IF(1;2;2;1;2;2;2;2;1;2) = 1,1,0, η οποία μετατρέπεται στον πίνακα {1;0;0;1;0;0;0;1;0} όπου το 1 είναι μια μοναδική τιμή και το 0 είναι μια διπλή τιμή.

• Τέλος, η συνάρτηση SUM αθροίζει τις τιμές στον πίνακα που επιστρέφει η IF και εξάγει τον συνολικό αριθμό των μοναδικών τιμών, που είναι ακριβώς αυτό που θέλαμε.

Συμβουλή. Για να δείτε σε τι αξιολογείται ένα συγκεκριμένο τμήμα του τύπου μοναδικών τιμών του Excel, επιλέξτε το τμήμα αυτό στη γραμμή τύπων και πατήστε το πλήκτρο F9.

Καταμέτρηση μοναδικών τιμών κειμένου στο Excel

Εάν η λίστα του Excel περιέχει τόσο αριθμητικές τιμές όσο και τιμές κειμένου και θέλετε να μετράτε μόνο τις μοναδικές τιμές κειμένου, προσθέστε τη συνάρτηση ISTEXT στον τύπο του πίνακα που συζητήθηκε παραπάνω:

=SUM(IF(ISTEXT(A2:A10)*COUNTIF(A2:A10,A2:A10)=1,1,0))

Όπως γνωρίζετε, η συνάρτηση ISTEXT του Excel επιστρέφει TRUE αν μια εκτιμώμενη τιμή είναι κείμενο, FALSE διαφορετικά. Δεδομένου ότι ο αστερίσκος (*) λειτουργεί ως τελεστής AND σε τύπους συστοιχιών, η συνάρτηση IF επιστρέφει 1 μόνο αν μια τιμή είναι και κείμενο και μοναδική, 0 διαφορετικά. Και αφού η συνάρτηση SUM προσθέσει όλα τα 1, θα λάβετε μια καταμέτρηση των μοναδικών τιμών κειμένου στην καθορισμένη περιοχή.

Μην ξεχάσετε να πατήσετε Ctrl + Shift + Enter για να εισαγάγετε σωστά τον τύπο του πίνακα, και θα έχετε ένα αποτέλεσμα παρόμοιο με αυτό:

Όπως μπορείτε να δείτε στο παραπάνω στιγμιότυπο οθόνης, ο τύπος επιστρέφει το συνολικό αριθμό μοναδικών τιμών κειμένου, εξαιρουμένων των κενών κελιών, των αριθμών, των λογικών τιμών TRUE και FALSE και των σφαλμάτων.

Καταμέτρηση μοναδικών αριθμητικών τιμών στο Excel

Για να μετρήσετε μοναδικούς αριθμούς σε μια λίστα δεδομένων, χρησιμοποιήστε έναν τύπο πίνακα όπως μόλις χρησιμοποιήσαμε για την καταμέτρηση μοναδικών τιμών κειμένου, με τη μόνη διαφορά ότι ενσωματώνετε τον ISNUMBER αντί του ISTEXT στον τύπο μοναδικών τιμών:

=SUM(IF(ISNUMBER(A2:A10)*COUNTIF(A2:A10,A2:A10)=1,1,0))

Σημείωση: Δεδομένου ότι το Microsoft Excel αποθηκεύει ημερομηνίες και ώρες ως αύξοντες αριθμούς, υπολογίζονται επίσης.

Καταμέτρηση μοναδικών τιμών με ευαισθησία στην πεζότητα στο Excel

Εάν ο πίνακάς σας περιέχει δεδομένα ευαίσθητα στην πεζότητα, ο ευκολότερος τρόπος για την καταμέτρηση των μοναδικών τιμών θα ήταν η δημιουργία μιας βοηθητικής στήλης με τον ακόλουθο τύπο πίνακα για τον εντοπισμό διπλών και μοναδικών στοιχείων:

=IF(SUM((--EXACT($A$2:$A$10,A2)))=1, "Unique", "Dupe")

Και στη συνέχεια, χρησιμοποιήστε μια απλή συνάρτηση COUNTIF για να μετρήσετε τις μοναδικές τιμές:

=COUNTIF(B2:B10, "unique")

Καταμέτρηση διακριτών τιμών στο Excel (μοναδικές και 1ες διπλές εμφανίσεις)

Για να λάβετε μια καταμέτρηση των διαφορετικών τιμών σε μια λίστα, χρησιμοποιήστε τον ακόλουθο τύπο:

Θυμηθείτε ότι πρόκειται για τύπο πίνακα και επομένως θα πρέπει να πατήσετε τη συντόμευση Ctrl + Shift + Enter αντί του συνηθισμένου πλήκτρου Enter.

Εναλλακτικά, μπορείτε να χρησιμοποιήσετε τη συνάρτηση SUMPRODUCT και να ολοκληρώσετε τον τύπο με τον συνήθη τρόπο πατώντας το πλήκτρο Enter:

Για παράδειγμα, για να μετρήσετε τις ξεχωριστές τιμές στο εύρος A2:A10, μπορείτε να χρησιμοποιήσετε είτε:

=SUM(1/COUNTIF(A2:A10,A2:A10))

Ή

=SUMPRODUCT(1/COUNTIF(A2:A10,A2:A10))

Πώς λειτουργεί ο ξεχωριστός τύπος του Excel

Όπως ήδη γνωρίζετε, χρησιμοποιούμε τη συνάρτηση COUNTIF για να βρούμε πόσες φορές εμφανίζεται κάθε μεμονωμένη τιμή στο καθορισμένο εύρος. Στο παραπάνω παράδειγμα, το αποτέλεσμα της συνάρτησης COUNTIF είναι ο ακόλουθος πίνακας: {2;2;3;1;2;2;3;1;3} .

Μετά από αυτό, εκτελείται ένας αριθμός πράξεων διαίρεσης, όπου κάθε τιμή του πίνακα χρησιμοποιείται ως διαιρέτης με 1 ως μέρισμα. Αυτό μετατρέπει όλες τις διπλές τιμές σε κλασματικούς αριθμούς που αντιστοιχούν στον αριθμό των διπλών εμφανίσεων. Για παράδειγμα, αν μια τιμή εμφανίζεται 2 φορές στη λίστα, δημιουργεί 2 στοιχεία στον πίνακα με τιμή 0,5 (1/2=0,5). Και αν μια τιμή εμφανίζεται 3 φορές, δημιουργείπαράγει 3 στοιχεία στον πίνακα με τιμή 0.3(3). Στο παράδειγμά μας, το αποτέλεσμα της εντολής 1/COUNTIF(A2:A10,A2:A10)) είναι ο πίνακας {0.5;0.5;0.3(3);1;0.5;0.5;0.3(3);1;0.3(3)} .

Δεν βγάζει νόημα μέχρι στιγμής; Αυτό συμβαίνει επειδή δεν έχουμε εφαρμόσει ακόμα τη συνάρτηση SUM / SUMPRODUCT. Όταν μία από αυτές τις συναρτήσεις αθροίζει τις τιμές στον πίνακα, το άθροισμα όλων των κλασματικών αριθμών για κάθε μεμονωμένο στοιχείο δίνει πάντα 1, ανεξάρτητα από το πόσες εμφανίσεις αυτού του στοιχείου υπάρχουν στη λίστα. Και επειδή όλες οι μοναδικές τιμές εμφανίζονται στον πίνακα ως 1 (1/1=1), το τελικό αποτέλεσμα που επιστρέφει η συνάρτησηείναι ο συνολικός αριθμός όλων των διαφορετικών τιμών στη λίστα.

Τύποι για την καταμέτρηση διακριτών τιμών διαφορετικών τύπων

Όπως συμβαίνει και με την καταμέτρηση μοναδικών τιμών στο Excel, μπορείτε να χρησιμοποιήσετε παραλλαγές του βασικού τύπου του Excel count distinct για να χειριστείτε συγκεκριμένους τύπους τιμών, όπως αριθμούς, κείμενο και τιμές με ευαισθησία στην πεζότητα.

Να θυμάστε ότι όλοι οι παρακάτω τύποι είναι τύποι συστοιχίας και απαιτούν το πάτημα των πλήκτρων Ctrl + Shift + Enter .

Καταμέτρηση διαφορετικών τιμών αγνοώντας τα κενά κελιά

Εάν μια στήλη στην οποία θέλετε να μετρήσετε διακριτές τιμές μπορεί να περιέχει κενά κελιά, θα πρέπει να προσθέσετε μια συνάρτηση IF που θα ελέγχει την καθορισμένη περιοχή για κενά (ο βασικός τύπος διακριτών τιμών του Excel που συζητήθηκε παραπάνω θα επέστρεφε το σφάλμα #DIV/0 σε αυτή την περίπτωση):

Για παράδειγμα, για να μετρήσετε διακριτές τιμές στην περιοχή A2:A10, χρησιμοποιήστε τον ακόλουθο τύπο πίνακα:

=SUM(IF(A2:A10"",1/COUNTIF(A2:A10, A2:A10), 0))

Τύπος για να μετρήσετε ξεχωριστές τιμές κειμένου

Για να μετρήσουμε τις ξεχωριστές τιμές κειμένου σε μια στήλη, θα χρησιμοποιήσουμε την ίδια προσέγγιση που μόλις χρησιμοποιήσαμε για να αποκλείσουμε τα κενά κελιά.

Όπως μπορείτε εύκολα να μαντέψετε, θα ενσωματώσουμε απλώς τη συνάρτηση ISTEXT στον ξεχωριστό τύπο μέτρησης του Excel:

Και εδώ είναι ένα πραγματικό παράδειγμα τύπου:

=SUM(IF(ISTEXT(A2:A10),1/COUNTIF(A2:A10, A2:A10),""))

Τύπος για να μετρήσετε διαφορετικούς αριθμούς

Για να μετρήσετε διακριτές αριθμητικές τιμές (αριθμούς, ημερομηνίες και ώρες), χρησιμοποιήστε τη συνάρτηση ISNUMBER:

Για παράδειγμα, για να μετρήσετε όλους τους διαφορετικούς αριθμούς στην περιοχή A2:A10, χρησιμοποιήστε τον ακόλουθο τύπο:

=SUM(IF(ISNUMBER(A2:A10),1/COUNTIF(A2:A10, A2:A10),""))

Καταμέτρηση διαφορετικών τιμών με ευαισθησία στην πεζότητα στο Excel

Ομοίως με την καταμέτρηση των μοναδικών τιμών με ευαισθησία στην πεζότητα, ο ευκολότερος τρόπος για την καταμέτρηση των διακριτών τιμών με ευαισθησία στην πεζότητα είναι να προσθέσετε μια βοηθητική στήλη με τον τύπο του πίνακα που προσδιορίζει τις μοναδικές τιμές, συμπεριλαμβανομένων των πρώτων διπλών εμφανίσεων. Ο τύπος είναι ουσιαστικά ο ίδιος με αυτόν που χρησιμοποιήσαμε για την καταμέτρηση των μοναδικών τιμών με ευαισθησία στην πεζότητα, με μια μικρή αλλαγή σε μια αναφορά κελιού που κάνει μεγάλη διαφορά:

=IF(SUM((--EXACT($A$2:$A2,$A2)))=1, "Distinct","")

Όπως θυμάστε, όλοι οι τύποι συστοιχιών στο Excel απαιτούν το πάτημα των πλήκτρων Ctrl + Shift + Enter .

Αφού ολοκληρωθεί ο παραπάνω τύπος, μπορείτε να μετρήσετε τις "διακριτές" τιμές με έναν συνηθισμένο τύπο COUNTIF, όπως αυτός:

=COUNTIF(B2:B10, "distinct")

Αν δεν υπάρχει τρόπος να προσθέσετε μια βοηθητική στήλη στο φύλλο εργασίας σας, μπορείτε να χρησιμοποιήσετε το ακόλουθο σύνθετο τύπος συστοιχίας για την καταμέτρηση διαφορετικών τιμών με ευαισθησία στην πεζότητα χωρίς τη δημιουργία πρόσθετης στήλης:

=SUM(IFERROR(1/IF($A$2:$A$10"", FREQUENCY(IF(EXACT($A$2:$A$10, TRANSPOSE($A$2:$A$10)), MATCH(ROW($A$2:$A$10), ROW($A$2:$A$10)), ""), MATCH(ROW($A$2:$A$10), ROW($A$2:$A$10)))), 0), 0))))

Καταμέτρηση μοναδικών και διακριτών γραμμών στο Excel

Η καταμέτρηση μοναδικών / διακριτών γραμμών στο Excel είναι παρόμοια με την καταμέτρηση μοναδικών και διακριτών τιμών, με τη μόνη διαφορά ότι χρησιμοποιείτε τη συνάρτηση COUNTIFS αντί της COUNTIF, η οποία σας επιτρέπει να καθορίσετε πολλές στήλες για να ελέγξετε για μοναδικές τιμές.

Για παράδειγμα, για να μετρήσετε τα μοναδικά ή διακριτά ονόματα με βάση τις τιμές στις στήλες Α (Όνομα) και Β (Επώνυμο), χρησιμοποιήστε έναν από τους ακόλουθους τύπους:

Τύπος για την καταμέτρηση μοναδικών γραμμών:

=SUM(IF(COUNTIFS(A2:A10,A2:A10, B2:B10,B2:B10)=1,1,0))

Τύπος για την καταμέτρηση διακριτών γραμμών:

=SUM(1/COUNTIFS(A2:A10,A2:A10,B2:B10,B2:B10))

Φυσικά, δεν περιορίζεστε στην καταμέτρηση μοναδικών γραμμών με βάση μόνο δύο στήλες, η συνάρτηση COUNTIFS του Excel μπορεί να επεξεργαστεί έως και 127 ζεύγη περιοχών/κριτηρίων.

Καταμέτρηση διαφορετικών τιμών στο Excel χρησιμοποιώντας έναν πίνακα PivotTable

Οι τελευταίες εκδόσεις των Excel 2013 και Excel 2016 διαθέτουν ένα ειδικό χαρακτηριστικό που επιτρέπει την αυτόματη καταμέτρηση των διαφορετικών τιμών σε έναν πίνακα pivot. Το ακόλουθο στιγμιότυπο οθόνης δίνει μια ιδέα για το πώς το Excel Διακεκριμένη μέτρηση μοιάζει:

Για να δημιουργήσετε έναν πίνακα pivot με τον ξεχωριστό αριθμό για μια συγκεκριμένη στήλη, εκτελέστε τα ακόλουθα βήματα.

1. Επιλέξτε τα δεδομένα που θα συμπεριληφθούν σε έναν πίνακα pivot, μεταβείτε στο παράθυρο Εισαγωγή καρτέλα, Πίνακες και κάντε κλικ στο κουμπί PivotTable κουμπί.
2. Στο Δημιουργία PivotTable διαλόγου, επιλέξτε αν θα τοποθετήσετε τον πίνακα περιστροφής σας σε ένα νέο ή υπάρχον φύλλο εργασίας και φροντίστε να επιλέξετε την επιλογή Προσθέστε αυτά τα δεδομένα στο μοντέλο δεδομένων πλαίσιο ελέγχου.

Μπορείτε επίσης να δώσετε ένα προσαρμοσμένο όνομα στο Distinct Count, αν θέλετε.

Ο νεοδημιουργηθείς πίνακας Pivot θα εμφανίζει τον αριθμό των διακριτών στοιχείων όπως φαίνεται στο πρώτο στιγμιότυπο οθόνης αυτής της ενότητας.

Συμβουλή. Αφού ενημερώσετε τα δεδομένα της πηγής σας, θυμηθείτε να ενημερώσετε τον PivotTable για να ενημερώσετε τον αριθμό των διακριτών δεδομένων. Για να ανανεώσετε έναν Pivot Table, απλά κάντε κλικ στο κουμπί Ανανέωση στο κουμπί Αναλύστε το στην καρτέλα Δεδομένα ομάδα.

Με αυτόν τον τρόπο μετράτε διακριτές και μοναδικές τιμές στο Excel. Αν κάποιος θέλει να ρίξει μια πιο προσεκτική ματιά στους τύπους που συζητούνται σε αυτό το σεμινάριο, μπορείτε να κατεβάσετε το δείγμα του βιβλίου εργασίας Excel Count Unique.

Σας ευχαριστώ που διαβάσατε και ελπίζω να σας ξαναδώ την επόμενη εβδομάδα. Στο επόμενο άρθρο, θα συζητήσουμε διάφορους τρόπους για να βρούμε, να φιλτράρουμε, να εξάγουμε και να αναδείξουμε μοναδικές τιμές στο Excel. Παραμείνετε συντονισμένοι!