Bu eğitimde, düzensiz zamanlamaya sahip nakit akışları için iç getiri oranını (IRR) hesaplamak üzere Excel'de XIRR'nin nasıl kullanılacağı ve kendi XIRR hesaplayıcınızı nasıl yapacağınız gösterilmektedir.

Sermaye yoğun bir kararla karşı karşıya kaldığınızda, iç getiri oranının hesaplanması arzu edilir çünkü farklı yatırımlar için öngörülen getirileri karşılaştırmanıza olanak tanır ve karar vermek için nicel bir temel sağlar.

Önceki eğitimimizde, Excel IRR fonksiyonu ile iç getiri oranının nasıl hesaplanacağına bakmıştık. Bu yöntem hızlı ve basittir, ancak önemli bir sınırlaması vardır - IRR fonksiyonu tüm nakit akışlarının aylık veya yıllık gibi eşit zaman aralıklarında gerçekleştiğini varsayar. Ancak gerçek hayattaki durumlarda, nakit girişleri ve çıkışları genellikle düzensiz aralıklarla gerçekleşir.Neyse ki, Microsoft Excel'in bu gibi durumlarda IRR'yi bulmak için başka bir işlevi vardır ve bu eğitim size onu nasıl kullanacağınızı öğretecektir.

Excel'de XIRR işlevi

Excel XIRR işlevi, periyodik olabilen veya olamayan bir dizi nakit akışı için iç getiri oranını döndürür.

Bu işlev Excel 2007'de kullanıma sunulmuştur ve Excel 2010, Excel 2013, Excel 2016, Excel 2019 ve Office 365 için Excel'in sonraki tüm sürümlerinde mevcuttur.

XIRR fonksiyonunun sözdizimi aşağıdaki gibidir:

Nerede?

• Değerler (gerekli) - bir dizi giriş ve çıkışı temsil eden bir dizi veya hücre aralığı.
• Tarihler (gerekli) - nakit akışlarına karşılık gelen tarihler. Tarihler herhangi bir sırada olabilir, ancak ilk yatırımın tarihi dizide ilk sırada olmalıdır.
• Tahmin et (isteğe bağlı) - yüzde veya ondalık sayı olarak verilen beklenen IRR. Atlanırsa, Excel varsayılan 0,1 (%10) oranını kullanır.

Örneğin, A2:A5'teki nakit akışları serisi ve B2:B5'teki tarihler için IRR'yi hesaplamak için bu formülü kullanırsınız:

=XIRR(A2:A5, B2:B5)

İpucu: Sonucun doğru görüntülenmesi için lütfen Yüzde formatı formül hücresi için ayarlanır.

XIRR fonksiyonu hakkında bilmeniz gereken 6 şey

Aşağıdaki notlar, XIRR fonksiyonunun iç mekaniğini daha iyi anlamanıza ve çalışma sayfalarınızda en verimli şekilde kullanmanıza yardımcı olacaktır.

1. Excel'deki XIRR, eşit olmayan zamanlamaya sahip nakit akışları için iç getiri oranını hesaplamak üzere tasarlanmıştır. Kesin ödeme tarihleri bilinmeyen periyodik nakit akışları için IRR işlevini kullanabilirsiniz.
2. Değer aralığı en az bir pozitif (gelir) ve bir negatif (giden ödeme) değer içermelidir.
3. İlk değer bir harcama (ilk yatırım) ise, negatif bir sayı ile gösterilmelidir. İlk yatırım iskonto edilmez; sonraki ödemeler ilk nakit akışı tarihine geri getirilir ve 365 günlük bir yıla göre iskonto edilir.
4. Tüm tarihler tam sayılara kesilir, yani bir tarihin zamanı temsil eden kesirli kısmı kaldırılır.
5. Tarihler, tarih içeren hücrelere referans olarak veya TARİH işlevi gibi formüllerin sonuçları olarak girilen geçerli Excel tarihleri olmalıdır. Tarihler metin biçiminde girilirse sorunlar oluşabilir.
6. Excel'de XIRR her zaman bir yıllıklandırılmış IRR aylık veya haftalık nakit akışlarını hesaplarken bile.

Excel'de XIRR hesaplaması

Excel'deki XIRR işlevi, bu denklemi karşılayan oranı bulmak için bir deneme yanılma yaklaşımı kullanır:

Nerede?

• P - nakit akışı (ödeme)
• d - tarih
• i - dönem numarası
• n - dönemler toplamı

Sağlanmışsa tahminle, sağlanmamışsa varsayılan %10 ile başlayan Excel, %0,000001 doğrulukla sonuca ulaşmak için yinelemeler yapar. 100 denemeden sonra doğru bir oran bulunamazsa, #NUM! hatası döndürülür.

Bu denklemin geçerliliğini kontrol etmek için XIRR formülünün sonucuyla test edelim. Hesaplamamızı basitleştirmek için aşağıdaki dizi formülünü kullanacağız (lütfen herhangi bir dizi formülünün Ctrl + Shift + Enter tuşlarına basılarak tamamlanması gerektiğini unutmayın):

=SUM(A2:A5/((1+$E$1)^((B2:B5-$B$2)/365)))

Nerede?

• A2:A5 nakit akışlarıdır
• B2:B5 tarihleridir
• E1, XIRR tarafından döndürülen orandır

Aşağıdaki ekran görüntüsünde gösterildiği gibi, sonuç sıfıra çok yakındır. Q.E.D. :)

Excel'de XIRR nasıl hesaplanır - formül örnekleri

Aşağıda, XIRR işlevinin Excel'deki yaygın kullanımlarını gösteren birkaç örnek bulunmaktadır.

Excel'de temel XIRR formülü

Diyelim ki 2017 yılında 1.000 $ yatırım yaptınız ve önümüzdeki 6 yıl içinde bir miktar kâr elde etmeyi bekliyorsunuz. Bu yatırımın iç getiri oranını bulmak için şu formülü kullanın:

=XIRR(A2:A8, B2:B8)

Burada A2:A8 nakit akışları ve B2:B8 nakit akışlarına karşılık gelen tarihlerdir:

Bu yatırımın karlılığını değerlendirmek için, XIRR çıktısını şirketinizin ağırlıklı ortalama sermaye maliyeti veya engel oranı Geri dönüş oranı sermaye maliyetinden yüksekse, proje iyi bir yatırım olarak kabul edilebilir.

Çeşitli yatırım seçeneklerini karşılaştırırken, öngörülen getiri oranının bir karar vermeden önce tahmin etmeniz gereken faktörlerden sadece biri olduğunu lütfen unutmayın. Daha fazla bilgi için lütfen İç Getiri Oranı (IRR) nedir?

Excel XIRR işlevinin tam biçimi

Şu veya bu yatırımdan ne tür bir getiri beklediğinizi biliyorsanız, beklentinizi bir tahmin olarak kullanabilirsiniz. Özellikle doğru olduğu açık olan bir XIRR formülü #NUM! hatası verdiğinde faydalıdır.

Aşağıda gösterilen veri girişi için, tahmin içermeyen bir XIRR formülü hata verir:

=XIRR(A2:A7, B2:B7)

Öngörülen geri dönüş oranı (-%20) tahmin et argümanı Excel'in sonuca ulaşmasına yardımcı olur:

=XIRR(A2:A7, B2:B7, -20%)

Aylık nakit akışları için XIRR nasıl hesaplanır?

Yeni başlayanlar için, lütfen şunu unutmayın - hesapladığınız nakit akışları ne olursa olsun, Excel XIRR işlevi bir yıllık getiri oranı .

Bundan emin olmak için, aylık ve yıllık olarak gerçekleşen aynı nakit akışları serisi (A2:A8) için IRR'yi bulalım (tarihler B2:B8'de):

=XIRR(A2:A8, B2:B8)

Aşağıdaki ekran görüntüsünde de görebileceğiniz gibi, yıllık nakit akışları durumunda IRR %7,68'den aylık nakit akışları için yaklaşık %145'e çıkmaktadır! Aradaki fark, yalnızca paranın zaman değeri faktörüyle gerekçelendirilemeyecek kadar yüksek görünmektedir:

Yaklaşık bir değer bulmak için aylık XIRR E1'in normal XIRR formülünün sonucu olduğu aşağıdaki hesaplamayı kullanabilirsiniz:

=(1+E1)^(1/12)-1

Ya da XIRR'yi doğrudan denklemin içine yerleştirebilirsiniz:

=(1+XIRR(A2:A8,B2:B8))^(1/12)-1

Ek bir kontrol olarak, aynı nakit akışları üzerinde IRR fonksiyonunu kullanalım. Lütfen IRR'nin de yaklaşık bir oran hesaplayacağını unutmayın çünkü tüm zaman dilimlerinin eşit olduğunu varsayar:

=IRR(A2:A8)

Bu hesaplamalar sonucunda aylık %7,77'lik bir XIRR elde ediyoruz ki bu da IRR formülünün ürettiği %7,68'e çok yakın:

Sonuç : aylık nakit akışları için yıllık IRR arıyorsanız, XIRR fonksiyonunu saf haliyle kullanın; aylık IRR elde etmek için yukarıda açıklanan ayarlamayı uygulayın.

Excel XIRR şablonu

Farklı projeler için iç getiri oranını hızlı bir şekilde elde etmek için Excel için çok yönlü bir XIRR hesaplayıcısı oluşturabilirsiniz:

1. Nakit akışlarını ve tarihleri iki ayrı sütuna girin (bu örnekte A ve B).
2. Adında iki dinamik tanımlı aralık oluşturun Nakit_akışları ve Tarihler Teknik olarak, bu formüller olarak adlandırılacaktır:

   Nakit_akışları:

   =OFFSET(Sayfa1!$A$2,0,0,COUNT(Sayfa1!$A:$A),1)

   Tarihler:

   =OFFSET(Sayfa1!$B$2,0,0,COUNT(Sayfa1!$B:$B),1)

   Nerede Sayfa1 çalışma sayfanızın adı, A2 ilk nakit akışı ve B2 ilk tarihtir.

   Ayrıntılı adım adım yönergeler için lütfen Excel'de dinamik adlandırılmış aralık oluşturma bölümüne bakın.

3. XIRR formülüne oluşturduğunuz dinamik tanımlı adları verin:

=XIRR(Cash_flows, Dates)

Bitti! Artık istediğiniz kadar nakit akışı ekleyebilir veya çıkarabilirsiniz ve dinamik XIRR formülünüz buna göre yeniden hesaplanacaktır:

Excel'de XIRR ve IRR

Excel XIRR ve IRR fonksiyonları arasındaki temel fark şudur:

• IRR Bir nakit akışı serisindeki tüm dönemlerin eşit olduğunu varsayar. Bu fonksiyonu aylık, üç aylık veya yıllık gibi periyodik nakit akışları için iç getiri oranını bulmak için kullanırsınız.
• XIRR her bir nakit akışına bir tarih atamanıza olanak tanır. Dolayısıyla, periyodik olması gerekmeyen nakit akışları için IRR hesaplamak üzere bu işlevi kullanın.

Genel olarak, ödemelerin kesin tarihlerini biliyorsanız, daha iyi hesaplama doğruluğu sağladığından XIRR kullanmanız önerilir.

Örnek olarak, aynı nakit akışları için IRR ve XIRR sonuçlarını karşılaştıralım:

Tüm ödemeler şu tarihlerde gerçekleşirse düzenli aralıklarla fonksiyonları birbirine çok yakın sonuçlar döndürür:

Eğer nakit akışlarının zamanlaması eşitsiz sonuçlar arasındaki fark oldukça önemlidir:

Excel'de XIRR ve XNPV

XIRR, XNPV fonksiyonu ile yakından ilişkilidir çünkü XIRR'nin sonucu sıfır net bugünkü değere yol açan iskonto oranıdır. Başka bir deyişle, XIRR, XNPV = 0'dır. Aşağıdaki örnek Excel'de XIRR ve XNPV arasındaki ilişkiyi göstermektedir.

Diyelim ki bir yatırım fırsatını değerlendiriyorsunuz ve bu yatırımın hem net bugünkü değerini hem de iç getiri oranını incelemek istiyorsunuz.

A2:A5'teki nakit akışları, B2:B5'teki tarihler ve E1'deki iskonto oranı ile aşağıdaki XNPV formülü size gelecekteki nakit akışlarının net bugünkü değerini verecektir:

=XNPV(E1, A2:A5, B2:B5)

Pozitif bir NPV, projenin karlı olduğunu gösterir:

Şimdi, net bugünkü değeri sıfır yapacak iskonto oranını bulalım. Bunun için XIRR fonksiyonunu kullanacağız:

=XIRR(A2:A5, B2:B5)

XIRR tarafından üretilen oranın gerçekten sıfır NPV'ye yol açıp açmadığını kontrol etmek için oran XNPV formülünüzün argümanı:

=XNPV(E4, A2:A5, B2:B5)

Ya da tüm XIRR işlevini yerleştirin:

=XNPV(XIRR(A2:A5, B2:B5), A2:A5, B2:B5)

Evet, 2 ondalık basamağa yuvarlanmış XNPV sıfıra eşittir:

Tam NPV değerini görüntülemek için, daha fazla ondalık basamak göstermeyi seçin veya XNPV hücresine Bilimsel biçimi uygulayın. Bu, şuna benzer bir sonuç üretecektir:

Bilimsel gösterime aşina değilseniz, ondalık sayıya dönüştürmek için aşağıdaki hesaplamayı yapın:

1.11E-05 = 1.11*10^-5 = 0.0000111

Excel XIRR işlevi çalışmıyor

Excel'de XNPV işleviyle ilgili bir sorunla karşılaştıysanız, kontrol etmeniz gereken ana noktalar aşağıda verilmiştir.

#NUM! hatası

Aşağıdaki nedenlerden dolayı #NUM hatası oluşabilir:

• Bu değerler ve tarihler aralıkları farklı uzunluklara sahiptir (farklı sayıda sütun veya satır).
• Bu değerler dizisi en az bir pozitif ve bir negatif değer içermez.
• Sonraki tarihlerden herhangi biri ilk tarihten daha erkendir.
• Bu durumda, farklı bir tahmin deneyin. 100 iterasyondan sonra bir sonuç bulunamadı.

#DEĞER! hata

DEĞER hatası aşağıdakilerden kaynaklanıyor olabilir:

• Verilenlerden herhangi biri değerler sayısal değildir.
• Sağlanan tarihlerden bazıları geçerli Excel tarihleri olarak tanımlanamaz.

Bu eğitimde tartışılan formüllere daha yakından bakmak için aşağıdaki örnek çalışma kitabımızı indirebilirsiniz. Okuduğunuz için teşekkür eder, gelecek hafta blogumuzda görüşmek dileğiyle!

İndirmek için pratik çalışma kitabı

XIRR Excel şablonu (.xlsx dosyası)