Táboa de contidos
O titorial mostra como usar XIRR en Excel para calcular a taxa interna de retorno (IRR) dos fluxos de caixa con temporización irregular e como facer a túa propia calculadora XIRR.
Cando se enfronta a unha decisión intensiva en capital, é desexable calcular a taxa interna de retorno porque permite comparar os retornos previstos para diferentes investimentos e ofrece unha base cuantitativa para tomar a decisión.
No noso tutorial anterior, analizamos como calcular a taxa interna de retorno coa función IRR de Excel. Ese método é rápido e sinxelo, pero ten unha limitación esencial: a función IRR asume que todos os fluxos de caixa ocorren a intervalos de tempo iguais, como mensual ou anualmente. En situacións da vida real, con todo, as entradas e saídas de efectivo adoitan ocorrer a intervalos irregulares. Afortunadamente, Microsoft Excel ten outra función para atopar IRR nestes casos, e este tutorial ensinarache como usalo.
Función XIRR en Excel
O Excel XIRR a función devolve a taxa interna de retorno dunha serie de fluxos de caixa que poden ser periódicos ou non.
A función introduciuse en Excel 2007 e está dispoñible en todas as versións posteriores de Excel 2010, Excel 2013 e Excel 2016. , Excel 2019 e Excel para Office 365.
A sintaxe da función XIRR é a seguinte:
XIRR(valores, datas, [adiviña])Onde:
- Valores (obrigatorio) – anmatriz ou un rango de celas que representan unha serie de entradas e saídas.
- Datas (obrigatorio): datas correspondentes aos fluxos de caixa. As datas poden aparecer en calquera orde, pero a data do investimento inicial debe estar a primeira da matriz.
- Adiviña (opcional): unha TIR esperada que se proporciona como porcentaxe ou número decimal. Se se omite, Excel utiliza a taxa predeterminada de 0,1 (10%).
Por exemplo, para calcular a TIR para a serie de fluxos de caixa en A2:A5 e as datas en B2:B5, use esta fórmula:
=XIRR(A2:A5, B2:B5)
Consello. Para que o resultado se visualice correctamente, asegúrese de que o formato Porcentaxe estea configurado para a cela da fórmula.
6 cousas que debes saber sobre a función XIRR
As seguintes notas axudaranche a comprender mellor a mecánica interna da función XIRR e utilizala nas túas follas de traballo de forma máis eficiente.
- XIRR en Excel está deseñado para calcular a taxa interna de retorno dos fluxos de caixa con tempo desigual. Para fluxos de caixa periódicos con datas de pago exactas descoñecidas, pode utilizar a función IRR.
- O intervalo de valores debe conter polo menos un valor positivo (ingresos) e un negativo (pagos saíntes).
- Se o primeiro valor é un desembolso (investimento inicial), deberá representarse mediante un número negativo. Non se desconta o investimento inicial; os pagos posteriores volven á data do primeiro fluxo de caixa e descontan en funciónnun ano de 365 días.
- Todas as datas truncanse a números enteiros, o que significa que se elimina a fracción dunha data que representa o tempo.
- As datas deben ser datas de Excel válidas introducidas como referencias a celas que conteñan datas ou resultados de fórmulas como a función DATE. Se as datas se introducen no formato de texto, poden producirse problemas.
- XIRR en Excel sempre devolve unha TIR anual mesmo cando se calculan fluxos de caixa mensuais ou semanais.
Cálculo XIRR en Excel
A función XIRR en Excel usa un enfoque de proba e erro para atopar a taxa que satisface esta ecuación:
Onde:
- P - fluxo de efectivo (pago)
- d - data
- i - número de período
- n - período total
Comezando coa suposición se se proporciona ou co 10% predeterminado se non, Excel pasa por iteracións para chegar ao resultado cunha precisión do 0,000001%. Se despois de 100 intentos non se atopa unha taxa precisa, o #NUM! devólvese un erro.
Para comprobar a validez desta ecuación, comprobamos co resultado da fórmula XIRR. Para simplificar o noso cálculo, utilizaremos a seguinte fórmula matricial (lembra que calquera fórmula matricial debe completarse premendo Ctrl + Maiús + Intro ):
=SUM(A2:A5/((1+$E$1)^((B2:B5-$B$2)/365)))
Onde:
- A2:A5 son os fluxos de caixa
- B2:B5 son as datas
- E1 é a taxa devolta por XIRR
Como se mostra en na captura de pantalla a continuación, o resultado está moi próximoa cero. Q.E.D. :)
Como calcular XIRR en Excel: exemplos de fórmulas
Abaixo amósanse algúns exemplos que demostran os usos comúns da función XIRR en Excel.
Fórmula XIRR básica en Excel
Supoña que investiches 1.000 $ en 2017 e esperas recibir algún beneficio nos próximos 6 anos. Para atopar a taxa interna de retorno deste investimento, use esta fórmula:
=XIRR(A2:A8, B2:B8)
Onde A2:A8 son fluxos de caixa e B2:B8 son as datas correspondentes aos fluxos de caixa:
Para xulgar a rendibilidade deste investimento, compare a produción de XIRR co custo medio ponderado do capital ou a taxa obstáculo da súa empresa. Se a taxa de devolución é superior ao custo do capital, o proxecto pódese considerar un bo investimento.
Ao comparar varias opcións de investimento, lembre que a taxa de retorno proxectada é só un dos factores que debe estimar. antes de tomar unha decisión. Para obter máis información, consulte Cal é a taxa interna de retorno (IRR)?
Formulario completo da función XIRR de Excel
No caso de que saiba que tipo de retorno está a esperar deste ou aquel investimento, pode usar a súa expectativa como unha suposición. É especialmente útil cando unha fórmula XIRR obviamente correcta arroxa un #NUM! erro.
Para a entrada de datos que se mostra a continuación, unha fórmula XIRR sen adiviñar devolve un erro:
=XIRR(A2:A7, B2:B7)
A taxa de retorno prevista(-20%) colocado no argumento adiviñar axuda a Excel a chegar ao resultado:
=XIRR(A2:A7, B2:B7, -20%)
Como calcular o XIRR para fluxos de efectivo mensuais
Para comezar, lembre isto: sexan cales sexan os fluxos de efectivo que estea calculando, a función XIRR de Excel produce unha taxa de retorno anual .
Para asegurarse de isto, busquemos a TIR para a mesma serie de fluxos de caixa (A2:A8) que se producen mensuais e anuais (as datas están en B2:B8):
=XIRR(A2:A8, B2:B8)
Como podes ver en Na seguinte captura de pantalla, a TIR pasa do 7,68% no caso de fluxos de caixa anuais a preto do 145% para os fluxos de caixa mensuais. A diferenza parece demasiado alta para ser xustificada só polo factor do valor temporal do diñeiro:
Para atopar un XIRR mensual aproximado, podes utilizar o seguinte cálculo, onde E1 é o resultado da fórmula XIRR regular:
=(1+E1)^(1/12)-1
Ou pode incorporar XIRR directamente na ecuación:
=(1+XIRR(A2:A8,B2:B8))^(1/12)-1
Como un cheque adicional, usemos a función IRR nos mesmos fluxos de caixa. Teña en conta que o IRR tamén calculará unha taxa aproximada porque supón que todos os períodos de tempo son iguais:
=IRR(A2:A8)
Como resultado destes cálculos, obtemos un XIRR mensual de 7,77 %, que está moi preto do 7,68% producido pola fórmula TIR:
A conclusión : se buscas unha TIR anualizada para efectivo mensual fluxos, use a función XIRR na súa forma pura; para obter unha TIR mensual, solicitao axuste descrito anteriormente.
Modelo XIRR de Excel
Para obter rapidamente a taxa de retorno interna de diferentes proxectos, pode crear unha calculadora XIRR versátil para Excel. Vexa como:
- Introduza os fluxos de caixa e as datas en dúas columnas individuais (A e B neste exemplo).
- Cree dous intervalos definidos dinámicos, denominados Fluxos_efectivo e Datas . Tecnicamente, denominaranse fórmulas:
Cash_flows:
=OFFSET(Sheet1!$A$2,0,0,COUNT(Sheet1!$A:$A),1)Datas:
=OFFSET(Sheet1!$B$2,0,0,COUNT(Sheet1!$B:$B),1)Onde é Folla1 o nome da túa folla de traballo, A2 é o primeiro fluxo de caixa e B2 é a primeira data.
Para obter instrucións detalladas paso a paso, consulta Como crear un intervalo de nomes dinámico en Excel.
- Introduce os nomes definidos dinámicos que creaches á fórmula XIRR:
=XIRR(Cash_flows, Dates)
Feito! Agora podes engadir ou eliminar tantos fluxos de caixa como queiras e a túa fórmula XIRR dinámica volverase calcular en consecuencia:
XIRR vs. IRR en Excel
A principal diferenza entre as funcións XIRR e IRR de Excel é a seguinte:
- IRR asume que todos os períodos dunha serie de fluxos de caixa son iguais. Usa esta función para atopar a taxa interna de retorno dos fluxos de caixa periódicos, como mensuais, trimestrais ou anuais.
- XIRR permítelle asignar unha data a cada fluxo de caixa individual. Entón, use esta función para calcular TIR para fluxos de caixa que non son necesariamente periódicos.
Xeneralmente,se coñeces as datas exactas dos pagos, é recomendable utilizar XIRR porque proporciona unha mellor precisión de cálculo.
Comaremos, por exemplo, os resultados de IRR e XIRR para os mesmos fluxos de caixa:
Se todos os pagos ocorren a intervalos regulares , as funcións devolven resultados moi próximos:
Se o momento dos fluxos de caixa é desigual , a diferenza entre os resultados é bastante significativa:
XIRR e XNPV en Excel
XIRR está estreitamente relacionada coa función XNPV porque o O resultado de XIRR é a taxa de desconto que conduce a un valor actual neto cero. Noutras palabras, XIRR é XNPV = 0. O seguinte exemplo demostra a relación entre XIRR e XNPV en Excel.
Digamos que está a considerar algunha oportunidade de investimento e quere examinar tanto o valor actual neto como a taxa interna. de retorno deste investimento.
Cos fluxos de caixa en A2:A5, as datas en B2:B5 e a taxa de desconto en E1, a seguinte fórmula XNPV daralle o valor actual neto dos fluxos de caixa futuros:
=XNPV(E1, A2:A5, B2:B5)
Un VAN positivo indica que o proxecto é rendible:
Agora, imos atopar a taxa de desconto que fará que o valor actual neto cero. Para iso, utilizamos a función XIRR:
=XIRR(A2:A5, B2:B5)
Para comprobar se a taxa producida por XIRR realmente leva a un VPN cero, colócaa no argumento taxa de o teu XNPVfórmula:
=XNPV(E4, A2:A5, B2:B5)
Ou incorporar toda a función XIRR:
=XNPV(XIRR(A2:A5, B2:B5), A2:A5, B2:B5)
Si, o XNPV redondeado a 2 decimais é igual a cero:
Para mostrar o valor NPV exacto, escolla mostrar máis cifras decimais ou aplique o formato científico á cela XNPV. Isto producirá un resultado similar a este:
Se non estás familiarizado coa notación científica, realiza o seguinte cálculo para convertela nun número decimal:
1.11E-05 = 1.11*10^-5 = 0.0000111
A función XIRR de Excel non funciona
Se atopou un problema coa función XNPV en Excel, a continuación móstranse os puntos principais a comprobar.
#NUM ! error
É posible que se produza un erro #NUM polos seguintes motivos:
- Os intervalos de valores e datas teñen lonxitudes diferentes (diferentes número de columnas ou filas).
- A matriz valores non contén polo menos un valor positivo e un negativo.
- Calquera das datas posteriores é anterior á primeira. data.
- Non se atopa un resultado despois de 100 iteracións. Neste caso, proba cunha suposición diferente.
#VALOR! error
Un erro #VALUE pode ser causado polo seguinte:
- Calgún dos valores proporcionados non son numéricos.
- Algúns das datas fornecidas non se poden identificar como datas válidas de Excel.
Así é como calculas XIRR en Excel. Para ter unha ollada máis atenta ás fórmulas que se comentan neste tutorial, podes descargar a nosa mostracaderno de traballo a continuación. Grazas por ler e espero verte no noso blog a vindeira semana!
Caderno de prácticas para descargar
Modelo de Excel XIRR (ficheiro .xlsx)
