Tutorial pokazuje jak wykorzystać XIRR w Excelu do obliczenia wewnętrznej stopy zwrotu (IRR) dla przepływów pieniężnych o nieregularnych terminach oraz jak stworzyć własny kalkulator XIRR.

Kiedy stoisz przed decyzją wymagającą dużego kapitału, obliczenie wewnętrznej stopy zwrotu jest pożądane, ponieważ pozwala porównać przewidywane zyski dla różnych inwestycji i daje ilościową podstawę do podjęcia decyzji.

W poprzednim poradniku przyjrzeliśmy się, jak obliczyć wewnętrzną stopę zwrotu za pomocą funkcji IRR w Excelu. Metoda ta jest szybka i prosta, ale ma istotne ograniczenie - funkcja IRR zakłada, że wszystkie przepływy pieniężne występują w równych odstępach czasu, np. co miesiąc lub co rok. W rzeczywistych sytuacjach jednak wpływy i wypływy pieniężne często występują w nieregularnych odstępach czasu.Na szczęście Microsoft Excel ma inną funkcję, aby znaleźć IRR w takich przypadkach, a ten samouczek nauczy Cię, jak z niej korzystać.

Funkcja XIRR w programie Excel

Funkcja XIRR programu Excel zwraca wewnętrzną stopę zwrotu dla serii przepływów pieniężnych, które mogą być okresowe lub nie.

Funkcja została wprowadzona w programie Excel 2007 i jest dostępna we wszystkich późniejszych wersjach programów Excel 2010, Excel 2013, Excel 2016, Excel 2019 i Excel dla Office 365.

Składnia funkcji XIRR jest następująca:

Gdzie:

• Wartości (wymagane) - tablica lub zakres komórek, które reprezentują serię wpływów i wypływów.
• Daty (wymagane) - daty odpowiadające przepływom pieniężnym. Daty mogą występować w dowolnej kolejności, ale data początkowej inwestycji musi być pierwsza w tablicy.
• Guess (opcjonalnie) - oczekiwana stopa IRR podawana jako procent lub liczba dziesiętna. Jeśli zostanie pominięta, Excel używa domyślnej stopy 0,1 (10%).

Na przykład, aby obliczyć IRR dla serii przepływów pieniężnych w A2:A5 i dat w B2:B5, użyłbyś tego wzoru:

=XIRR(A2:A5, B2:B5)

Wskazówka: Aby wynik był wyświetlany prawidłowo, należy upewnić się, że Procent format jest ustawiony dla komórki formuły.

6 rzeczy, które powinieneś wiedzieć o funkcji XIRR

Poniższe uwagi pomogą Ci lepiej zrozumieć wewnętrzną mechanikę funkcji XIRR i najskuteczniej wykorzystać ją w swoich arkuszach.

1. XIRR w Excelu jest przeznaczony do obliczania wewnętrznej stopy zwrotu dla przepływów pieniężnych o nierównych terminach. W przypadku okresowych przepływów pieniężnych, których dokładne terminy płatności nie są znane, można użyć funkcji IRR.
2. Zakres wartości musi zawierać co najmniej jedną wartość dodatnią (przychód) i jedną ujemną (wypłata).
3. Jeżeli pierwszą wartością jest nakład (inwestycja początkowa), musi być ona reprezentowana przez liczbę ujemną. Inwestycja początkowa nie jest dyskontowana; kolejne płatności są sprowadzane do daty pierwszego przepływu pieniężnego i dyskontowane w oparciu o rok 365-dniowy.
4. Wszystkie daty są obcięte do liczb całkowitych, co oznacza, że część ułamkowa daty, która reprezentuje czas, jest usuwana.
5. Daty muszą być poprawnymi datami programu Excel wprowadzonymi jako odwołania do komórek zawierających daty lub wyniki formuł, takich jak funkcja DATA. Jeśli daty są wprowadzane w formacie tekstowym, mogą wystąpić problemy.
6. XIRR w Excelu zawsze zwraca wartość annualizowana wewnętrzna stopa zwrotu nawet przy obliczaniu miesięcznych lub tygodniowych przepływów pieniężnych.

Obliczanie XIRR w Excelu

Funkcja XIRR w Excelu wykorzystuje podejście prób i błędów, aby znaleźć stopę, która spełnia to równanie:

Gdzie:

• P - przepływ pieniężny (płatność)
• d - data
• i - numer okresu
• n - okresy ogółem

Rozpoczynając od zgadywania, jeśli zostało podane, lub od domyślnego 10%, jeśli nie, Excel przechodzi przez iteracje, aby uzyskać wynik z dokładnością do 0,000001%. Jeśli po 100 próbach nie zostanie znaleziony dokładny wskaźnik, zwracany jest błąd #NUM!

Aby sprawdzić poprawność tego równania, przetestujmy je z wynikiem formuły XIRR. Aby uprościć nasze obliczenia, będziemy używać następującej formuły tablicowej (proszę pamiętać, że każda formuła tablicowa musi być zakończona naciśnięciem klawiszy Ctrl + Shift + Enter ):

=SUM(A2:A5/((1+$E$1)^((B2:B5-$B$2)/365)))

Gdzie:

• A2:A5 są przepływami pieniężnymi
• B2:B5 to daty
• E1 jest stopą zwracaną przez XIRR

Jak widać na poniższym zrzucie ekranu, wynik jest bardzo bliski zeru. Q.E.D. :)

Jak obliczyć XIRR w Excelu - przykłady formuł

Poniżej znajduje się kilka przykładów, które pokazują powszechne zastosowania funkcji XIRR w Excelu.

Podstawowa formuła XIRR w Excelu

Załóżmy, że zainwestowałeś 1000 dolarów w 2017 roku i oczekujesz, że w ciągu najbliższych 6 lat otrzymasz pewien zysk. Aby znaleźć wewnętrzną stopę zwrotu dla tej inwestycji, użyj tego wzoru:

=XIRR(A2:A8, B2:B8)

Gdzie A2:A8 to przepływy pieniężne, a B2:B8 to daty odpowiadające przepływom pieniężnym:

Aby ocenić opłacalność tej inwestycji, porównaj wynik XIRR z wynikiem Twojej firmy średni ważony koszt kapitału lub podstawowa stopa procentowa Jeżeli stopa zwrotu jest wyższa niż koszt kapitału, to projekt można uznać za dobrą inwestycję.

Porównując kilka opcji inwestycyjnych, należy pamiętać, że prognozowana stopa zwrotu jest tylko jednym z czynników, które należy oszacować przed podjęciem decyzji. Więcej informacji można znaleźć w części Co to jest wewnętrzna stopa zwrotu (IRR)?

Pełna postać funkcji XIRR w Excelu

W przypadku, gdy wiesz, jakiego zwrotu spodziewasz się po tej lub innej inwestycji, możesz użyć swojego oczekiwania jako domysłu. Jest to szczególnie pomocne, gdy oczywiście poprawna formuła XIRR rzuca błąd #NUM!

Dla przedstawionego poniżej wejścia danych, formuła XIRR bez zgadywania zwraca błąd:

=XIRR(A2:A7, B2:B7)

Przewidywana stopa zwrotu (-20%) umieszczona w przypuszczenie argument pomaga Excelowi dojść do wyniku:

=XIRR(A2:A7, B2:B7, -20%)

Jak obliczyć XIRR dla miesięcznych przepływów pieniężnych

Na początek zapamiętaj to - niezależnie od tego, jakie przepływy pieniężne obliczasz, funkcja XIRR w Excelu produkuje roczna stopa zwrotu .

Aby się w tym upewnić, znajdźmy IRR dla tej samej serii przepływów pieniężnych (A2:A8), które występują co miesiąc i co rok (daty są w B2:B8):

=XIRR(A2:A8, B2:B8)

Jak widać na poniższym zrzucie ekranu, IRR zmienia się z 7,68% w przypadku rocznych przepływów pieniężnych do około 145% dla miesięcznych przepływów pieniężnych! Różnica wydaje się zbyt duża, aby uzasadnić ją wyłącznie czynnikiem wartości pieniądza w czasie:

Aby znaleźć przybliżoną miesięczna XIRR , można skorzystać z poniższego wyliczenia, gdzie E1 jest wynikiem zwykłego wzoru XIRR:

=(1+E1)^(1/12)-1

Możesz też osadzić XIRR bezpośrednio w równaniu:

=(1+XIRR(A2:A8,B2:B8))^(1/12)-1

Jako dodatkowe sprawdzenie, użyjmy funkcji IRR na tych samych przepływach pieniężnych. Należy pamiętać, że IRR również obliczy przybliżoną stopę, ponieważ zakłada, że wszystkie okresy czasu są równe:

=IRR(A2:A8)

W wyniku tych obliczeń otrzymujemy miesięczną stopę XIRR na poziomie 7,77%, która jest bardzo zbliżona do 7,68% uzyskanej ze wzoru IRR:

Wniosek : jeśli szukasz annualizowanej IRR dla miesięcznych przepływów pieniężnych, użyj funkcji XIRR w czystej postaci; aby uzyskać miesięczną IRR, zastosuj korektę opisaną powyżej.

Szablon XIRR w Excelu

Aby szybko uzyskać wewnętrzną stopę zwrotu dla różnych projektów, można utworzyć wszechstronny kalkulator XIRR dla programu Excel.Oto jak:

1. Wprowadź przepływy pieniężne i daty w dwóch indywidualnych kolumnach (A i B w tym przykładzie).
2. Utwórz dwa dynamicznie definiowane zakresy, o nazwach przepływy pieniężne oraz Daty Technicznie rzecz biorąc, będą to formuły nazwane:

   Cash_flows:

   =OFFSET(Sheet1!$A$2,0,0,COUNT(Sheet1!$A:$A),1)

   Daty:

   =OFFSET(Sheet1!$B$2,0,0,COUNT(Sheet1!$B:$B),1)

   Gdzie Plansza1. to nazwa Twojego arkusza, A2 to pierwszy przepływ pieniężny, a B2 to pierwsza data.

   Szczegółowe instrukcje krok po kroku znajdziesz w rozdziale Jak utworzyć dynamiczny zakres nazwany w programie Excel.

3. Dostarcz do formuły XIRR dynamicznie zdefiniowane nazwy, które stworzyłeś:

=XIRR(Cash_flows, Dates)

Teraz możesz dodać lub usunąć dowolną liczbę przepływów pieniężnych, a Twoja dynamiczna formuła XIRR zostanie odpowiednio przeliczona:

XIRR a IRR w Excelu

Główna różnica między funkcjami Excel XIRR i IRR jest taka:

• IRR Zakłada, że wszystkie okresy w serii przepływów pieniężnych są równe. Używasz tej funkcji, aby znaleźć wewnętrzną stopę zwrotu dla okresowych przepływów pieniężnych, takich jak miesięczne, kwartalne lub roczne.
• XIRR pozwala na przypisanie daty do każdego pojedynczego przepływu pieniężnego. Tak więc, należy użyć tej funkcji do obliczenia IRR dla przepływów pieniężnych, które niekoniecznie są okresowe.

Generalnie, jeśli znasz dokładne daty płatności, warto skorzystać z XIRR, ponieważ zapewnia on lepszą dokładność obliczeń.

Jako przykład porównajmy wyniki IRR i XIRR dla tych samych przepływów pieniężnych:

Jeżeli wszystkie płatności następują o godz. regularne odstępy , funkcje te zwracają bardzo zbliżone wyniki:

Jeżeli terminy przepływów pieniężnych są nierówny , różnica między wynikami jest dość znaczna:

XIRR i XNPV w Excelu

XIRR jest ściśle związana z funkcją XNPV, ponieważ wynikiem działania XIRR jest stopa dyskontowa, która prowadzi do zerowej wartości bieżącej netto. Innymi słowy, XIRR to XNPV = 0. Poniższy przykład demonstruje związek między XIRR i XNPV w programie Excel.

Powiedzmy, że rozważasz jakąś możliwość inwestycyjną i chcesz zbadać zarówno wartość bieżącą netto, jak i wewnętrzną stopę zwrotu z tej inwestycji.

Mając przepływy pieniężne w A2:A5, daty w B2:B5 i stopę dyskontową w E1, następujący wzór XNPV da Ci wartość bieżącą netto przyszłych przepływów pieniężnych:

=XNPV(E1, A2:A5, B2:B5)

Dodatnia NPV wskazuje, że projekt jest opłacalny:

Teraz znajdźmy, jaka stopa dyskontowa sprawi, że wartość bieżąca netto wyniesie zero. W tym celu wykorzystujemy funkcję XIRR:

=XIRR(A2:A5, B2:B5)

Aby sprawdzić, czy stopa uzyskana przez XIRR rzeczywiście prowadzi do zerowej NPV, umieść ją w stawka argument swojej formuły XNPV:

=XNPV(E4, A2:A5, B2:B5)

Albo osadzić całą funkcję XIRR:

=XNPV(XIRR(A2:A5, B2:B5), A2:A5, B2:B5)

Tak, XNPV zaokrąglone do 2 miejsc po przecinku jest równe zeru:

Aby wyświetlić dokładną wartość NPV, wybierz opcję pokazania większej liczby miejsc po przecinku lub zastosuj format naukowy do komórki XNPV. Dzięki temu uzyskasz wynik podobny do tego:

Jeśli nie znasz notacji naukowej, wykonaj poniższe obliczenia, aby przekonwertować ją na liczbę dziesiętną:

1.11E-05 = 1.11*10^-5 = 0.0000111

Funkcja XIRR w programie Excel nie działa

Jeśli natrafiłeś na problem z funkcją XNPV w programie Excel, poniżej znajdują się główne punkty do sprawdzenia.

#NUM! błąd

Błąd #NUM może wystąpić z następujących powodów:

• Na stronie wartości oraz daty zakresy mają różną długość (różną liczbę kolumn lub wierszy).
• Na stronie wartości tablica nie zawiera co najmniej jednej wartości dodatniej i jednej ujemnej.
• Każda z kolejnych dat jest wcześniejsza od daty pierwszej.
• Wynik nie został znaleziony po 100 iteracjach, w tym przypadku spróbuj innego domysłu.

#Błąd!

Błąd #VALUE może być spowodowany przez następujące elementy:

• Każdy z dostarczonych wartości są nienumeryczne.
• Niektóre z dostarczonych dat nie mogą być zidentyfikowane jako ważne daty Excela.

Tak właśnie oblicza się XIRR w Excelu. Aby przyjrzeć się bliżej formułom omawianym w tym tutorialu, zapraszamy do pobrania naszego przykładowego skoroszytu poniżej. Dziękuję za lekturę i mam nadzieję, że zobaczymy się na naszym blogu za tydzień!

Zeszyt ćwiczeń do pobrania

Szablon XIRR w Excelu (plik .xlsx)