Udhëzuesi tregon se si të përdorni XIRR në Excel për të llogaritur normën e brendshme të kthimit (IRR) për flukset monetare me kohë të parregullt dhe si të krijoni kalkulatorin tuaj XIRR.

Kur ju jeni përballur me një vendim me kapital intensiv, llogaritja e normës së brendshme të kthimit është e dëshirueshme sepse ju lejon të krahasoni kthimet e parashikuara për investime të ndryshme dhe jep një bazë sasiore për marrjen e vendimit.

Në tutorialin tonë të mëparshëm, ne shikuam se si të llogarisim normën e brendshme të kthimit me funksionin Excel IRR. Kjo metodë është e shpejtë dhe e drejtpërdrejtë, por ka një kufizim thelbësor – funksioni IRR supozon që të gjitha flukset monetare ndodhin në intervale të barabarta kohore, si p.sh. mujore ose vjetore. Megjithatë, në situatat e jetës reale, hyrjet dhe daljet e parave shpesh ndodhin në intervale të parregullta. Fatmirësisht, Microsoft Excel ka një funksion tjetër për të gjetur IRR në raste të tilla dhe ky tutorial do t'ju mësojë se si ta përdorni atë.

Funksioni XIRR në Excel

Excel XIRR funksioni kthen normën e brendshme të kthimit për një seri fluksesh monetare që mund të jenë ose jo periodike.

Funksioni u prezantua në Excel 2007 dhe është i disponueshëm në të gjitha versionet e mëvonshme të Excel 2010, Excel 2013, Excel 2016 , Excel 2019 dhe Excel për Office 365.

Sintaksa e funksionit XIRR është si më poshtë:

Ku:

• Vlerat (kërkohet) – angrup ose një varg qelizash që përfaqësojnë një sërë hyrjesh dhe daljesh.
• Data (kërkohet) – data që korrespondojnë me flukset monetare. Datat mund të ndodhin në çdo mënyrë, por data e investimit fillestar duhet të jetë e para në grup.
• Guess (opsionale) – një IRR e pritshme e dhënë si përqindje ose numër dhjetor. Nëse hiqet, Excel përdor normën e paracaktuar prej 0.1 (10%).

Për shembull, për të llogaritur IRR për serinë e flukseve monetare në A2:A5 dhe datat në B2:B5, do të përdorni këtë formulë:

=XIRR(A2:A5, B2:B5)

Këshillë. Që rezultati të shfaqet saktë, ju lutemi sigurohuni që formati Përqindja të jetë vendosur për qelizën e formulës.

6 gjëra që duhet të dini për funksionin XIRR

Shënimet e mëposhtme do t'ju ndihmojnë të kuptoni më mirë mekanikën e brendshme të funksionit XIRR dhe ta përdorni atë në fletët tuaja të punës në mënyrë më efikase.

1. XIRR në Excel është krijuar për llogaritjen e normës së brendshme të kthimit për flukset monetare me kohë të pabarabartë. Për flukse monetare periodike me data të sakta pagese të panjohura, mund të përdorni funksionin IRR.
2. Sfera e vlerave duhet të përmbajë të paktën një vlerë pozitive (të ardhura) dhe një vlerë negative (pagesë dalëse).
3. Nëse vlera e parë është një shpenzim (investim fillestar), ajo duhet të përfaqësohet me një numër negativ. Investimi fillestar nuk zbritet; pagesat e mëvonshme kthehen në datën e fluksit të parë të parasë dhe skontohen në bazënë një vit 365-ditor.
4. Të gjitha datat janë të shkurtuara në numra të plotë, që do të thotë se pjesa e pjesshme e një date që përfaqëson kohën është hequr.
5. Datat duhet të jenë data të vlefshme Excel të futura si referenca për qelizat që përmbajnë data ose rezultatet e formulave të tilla si funksioni DATE. Nëse datat futen në formatin e tekstit, mund të shfaqen probleme.
6. XIRR në Excel kthen gjithmonë një IRR të përvitshme edhe kur llogarit flukset monetare mujore ose javore.

Llogaritja XIRR në Excel

Funksioni XIRR në Excel përdor një qasje prove dhe gabimi për të gjetur shkallën që plotëson këtë ekuacion:

Ku:

• P - fluksi i parave (pagesa)
• d - data
• i - numri i periudhës
• n - periudha totale

Duke filluar me supozimin nëse ofrohet ose me parazgjedhjen 10% nëse jo, Excel kalon nëpër përsëritje për të arritur në rezultatin me saktësi 0.000001%. Nëse pas 100 përpjekjesh nuk gjendet një normë e saktë, #NUM! është kthyer gabimi.

Për të kontrolluar vlefshmërinë e këtij ekuacioni, le ta testojmë atë kundrejt rezultatit të formulës XIRR. Për të thjeshtuar llogaritjen tonë, ne do të përdorim formulën e mëposhtme të grupit (ju lutemi mbani mend se çdo formulë grupi duhet të plotësohet duke shtypur Ctrl + Shift + Enter):

=SUM(A2:A5/((1+$E$1)^((B2:B5-$B$2)/365)))

Where:

• A2:A5 janë flukset monetare
• B2:B5 janë datat
• E1 është norma e kthyer nga XIRR

Siç tregohet në Pamja e ekranit më poshtë, rezultati është shumë afërnë zero. Q.E.D. :)

Si të llogarisni XIRR në Excel – shembuj formulash

Më poshtë janë disa shembuj që demonstrojnë përdorimet e zakonshme të funksionit XIRR në Excel.

Formula bazë XIRR në Excel

Supozoni se keni investuar 1000 dollarë në 2017 dhe prisni të merrni një fitim në 6 vitet e ardhshme. Për të gjetur normën e brendshme të kthimit për këtë investim, përdorni këtë formulë:

=XIRR(A2:A8, B2:B8)

Ku A2:A8 janë flukset monetare dhe B2:B8 janë datat që korrespondojnë me flukset monetare:

Për të gjykuar përfitueshmërinë e këtij investimi, krahasoni produktin XIRR me kostoja mesatare e ponderuar e kapitalit ose norma e pengesës e kompanisë suaj. Nëse norma e kthimit është më e lartë se kostoja e kapitalit, projekti mund të konsiderohet një investim i mirë.

Kur krahasoni disa opsione investimi, mbani mend se një normë e parashikuar e kthimit është vetëm një nga faktorët që duhet të vlerësoni përpara se të merrni një vendim. Për më shumë informacion, ju lutemi shihni Cila është norma e brendshme e kthimit (IRR)?

Formulari i plotë i funksionit Excel XIRR

Në rast se e dini se çfarë lloj kthimi prisni nga ky apo ai investimi, ju mund të përdorni pritjet tuaja si një supozim. Është veçanërisht e dobishme kur një formulë dukshëm e saktë XIRR hedh një #NUM! gabim.

Për futjen e të dhënave të paraqitur më poshtë, një formulë XIRR pa supozimin kthen një gabim:

=XIRR(A2:A7, B2:B7)

Shkalla e kthimit të parashikuar(-20%) e vendosur në argumentin me mend ndihmon Excel të arrijë në rezultatin:

=XIRR(A2:A7, B2:B7, -20%)

Si të llogaritet XIRR për flukset mujore monetare

Për fillestarët, ju lutemi mbani mend këtë – çfarëdo fluksesh monetare që jeni duke llogaritur, funksioni Excel XIRR prodhon një normë vjetore të kthimit .

Për t'u siguruar që kjo, le të gjejmë IRR për të njëjtën seri fluksesh monetare (A2:A8) që ndodhin mujore dhe vjetore (datat janë në B2:B8):

=XIRR(A2:A8, B2:B8)

Siç mund ta shihni në në pamjen e mëposhtme të ekranit, IRR shkon nga 7.68% në rastin e flukseve vjetore të parasë në rreth 145% për flukset mujore të parasë! Diferenca duket shumë e lartë për t'u justifikuar vetëm nga faktori i vlerës në kohë të parasë:

Për të gjetur një XIRR mujore të përafërt , mund të përdorni sa më poshtë llogaritja, ku E1 është rezultati i formulës së rregullt XIRR:

=(1+E1)^(1/12)-1

Ose mund të futni XIRR direkt në ekuacionin:

=(1+XIRR(A2:A8,B2:B8))^(1/12)-1

Si një kontroll shtesë, le të përdorim funksionin IRR për të njëjtat flukse monetare. Ju lutemi mbani parasysh se IRR do të llogarisë gjithashtu një normë të përafërt sepse supozon të gjitha periudhat kohore të barabarta:

=IRR(A2:A8)

Si rezultat i këtyre llogaritjeve, marrim një XIRR mujore prej 7,77 %, që është shumë afër 7.68% e prodhuar nga formula IRR:

Përfundimi : nëse jeni duke kërkuar për një IRR vjetore për para mujore rrjedh, përdorni funksionin XIRR në formën e tij të pastër; për të marrë një IRR mujore, aplikonirregullimi i përshkruar më sipër.

Model Excel XIRR

Për të marrë shpejt normën e brendshme të kthimit për projekte të ndryshme, mund të krijoni një kalkulator të gjithanshëm XIRR për Excel. Ja se si:

1. Futni flukset monetare dhe datat në dy kolona individuale (A dhe B në këtë shembull).
2. Krijoni dy intervale dinamike të përcaktuara, të quajtura Flukset_monetare dhe Datat . Teknikisht, ato do të emërtohen formula:

   Flukset e parasë:

   =OFFSET(Sheet1!$A$2,0,0,COUNT(Sheet1!$A:$A),1)

   Datat:

   =OFFSET(Sheet1!$B$2,0,0,COUNT(Sheet1!$B:$B),1)

   Ku është Fleta1 emri i fletës suaj të punës, A2 është fluksi i parë i parasë dhe B2 është data e parë.

   Për udhëzimet e detajuara hap pas hapi, ju lutemi shihni Si të krijoni një diapazon dinamik me emër në Excel.

3. Furnizoni emrat e përcaktuar dinamikë që keni krijuar në formulën XIRR:

=XIRR(Cash_flows, Dates)

U krye! Tani mund të shtoni ose hiqni sa më shumë flukse monetare që dëshironi dhe formula juaj dinamike XIRR do të rillogaritet në përputhje me rrethanat:

XIRR kundrejt IRR në Excel

Dallimi kryesor midis funksioneve Excel XIRR dhe IRR është ky:

• IRR supozon se të gjitha periudhat në një seri fluksesh monetare janë të barabarta. Ju e përdorni këtë funksion për të gjetur normën e brendshme të kthimit për flukset monetare periodike si mujore, tremujore ose vjetore.
• XIRR ju lejon të caktoni një datë për çdo fluks monetar individual. Pra, përdorni këtë funksion për të llogaritur IRR për flukset monetare që nuk janë domosdoshmërisht periodike.

Në përgjithësi,nëse i dini datat e sakta të pagesave, këshillohet të përdorni XIRR sepse siguron saktësi më të mirë të llogaritjes.

Si shembull, le të krahasojmë rezultatet e IRR dhe XIRR për të njëjtat flukse monetare:

Nëse të gjitha pagesat ndodhin në intervale të rregullta , funksionet japin rezultate shumë të afërta:

Nëse koha e flukseve monetare është i pabarabartë , ndryshimi midis rezultateve është mjaft domethënës:

XIRR dhe XNPV në Excel

XIRR është i lidhur ngushtë me funksionin XNPV sepse rezultati i XIRR është norma e skontimit që çon në një vlerë aktuale neto zero. Me fjalë të tjera, XIRR është XNPV = 0. Shembulli i mëposhtëm tregon marrëdhënien midis XIRR dhe XNPV në Excel.

Le të themi se po konsideroni një mundësi investimi dhe dëshironi të ekzaminoni vlerën aktuale neto dhe normën e brendshme e kthimit të këtij investimi.

Me flukset monetare në A2:A5, datat në B2:B5 dhe normën e skontimit në E1, formula e mëposhtme XNPV do t'ju japë vlerën aktuale neto të flukseve monetare të ardhshme:

=XNPV(E1, A2:A5, B2:B5)

Një NPV pozitive tregon se projekti është fitimprurës:

Tani, le të gjejmë se çfarë norme skontimi do ta bëjë vlerën aktuale neto zero. Për këtë, ne përdorim funksionin XIRR:

=XIRR(A2:A5, B2:B5)

Për të kontrolluar nëse norma e prodhuar nga XIRR çon vërtet në një NPV zero, vendoseni atë në argumentin rate të XNPV-ja juajformula:

=XNPV(E4, A2:A5, B2:B5)

Ose futni të gjithë funksionin XIRR:

=XNPV(XIRR(A2:A5, B2:B5), A2:A5, B2:B5)

Po, XNPV e rrumbullakosur në 2 shifra dhjetore është e barabartë me zero:

Për të shfaqur vlerën e saktë NPV, zgjidhni të shfaqni më shumë shifra dhjetore ose aplikoni formatin shkencor në qelizën XNPV. Kjo do të prodhojë një rezultat të ngjashëm me këtë:

Nëse nuk jeni njohur me shënimin shkencor, kryeni llogaritjen e mëposhtme për ta kthyer atë në një numër dhjetor:

1.11E-05 = 1.11*10^-5 = 0.0000111

Funksioni Excel XIRR nuk funksionon

Nëse keni hasur në një problem me funksionin XNPV në Excel, më poshtë janë pikat kryesore për të kontrolluar.

#NUM ! gabim

Një gabim #NUM mund të ndodhë për arsyet e mëposhtme:

• Sferat vlerat dhe datat kanë gjatësi të ndryshme (të ndryshme numri i kolonave ose rreshtave).
• Sarreti vlerat nuk përmban të paktën një vlerë pozitive dhe një negative.
• Çdo nga datat e mëvonshme është më e hershme se e para datë.
• Nuk gjendet një rezultat pas 100 përsëritjeve. Në këtë rast, provo një supozim tjetër.

#VALUE! gabim

Një gabim #VALUE mund të shkaktohet nga sa vijon:

• Çdo nga vlerat të dhëna janë jo numerike.
• Disa nga datat e dhëna nuk mund të identifikohen si data të vlefshme Excel.

Kështu llogaritni XIRR në Excel. Për të parë më nga afër formulat e diskutuara në këtë tutorial, jeni të mirëpritur të shkarkoni mostrën tonëfletore pune më poshtë. Ju falënderoj që lexoni dhe shpresoj t'ju shohim në blogun tonë javën tjetër!

Praktikoni librin e punës për shkarkim

shabllon XIRR Excel (skedari .xlsx)