El tutorial muestra cómo utilizar XIRR en Excel para calcular la tasa interna de rentabilidad (TIR) de los flujos de caja con un calendario irregular y cómo hacer su propia calculadora XIRR.

Cuando nos enfrentamos a una decisión que requiere mucho capital, calcular la tasa interna de rentabilidad es conveniente porque nos permite comparar los rendimientos previstos para distintas inversiones y nos da una base cuantitativa para tomar la decisión.

En nuestro tutorial anterior, vimos cómo calcular la tasa interna de rentabilidad con la función TIR de Excel. Ese método es rápido y sencillo, pero tiene una limitación esencial: la función TIR supone que todos los flujos de caja se producen en intervalos de tiempo iguales, como mensuales o anuales. Sin embargo, en situaciones de la vida real, las entradas y salidas de caja suelen producirse a intervalos irregulares.Afortunadamente, Microsoft Excel dispone de otra función para hallar la TIR en estos casos, y este tutorial le enseñará a utilizarla.

Función XIRR en Excel

La función XIRR de Excel devuelve la tasa interna de rentabilidad de una serie de flujos de caja que pueden ser periódicos o no.

La función se introdujo en Excel 2007 y está disponible en todas las versiones posteriores de Excel 2010, Excel 2013, Excel 2016, Excel 2019 y Excel para Office 365.

La sintaxis de la función XIRR es la siguiente:

Dónde:

• Valores (obligatorio) - una matriz o un rango de celdas que representan una serie de entradas y salidas.
• Fechas (obligatorio) - fechas correspondientes a los flujos de caja. Las fechas pueden aparecer en cualquier orden, pero la fecha de la inversión inicial debe ser la primera de la matriz.
• Adivina (opcional) - una TIR esperada suministrada como porcentaje o número decimal. Si se omite, Excel utiliza la tasa por defecto de 0,1 (10%).

Por ejemplo, para calcular la TIR de la serie de flujos de caja de A2:A5 y las fechas de B2:B5, se utilizaría esta fórmula:

=XIRR(A2:A5, B2:B5)

Consejo: Para que el resultado se muestre correctamente, asegúrese de que el campo Porcentaje para la celda de la fórmula.

6 cosas que debes saber sobre la función XIRR

Las siguientes notas le ayudarán a comprender mejor la mecánica interna de la función XIRR y a utilizarla en sus hojas de cálculo de la forma más eficaz.

1. XIRR en Excel está diseñado para calcular la tasa interna de rendimiento para flujos de caja con calendario desigual. Para flujos de caja periódicos con fechas de pago exactas desconocidas, puede utilizar la función TIR.
2. El rango de valores debe contener al menos un valor positivo (ingreso) y uno negativo (salida de pago).
3. Si el primer valor es un desembolso (inversión inicial), debe representarse con un número negativo. La inversión inicial no se descuenta; los pagos posteriores se retrotraen a la fecha del primer flujo de caja y se descuentan sobre la base de un año de 365 días.
4. Todas las fechas se truncan a números enteros, lo que significa que se elimina la parte fraccionaria de una fecha que representa el tiempo.
5. Las fechas deben ser fechas válidas de Excel introducidas como referencias a celdas que contienen fechas o resultados de fórmulas como la función FECHA. Si las fechas se introducen en formato de texto, pueden producirse problemas.
6. XIRR en Excel siempre devuelve un TIR anualizada incluso al calcular los flujos de caja mensuales o semanales.

Cálculo de XIRR en Excel

La función XIRR de Excel utiliza un método de ensayo y error para encontrar la tasa que satisface esta ecuación:

Dónde:

• P - flujo de caja (pago)
• d - fecha
• i - número de período
• n - total de periodos

Comenzando con la suposición si se proporciona o con el 10% por defecto si no, Excel va a través de iteraciones para llegar al resultado con una precisión del 0,000001%. Si después de 100 intentos no se encuentra una tasa precisa, se devuelve el error #NUM!

Para comprobar la validez de esta ecuación, comparémosla con el resultado de la fórmula XIRR. Para simplificar nuestro cálculo, utilizaremos la siguiente fórmula de matriz (recuerde que cualquier fórmula de matriz debe completarse pulsando Ctrl + Mayús + Intro ):

=SUM(A2:A5/((1+$E$1)^((B2:B5-$B$2)/365)))

Dónde:

• A2:A5 son los flujos de caja
• B2:B5 son las fechas
• E1 es el tipo devuelto por la XIRR

Como se muestra en la siguiente captura de pantalla, el resultado es muy cercano a cero. Q.E.D. :)

Cómo calcular la XIRR en Excel - ejemplos de fórmulas

A continuación se presentan algunos ejemplos que demuestran los usos comunes de la función XIRR en Excel.

Fórmula básica XIRR en Excel

Supongamos que invirtió 1.000 $ en 2017 y espera recibir algún beneficio en los próximos 6 años. Para hallar la tasa interna de rentabilidad de esta inversión, utilice esta fórmula:

=XIRR(A2:A8, B2:B8)

Donde A2:A8 son los flujos de caja y B2:B8 son las fechas correspondientes a los flujos de caja:

Para juzgar la rentabilidad de esta inversión, compare el resultado de la XIRR con el de su empresa coste medio ponderado del capital o tasa crítica de rentabilidad Si la tasa de rentabilidad es superior al coste del capital, el proyecto puede considerarse una buena inversión.

Cuando compare varias opciones de inversión, recuerde que la tasa de rentabilidad prevista es sólo uno de los factores que debe estimar antes de tomar una decisión. Para más información, consulte ¿Qué es la tasa interna de rentabilidad (TIR)?

Forma completa de la función XIRR de Excel

En caso de que sepa qué tipo de rendimiento espera de tal o cual inversión, puede utilizar su expectativa como una suposición. Es especialmente útil cuando una fórmula XIRR obviamente correcta arroja un error #¡NUM!

Para la entrada de datos que se muestra a continuación, una fórmula XIRR sin la conjetura devuelve un error:

=XIRR(A2:A7, B2:B7)

La tasa de rentabilidad prevista (-20%) puesta en el adivina ayuda a Excel a obtener el resultado:

=XIRR(A2:A7, B2:B7, -20%)

Cómo calcular la XIRR para flujos de caja mensuales

Para empezar, recuerde lo siguiente: sean cuales sean los flujos de caja que esté calculando, la función XIRR de Excel produce un tasa de rendimiento anual .

Para asegurarnos de ello, vamos a hallar la TIR para la misma serie de flujos de caja (A2:A8) que se producen mensual y anualmente (las fechas están en B2:B8):

=XIRR(A2:A8, B2:B8)

Como puede verse en la siguiente captura de pantalla, la TIR pasa del 7,68% en el caso de los flujos de caja anuales a cerca del 145% en el caso de los flujos de caja mensuales. La diferencia parece demasiado elevada para justificarse únicamente por el factor del valor temporal del dinero:

Para encontrar un XIRR mensual puede utilizar el siguiente cálculo, en el que E1 es el resultado de la fórmula XIRR normal:

=(1+E1)^(1/12)-1

También puede incluir la XIRR directamente en la ecuación:

=(1+XIRR(A2:A8,B2:B8))^(1/12)-1

Como comprobación adicional, utilicemos la función TIR en los mismos flujos de caja. Tenga en cuenta que la TIR también calculará una tasa aproximada porque asume que todos los periodos de tiempo son iguales:

=IRR(A2:A8)

Como resultado de estos cálculos, obtenemos una TIRX mensual del 7,77%, muy próxima al 7,68% que arroja la fórmula de la TIR:

Conclusión si busca una TIR anualizada para flujos de caja mensuales, utilice la función XIRR en su forma pura; para obtener una TIR mensual, aplique el ajuste descrito anteriormente.

Plantilla Excel XIRR

Para obtener rápidamente la tasa interna de rentabilidad de distintos proyectos, puedes crear una versátil calculadora XIRR para Excel. A continuación te explicamos cómo:

1. Introduzca los flujos de caja y las fechas en dos columnas individuales (A y B en este ejemplo).
2. Cree dos rangos dinámicos definidos, denominados Flujos_de_efectivo y Fechas Técnicamente, serán fórmulas con nombre:

   Flujos_de_efectivo:

   =OFFSET(Hoja1!$A$2,0,0,COUNT(Hoja1!$A:$A),1)

   Fechas:

   =OFFSET(Hoja1!$B$2,0,0,COUNT(Hoja1!$B:$B),1)

   Dónde Hoja1 es el nombre de la hoja de cálculo, A2 es el primer flujo de caja y B2 es la primera fecha.

   Para obtener instrucciones detalladas paso a paso, consulte Cómo crear un rango dinámico con nombre en Excel.

3. Suministre los nombres dinámicos definidos que ha creado a la fórmula XIRR:

=XIRR(Flujos_de_efectivo, Fechas)

Ahora puede añadir o eliminar tantos flujos de caja como desee y su fórmula dinámica XIRR se recalculará en consecuencia:

XIRR vs. IRR en Excel

La principal diferencia entre las funciones XIRR e IRR de Excel es la siguiente:

• TIR supone que todos los períodos de una serie de flujos de caja son iguales. Esta función se utiliza para hallar la tasa interna de rentabilidad de flujos de caja periódicos, como mensuales, trimestrales o anuales.
• XIRR le permite asignar una fecha a cada flujo de caja individual. Por lo tanto, utilice esta función para calcular la TIR para flujos de caja que no sean necesariamente periódicos.

Por lo general, si conoce las fechas exactas de los pagos, es aconsejable utilizar la XIRR porque proporciona una mayor precisión de cálculo.

A modo de ejemplo, comparemos los resultados de la TIR y la TIRX para los mismos flujos de caja:

Si todos los pagos se producen en intervalos regulares las funciones arrojan resultados muy parecidos:

Si el calendario de los flujos de caja es desigual la diferencia entre los resultados es bastante significativa:

XIRR y XNPV en Excel

XIRR está estrechamente relacionada con la función XNPV porque el resultado de XIRR es la tasa de descuento que conduce a un valor actual neto cero. En otras palabras, XIRR es XNPV = 0. El siguiente ejemplo demuestra la relación entre XIRR y XNPV en Excel.

Supongamos que está considerando una oportunidad de inversión y quiere examinar tanto el valor actual neto como la tasa interna de rentabilidad de esta inversión.

Con los flujos de caja en A2:A5, las fechas en B2:B5 y el tipo de descuento en E1, la siguiente fórmula XNPV le dará el valor actual neto de los flujos de caja futuros:

=XNPV(E1, A2:A5, B2:B5)

Un VAN positivo indica que el proyecto es rentable:

Ahora, vamos a averiguar qué tipo de descuento hará que el valor actual neto sea cero. Para ello, utilizamos la función XIRR:

=XIRR(A2:A5, B2:B5)

Para comprobar si la tasa producida por XIRR conduce realmente a un VAN cero, colóquela en el tarifa argumento de su fórmula XNPV:

=XNPV(E4, A2:A5, B2:B5)

O incrustar toda la función XIRR:

=XNPV(XIRR(A2:A5, B2:B5), A2:A5, B2:B5)

Sí, el XNPV redondeado a 2 decimales es igual a cero:

Para mostrar el valor exacto del VAN, elija mostrar más decimales o aplique el formato Científico a la celda XNPV. Eso producirá un resultado similar a éste:

Si no estás familiarizado con la notación científica, realiza el siguiente cálculo para convertirlo en un número decimal:

1.11E-05 = 1.11*10^-5 = 0.0000111

La función XIRR de Excel no funciona

Si se ha encontrado con un problema con la función XNPV en Excel, a continuación se indican los principales puntos que debe comprobar.

¡Error #NUM!

Puede producirse un error #NUM por los siguientes motivos:

• En valores y fechas Los rangos tienen diferentes longitudes (diferente número de columnas o filas).
• En valores no contiene al menos un valor positivo y uno negativo.
• Cualquiera de las fechas posteriores es anterior a la primera.
• No se encuentra un resultado después de 100 iteraciones. En este caso, pruebe con una suposición diferente.

#Error

Un error #VALOR puede ser causado por lo siguiente:

• Cualquiera de los valores no son numéricos.
• Algunas de las fechas suministradas no pueden identificarse como fechas válidas de Excel.

Así es como se calcula la XIRR en Excel. Para ver más de cerca las fórmulas tratadas en este tutorial, te invito a descargar nuestro libro de trabajo de ejemplo a continuación. Te doy las gracias por leer y ¡espero verte en nuestro blog la semana que viene!

Cuaderno de prácticas para descargar

Plantilla Excel XIRR (archivo .xlsx)