Die tutoriaal wys hoe om XIRR in Excel te gebruik om die interne opbrengskoers (IRR) vir kontantvloei met onreëlmatige tydsberekening te bereken en hoe om jou eie XIRR-sakrekenaar te maak.

Wanneer jy voor 'n kapitaalintensiewe besluit te staan ​​kom, is die berekening van die interne opbrengskoers wenslik, want dit laat jou die geprojekteerde opbrengste vir verskillende beleggings vergelyk en gee 'n kwantitatiewe basis om die besluit te neem.

In ons vorige tutoriaal, ons het gekyk hoe om die interne opbrengskoers met die Excel IRR-funksie te bereken. Daardie metode is vinnig en eenvoudig, maar dit het 'n wesenlike beperking – die IRR-funksie neem aan dat alle kontantvloei op gelyke tydsintervalle plaasvind, soos maandeliks of jaarliks. In werklike situasies vind kontantinvloei en -uitvloei egter dikwels met onreëlmatige tussenposes plaas. Gelukkig het Microsoft Excel nog 'n funksie om IRR in sulke gevalle te vind, en hierdie tutoriaal sal jou leer hoe om dit te gebruik.

XIRR-funksie in Excel

Die Excel XIRR funksie gee die interne opbrengskoers vir 'n reeks kontantvloeie wat periodiek mag of nie mag wees nie.

Die funksie is in Excel 2007 bekendgestel en is beskikbaar in alle latere weergawes van Excel 2010, Excel 2013, Excel 2016 , Excel 2019 en Excel vir Office 365.

Die sintaksis van die XIRR-funksie is soos volg:

Waar:

• Waardes (vereis) – anskikking of 'n reeks selle wat 'n reeks invloeie en uitvloeie verteenwoordig.
• Datums (vereis) – datums wat met kontantvloei ooreenstem. Datums kan in enige volgorde voorkom, maar die datum van die aanvanklike belegging moet eerste in die skikking wees.
• Raai (opsioneel) – 'n verwagte IRR verskaf as 'n persentasie of desimale getal. As dit weggelaat word, gebruik Excel die verstekkoers van 0.1 (10%).

Om byvoorbeeld IRR vir die reeks kontantvloeie in A2:A5 en datums in B2:B5 te bereken, sal jy gebruik hierdie formule:

=XIRR(A2:A5, B2:B5)

Wenk. Vir die resultaat om korrek te vertoon, maak asseblief seker dat die Persentasie -formaat vir die formulesel gestel is.

6 dinge wat jy oor XIRR-funksie moet weet

Die volgende aantekeninge sal jou help om die innerlike meganika van die XIRR-funksie beter te verstaan ​​en dit die doeltreffendste in jou werkblaaie te gebruik.

1. XIRR in Excel is ontwerp vir die berekening van die interne opbrengskoers vir kontantvloei met ongelyke tydsberekening. Vir periodieke kontantvloeie met presiese betalingsdatums onbekend, kan jy die IRR-funksie gebruik.
2. Die reeks waardes moet ten minste een positiewe (inkomste) en een negatiewe (uitgaande betaling) waarde bevat.
3. As die eerste waarde 'n uitgawe (aanvanklike belegging) is, moet dit deur 'n negatiewe getal voorgestel word. Die aanvanklike belegging word nie verdiskonteer nie; daaropvolgende betalings word teruggebring na die datum van die eerste kontantvloei en verdiskonteer gebaseerop 'n 365-dae jaar.
4. Alle datums word afgekap tot heelgetalle, wat beteken dat die breukdeel van 'n datum wat tyd verteenwoordig verwyder word.
5. Datums moet geldige Excel-datums wees wat ingevoer word as verwysings na selle wat datums of resultate van formules soos die DATUM-funksie bevat. As datums in die teksformaat ingevoer word, kan probleme voorkom.
6. XIRR in Excel gee altyd 'n jaarlikse IRR terug, selfs wanneer maandelikse of weeklikse kontantvloei bereken word.

XIRR-berekening in Excel

Die XIRR-funksie in Excel gebruik 'n proef-en-foutbenadering om die koers te vind wat aan hierdie vergelyking voldoen:

Waar:

• P - kontantvloei (betaling)
• d - datum
• i - periodenommer
• n - periodes totaal

Begin met die raaiskoot as verskaf of met die verstek 10% indien nie, Excel gaan deur iterasies om by die resultaat te kom met 0,000001% akkuraatheid. As 'n akkurate koers na 100 pogings nie gevind word nie, sal die #NUM! fout word teruggestuur.

Om die geldigheid van hierdie vergelyking na te gaan, kom ons toets dit teen die resultaat van die XIRR-formule. Om ons berekening te vereenvoudig, sal ons die volgende skikkingsformule gebruik (onthou asseblief dat enige skikkingsformule voltooi moet word deur Ctrl + Shift + Enter te druk):

=SUM(A2:A5/((1+$E$1)^((B2:B5-$B$2)/365)))

Waar:

• A2:A5 is die kontantvloei
• B2:B5 is die datums
• E1 is die koers wat deur XIRR teruggegee word

Soos getoon in die kiekie hieronder, die resultaat is baie nabytot nul. V.E.D. :)

Hoe om XIRR in Excel te bereken – formulevoorbeelde

Hieronder is 'n paar voorbeelde wat die algemene gebruike van die XIRR-funksie in Excel demonstreer.

Basiese XIRR-formule in Excel

Gestel jy het $1 000 in 2017 belê en verwag om 'n bietjie wins in die volgende 6 jaar te ontvang. Om die interne opbrengskoers vir hierdie belegging te vind, gebruik hierdie formule:

=XIRR(A2:A8, B2:B8)

Waar A2:A8 kontantvloei is en B2:B8 die datums is wat ooreenstem met die kontantvloei:

Om die winsgewendheid van hierdie belegging te oordeel, vergelyk die XIRR-uitset met jou maatskappy se geweegde gemiddelde koste van kapitaal of hekkieskoers . As die opbrengskoers hoër is as die koste van kapitaal, kan die projek as 'n goeie belegging beskou word.

Wanneer jy verskeie beleggingsopsies vergelyk, onthou asseblief dat 'n geprojekteerde opbrengskoers net een van die faktore is wat jy moet skat voordat 'n besluit geneem word. Vir meer inligting, sien asseblief Wat is die interne opbrengskoers (IRR)?

Volledige vorm van Excel XIRR-funksie

In geval jy weet watter soort opbrengs jy van hierdie of daardie verwag belegging, kan jy jou verwagting as 'n raaiskoot gebruik. Dit is veral nuttig wanneer 'n duidelik korrekte XIRR-formule 'n #NUM gooi! fout.

Vir die data-invoer wat hieronder getoon word, gee 'n XIRR-formule sonder die raai 'n fout:

=XIRR(A2:A7, B2:B7)

Die verwagte opbrengskoers(-20%) sit die raai -argument in, help Excel om by die resultaat uit te kom:

=XIRR(A2:A7, B2:B7, -20%)

Hoe om XIRR te bereken vir maandelikse kontantvloei

Om mee te begin, onthou asseblief dit – watter kontantvloei jy ook al bereken, die Excel XIRR-funksie lewer 'n jaarlikse opbrengskoers .

Om seker te maak van dit, kom ons vind IRR vir dieselfde reeks kontantvloeie (A2:A8) wat maandeliks en jaarliks ​​voorkom (die datums is in B2:B8):

=XIRR(A2:A8, B2:B8)

Soos jy kan sien in die onderstaande skermkiekie, die IRR gaan van 7.68% in die geval van jaarlikse kontantvloei tot ongeveer 145% vir maandelikse kontantvloei! Die verskil lyk te hoog om geregverdig te word deur die tydwaarde van geldfaktor alleen:

Om 'n benaderde maandelikse XIRR te vind, kan jy die onderstaande gebruik berekening, waar E1 die resultaat is van die gereelde XIRR-formule:

=(1+E1)^(1/12)-1

Of jy kan XIRR direk in die vergelyking insluit:

=(1+XIRR(A2:A8,B2:B8))^(1/12)-1

As 'n bykomende tjek, kom ons gebruik die IRR-funksie op dieselfde kontantvloei. Hou asseblief in gedagte dat IRR ook 'n benaderde koers sal bereken omdat dit aanvaar dat al die tydperke gelyk is:

=IRR(A2:A8)

As die resultaat van hierdie berekeninge, kry ons 'n maandelikse XIRR van 7.77 %, wat baie naby aan 7.68% is wat deur die IRR-formule geproduseer word:

Die gevolgtrekking : as jy op soek is na 'n geannualiseerde IRR vir maandelikse kontant vloei, gebruik die XIRR-funksie in sy suiwer vorm; om 'n maandelikse IRR te kry, doen aansoekdie aanpassing hierbo beskryf.

Excel XIRR-sjabloon

Om vinnig die interne opbrengskoers vir verskillende projekte te kry, kan jy 'n veelsydige XIRR-sakrekenaar vir Excel skep. Hier is hoe:

1. Voer die kontantvloeie en datums in twee individuele kolomme in (A en B in hierdie voorbeeld).
2. Skep twee dinamiese gedefinieerde reekse, genaamd Kontantvloei en Datums . Tegnies sal dit formules genoem word:

   Kontantvloei:

   =OFFSET(Sheet1!$A$2,0,0,COUNT(Sheet1!$A:$A),1)

   Datums:

   =OFFSET(Sheet1!$B$2,0,0,COUNT(Sheet1!$B:$B),1)

   Waar Blad1 is die naam van jou werkblad, A2 is die eerste kontantvloei, en B2 is die eerste datum.

   Vir die gedetailleerde stap-vir-stap-instruksies, sien asseblief Hoe om 'n dinamiese benoemde reeks in Excel te skep.

3. Voorsien die dinamiese gedefinieerde name wat jy geskep het aan die XIRR-formule:

=XIRR(Cash_flows, Dates)

Klaar! Jy kan nou soveel kontantvloeie byvoeg of verwyder as wat jy wil, en jou dinamiese XIRR-formule sal dienooreenkomstig herbereken:

XIRR vs. IRR in Excel

Die belangrikste verskil tussen Excel XIRR en IRR funksies is dit:

• IRR neem aan dat al die tydperke in 'n reeks kontantvloei gelyk is. Jy gebruik hierdie funksie om die interne opbrengskoers vir periodieke kontantvloeie soos maandeliks, kwartaalliks of jaarliks ​​te vind.
• XIRR laat jou toe om 'n datum aan elke individuele kontantvloei toe te ken. Dus, gebruik hierdie funksie om IRR te bereken vir kontantvloeie wat nie noodwendig periodiek is nie.

Algemeen,as jy die presiese datums van die betalings ken, is dit raadsaam om XIRR te gebruik, want dit bied beter berekeningsakkuraatheid.

As 'n voorbeeld, kom ons vergelyk die resultate van IRR en XIRR vir dieselfde kontantvloei:

As al die betalings met gereelde intervalle plaasvind, gee die funksies baie naby resultate:

As die tydsberekening van kontantvloei is ongelyk , is die verskil tussen die resultate redelik betekenisvol:

XIRR en XNPV in Excel

XIRR is nou verwant aan die XNPV-funksie omdat die resultaat van XIRR is die verdiskonteringskoers wat lei tot 'n nul netto huidige waarde. Met ander woorde, XIRR is XNPV = 0. Die volgende voorbeeld demonstreer die verhouding tussen XIRR en XNPV in Excel.

Kom ons sê jy oorweeg een of ander beleggingsgeleentheid en wil beide die netto huidige waarde en die interne koers ondersoek van opbrengs op hierdie belegging.

Met die kontantvloeie in A2:A5, datums in B2:B5 en die verdiskonteringskoers in E1, sal die volgende XNPV-formule vir jou die netto huidige waarde van die toekomstige kontantvloei gee:

=XNPV(E1, A2:A5, B2:B5)

'n Positiewe NHW dui aan dat die projek winsgewend is:

Kom ons kyk nou watter verdiskonteringskoers die netto huidige waarde sal maak nul. Hiervoor gebruik ons ​​die XIRR-funksie:

=XIRR(A2:A5, B2:B5)

Om te kyk of die koers wat deur XIRR geproduseer word werklik tot 'n nul NPV lei, plaas dit in die koers -argument van jou XNPVformule:

=XNPV(E4, A2:A5, B2:B5)

Of sluit die hele XIRR-funksie in:

=XNPV(XIRR(A2:A5, B2:B5), A2:A5, B2:B5)

Jip, die XNPV afgerond tot 2 desimale plekke is gelyk aan nul:

Om die presiese NPV-waarde te vertoon, kies om meer desimale plekke te wys of pas die Wetenskaplike formaat op die XNPV-sel toe. Dit sal 'n resultaat soortgelyk aan hierdie lewer:

As jy nie vertroud is met die wetenskaplike notasie nie, voer die volgende berekening uit om dit na 'n desimale getal om te skakel:

1.11E-05 = 1.11*10^-5 = 0.0000111

Excel XIRR-funksie werk nie

As jy 'n probleem met die XNPV-funksie in Excel ondervind het, hieronder is die hoofpunte om na te gaan.

#NUM ! fout

'n #NUM-fout kan voorkom as gevolg van die volgende redes:

• Die waardes en datums reekse het verskillende lengtes (verskillende aantal kolomme of rye).
• Die waardes -skikking bevat nie ten minste een positiewe en een negatiewe waarde nie.
• Enige van die daaropvolgende datums is vroeër as die eerste datum.
• 'n Resultaat word nie gevind na 100 iterasies nie. Probeer in hierdie geval 'n ander raaiskoot.

#VALUE! fout

'n #VALUE-fout kan deur die volgende veroorsaak word:

• Enige van die verskafde waardes is nie-numeries.
• Sommige van die verskafde datums kan nie as geldige Excel-datums geïdentifiseer word nie.

Dis hoe jy XIRR in Excel bereken. Om die formules wat in hierdie tutoriaal bespreek word nader te kyk, is u welkom om ons voorbeeld af te laaiwerkboek hieronder. Ek bedank jou vir die lees en hoop om jou volgende week op ons blog te sien!

Oefenwerkboek om af te laai

XIRR Excel-sjabloon (.xlsx-lêer)