Yo'riqnoma Excelda XIRR-dan qanday qilib tartibsiz vaqtli pul oqimlari uchun ichki daromad stavkasini (IRR) hisoblash va XIRR kalkulyatoringizni qanday yaratishni ko'rsatadi.

Qachon Siz kapitalni ko'p talab qiladigan qarorga duch kelasiz, ichki daromad stavkasini hisoblash maqsadga muvofiqdir, chunki u turli investitsiyalar bo'yicha rejalashtirilgan daromadlarni solishtirish imkonini beradi va qaror qabul qilish uchun miqdoriy asos beradi.

Oldingi darsimizda, biz Excel IRR funksiyasi bilan ichki daromad stavkasini qanday hisoblashni ko'rib chiqdik. Bu usul tez va tushunarli, ammo uning muhim cheklovi bor - IRR funktsiyasi barcha pul oqimlari oylik yoki yillik kabi teng vaqt oralig'ida sodir bo'lishini nazarda tutadi. Haqiqiy hayotda esa, pul mablag'larining kirib kelishi va chiqishi ko'pincha tartibsiz vaqt oralig'ida sodir bo'ladi. Yaxshiyamki, Microsoft Excel-da bunday hollarda IRR-ni topish uchun yana bir funksiya bor va bu qo‘llanma uni qanday ishlatishni o‘rgatadi.

Excel-dagi XIRR funksiyasi

Excel XIRR funktsiya davriy bo'lishi mumkin bo'lgan yoki bo'lmasligi mumkin bo'lgan bir qator pul oqimlari uchun ichki daromad stavkasini qaytaradi.

Funktsiya Excel 2007 da joriy qilingan va Excel 2010, Excel 2013, Excel 2016 ning barcha keyingi versiyalarida mavjud. , Excel 2019 va Office 365 uchun Excel.

XIRR funksiyasining sintaksisi quyidagicha:

Bu yerda:

• Qiymatlar (majburiy) – anmassiv yoki bir qator kirish va chiqishlarni ifodalovchi hujayralar diapazoni.
• Sanalar (zarur) – pul oqimlariga mos keladigan sanalar. Sanalar har qanday tartibda bo'lishi mumkin, lekin boshlang'ich investitsiya sanasi massivda birinchi bo'lishi kerak.
• Tasavvur qiling (ixtiyoriy) – foiz yoki kasr soni sifatida taqdim etilgan kutilgan IRR. Agar o'tkazib yuborilmagan bo'lsa, Excel standart 0,1 (10%) stavkasini ishlatadi.

Masalan, A2:A5 va B2:B5 sanalaridagi pul oqimlari qatori uchun IRRni hisoblash uchun siz ushbu formuladan foydalaning:

=XIRR(A2:A5, B2:B5)

Maslahat. Natija to'g'ri ko'rsatilishi uchun formula katakchasi uchun Foiz formati o'rnatilganligiga ishonch hosil qiling.

XIRR funksiyasi haqida bilishingiz kerak bo'lgan 6 ta narsa

Quyidagi eslatmalar XIRR funksiyasining ichki mexanikasini yaxshiroq tushunishga va undan ish varaqlarida eng samarali foydalanishga yordam beradi.

1. Excel-dagi XIRR teng bo'lmagan vaqt bilan pul oqimlari uchun ichki daromadlilik darajasini hisoblash uchun mo'ljallangan. Aniq toʻlov sanalari nomaʼlum boʻlgan davriy pul oqimlari uchun siz IRR funksiyasidan foydalanishingiz mumkin.
2. Qiymatlar oraligʻida kamida bitta ijobiy (daromad) va bitta salbiy (chiqish toʻlovi) qiymat boʻlishi kerak.
3. Agar birinchi qiymat xarajatlar (dastlabki investitsiyalar) bo'lsa, u manfiy raqam bilan ifodalanishi kerak. Dastlabki investitsiyalar diskontlanmaydi; keyingi to'lovlar birinchi pul oqimi sanasiga qaytariladi va diskontlanadi365 kunlik yilda.
4. Barcha sanalar butun sonlarga qisqartiriladi, ya'ni sananing vaqtni bildiruvchi kasr qismi olib tashlanadi.
5. Sanalar havola sifatida kiritilgan to'g'ri Excel sanalari bo'lishi kerak. DATE funksiyasi kabi sanalar yoki formulalar natijalarini o'z ichiga olgan hujayralar. Agar sanalar matn formatida kiritilsa, muammolar yuzaga kelishi mumkin.
6. Excel'dagi XIRR har doim oylik yoki haftalik pul oqimlarini hisoblashda ham yillik IRR ni qaytaradi.

Excel’da XIRR hisobi

Excel’dagi XIRR funksiyasi ushbu tenglamani qanoatlantiradigan tezlikni topish uchun sinov va xato usulidan foydalanadi:

Bu yerda:

• P - pul oqimi (to'lov)
• d - sana
• i - davr raqami
• n - davrlar jami

Taxmindan boshlab, agar taqdim etilgan bo'lsa yoki standart 10% bo'lmasa, Excel 0,000001% aniqlik bilan natijaga erishish uchun iteratsiyalardan o'tadi. Agar 100 ta urinishdan keyin aniq raqam topilmasa, #NUM! xato qaytariladi.

Ushbu tenglamaning to'g'riligini tekshirish uchun uni XIRR formulasi natijasi bilan sinab ko'raylik. Hisoblashni soddalashtirish uchun biz quyidagi massiv formulasidan foydalanamiz (iltimos, esda tutingki, har qanday massiv formulasi Ctrl + Shift + Enter tugmalarini bosib to‘ldirilishi kerak):

=SUM(A2:A5/((1+$E$1)^((B2:B5-$B$2)/365)))

Bu yerda:

• A2:A5 - pul oqimlari
• B2:B5 - sanalar
• E1 - XIRR tomonidan qaytarilgan stavka

Ko'rsatilgandek quyidagi skrinshot, natija juda yaqinnolga. Q.E.D. :)

Excelda XIRRni qanday hisoblash mumkin – formula misollari

Quyida Excelda XIRR funksiyasidan umumiy foydalanishni koʻrsatadigan bir nechta misollar keltirilgan.

Excel-dagi XIRR-ning asosiy formulasi

Aytaylik, siz 2017-yilda 1000 dollar sarmoya kiritdingiz va keyingi 6 yil ichida biroz foyda olishni kutyapsiz. Ushbu investitsiyaning ichki daromadlilik darajasini topish uchun quyidagi formuladan foydalaning:

=XIRR(A2:A8, B2:B8)

Bu erda A2:A8 pul oqimlari va B2:B8 pul oqimlariga mos keladigan sanalar:

Ushbu sarmoyaning rentabelligini baholash uchun XIRR mahsulotini kompaniyangizning kapitalning oʻrtacha oʻrtacha qiymati yoki toʻsiqlar darajasi bilan solishtiring. Qaytarilgan stavka kapital qiymatidan yuqori bo'lsa, loyihani yaxshi investitsiya deb hisoblash mumkin.

Bir nechta investitsiya variantlarini solishtirganda, esda tutingki, prognoz qilingan daromad darajasi siz taxmin qilishingiz kerak bo'lgan omillardan faqat biri hisoblanadi. qaror qabul qilishdan oldin. Qo'shimcha ma'lumot olish uchun qarang: Ichki daromad darajasi (IRR) nima?

Excel XIRR funksiyasining to'liq shakli

Agar siz u yoki bu narsadan qanday daromad kutayotganingizni bilsangiz investitsiya, siz taxmin sifatida o'zingizning taxminlaringizdan foydalanishingiz mumkin. Bu, ayniqsa, aniq to'g'ri XIRR formulasi #NUM! xato.

Quyida ko'rsatilgan ma'lumotlarni kiritish uchun, taxminsiz XIRR formulasi xatoni qaytaradi:

=XIRR(A2:A7, B2:B7)

Kutilayotgan qaytish tezligi(-20%) taxmin qilish argumenti Excelga natijaga erishishga yordam beradi:

=XIRR(A2:A7, B2:B7, -20%)

XIRRni qanday hisoblash mumkin oylik pul oqimlari

Yangi boshlanuvchilar uchun buni esda tuting – siz hisoblayotgan pul oqimlaridan qat'i nazar, Excel XIRR funksiyasi yillik daromad stavkasini ishlab chiqaradi.

Ishonch hosil qilish uchun Buning uchun oylik va yillik (sanalar B2:B8 da) sodir bo'ladigan bir xil pul oqimlari seriyasi (A2:A8) uchun IRR ni topamiz:

=XIRR(A2:A8, B2:B8)

Ko'rib turganingizdek Quyidagi skrinshotda yillik pul oqimlari uchun IRR 7,68% dan oylik pul oqimlari uchun taxminan 145% gacha boradi! Farqni faqat pul omilining vaqt qiymati bilan oqlash uchun juda katta ko'rinadi:

Taxminan oylik XIRR ni topish uchun siz quyidagidan foydalanishingiz mumkin. hisoblash, bu erda E1 oddiy XIRR formulasining natijasidir:

=(1+E1)^(1/12)-1

Yoki siz XIRRni to'g'ridan-to'g'ri tenglamaga kiritishingiz mumkin:

=(1+XIRR(A2:A8,B2:B8))^(1/12)-1

As qo'shimcha tekshirish, keling, bir xil pul oqimlarida IRR funktsiyasidan foydalanamiz. Shuni yodda tutingki, IRR ham taxminiy stavkani hisoblaydi, chunki u barcha vaqt davrlarini teng deb hisoblaydi:

=IRR(A2:A8)

Ushbu hisob-kitoblar natijasida biz oylik XIRR 7,77 ni olamiz. %, bu IRR formulasi bo'yicha ishlab chiqarilgan 7,68% ga juda yaqin:

Xulosa : agar siz oylik naqd pul uchun yillik IRRni qidirsangiz oqimlar, XIRR funktsiyasidan sof shaklda foydalaning; oylik IRR olish uchun murojaat qilingyuqorida tavsiflangan sozlash.

Excel XIRR shabloni

Turli loyihalar uchun daromadning ichki tezligini tezda olish uchun siz Excel uchun ko'p qirrali XIRR kalkulyatorini yaratishingiz mumkin. Mana shunday:

1. Naqd pul oqimlari va sanalarini ikkita alohida ustunga kiriting (bu misolda A va B).
2. Pul_oqimlari<2 deb nomlangan ikkita dinamik belgilangan diapazon yarating> va Sanalar . Texnik jihatdan, bu formulalar deb nomlanadi:

   Pul oqimlari:

   =OFFSET(Sheet1!$A$2,0,0,COUNT(Sheet1!$A:$A),1)

   Sanalar:

   =OFFSET(Sheet1!$B$2,0,0,COUNT(Sheet1!$B:$B),1)

   Bu erda Varaq1 ish varaqingiz nomi, A2 birinchi pul oqimi, B2 esa birinchi sana.

   Batafsil bosqichma-bosqich ko'rsatmalar uchun Excelda dinamik nomli diapazonni qanday yaratish bo'limiga qarang.

3. XIRR formulasiga yaratgan dinamik belgilangan nomlarni kiriting:

=XIRR(Cash_flows, Dates)

Bajarildi! Endi siz xohlagancha pul oqimlarini qo'shishingiz yoki olib tashlashingiz mumkin va sizning dinamik XIRR formulangiz mos ravishda qayta hisoblab chiqiladi:

Excel'dagi XIRR va IRR

Excel XIRR va IRR funktsiyalari o'rtasidagi asosiy farq quyidagilardan iborat:

• IRR pul oqimlari qatoridagi barcha davrlar teng deb hisoblanadi. Siz bu funksiyadan oylik, choraklik yoki yillik kabi davriy pul oqimlarining ichki daromadlilik stavkasini topish uchun foydalanasiz.
• XIRR har bir alohida pul oqimiga sana belgilash imkonini beradi. Shunday qilib, davriy bo'lishi shart bo'lmagan pul oqimlari uchun IRRni hisoblash uchun ushbu funksiyadan foydalaning.

Umuman olganda,Agar siz toʻlovlarning aniq sanalarini bilsangiz, XIRR dan foydalanish tavsiya etiladi, chunki u yaxshi hisoblash aniqligini taʼminlaydi.

Misol sifatida, xuddi shu pul oqimlari uchun IRR va XIRR natijalarini solishtiramiz:

Agar barcha to'lovlar muntazam vaqt oralig'ida amalga oshirilsa, funktsiyalar juda yaqin natijalarni qaytaradi:

Agar pul oqimlari vaqti bo'lsa teng bo'lmagan , natijalar orasidagi farq ancha sezilarli:

XIRR va Excelda XNPV

XIRR XNPV funktsiyasi bilan chambarchas bog'liq, chunki XIRR natijasi - nolga teng sof joriy qiymatga olib keladigan diskont stavkasi. Boshqacha qilib aytganda, XIRR - XNPV = 0. Quyidagi misol Excelda XIRR va XNPV o'rtasidagi munosabatni ko'rsatadi.

Aytaylik, siz investitsiya imkoniyatlarini ko'rib chiqyapsiz va sof joriy qiymat va ichki kursni o'rganmoqchisiz. ushbu investitsiyadan olingan daromad.

A2:A5dagi pul oqimlari, B2:B5 sanalari va E1dagi diskont stavkasi bilan quyidagi XNPV formulasi sizga kelajakdagi pul oqimlarining sof joriy qiymatini beradi:

=XNPV(E1, A2:A5, B2:B5)

Ijobiy NPV loyihaning foydali ekanligini ko'rsatadi:

Endi, sof joriy qiymatni qanday diskont stavkasi qilishini topamiz. nol. Buning uchun biz XIRR funksiyasidan foydalanamiz:

=XIRR(A2:A5, B2:B5)

XIRR tomonidan ishlab chiqarilgan stavka haqiqatan ham nol NPV ga olib kelishini tekshirish uchun uni stavka argumentiga qo'ying. sizning XNPVformula:

=XNPV(E4, A2:A5, B2:B5)

Yoki butun XIRR funksiyasini kiriting:

=XNPV(XIRR(A2:A5, B2:B5), A2:A5, B2:B5)

Ha, 2 kasrga yaxlitlangan XNPV nolga teng:

Aniq NPV qiymatini ko'rsatish uchun ko'proq o'nli kasrlarni ko'rsatishni tanlang yoki XNPV yacheykaga Ilmiy formatni qo'llang. Bu shunga o'xshash natija beradi:

Agar siz ilmiy belgilar bilan tanish bo'lmasangiz, uni o'nlik songa aylantirish uchun quyidagi hisob-kitoblarni bajaring:

1.11E-05 = 1.11*10^-5 = 0.0000111

Excel XIRR funksiyasi ishlamayapti

Agar siz Excelda XNPV funksiyasi bilan bog'liq muammoga duch kelgan bo'lsangiz, quyida tekshirilishi kerak bo'lgan asosiy fikrlar keltirilgan.

#NUM ! xato

#NUM xato quyidagi sabablarga ko'ra yuzaga kelishi mumkin:

• qiymatlar va sanalar diapazonlari turli uzunliklarga ega (har xil ustunlar yoki satrlar soni).
• qiymatlar massivida kamida bitta ijobiy va bitta salbiy qiymat mavjud emas.
• Keyingi sanalarning har biri birinchisidan oldinroq. sana.
• 100 ta takrorlashdan keyin natija topilmadi. Bunday holda, boshqacha taxmin qiling.

#VALUE! xato

#VALUE xatosi quyidagilardan kelib chiqishi mumkin:

• Taqdim etilgan qiymatlarning har biri raqamli emas.
• Ba'zilari berilgan sanalarni haqiqiy Excel sanalari sifatida aniqlash mumkin emas.

Excelda XIRRni shunday hisoblaysiz. Ushbu qo'llanmada muhokama qilingan formulalar bilan yaqindan tanishish uchun siz bizning namunamizni yuklab olishingiz mumkinquyida ish kitobi. O'qiganingiz uchun rahmat va keyingi haftada blogimizda ko'rishga umid qilaman!

Yuklab olish uchun mashq kitobi

XIRR Excel shablonini (.xlsx fayli)