Das Tutorial zeigt, wie man XIRR in Excel verwendet, um den internen Zinsfuß (IRR) für Cashflows mit unregelmäßigem Timing zu berechnen und wie man einen eigenen XIRR-Rechner erstellt.

Wenn Sie vor einer kapitalintensiven Entscheidung stehen, ist die Berechnung des internen Zinsfußes wünschenswert, weil Sie damit die voraussichtlichen Erträge verschiedener Investitionen vergleichen können und eine quantitative Grundlage für die Entscheidung erhalten.

In unserem vorangegangenen Tutorial haben wir uns angesehen, wie man den internen Zinsfuß mit der Excel-Funktion IRR berechnet. Diese Methode ist schnell und einfach, hat aber eine wesentliche Einschränkung: Die IRR-Funktion geht davon aus, dass alle Cashflows in gleichen Zeitintervallen, z. B. monatlich oder jährlich, auftreten. In der Praxis treten die Mittelzu- und -abflüsse jedoch oft in unregelmäßigen Abständen auf.Glücklicherweise verfügt Microsoft Excel über eine weitere Funktion zur Ermittlung des IRR in solchen Fällen, und in diesem Lernprogramm lernen Sie, wie man sie verwendet.

XIRR-Funktion in Excel

Die Excel-Funktion XIRR liefert den internen Zinsfuß für eine Reihe von Cashflows, die periodisch oder nicht periodisch sein können.

Die Funktion wurde in Excel 2007 eingeführt und ist in allen späteren Versionen von Excel 2010, Excel 2013, Excel 2016, Excel 2019 und Excel für Office 365 verfügbar.

Die Syntax der XIRR-Funktion lautet wie folgt:

Wo:

• Werte (erforderlich) - ein Array oder ein Bereich von Zellen, die eine Reihe von Zuflüssen und Abflüssen darstellen.
• Daten (erforderlich) - Daten, die den Cashflows entsprechen. Die Reihenfolge der Daten ist beliebig, aber das Datum der Erstinvestition muss an erster Stelle stehen.
• Erraten: (optional) - ein erwarteter interner Zinsfuß, der als Prozentsatz oder Dezimalzahl angegeben wird. Wird dieser Wert nicht angegeben, verwendet Excel den Standardwert von 0,1 (10 %).

Um beispielsweise den IRR für die Cashflow-Reihen A2:A5 und die Daten B2:B5 zu berechnen, würden Sie diese Formel verwenden:

=XIRR(A2:A5, B2:B5)

Tipp: Damit das Ergebnis korrekt angezeigt wird, stellen Sie bitte sicher, dass die Prozentsatz Format für die Formelzelle eingestellt ist.

6 Dinge, die Sie über die XIRR-Funktion wissen sollten

Die folgenden Hinweise sollen Ihnen helfen, die innere Mechanik der XIRR-Funktion besser zu verstehen und sie in Ihren Arbeitsblättern möglichst effizient einzusetzen.

1. XIRR in Excel dient zur Berechnung des internen Zinsfußes für Cashflows mit ungleichem Zeitpunkt. Für periodische Cashflows, bei denen die genauen Zahlungszeitpunkte unbekannt sind, können Sie die IRR-Funktion verwenden.
2. Der Wertebereich muss mindestens einen positiven (Einkommen) und einen negativen (Zahlungsausgang) Wert enthalten.
3. Handelt es sich bei dem ersten Wert um eine Ausgabe (Erstinvestition), so ist diese durch eine negative Zahl darzustellen. Die Erstinvestition wird nicht abgezinst; spätere Zahlungen werden auf den Zeitpunkt des ersten Cashflows zurückgeführt und auf der Grundlage eines Jahres mit 365 Tagen abgezinst.
4. Alle Datumsangaben werden zu ganzen Zahlen abgeschnitten, d. h. der Bruchteil eines Datums, der die Zeit darstellt, wird entfernt.
5. Bei den Datumsangaben muss es sich um gültige Excel-Datumsangaben handeln, die als Verweise auf Zellen mit Datumsangaben oder als Ergebnisse von Formeln wie der Funktion DATE eingegeben werden. Werden Datumsangaben im Textformat eingegeben, können Probleme auftreten.
6. XIRR in Excel gibt immer einen annualisierte IRR auch bei der Berechnung der monatlichen oder wöchentlichen Cashflows.

XIRR-Berechnung in Excel

Die XIRR-Funktion in Excel verwendet einen Trial-and-Error-Ansatz, um die Rate zu finden, die diese Gleichung erfüllt:

Wo:

• P - Cashflow (Zahlung)
• d - Datum
• i - Nummer des Zeitraums
• n - Perioden insgesamt

Beginnend mit der Schätzung, falls angegeben, oder mit den standardmäßigen 10 %, falls nicht, durchläuft Excel mehrere Iterationen, um das Ergebnis mit einer Genauigkeit von 0,000001 % zu erhalten. Wenn nach 100 Versuchen keine genaue Rate gefunden wird, wird der Fehler #NUM! zurückgegeben.

Um die Gültigkeit dieser Gleichung zu überprüfen, vergleichen wir sie mit dem Ergebnis der XIRR-Formel. Zur Vereinfachung unserer Berechnung verwenden wir die folgende Array-Formel (bitte denken Sie daran, dass jede Array-Formel durch Drücken von Strg + Umschalt + Enter abgeschlossen werden muss):

=SUM(A2:A5/((1+$E$1)^((B2:B5-$B$2)/365)))

Wo:

• A2:A5 sind die Zahlungsströme
• B2:B5 sind die Daten
• E1 ist der von XIRR ermittelte Satz

Wie der folgende Screenshot zeigt, liegt das Ergebnis sehr nahe bei Null. Q.E.D. :)

Wie man den XIRR in Excel berechnet - Formelbeispiele

Nachfolgend finden Sie einige Beispiele, die die gängige Verwendung der XIRR-Funktion in Excel veranschaulichen.

Grundlegende XIRR-Formel in Excel

Angenommen, Sie haben im Jahr 2017 1.000 $ investiert und erwarten in den nächsten 6 Jahren einen gewissen Gewinn. Um den internen Zinsfuß für diese Investition zu ermitteln, verwenden Sie diese Formel:

=XIRR(A2:A8, B2:B8)

Dabei sind A2:A8 die Zahlungsströme und B2:B8 die den Zahlungsströmen entsprechenden Daten:

Um die Rentabilität dieser Investition zu beurteilen, vergleichen Sie die XIRR-Ausgabe mit der Ihres Unternehmens gewichteter durchschnittlicher Kapitalkostensatz oder Hurdle Rate Wenn die Rendite höher ist als die Kapitalkosten, kann das Projekt als gute Investition betrachtet werden.

Wenn Sie mehrere Investitionsmöglichkeiten vergleichen, denken Sie bitte daran, dass die prognostizierte Rendite nur einer der Faktoren ist, die Sie vor einer Entscheidung schätzen sollten. Weitere Informationen finden Sie unter Was ist der interne Zinsfuß (IRR)?

Vollständige Form der Excel XIRR-Funktion

Wenn Sie wissen, welche Art von Rendite Sie von dieser oder jener Investition erwarten, können Sie Ihre Erwartung als Schätzung verwenden. Das ist besonders hilfreich, wenn eine offensichtlich korrekte XIRR-Formel einen #NUM!-Fehler auswirft.

Bei der unten gezeigten Dateneingabe ergibt eine XIRR-Formel ohne die Schätzung einen Fehler:

=XIRR(A2:A7, B2:B7)

Die erwartete Rücklaufquote (-20%), die in der erraten hilft Excel, das Ergebnis zu ermitteln:

=XIRR(A2:A7, B2:B7, -20%)

Wie berechnet man den XIRR für monatliche Cashflows?

Für den Anfang sollten Sie sich Folgendes merken: Unabhängig von den Cashflows, die Sie berechnen, erzeugt die XIRR-Funktion von Excel einen jährliche Rendite .

Um sich dessen zu vergewissern, ermitteln wir den IRR für dieselbe Reihe von Cashflows (A2:A8), die monatlich und jährlich auftreten (die Daten stehen in B2:B8):

=XIRR(A2:A8, B2:B8)

Wie Sie in der nachstehenden Abbildung sehen können, steigt der IRR von 7,68 % bei jährlichen Cashflows auf etwa 145 % bei monatlichen Cashflows! Der Unterschied scheint zu hoch, um allein durch den Zeitwert des Geldes gerechtfertigt zu sein:

Zur Ermittlung eines ungefähren monatliche XIRR können Sie die folgende Berechnung verwenden, wobei E1 das Ergebnis der regulären XIRR-Formel ist:

=(1+E1)^(1/12)-1

Oder Sie können XIRR direkt in die Gleichung einbetten:

=(1+XIRR(A2:A8,B2:B8))^(1/12)-1

Bitte beachten Sie, dass die IRR-Funktion ebenfalls einen Näherungswert berechnet, da sie davon ausgeht, dass alle Zeiträume gleich sind:

=IRR(A2:A8)

Als Ergebnis dieser Berechnungen erhalten wir eine monatliche XIRR von 7,77 %, die sehr nahe an den 7,68 % liegt, die sich aus der IRR-Formel ergeben:

Die Schlussfolgerung Wenn Sie einen annualisierten IRR für monatliche Cashflows suchen, verwenden Sie die XIRR-Funktion in ihrer reinen Form; um einen monatlichen IRR zu erhalten, wenden Sie die oben beschriebene Anpassung an.

Excel XIRR-Vorlage

Um den internen Zinsfuß für verschiedene Projekte schnell zu ermitteln, können Sie einen vielseitigen XIRR-Rechner für Excel erstellen. So geht's:

1. Geben Sie die Cashflows und Daten in zwei einzelne Spalten ein (in diesem Beispiel A und B).
2. Erstellen Sie zwei dynamisch definierte Bereiche mit den Namen Cash_flows und Daten Technisch gesehen handelt es sich dabei um benannte Formeln:

   Cash_flows:

   =OFFSET(Blatt1!$A$2,0,0,COUNT(Blatt1!$A:$A),1)

   Termine:

   =OFFSET(Blatt1!$B$2,0,0,COUNT(Blatt1!$B:$B),1)

   Wo Blatt1 ist der Name Ihres Arbeitsblatts, A2 ist der erste Cashflow und B2 ist das erste Datum.

   Eine ausführliche Schritt-für-Schritt-Anleitung finden Sie unter Wie man einen dynamischen benannten Bereich in Excel erstellt.

3. Geben Sie die dynamisch definierten Namen, die Sie erstellt haben, in die XIRR-Formel ein:

=XIRR(Cash_flows, Daten)

Sie können nun beliebig viele Cashflows hinzufügen oder entfernen, und Ihre dynamische XIRR-Formel wird entsprechend neu berechnet:

XIRR vs. IRR in Excel

Der Hauptunterschied zwischen den Excel-Funktionen XIRR und IRR ist der folgende:

• IRR Sie verwenden diese Funktion, um den internen Zinsfuß für periodische Cashflows wie monatliche, vierteljährliche oder jährliche Cashflows zu ermitteln.
• XIRR ermöglicht es Ihnen, jedem einzelnen Cashflow ein Datum zuzuordnen. Verwenden Sie diese Funktion also, um den IRR für Cashflows zu berechnen, die nicht unbedingt periodisch sind.

Wenn Sie die genauen Daten der Zahlungen kennen, ist es im Allgemeinen ratsam, den XIRR zu verwenden, da er eine bessere Berechnungsgenauigkeit bietet.

Lassen Sie uns als Beispiel die Ergebnisse von IRR und XIRR für dieselben Cashflows vergleichen:

Wenn alle Zahlungen zu folgenden Zeitpunkten erfolgen regelmäßige Intervalle liefern die Funktionen sehr ähnliche Ergebnisse:

Wenn der Zeitpunkt der Zahlungsströme ungleich ist der Unterschied zwischen den Ergebnissen ziemlich signifikant:

XIRR und XNPV in Excel

XIRR ist eng mit der Funktion XNPV verbunden, da das Ergebnis von XIRR der Abzinsungssatz ist, der zu einem Kapitalwert von Null führt. Mit anderen Worten: XIRR ist XNPV = 0. Das folgende Beispiel veranschaulicht die Beziehung zwischen XIRR und XNPV in Excel.

Angenommen, Sie erwägen eine Investitionsmöglichkeit und möchten sowohl den Kapitalwert als auch den internen Zinsfuß dieser Investition untersuchen.

Mit den Cashflows in A2:A5, den Daten in B2:B5 und dem Abzinsungssatz in E1 ergibt die folgende XNPV-Formel den Nettogegenwartswert der künftigen Cashflows:

=XNPV(E1, A2:A5, B2:B5)

Ein positiver Kapitalwert bedeutet, dass das Projekt rentabel ist:

Nun wollen wir herausfinden, welcher Abzinsungssatz den Nettogegenwartswert zu Null macht. Dazu verwenden wir die XIRR-Funktion:

=XIRR(A2:A5, B2:B5)

Um zu prüfen, ob der durch XIRR ermittelte Zinssatz wirklich zu einem Kapitalwert von Null führt, setzen Sie ihn in die Satz Argument Ihrer XNPV-Formel:

=XNPV(E4, A2:A5, B2:B5)

Oder betten Sie die gesamte XIRR-Funktion ein:

=XNPV(XIRR(A2:A5, B2:B5), A2:A5, B2:B5)

Ja, der XNPV ist auf 2 Dezimalstellen gerundet gleich Null:

Wenn Sie den genauen Kapitalwert anzeigen möchten, wählen Sie die Option, mehr Dezimalstellen anzuzeigen, oder wenden Sie das wissenschaftliche Format auf die Zelle XNPV an, um ein ähnliches Ergebnis zu erhalten:

Wenn Sie mit der wissenschaftlichen Notation nicht vertraut sind, führen Sie die folgende Berechnung durch, um sie in eine Dezimalzahl umzuwandeln:

1.11E-05 = 1.11*10^-5 = 0.0000111

Excel XIRR-Funktion funktioniert nicht

Wenn Sie ein Problem mit der XNPV-Funktion in Excel haben, sollten Sie die folgenden Punkte überprüfen.

#NUM!-Fehler

Ein #NUM-Fehler kann aus den folgenden Gründen auftreten:

• Die Werte und Daten Bereiche haben unterschiedliche Längen (unterschiedliche Anzahl von Spalten oder Zeilen).
• Die Werte Array nicht mindestens einen positiven und einen negativen Wert enthält.
• Jedes der nachfolgenden Daten liegt vor dem ersten Datum.
• Wenn nach 100 Iterationen kein Ergebnis gefunden wurde, versuchen Sie es mit einer anderen Schätzung.

#VALUE! error

Ein #VALUE-Fehler kann durch Folgendes verursacht werden:

• Eine der mitgelieferten Werte nicht nummerisch sind.
• Einige der angegebenen Daten können nicht als gültige Excel-Daten identifiziert werden.

So berechnen Sie die XIRR in Excel. Wenn Sie sich die in diesem Tutorial besprochenen Formeln genauer ansehen möchten, können Sie gerne unsere Beispiel-Arbeitsmappe herunterladen. Ich danke Ihnen für die Lektüre und hoffe, Sie nächste Woche in unserem Blog begrüßen zu dürfen!

Übungsheft zum Herunterladen

XIRR-Excel-Vorlage (.xlsx-Datei)